Télécharger phase_01.dgibi

Retour à la liste

Numérotation des lignes :

  1. * fichier : phase_01.dgibi
  2. optio norm auto;
  3. ************************************************************************
  4. ************************************************************************
  5.  
  6. ************************************************************************
  7. * Cas test : phase01.dgibi
  8. * --------
  9. *
  10. * Categorie : Verification & Validation (Formule Analytique)
  11. * ---------
  12. *
  13. * Description :
  14. * -----------
  15. * plaque 2D sur laquelle on applique 3 modeles
  16. * 1- Diffusion de la chaleur
  17. * 2- Changement de phase THERMIQUE à 'T' = 0°C & Qlat > 0
  18. * 3- Changement de phase THERMIQUE 'T' =100°C & Qlat > 0
  19. * 4- Changement de phase THERMIQUE 'T' =-2°C & Qlat = 0
  20. *
  21. * La temperature initiale est de -20°C
  22. *
  23. * Le point P1 est soumis alternativement a un flux impose positif puis
  24. * negatif.
  25. *
  26. * Les 3 phases evoluent simultanement
  27. *
  28. * Validation :
  29. * ----------
  30. * L'integrale de l'energie injectee par P1 au cours du temps doit etre
  31. * egale (a la precision machine pres) a la chaleur reguliere (RHO.CP)
  32. * plus la chaleur singuliere de changement de phase (Chaleur latente)
  33. *
  34. ************************************************************************
  35.  
  36.  
  37. GRAPH = FAUX;
  38. 'OPTI' 'TRAC' 'PSC';
  39. 'OPTI' 'DIME' 2 'ELEM' 'QUA4' 'MODE' plan ;
  40.  
  41. *************** Temperature de changement de phase ************************
  42. T_ch1 = 0. ;
  43. lat1 = 1000. * 334.00D3 ;
  44. T_ch2 = 100. ;
  45. lat2 = 1000. * 2264.76D3 ;
  46. T_ch3 =-2. ;
  47. lat3 = 0.D0 ;
  48.  
  49. *************** Geometrie *************************************************
  50. P1 = 0. 0. ;
  51. P2 = 5.e-3 0. ;
  52. P3 = 5.e-3 10.e-3 ;
  53. P4 = 0. 10.e-3 ;
  54.  
  55. n = 20 ;
  56. L23 = P2 'DROI' n P3 ;
  57. L41 = P4 'DROI' n P1 ;
  58. L14 ='INVE' L41 ;
  59.  
  60. PA ='POIN' L41 'PROC' (0. 2.5e-3) ;
  61.  
  62. n = 10 ;
  63. MQUA4= ('INVE' L41) 'REGL' n L23 ;
  64. MTRI3='CHAN' 'TRI3' (L23 'REGL' n (L23 'PLUS' P2));
  65.  
  66. su1 = MQUA4 'ET' MTRI3;
  67.  
  68. MPOI1='CHAN' 'POI1' su1 ;
  69. MPOI1='POIN' MPOI1 'DROI' P1 P2 1.D-10 ;
  70. L_BAS='ELEM' ('CONT' su1) 'APPU' 'STRI' MPOI1;
  71.  
  72. **************** Modeles et caracteristiques *********************************
  73. modth1 ='MODE' su1 'THERMIQUE' 'CONDUCTION' 'CONS' 'CON1' ;
  74. modph1 ='MODE' su1 'CHANGEMENT_PHASE' 'PARFAIT' 'INCO' 'T' 'Q' 'CONS' 'CHP1' ;
  75. modph2 ='MODE' su1 'CHANGEMENT_PHASE' 'PARFAIT' 'INCO' 'T' 'Q' 'CONS' 'CHP2' ;
  76. modph3 ='MODE' su1 'CHANGEMENT_PHASE' 'PARFAIT' 'INCO' 'T' 'Q' 'CONS' 'CHP3' ;
  77.  
  78. modtot = modth1 'ET' modph1 'ET' modph2 'ET' modph3 ;
  79.  
  80. rho1 = 4500. ;
  81. cp1 = 900. ;
  82. cd1 = rho1*cp1 ;
  83.  
  84. matth1 ='MATE' modth1 'C' cp1 'K' 50. 'RHO' rho1 ;
  85. matph1 ='MATE' modph1 'PRIM' T_ch1 'DUAL' lat1 ;
  86. matph2 ='MATE' modph2 'PRIM' T_ch2 'DUAL' lat2 ;
  87. matph3 ='MATE' modph3 'PRIM' T_ch3 'DUAL' lat3 ;
  88.  
  89. mattot = matth1 'ET' matph1 'ET' matph2 'ET' matph3 ;
  90.  
  91.  
  92. *************** Pas de temps "grossier" et fin ********************************
  93. * Durée totale
  94. TT1 = 1.2 ;
  95. TT2 = 2.0 ;
  96. dt1 = 0.1 ;
  97. *
  98. * pas de temps du début "grossier" jusqu'à Temps1 et ensuite fin jusqu'à Temps2 ;
  99. *
  100. Temps1 = 0.350e-3 ;
  101. Temps2 = 0.378e-3 ;
  102. Temps3 = 0.385e-3 ;
  103. listT = prog 0. 'PAS' dt1 TT1 'PAS' dt1 TT2;
  104. n1 = DIME listT ;
  105.  
  106. K1 = 1.D0 ;
  107. K2 =-1.D0 ;
  108. EvS = EVOL MANU 'TEMP' (PROG 0. TT1 (TT1+1.D-12) TT2) 'SOUR' (PROG K1 K1 K2 K2);
  109. 'SI' GRAPH;
  110. 'DESS' EvS 'TITR' 'Evolution chargement';
  111. 'FINS';
  112.  
  113. T_ini ='MANU' 'CHPO' su1 1 'T' -20. 'NATURE' 'DIFFUS' ;
  114. P_ini ='ZERO' modtot 'VARINTER' ;
  115.  
  116. 'SI' GRAPH ;
  117. 'TRAC' su1 T_ini 'TITR' 'Temperature initiale' ;
  118. 'FINS';
  119.  
  120. * CHARGEMENT
  121. srcth1 ='MANU' 'CHPO' ('MANU' 'POI1' P1) 1 'Q' 5.D4 ;
  122. charth1 ='CHAR' 'Q' srcth1 EvS ;
  123.  
  124. chartot = charth1 ;
  125.  
  126. * PASAPAS
  127. xtab = TABL ;
  128. xtab.'TEMPERATURES' = table ;
  129. xtab.'TEMPERATURES' . 0 = T_ini ;
  130. *xtab.'CELSIUS' = VRAI ;
  131. *xtab.'PROPORTIONS_PHASE' = TABL ;
  132. *xtab.'PROPORTIONS_PHASE'. 0= P_ini ;
  133. xtab.'MODELE' = modtot ;
  134. xtab.'CARACTERISTIQUES' = mattot ;
  135. xtab.'CHARGEMENT' = chartot ;
  136. xtab.'TEMPS_CALCULES' = listT ;
  137. xtab.'PROCESSEURS' ='MONOPROCESSEUR' ;
  138.  
  139. PASAPAS xtab ;
  140.  
  141. * POST-TRAITEMENT
  142. *'OPTI' 'EPTR' 10 ;
  143. csu1 ='CONT' su1 ;
  144. MCHLAT ='EXCO' mattot 'DUAL' 'PPHA' ;
  145.  
  146. NSAUV ='DIME' xtab.'TEMPERATURES' ;
  147.  
  148. LTEMP=VIDE 'LISTREEL' ;
  149. LTPS =VIDE 'LISTREEL' ;
  150. Pmoy1=VIDE 'LISTREEL' ;
  151. Pmoy2=VIDE 'LISTREEL' ;
  152. Pmoy3=VIDE 'LISTREEL' ;
  153.  
  154. LISOV=PROG 0. 'PAS' 0.01 3. ;
  155.  
  156. REPE SURI NSAUV;
  157. II =&SURI ;
  158. TPSi = xtab.'TEMPS' . (II-1) ;
  159. TEMPi= xtab.'TEMPERATURES' . (II-1) ;
  160. PROPi= xtab.'PROPORTIONS_PHASE'. (II-1) ;
  161.  
  162. TEMPi='EXCO' TEMPi 'T' 'T' ;
  163. T1 ='EXTR' TEMPi 'T' PA ;
  164.  
  165. PMi1 ='INTG' modph1 PROPi ;
  166. PMi2 ='INTG' modph2 PROPi ;
  167. PMi3 ='INTG' modph3 PROPi ;
  168.  
  169. LTPS =LTPS 'ET' TPSi ;
  170. LTEMP=LTEMP 'ET' T1 ;
  171. Pmoy1=Pmoy1 'ET' PMi1 ;
  172. Pmoy2=Pmoy2 'ET' PMi2 ;
  173. Pmoy3=Pmoy3 'ET' PMi3 ;
  174.  
  175. PROP_SOMME =('REDU' PROPi modph1) + ('CHAN' ('REDU' PROPi modph2) 'CONS' 'CHP1') + ('CHAN' ('REDU' PROPi modph3) 'CONS' 'CHP1');
  176. 'TRAC' PROP_SOMME modph1 'TITR' ('CHAI' 'Proportion sommee :' TPSi 's') LISOV ;
  177. 'FIN' SURI;
  178.  
  179. EVO2 = 'EVOL' 'ROUG' 'MANU' 'Tps' LTPS 'TPA ' LTEMP ;
  180. EVO3 =('EVOL' 'BLEU' 'MANU' 'Tps' LTPS 'PMO1' Pmoy1) 'ET'
  181. ('EVOL' 'BOUT' 'MANU' 'Tps' LTPS 'PMO2' Pmoy2) 'ET'
  182. ('EVOL' 'BRIQ' 'MANU' 'Tps' LTPS 'PMO3' Pmoy3) ;
  183. 'DESS' EVO2 ('CHAI' 'Temperature au point PA au cours du temps');
  184. 'DESS' EVO3 ('CHAI' 'Moyennes des proportions de phase au cours du temps');
  185.  
  186. * Bilan d'energie :
  187. E_ext ='MAXI' ('RESU' ((K1*srcth1*TT1) + (K2*srcth1*(TT2-TT1)))) ;
  188. E_reg ='INTG' modth1 ('CHAN' 'CHAM' modth1 (rho1 * cp1 * (TEMPi - T_ini))) ;
  189. MCHLA1 ='REDU' modph1 MCHLAT ;
  190. DELTA1 ='REDU' modph1 (PROPi - P_ini) ;
  191. E_sing1='INTG' modph1 (MCHLA1 * DELTA1) 'PPHA' ;
  192. MCHLA2 ='REDU' modph2 MCHLAT ;
  193. DELTA2 ='REDU' modph2 (PROPi - P_ini) ;
  194. E_sing2='INTG' modph2 (MCHLA2 * DELTA2) 'PPHA' ;
  195.  
  196.  
  197. 'SI'(E_ext 'NEG' 0.D0);
  198. ERR1 =(E_ext - (E_reg + E_sing1 + E_sing2)) / E_ext ;
  199. 'SINO';
  200. ERR1 = E_ext - (E_reg + E_sing1 + E_sing2) ;
  201. 'FINS';
  202.  
  203. CHAI1 ='CHAI' E_ext ' =?' (E_reg + E_sing1 + E_sing2) ' |' ERR1 ;
  204. 'MESS' CHAI1 ;
  205. 'SI' (('ABS' ERR1) >EG 1.D-14);
  206. 'ERRE' 5 ;
  207. 'FINS';
  208.  
  209. 'FIN';
  210.  
  211.  
  212.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales