Télécharger moontrac3d.dgibi

Retour à la liste

Numérotation des lignes :

  1. * fichier : moontrac3d.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4. *======================================================================*
  5. * MODELE HYPERELASTIQUE MOONEY RIVLIN QUASI-INCOMPRESSIBLE *
  6. * EN GRANDES TRANSFORMATIONS *
  7. * *
  8. * TEST DE VALIDATION DU MODELE : TRACTION (3D) SIMPLE SELON AXE Z *
  9. * COMPARAISON AVEC LA SOLUTION ANALYTIQUE INCOMPRESSIBLE *
  10. * *
  11. * Contribution de Laurent Gornet - Ecole Centrale de Nantes (2008) *
  12. *======================================================================*
  13. * Pour plus d'informations, voir la presentation de L. Gornet lors *
  14. * du Club Cast3m 2006, disponible sur le site Web de Cast3m. *
  15. *======================================================================*
  16. * Exemple d'utilisation d'un modele UMAT en grandes transformations *
  17. * *
  18. * Note : Actuellement en grandes deformations dans PASAPAS, le modele *
  19. * ne peut contenir que des modeles de type UMAT. On ne peut *
  20. * pas melanger les derivees objectives et les modeles de C3m. *
  21. *======================================================================*
  22.  
  23. 'OPTION' 'DIME' 3 'MODE' 'TRID' 'ECHO' 0 ;
  24. * Mettre VRAI si l'on souhaite divers traces.
  25. GRAPH = FAUX ;
  26. * Mettre 1 ou 2 selon le type de calcul voulu
  27. ICALCUL = 1 ;
  28. *
  29. 'SI' ('>' ICALCUL 2) ;
  30. 'MESS' 'ICALCUL doit valoir 1 ou 2' ;
  31. 'ERREUR' 5 ;
  32. 'FINSI' ;
  33.  
  34. title = 'CHAINE' 'MOONEY RIVLIN - ' 'TRACTION UNIAXIALE Z' ;
  35.  
  36. *======================================================================*
  37. * Geometrie - Maillage *
  38. *======================================================================*
  39. * Longueur (direction x) du pave :
  40. Lg_x = 1. ;
  41. * Largeur (direction y) du pave :
  42. Lg_y = 1. ;
  43. * Hauteur (direction z) du pave :
  44. Lg_z = 1. ;
  45. * Nombre d'elements selon les directions x, y et z :
  46. 'SI' ('EGA' ICALCUL 1) ;
  47. Nel_x = 2 ;
  48. Nel_y = 2 ;
  49. Nel_z = 2 ;
  50. 'OPTION' 'ELEM' 'CUB8' ;
  51. 'FINSI' ;
  52. 'SI' ('EGA' ICALCUL 2) ;
  53. Nel_x = 3 ;
  54. Nel_y = 3 ;
  55. Nel_z = 7 ;
  56. 'OPTION' 'ELEM' 'CU20' ;
  57. 'FINSI' ;
  58. *
  59. P1 = 0. 0. 0. ;
  60. P2 = Lg_x 0. 0. ;
  61. P3 = Lg_x Lg_y 0. ;
  62. P4 = 0. Lg_y 0. ;
  63. *
  64. L1 = 'DROITE' Nel_x P1 P2 ;
  65. L2 = 'DROITE' Nel_y P2 P3 ;
  66. L3 = 'DROITE' Nel_x P3 P4 ;
  67. L4 = 'DROITE' Nel_y P4 P1 ;
  68. *
  69. SBas = 'DALLER' L1 L2 L3 L4 ;
  70. Pave = 'VOLUME' SBas 'TRANS' Nel_z (0. 0. Lg_z) ;
  71. Shau = 'FACE' 2 Pave 'COULEUR' 'BLEU' ;
  72. 'SI' GRAPH ;
  73. 'TRACER' Pave 'TITRE' ('CHAINE' title ' - MAILLAGE') 'CACH' ;
  74. 'FINSI' ;
  75.  
  76. *======================================================================*
  77. * Modele - Materiau - Caracteristiques (en MPa) *
  78. *======================================================================*
  79. * Ne pas oublier de definir les parametres lies a l'elasticite.
  80. * Meme si ce n'est pas utilise dans le modele, cela est utile pour
  81. * l'operateur de convergence mecanique de PASAPAS-INCREME.
  82. *
  83. LCMAT = 'MOTS' 'YOUN' 'NU ' 'D ' 'C1' 'C2' ;
  84. MO = 'MODELISER' Pave 'MECANIQUE' 'ELASTIQUE' 'ISOTROPE'
  85. 'NON_LINEAIRE' 'UTILISATEUR'
  86. 'NUME_LOI' 31 'C_MATERIAU' LCMAT ;
  87. *
  88. * Coefficients du modele de Mooney-Rivlin (en MPa) :
  89. CoeC1 = 0.183 ; CoeC2 = 0.0034 ;
  90. * CoeC1 = 1. MPa et CoeD = 1.E-4 MPa**-1 !
  91. * Lorsque CoeD tend vers 0, on retrouve un modele de type Mooney-Rivlin
  92. * incompressible. Ici on met une valeur "petite" de CoeD pour pouvoir
  93. * utiliser la solution analytique du modele de Mooney-Rivlin correspon-
  94. * dant pour les tests de comparaison. Si CoeD a une valeur trop "impor-
  95. * tante", il faut modifier la valeur du coefficient de Poisson, qui
  96. * s'eloigne alors de 0.5 (incompressibilite).
  97. * On fixe le coefficient de Poisson ("proche" de 0.5 si D est "petit").
  98. * Le module de Young initial est alors connu :
  99. * (le module de cisaillement vaut pour ce modele : mu = 2.CoeC1)
  100. * La valeur du module de Young utilise pour les estimations elastiques
  101. * doit etre superieure au module tangent pour le niveau de deformation
  102. * atteint en fin de calcul (sinon risque de non convergence).
  103.  
  104. *XNU = 0.499 ;
  105. YOUini = 3.*(2.*(CoeC1+CoeC2)) ;
  106. *
  107. 'SI' ('EGA' ICALCUL 1) ;
  108. XNU = 0.497 ;
  109. CoeD = 1.E-4 ;
  110. YOU = 100. * YOUini ;
  111. 'FINSI' ;
  112. 'SI' ('EGA' ICALCUL 2) ;
  113. XNU = 0.495 ;
  114. CoeD = 1.E-2 ;
  115. YOU = 200. * YOUini ;
  116. 'FINSI' ;
  117. *
  118. MA = 'MATERIAU' MO 'YOUN' YOU 'NU ' XNU
  119. 'D ' CoeD 'C1 ' CoeC1 'C2 ' CoeC2 ;
  120.  
  121. *==================================================================*
  122. * Conditions aux limites *
  123. *==================================================================*
  124. BL1 = 'BLOQUER' 'UZ ' Shau ;
  125. BL2 = 'BLOQUER' 'UZ ' Sbas ;
  126. BL3 = 'BLOQUER' 'UX ' L4 ;
  127. BL4 = 'BLOQUER' 'UY ' L1 ;
  128. BLTOT = BL1 'ET' BL2 'ET' BL3 'ET' BL4 ;
  129. *
  130. * Definition des instants du chargement :
  131. t_deb = 0. ; t_fin = 10. ;
  132. L_tps = 'PROG' t_deb t_fin ;
  133. * Deplacement suivant Z :
  134. L_UZ = 'PROG' 0. (3.0 * Lg_z) ;
  135. FF_z = 'DEPIMP' BL1 1. ;
  136. EV_z = 'EVOL' 'MANU' 'TEMPS' L_tps 'LAMZ' L_UZ ;
  137. CHARTOT = 'CHARGEMENT' 'DIMP' FF_z EV_z ;
  138.  
  139. *======================================================================*
  140. * Initialisation de la table pour appel a PASAPAS *
  141. *======================================================================*
  142. TAB1 = 'TABLE' ;
  143. TAB1.'MODELE' = MO ;
  144. TAB1.'CARACTERISTIQUES' = MA ;
  145. TAB1.'BLOCAGES_MECANIQUES' = BLTOT ;
  146. TAB1.'CHARGEMENT' = CHARTOT ;
  147. *TAB1.'PRECISION' = 1.E-7 ;
  148. *TAB1.'FTOL' = 1.E-5 ;
  149. *TAB1.'MTOL' = 1.E-5 ;
  150. TAB1.'CONVERGENCE_FORCEE' = FAUX ;
  151. TAB1.'GRANDS_DEPLACEMENTS' = VRAI ;
  152. TAB1.'HYPOTHESE_DEFORMATIONS' = MOT 'UTILISATEUR' ;
  153. TAB1.'TEMPS_CALCULES' = 'PROG' t_deb 'PAS' 0.1 t_fin ;
  154. TAB1.'TEMPS_SAUVES' = 'PROG' t_deb 'PAS' 0.5 t_fin ;
  155. tab1.reac_grands=500.;
  156. *
  157. L_abs = TAB1.'TEMPS_SAUVES' ;
  158. n_abs = 'DIMENSION' L_abs ;
  159. *
  160. * pas de controle de positivite si on veut que le ct passe
  161. tab1.'STABILITE' = faux;
  162. PASAPAS TAB1 ;
  163. *
  164. * Quelques traces de controle apres calculs
  165. 'SI' GRAPH ;
  166. Defo_0 = 'DEFORMEE' Pave (TAB1.'DEPLACEMENTS'.(n_abs-1)) 0. ;
  167. Defo_1 = 'DEFORMEE' Pave (TAB1.'DEPLACEMENTS'.(n_abs-1)) 1. 'VERT' ;
  168. 'TRACER' (Defo_0 'ET' Defo_1)
  169. 'TITRE' ('CHAINE' title ' - DEFORMEES INITIALE ET FINALE') ;
  170. 'TRACER' MO (TAB1.'CONTRAINTES'.(n_abs-1))
  171. 'TITRE' ('CHAINE' title ' - CONTRAINTES EN FIN DE CALCUL') ;
  172. 'FINSI' ;
  173. *
  174. *======================================================================*
  175. * Construction de la solution analytique INCOMPRESSIBLE *
  176. *======================================================================*
  177. * Definitions :
  178. * - Allongement selon direction y : Lamy = 1 + (UY/Lg_y)
  179. * - Densite d'energie de deformation hyperelastique : W(I1,I2)
  180. * - I1, I2 : trois invariants du tenseur de Cauchy-Green droit
  181. * Dans le cas du modele Neo-Hookeen :
  182. * W = CoeC1*(I1-3.) , soit dW/dI1 = CoeC1 et dW/dI2 = 0.
  183. *
  184. * Les contraintes de Cauchy sont calculables analytiquement :
  185. * - SCxx = 0.
  186. * - SCyy = 2.(Lamy**2 - 1./Lamy).(dW/dI1 + 1./Lamy.dW/dI2)
  187. * - SCxy = 0 (pas de cisaillement)
  188. * - SCzz = 0 (hypothese des contraintes planes)
  189. *
  190. L_Un = 'PROG' n_abs '*' 1. ;
  191. Lamz = L_Un + (('IPOL' L_abs L_tps L_UZ) / Lg_z) ;
  192. *
  193. SCxx_th = 0. * L_Un ;
  194. SCyy_th = 0. * L_Un ;
  195. L_z1 = Lamz * Lamz ; L_z2 = L_Un / Lamz ;
  196. SCzz_th = (L_z1 - L_z2) * ((2.*CoeC1*L_Un) + (2.*CoeC2*L_z2)) ;
  197. SCxy_th = 0. * L_Un ;
  198. SCxz_th = 0. * L_Un ;
  199. SCyz_th = 0. * L_Un ;
  200. *
  201. *======================================================================*
  202. * Comparaison des resultats avec la solution analytique *
  203. *======================================================================*
  204. * La comparaison s'effectue entre les valeurs moyennes des contraintes
  205. * calculees et les solutions analytiques correspondantes.
  206. * On ne cherche pas a verifier l'uniformite du champ de contraintes.
  207. * (Faire le calcul en mettant GRAPH a VRAI et voir les isovaleurs !)
  208. *
  209. TabD = TAB1.'DEPLACEMENTS' ;
  210. TabS = TAB1.'CONTRAINTES' ;
  211. Confini = 'FORM' ;
  212. ChmUn = 'MANU' 'CHML' MO 'SCAL' 1. ;
  213. *
  214. SCxx = 'PROG' 0. ;
  215. SCyy = 'PROG' 0. ;
  216. SCzz = 'PROG' 0. ;
  217. SCxy = 'PROG' 0. ;
  218. SCxz = 'PROG' 0. ;
  219. SCyz = 'PROG' 0. ;
  220. 'REPETER' Boucle (n_abs - 1) ;
  221. 'FORM' (TabD.&Boucle) ;
  222. VolSU = 'INTG' MO ChmUn ;
  223. mess ' volsu ' volsu;
  224. SCxx = SCxx 'ET' ('PROG' (('INTG' MO (TabS. &Boucle) 'SMXX')/VolSU)) ;
  225. SCyy = SCyy 'ET' ('PROG' (('INTG' MO (TabS. &Boucle) 'SMYY')/VolSU)) ;
  226. SCzz = SCzz 'ET' ('PROG' (('INTG' MO (TabS. &Boucle) 'SMZZ')/VolSU)) ;
  227. SCxy = SCxy 'ET' ('PROG' (('INTG' MO (TabS. &Boucle) 'SMXY')/VolSU)) ;
  228. SCxz = SCxz 'ET' ('PROG' (('INTG' MO (TabS. &Boucle) 'SMXZ')/VolSU)) ;
  229. SCyz = SCyz 'ET' ('PROG' (('INTG' MO (TabS. &Boucle) 'SMYZ')/VolSU)) ;
  230. 'FORM' Confini ;
  231. 'FIN' Boucle ;
  232. *
  233. * LG lamb
  234. L_abs = Lamz;
  235. *
  236. 'SI' GRAPH ;
  237. tlege = 'TABLE' ;
  238. tlege. 1 = 'MARQ CROI' ;
  239. tlege.'TITRE' = 'TABLE' ;
  240. tlege.'TITRE'. 1 = 'Numerique' ;
  241. tlege.'TITRE'. 2 = 'Analytique' ;
  242. Evxx = 'EVOL' 'ROUG' 'MANU' 'LAMB' L_abs 'SCXX' SCxx ;
  243. Evxx_th = 'EVOL' 'BLEU' 'MANU' 'LAMB' L_abs 'SCXX' SCxx_th ;
  244. 'DESSIN' (Evxx 'ET' Evxx_th) 'LEGE' tlege
  245. 'TITRE' ('CHAINE' title ' - CONTRAINTE DE CAUCHY XX (Pa)') ;
  246. Evyy = 'EVOL' 'ROUG' 'MANU' 'LAMB' L_abs 'SCYY' SCyy ;
  247. Evyy_th = 'EVOL' 'BLEU' 'MANU' 'LAMB' L_abs 'SCYY' SCyy_th ;
  248. 'DESSIN' (Evyy 'ET' Evyy_th) 'LEGE' tlege
  249. 'TITRE' ('CHAINE' title ' - CONTRAINTE DE CAUCHY YY (Pa)') ;
  250. Evzz = 'EVOL' 'ROUG' 'MANU' 'LAMB' L_abs 'SCZZ' SCzz ;
  251. Evzz_th = 'EVOL' 'BLEU' 'MANU' 'LAMB' L_abs 'SCZZ' SCzz_th ;
  252. 'DESSIN' (Evzz 'ET' Evzz_th) 'LEGE' tlege
  253. 'TITRE' ('CHAINE' title ' - CONTRAINTE DE CAUCHY ZZ (Pa)') ;
  254. Evxy = 'EVOL' 'ROUG' 'MANU' 'LAMB' L_abs 'SCXY' SCxy ;
  255. Evxy_th = 'EVOL' 'BLEU' 'MANU' 'LAMB' L_abs 'SCXY' SCxy_th ;
  256. 'DESSIN' (Evxy 'ET' Evxy_th) 'LEGE' tlege
  257. 'TITRE' ('CHAINE' title ' - CONTRAINTE DE CAUCHY XY (Pa)');
  258. Evxz = 'EVOL' 'ROUG' 'MANU' 'LAMB' L_abs 'SCXZ' SCxz ;
  259. Evxz_th = 'EVOL' 'BLEU' 'MANU' 'LAMB' L_abs 'SCXZ' SCxz_th ;
  260. 'DESSIN' (Evxz 'ET' Evxz_th) 'LEGE' tlege
  261. 'TITRE' ('CHAINE' title ' - CONTRAINTE DE CAUCHY XY (Pa)');
  262. Evyz = 'EVOL' 'ROUG' 'MANU' 'LAMB' L_abs 'SCYZ' SCyz ;
  263. Evyz_th = 'EVOL' 'BLEU' 'MANU' 'LAMB' L_abs 'SCYZ' SCyz_th ;
  264. 'DESSIN' (Evyz 'ET' Evyz_th) 'LEGE' tlege
  265. 'TITRE' ('CHAINE' title ' - CONTRAINTE DE CAUCHY XY (Pa)');
  266. 'FINSI' ;
  267. *
  268. * Tests de bon fonctionnement :
  269. Smaxref = 'MAXIMUM' ('ABS' SCzz_th) ;
  270. r_xx = 'MAXIMUM' ('ABS' (SCxx - SCxx_th)) / Smaxref ;
  271. r_yy = 'MAXIMUM' ('ABS' (SCyy - SCyy_th)) / Smaxref ;
  272. r_zz = 'MAXIMUM' ('ABS' (SCzz - SCzz_th)) / Smaxref ;
  273. uu= ('ABS' (SCzz - SCzz_th)) / Smaxref;
  274. list sczz; list SCzz_th; list uu;
  275. r_xy = 'MAXIMUM' ('ABS' (SCxy - SCxy_th)) / Smaxref ;
  276. r_xz = 'MAXIMUM' ('ABS' (SCxz - SCxz_th)) / Smaxref ;
  277. r_yz = 'MAXIMUM' ('ABS' (SCyz - SCyz_th)) / Smaxref ;
  278. *
  279. MESS ' RESULTATS : ' title ;
  280. MESS ' ------------------------------------------------- ';
  281. 'SAUTER' 1 'LIGNE' ;
  282. 'MESS' ' Tests de bon fonctionnement :' ;
  283. 'MESS' ' -------------------------------' ;
  284. 'MESS' ' Comparaison effectuee sur les contraintes de Cauchy' ;
  285. 'MESS' ' Ecart relatif maximal entre la valeur moyenne calculee' ;
  286. 'MESS' ' et la solution analytique' ;
  287. 'MESS' ' Composante XX : ' r_xx ;
  288. 'MESS' ' Composante YY : ' r_yy ;
  289. 'MESS' ' Composante ZZ : ' r_zz ;
  290. 'MESS' ' Composante XY : ' r_xy ;
  291. 'MESS' ' Composante XZ : ' r_xz ;
  292. 'MESS' ' Composante YZ : ' r_yz ;
  293. 'SAUTER' 1 'LIGNE' ;
  294. * Ecart relatif maximal tolere
  295. 'SI' ('EGA' ICALCUL 1) ;
  296. Sigref = 1.E-3 ;
  297. 'FINSI' ;
  298. 'SI' ('EGA' ICALCUL 2) ;
  299. Sigref = 1.E-2 ;
  300. 'FINSI' ;
  301. *
  302. L_z = 'PROG' r_xx r_yy r_zz r_xy r_xz r_yz ;
  303. 'SI' ('>EG' ('MAXIMUM' L_z) Sigref) ;
  304. 'MESS' ' ---------------------' ;
  305. 'MESS' ' ECHEC DU CAS-TEST !' ;
  306. 'MESS' ' ---------------------' ;
  307. 'ERREUR' 5 ;
  308. 'SINON' ;
  309. 'MESS' ' ----------------------' ;
  310. 'MESS' ' SUCCES DU CAS-TEST !' ;
  311. 'MESS' ' ----------------------' ;
  312. 'FINSI' ;
  313. 'SAUTER' 1 'LIGNE' ;
  314.  
  315. 'FIN' ;
  316.  
  317.  
  318.  
  319.  
  320.  
  321.  
  322.  
  323.  
  324.  
  325.  
  326.  
  327.  
  328.  
  329.  
  330.  
  331.  
  332.  
  333.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales