Télécharger mistral_cp.dgibi

Retour à la liste

Numérotation des lignes :

  1. * fichier : mistral_cp.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4. *
  5. * Test mistral_cp.dgibi: Jeux de donnees *
  6. * --------------------------------------- *
  7. * *
  8. opti echo 0 ;
  9. opti dime 2 elem qua8 ;
  10. opti mode plan cont ;
  11. *
  12. *******************************************************
  13. * TEST DE VALIDATION *
  14. * ------------------ *
  15. * MODELE MISTRAL *
  16. * ELASTICITE ET PLASTICITE INSTANTANE *
  17. * *
  18. * MAILLAGE: *
  19. * EPROUVETTE RECTANGULAIRE *
  20. * *
  21. * CHARGEMENT: *
  22. * DEPLACEMENT LATERAL IMPOSE MONOTONE CROISSANT *
  23. *******************************************************
  24. *
  25. * Geometrie
  26. *
  27. * ------------------------------------------
  28. XX = 1. ; YY = 0.5 ;
  29. * ------------------------------------------
  30. *
  31. P00 = 0. 0. ; P10 = XX 0. ;
  32. P11 = XX YY ; P01 = 0. YY ;
  33. *
  34. LX0 = droi 1 P00 P10 ;
  35. LY1 = droi 1 P10 P11 ;
  36. LX1 = droi 1 P11 P01 ;
  37. LY0 = droi 1 P01 P00 ;
  38. *
  39. * Maillage
  40. *
  41. EPROU = dall LX0 LY1 LX1 LY0 ;
  42. * trac EPROU ;
  43. *
  44. * Modele et materiau
  45. *
  46. MODL = mode EPROU mecanique elastique orthotrope
  47. viscoplastique mistral ;
  48. * ------------------------------------------------------------
  49. VEC1 = 1. 1. ; TETA = 45. ;
  50. SENSIP1 = -2 ; SENSIP2 = 1 ; ICBASE = 0 ;
  51. fichier = '/u2/castem/divers/mimatcp_par' ;
  52. PDILT E1 E2 E3 NU12 NU23 NU13 MU12 MU23 MU13
  53. PNBRE PCOHI PECOU PEDIR PRVCE PECRX PDVDI PCROI PINCR
  54. = @mistpar fichier SENSIP1 SENSIP2 ;
  55. * ------------------------------------------------------------
  56. MATER = mate MODL
  57. 'YG1 ' E1 'YG2 ' E2 'YG3 ' E3
  58. 'NU12' NU12 'NU23' NU23 'NU13' NU13
  59. 'G12 ' MU12
  60. 'ALP1' 0. 'ALP2' 0. 'TALP' 0. 'TREF' 300.
  61. 'DILT' PDILT 'NBRE' PNBRE 'COHI' PCOHI 'ACOU' PECOU 'EDIR' PEDIR
  62. 'RVCE' PRVCE 'ECRX' PECRX 'DVDI' PDVDI 'CROI' PCROI 'INCR' PINCR
  63. 'SIP1' SENSIP1 'SIP2' SENSIP2 'IBAS' ICBASE
  64. 'DIRECTION' VEC1 'INCLINE' TETA ;
  65. *
  66. * Conditions aux limites
  67. *
  68. CLX0 = bloq ux LX0 ;
  69. CLX1 = bloq ux LX1 ;
  70. CLY0 = bloq uy LY0 ;
  71. CLY1 = bloq uy LY1 ;
  72. CL = CLX0 et CLX1 et CLY0 et CLY1 ;
  73. *
  74. * Chargement
  75. *
  76. * -------------------------------------------------------
  77. T1 = 100. ; DT1 = 10. ;
  78. EPSXY1 = 0.01 ;
  79. TT0 = 300. ; TT1 = TT0 ;
  80. PHIT0 = 0. ;
  81. * -------------------------------------------------------
  82. TEMPS = prog 0. T1 ;
  83. TEMPSCAL = prog 0. pas DT1 T1 ;
  84. *
  85. DEPX = depi CLX1 YY ;
  86. DEPY = depi CLY1 XX ;
  87. EVEPS = evol manu TEMPS (prog 0. EPSXY1) ;
  88. CHADE = char dimp (DEPX et DEPY) EVEPS ;
  89. *
  90. TT = manu chpo EPROU 1 'T' 1. ;
  91. EVTT = evol manu TEMPS (prog TT0 TT1) ;
  92. CHTT = char 'T' TT EVTT ;
  93. *
  94. PHI = manu chpo EPROU 1 'FI' 1. ;
  95. EVFI = evol manu TEMPS (prog 0. 0.) ;
  96. CHFI = char 'FI' PHI EVFI ;
  97. *
  98. CHA = CHADE et CHTT et CHFI ;
  99. *
  100. * Valeurs initiales
  101. *
  102. VINT0 = zero MODL 'VARINTER' ;
  103. FIT0 = manu chml MODL 'FIT ' PHIT0 type 'SCALAIRE' 'STRESSES' ;
  104. VINT0 = VINT0 + FIT0 ;
  105. *
  106. * Calcul
  107. *
  108. TAB = TABLE ;
  109. TAB.'VARIABLES_INTERNES' = TABLE ;
  110. TAB.'BLOCAGES_MECANIQUES' = CL ;
  111. TAB.'CARACTERISTIQUES' = MATER ;
  112. TAB.'MODELE' = MODL ;
  113. TAB.'CHARGEMENT' = CHA ;
  114. TAB.'VARIABLES_INTERNES' . 0 = VINT0 ;
  115. TAB.'TEMPS_CALCULES' = TEMPSCAL ;
  116. TAB.'HYPOTHESE_DEFORMATIONS' = 'LINEAIRE' ;
  117. PASAPAS TAB ;
  118. *
  119. * Traitement des resultats
  120. *
  121. SIG = TAB.'CONTRAINTES' ;
  122. DEP = tab.'DEPLACEMENTS' ;
  123. VI = tab.'VARIABLES_INTERNES' ;
  124. NT = dime TEMPSCAL-1 ;
  125. * ----------------
  126. ERMAX = 0.001 ;
  127. * ----------------
  128. *
  129. SIGT = SIG.NT ;
  130. SIGT_PO = chang chpo MODL SIGT ;
  131. SIGXX = extr SIGT_PO SMXX P00 ;
  132. SIGYY = extr SIGT_PO SMYY P00 ;
  133. SIGZZ = extr SIGT_PO SMZZ P00 ;
  134. SIGXY = extr SIGT_PO SMXY P00 ;
  135. *
  136. DEPT = DEP.NT ;
  137. EPSIT = epsi DEPT MODL 'LINE' ;
  138. EPSIT_PO = chang chpo MODL EPSIT ;
  139. EPSXX = extr EPSIT_PO EPXX P00 ;
  140. EPSYY = extr EPSIT_PO EPYY P00 ;
  141. EPSZZ = extr EPSIT_PO EPZZ P00 ;
  142. EPSXY = (extr EPSIT_PO GAXY P00)/2. ;
  143. *
  144. VIT = VI.NT ;
  145. VIT_PO = chang chpo MODL VIT ;
  146. EPSP11 = extr VIT_PO EP01 P00 ;
  147. EPSP22 = extr VIT_PO EP02 P00 ;
  148. EPSP33 = extr VIT_PO EP03 P00 ;
  149. EPSP12 = extr VIT_PO EP04 P00 ;
  150. EPSP13 = extr VIT_PO EP05 P00 ;
  151. EPSP23 = extr VIT_PO EP06 P00 ;
  152. *
  153. mess ;
  154. mess 'SIGXX SIGYY SIGZZ : ' SIGXX SIGYY SIGZZ ;
  155. mess 'SIGXY : ' SIGXY ;
  156. mess ;
  157. mess 'EPSXX EPSYY EPSZZ : ' EPSXX EPSYY EPSZZ ;
  158. mess 'EPSXY : ' EPSXY ;
  159. mess ;
  160. mess 'EPSP11 EPSP22 EPSP33 : ' EPSP11 EPSP22 EPSP33 ;
  161. mess 'EPSP12 EPSP13 EPSP23 : ' EPSP12 EPSP13 EPSP23 ;
  162. mess ;
  163.  
  164. * SIGT_XY = exco SIGT 'SMXY' ;
  165. * trac SIGT_XY MODL ;
  166. * GAMA_XY = exco EPSIT 'GAXY' ;
  167. * trac GAMA_XY MODL ;
  168. * ------------------------------------------------------------
  169. MUXY = 4.E10 ;
  170. * ------------------------------------------------------------
  171. AA = 400.E6 ; BB = 1.E10 ;
  172. A0 = AA/(2.*MUXY) ;
  173. A1 = 1. + (BB/MUXY) ;
  174. EPSPXY1 = (EPSXY1-A0)/A1 ;
  175. SIGXY1 = AA + (2.*BB*EPSPXY1) ;
  176. EPSEXY1 = SIGXY1/(2.*MUXY) ;
  177. * -----------------------------------------------------
  178. *
  179. ERSIGXY = ABS( (SIGXY/SIGXY1) - 1. ) ;
  180. EREPSXY = ABS( (EPSXY/EPSXY1) - 1. ) ;
  181. EREPSPXY = ABS( (EPSP12/EPSPXY1) - 1. ) ;
  182. *
  183. si (ERSIGXY > ERMAX) ;
  184. mess ;
  185. mess 'ABS(erreur relative) sur la contrainte > ' ERMAX ;
  186. mess ERSIGXY ;
  187. finsi ;
  188. si (EREPSXY > ERMAX) ;
  189. mess ;
  190. mess 'ABS(erreur relative) sur la deformation > ' ERMAX ;
  191. mess EREPSXY ;
  192. finsi ;
  193. si (EREPSPXY > ERMAX) ;
  194. mess ;
  195. mess 'ABS(erreur relative) sur la deformation plastique > ' ERMAX ;
  196. mess EREPSPXY ;
  197. mess ;
  198. finsi ;
  199. P_ER = prog ERSIGXY EREPSXY EREPSPXY ;
  200. ERMA = maxi P_ER ;
  201. si (ERMA > ERMAX) ;
  202. ERRE 5 ;
  203. finsi ;
  204.  
  205. fin ;
  206.  
  207.  
  208.  
  209.  
  210.  
  211.  
  212.  
  213.  
  214.  
  215.  
  216.  
  217.  
  218.  
  219.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales