Télécharger norton_cis1.dgibi

Retour à la liste

Numérotation des lignes :

  1. * fichier : norton_cis1.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4. * Test Norton_cis1.dgibi: Jeux de données *
  5. * --------------------------------------- *
  6. * *
  7. *
  8. **************************************************
  9. * *
  10. * TEST DE VALIDATION D'UNE LOI DE COMPORTEMENT *
  11. * -------------------------------------------- *
  12. * DE MATERIAU *
  13. * ----------- *
  14. * *
  15. * LOI DE COMPORTEMENT DE FLUAGE DE : *
  16. * NORTON *
  17. * *
  18. * TEST POUR DES ELEMENTS MASSIFS *
  19. * ------------------------------ *
  20. * *
  21. * MAILLAGE: *
  22. * UNE PLAQUE CARREE DE COTE L=1 M *
  23. * *
  24. * CHARGEMENT: *
  25. * CISAILLEMENT PUR *
  26. * FORCES IMPOSEES *
  27. * DEFORMATIONS PLANES *
  28. * *
  29. **************************************************
  30. opti echo 0 dime 2 elem qua4 ;
  31. *
  32. * Maillage
  33. *
  34. p1 = 0. 0. ;
  35. p2 = 1. 0. ;
  36. p3 = 1. 1. ;
  37. p4 = 0. 1. ;
  38. li1 = d p1 1 p2 ;
  39. li2 = d p2 1 p3 ;
  40. li3 = d p3 1 p4 ;
  41. li4 = d p4 1 p1 ;
  42. mail1 = 'SURF' ( li1 'ET' li2 'ET' li3 'ET' li4 ) 'PLAN' ;
  43. *
  44. * Modele
  45. *
  46. AF1 = 1.E-45 ;
  47. AF2 = 5. ;
  48. AF3 = 1.2 ;
  49. SMAX = 2.1E8 ;
  50. youn0 = 2.1E11 ;
  51. nu0 = .3 ;
  52. mod0 = 'MODE' mail1 'MECANIQUE' 'ELASTIQUE' 'ISOTROPE'
  53. 'FLUAGE' 'NORTON' ;
  54. mat0 = 'MATE' mod0 'YOUN' youn0 'NU' nu0 'AF1' AF1
  55. 'AF2' AF2 'AF3' AF3 'SMAX' SMAX ;
  56. *
  57. * Conditions aux limites
  58. *
  59. cl1 = 'BLOQ' mail1 'UY' ;
  60. cl2 = 'BLOQ' li1 'UX' ;
  61. cl0 = cl1 'ET' cl2 ;
  62. *
  63. * Chargement
  64. *
  65. depmax = 7.E7 ;
  66. *chp1 = 'COOR' 2 mail1 ;
  67. *chp1 = chp1 * depmax / 1. ;
  68. *chp1 = 'NOMC' chp1 'UX' ;
  69. *titr ' Champ de forces impose' ;
  70. *trace chp1 mail1 ;
  71. *chp2 = 'MANU' 'CHPO' mail1 1 'UY' 0. ;
  72. *chp0 = chp1 + chp2 ;
  73. dep1 = 'FORCE' li1 'FX' ( -1. * depmax ) 'FY' 0. ;
  74. dep2 = 'FORCE' li3 'FX' depmax 'FY' 0. ;
  75. dep0 = dep1 'ET' dep2 ;
  76. ev0 = 'EVOL' 'MANU' temps ( 'PROG' 0. 1.E-4 1000. )
  77. y ( 'PROG' 0. 1. 1. ) ;
  78. cha0 = 'CHAR' 'MECA' dep0 ev0 ;
  79. *
  80. dt0 = .020 ;
  81. dt1 = 2. * dt0 ;
  82. dt2 = 5. * dt1 ;
  83. dt3 = 5. * dt2 ;
  84. tfin0 = 20. ;
  85. *
  86. * Appel à PASAPAS
  87. *
  88. ta1 = 'TABLE' ;
  89. ta1 .'MODELE' = mod0 ;
  90. ta1 .'CARACTERISTIQUES' = mat0 ;
  91. ta1 .'CHARGEMENT' = cha0 ;
  92. ta1 .'BLOCAGES_MECANIQUES' = cl0 ;
  93. ta1 .'TEMPS_CALCULES' = ( 'PROG' 0. 'PAS' 1.E-4 2.E-4 ) 'ET'
  94. ( 'PROG' 3.E-4 dt0 ) 'ET'
  95.  
  96. ( 'PROG' dt1 'PAS' dt0 dt2 ) 'ET'
  97. ( 'PROG' ( dt2 + dt2 ) 'PAS' dt2 dt3 ) 'ET'
  98. ( 'PROG' ( dt3 + dt3 ) 'PAS' dt3 tfin0 ) ;
  99. *
  100. list ta1.'TEMPS_CALCULES';
  101. TMASAU=table;
  102. ta1 . 'MES_SAUVEGARDES'=TMASAU;
  103. TMASAU .'DEFTO'=VRAI;
  104. TMASAU .'DEFIN'=VRAI;
  105. PASAPAS ta1 ;
  106. *
  107. * Post traitement
  108. *
  109. dim0 = 'DIME' ta1 .'TEMPS' ;
  110. eps10 = 'PROG' 0. ;
  111. sigm10 = 'PROG' 0. ;
  112. def10 = 'PROG' 0. ;
  113. def_th2 = 'PROG' 0. ;
  114. sig_th2 = 'PROG' 0. ;
  115. err_e2 = 'PROG' 0. ;
  116. err_s2 = 'PROG' 0. ;
  117. temp2 = 'PROG' 0. ;
  118. rac0 = ( 3. ) ** ( .5 ) ;
  119. H0 = youn0 / ( 2. * ( 1. + nu0 ) ) ;
  120. *
  121. opti echo 1;
  122. prob0 = vrai ;
  123. 'REPETER' bloc0 ( dim0 - 1 ) ;
  124. i1 = &bloc0 ;
  125. *
  126. * Résultats calculés
  127. *
  128. def0 = ta1 .'DEFORMATIONS_INELASTIQUES'.i1 ;
  129. depl0 = ta1 .'DEPLACEMENTS'.i1 ;
  130. sigm0 = ta1 .'CONTRAINTES'.i1 ;
  131. temp0 = ta1 .'TEMPS'.i1 ;
  132. var0 = ta1 .'VARIABLES_INTERNES'.i1 ;
  133. eps0 = 'EPSI' mod0 depl0 ;
  134. eps1 = 'EXTR' ( 'EXCO' eps0 'GAXY' 'SCAL' ) 'SCAL' 1 1 1 ;
  135. sigm1 = 'EXTR' ( 'EXCO' sigm0 'SMXY' 'SCAL' ) 'SCAL' 1 1 1 ;
  136. def1 = 'EXTR' ( 'EXCO' def0 'GIXY' 'SCAL' ) 'SCAL' 1 1 1 ;
  137. eps10 = eps10 'ET' ( 'PROG' eps1 ) ;
  138. sigm10 = sigm10 'ET' ( 'PROG' sigm1 ) ;
  139. sigeq0 = 'VMIS' sigm0 mod0 ;
  140. sigeq1 = 'EXTR' sigeq0 'SCAL' 1 1 1 ;
  141. def10 = def10 'ET' ( 'PROG' def1 ) ;
  142. temp2 = temp2 'ET' ( 'PROG' temp0 ) ;
  143. var1 = 'EXTR' ( 'EXCO' var0 'EPSE' 'SCAL' ) 'SCAL' 1 1 1 ;
  144. sig0 = 'CHAN' 'CHPO' eps0 mod0 ;
  145. sigx = 'EXCO' sig0 'EPXX' ;
  146. sigy = 'EXCO' sig0 'EPYY' ;
  147. sigxy = 'EXCO' sig0 'GAXY' ;
  148. *titr ' Contraintes suivant X' ;
  149. *trace sigx mail1 ;
  150. *titr ' Contraintes suivant Y' ;
  151. *trace sigy mail1 ;
  152. *titr ' Contraintes de cisaillement' ;
  153. *trace sigxy mail1 ;
  154. *
  155. * Résultats analytiques
  156. *
  157. y2 = ( ( rac0 * depmax ) ** ( AF2 ) ) ;
  158. y2 = y2 * ( temp0 ** AF3 ) ;
  159. x2 = y2 * AF1 * rac0 ;
  160. *
  161. def_th1 = x2 ;
  162. sig_th1 = H0 * ( eps1 - x2 ) ;
  163. *
  164. def_th2 = def_th2 'ET' ( 'PROG' def_th1 ) ;
  165. sig_th2 = sig_th2 'ET' ( 'PROG' sig_th1 ) ;
  166. *mess ' sig calculée =' sigm1 ;
  167. *mess ' sig theorique =' sig_th1 ;
  168. *mess ' def calculée =' def1 ;
  169. *mess ' def théorique =' def_th1 ;
  170. *
  171. * Erreurs
  172. *
  173. 'SI' ( def1 '>' ( 1.E-1 * eps1 ) ) ;
  174. err_e1 = ( 'ABS' ( def1 - def_th1 ) ) / def1 ;
  175. err_e1 = err_e1 * 100. ;
  176. 'SINON' ;
  177. err_e1 = 0. ;
  178. 'FINSI' ;
  179. 'SI' ( sigm1 '>' 0. ) ;
  180. err_s1 = ( 'ABS' ( sigm1 - sig_th1 ) ) / sigm1 ;
  181. err_s1 = err_s1 * 100. ;
  182. 'SINON' ;
  183. err_s1 = 0. ;
  184. 'FINSI' ;
  185. *
  186. 'SI' ( ( err_e1 '>' .25 ) 'OU' ( err_s1 '>' .25 ) ) ;
  187. prob0 = faux ;
  188. mess 'err_e1 err_s1' err_e1 err_s1 ;
  189. 'FINSI' ;
  190. err_e2 = err_e2 'ET' ( 'PROG' err_e1 ) ;
  191. err_s2 = err_s2 'ET' ( 'PROG' err_s1 ) ;
  192. *
  193. 'MESS' ' Fin du calcul de restitution au temps ' temp0 ;
  194. *mess ' ' ;
  195. *
  196. 'FIN' bloc0 ;
  197. *
  198. defo0 = 'DEFO' mail1 depl0 0. ;
  199. defo1 = 'DEFO' mail1 depl0 1. 'ROUG' ;
  200. *titr ' deformee finale' ;
  201. *trace ( defo0 'ET' defo1 ) ;
  202. *
  203. 'SI' ( prob0 'EGA' faux ) ;
  204. 'ERRE' 5 ;
  205. 'SINON' ;
  206. 'ERRE' 0 ;
  207. 'FINSI' ;
  208. *
  209. * Tracés
  210. *
  211. evo1 = 'EVOL' 'MANU' 'epsp' def10 'sigm' sigm10 ;
  212. evo2 = 'EVOL' 'MANU' 'epsp' def_th2 'sigm' sig_th2 ;
  213. evo3 = 'EVOL' 'MANU' 'epsp' def10 'erreur_%' err_e2 ;
  214. evo4 = 'EVOL' 'MANU' 'epsp' def10 'erreur_%' err_s2 ;
  215. evo5 = 'EVOL' 'MANU' 'temps' temp2 'epsp' def10 ;
  216. evo6 = 'EVOL' 'MANU' 'temps' temp2 'epsp' def_th2 ;
  217. TAB = 'TABLE' ;
  218. TAB. 1 = 'MARQ CROI ' ;
  219. TAB. 2 = 'MARQ PLUS ' ;
  220. TAB.'TITRE' = 'TABLE' ;
  221. TAB.'TITRE'. 1 = MOT 'CALCUL' ;
  222. TAB.'TITRE'. 2 = MOT 'THEORIE' ;
  223. *'DESSIN' ( evo1 'ET' evo2 )
  224. *'TITR' ' Comparaison calcul theorie'
  225. *'LEGE' TAB ;
  226. TAB = 'TABLE' ;
  227. TAB. 1 = 'MARQ CROI ' ;
  228. *TAB. 2 = 'MARQ PLUS ' ;
  229. TAB.'TITRE' = 'TABLE' ;
  230. TAB.'TITRE'. 1 = MOT 'DEFORMATION' ;
  231. *TAB.'TITRE'. 2 = MOT 'CONTRAINTE' ;
  232. *'DESSIN' ( evo3 )
  233. *'TITR' ' Evolution des erreurs (en pourcentage) '
  234. *'LEGE' TAB ;
  235. TAB = 'TABLE' ;
  236. TAB. 1 = 'MARQ CROI ' ;
  237. TAB. 2 = 'MARQ PLUS ' ;
  238. TAB.'TITRE' = 'TABLE' ;
  239. TAB.'TITRE'. 1 = MOT 'CALCUL' ;
  240. TAB.'TITRE'. 2 = MOT 'THEORIE' ;
  241. *'DESSIN' ( evo5 'ET' evo6 )
  242. *'TITR' ' Comparaison calcul theorie, deformation-temps'
  243. *'LEGE' TAB ;
  244. *
  245. 'FIN' ;
  246.  
  247.  
  248.  
  249.  
  250.  
  251.  
  252.  
  253.  
  254.  
  255.  
  256.  
  257.  
  258.  
  259.  
  260.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales