Télécharger la plaquette Cast3M


fr en

Télécharger mistral_D3d.dgibi

Retour à la liste

Numérotation des lignes : 

  1. * fichier :  mistral_D3d.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4. *
  5. *     Test mistral_D3d.dgibi: Jeux de donnees         *
  6. *     ---------------------------------------         *
  7. *                                                     *
  8. * repertoire des fichiers "divers"
  9. DIVERS = VENV 'CASTEM_DIVERS';
  10. *
  11.   opti echo 0 ;
  12.   opti dime 3 mode tridim elem cu20 ;
  13.  
  14. *
  15. *******************************************************
  16. *                TEST DE VALIDATION                   *
  17. *                ------------------                   *
  18. *  MODELE MISTRAL                                     *
  19. *    ELASTICITE ET PLASTICITE INSTANTANEE             *
  20. *                                                     *
  21. *  MAILLAGE:                                          *
  22. *     EPROUVETTE CUBIQUE                              *
  23. *                                                     *
  24. *  CHARGEMENT:                                        *
  25. *     DEPLACEMENT IMPOSE MONOTONE CROISSANT           *
  26. *******************************************************
  27. *
  28. * Geometrie
  29. *
  30. * ------------------------------------------
  31.   XX = 1. ; YY = 1. ; ZZ = 1. ;
  32. * ------------------------------------------
  33. *
  34.    PB00 = 0 0 0    ;  PB10 = XX 0 0 ;
  35.    PB11 = XX YY 0  ;  PB01 = 0 YY 0 ;
  36.    VECZ = 0 0 ZZ ;
  37. *
  38.    LBX0 = droi 1 PB00 PB10 ;
  39.    LBY1 = droi 1 PB10 PB11 ;
  40.    LBX1 = droi 1 PB11 PB01 ;
  41.    LBY0 = droi 1 PB01 PB00 ;
  42. *
  43. * Maillage
  44. *
  45.    PLB = dall LBX0 LBY1 LBX1 LBY0 plan ;
  46.    EPROU = PLB volu 1 tran VECZ ;
  47.    PLH = face 2 EPROU ;
  48.    PL0YZ = EPROU poin plan PB00 PB01 VECZ 1E-3 ;
  49.    PLX0Z = EPROU poin plan PB00 PB10 VECZ 1E-3 ;
  50. *   trac EPROU ;
  51. *
  52. * Modele et materiau
  53. *
  54.    MOD3 = mode EPROU mecanique elastique orthotrope
  55.                                viscoplastique mistral ;
  56. *
  57. * ------------------------------------------------------------
  58.   VEC1 = 1. 1. 0. ; VEC2 = -1. 1. 0. ; TETA = 45. ;
  59.   SENSIP1 = -2 ; SENSIP2 = 1 ; ICBASE = 0 ;
  60.   fichier = 'CHAINE' DIVERS '/mimatD3d_par' ;
  61.   PDILT    E1 E2 E3 NU12 NU23 NU13 MU12 MU23 MU13
  62.   PNBRE PCOHI PECOU PEDIR PRVCE PECRX PDVDI PCROI PINCR
  63.     = @mistpar fichier SENSIP1 SENSIP2 ;
  64. * ------------------------------------------------------------
  65.   MAT3 = mate MOD3  'YG1 ' E1    'YG2 ' E2   'YG3 ' E3
  66.                     'NU12' NU12  'NU23' NU23 'NU13' NU13
  67.                     'G12 ' MU12  'G13 ' MU13 'G23 ' MU23
  68.                     'ALP1' 0.    'ALP2' 0.   'ALP3' 0. 'TALP' 0. 'TREF' 300.
  69.  'DILT' PDILT 'NBRE' PNBRE 'COHI' PCOHI 'ACOU' PECOU 'EDIR' PEDIR
  70.  'RVCE' PRVCE 'ECRX' PECRX 'DVDI' PDVDI 'CROI' PCROI 'INCR' PINCR
  71.                     'SIP1' SENSIP1  'SIP2' SENSIP2  'IBAS' ICBASE
  72.                     'DIRECTION' VEC1 VEC2 'INCLINE' TETA ;
  73. *
  74. * Conditions aux limites
  75. *
  76.    CLB = bloq uz PLB ;
  77.    CLH = bloq uz PLH ;
  78.    CLYZ = bloq ux PL0YZ ;
  79.    CLXZ = bloq uy PLX0Z ;
  80.    CL = CLB et CLH et CLYZ et CLXZ ;
  81. *
  82. * Chargement
  83. *
  84. * -------------------------------------------------------
  85.    T1 = 100. ; DT1 = 10. ;
  86.    EPSZZ1 = 0.02 ;
  87.    TT1 = 300. ;
  88.    PHIT0 = 0. ;
  89. * -------------------------------------------------------
  90.    TEMPS = prog 0. T1 ;
  91.    TEMPSCAL = prog 0. pas DT1 T1 ;
  92. *
  93.    DEPZ = depi CLH ZZ ;
  94.    EVEPS = evol manu TEMPS (prog 0. EPSZZ1) ;
  95.    CHADE = char dimp DEPZ EVEPS ;
  96. *
  97.    TT = manu chpo EPROU 1 'T' 1. ;
  98.    EVTT = evol manu TEMPS (prog TT1 TT1) ;
  99.    CHTT = char 'T' TT EVTT ;
  100. *
  101.    PHI = manu chpo EPROU 1 'FI' 1. ;
  102.    EVFI = evol manu TEMPS (prog 0. 0.) ;
  103.    CHFI = char 'FI' PHI EVFI ;
  104. *
  105.    CHA = CHADE et CHTT et CHFI ;
  106. *
  107. * Valeurs initiales
  108. *
  109.    VINT0 = zero MOD3 'VARINTER' ;
  110.    FIT0 = manu chml MOD3 'FIT ' PHIT0 type 'SCALAIRE' 'STRESSES' ;
  111.    VINT0 = VINT0 + FIT0 ;
  112. *
  113. * Calcul
  114. *
  115.    TAB = TABLE ;
  116.    TAB.'VARIABLES_INTERNES' = TABLE ;
  117.    TAB.'BLOCAGES_MECANIQUES' = CL ;
  118.    TAB.'CARACTERISTIQUES' = MAT3 ;
  119.    TAB.'MODELE' = MOD3 ;
  120.    TAB.'CHARGEMENT' = CHA ;
  121.    TAB.'VARIABLES_INTERNES' . 0 = VINT0 ;
  122.    TAB.'TEMPS_CALCULES' = TEMPSCAL ;
  123.    TAB.'HYPOTHESE_DEFORMATIONS' = 'LINEAIRE' ;
  124. *
  125.    PASAPAS TAB ;
  126. *
  127. * Traitement des resultats
  128. *
  129.    SIG = TAB.'CONTRAINTES' ;
  130.    DEP = tab.'DEPLACEMENTS' ;
  131.    VI  = tab.'VARIABLES_INTERNES' ;
  132.    NT = dime TEMPSCAL-1 ;
  133. * ----------------
  134.    ERMAX = 0.005 ;
  135. * ----------------
  136. *
  137.    SIGT = SIG.NT ;
  138.    SIGT_PO = chang chpo MOD3 SIGT ;
  139.    SIGXX = extr SIGT_PO SMXX PB00 ;
  140.    SIGYY = extr SIGT_PO SMYY PB00 ;
  141.    SIGZZ = extr SIGT_PO SMZZ PB00 ;
  142.    SIGXY = extr SIGT_PO SMXY PB00 ;
  143.    SIGXZ = extr SIGT_PO SMXZ PB00 ;
  144.    SIGYZ = extr SIGT_PO SMYZ PB00 ;
  145. *
  146.    DEPT = DEP.NT ;
  147.    EPSIT = epsi DEPT MOD3 'LINE' ;
  148.    EPSIT_PO = chang chpo MOD3 EPSIT ;
  149.    EPSXX = extr EPSIT_PO EPXX PB00 ;
  150.    EPSYY = extr EPSIT_PO EPYY PB00 ;
  151.    EPSZZ = extr EPSIT_PO EPZZ PB00 ;
  152.    EPSXY = (extr EPSIT_PO GAXY PB00)/2. ;
  153.    EPSXZ = (extr EPSIT_PO GAXZ PB00)/2. ;
  154.    EPSYZ = (extr EPSIT_PO GAYZ PB00)/2. ;
  155. *
  156.    VIT = VI.NT ;
  157.    VIT_PO = chang chpo MOD3 VIT ;
  158.    EPSP11 = extr VIT_PO EP01 PB00 ;
  159.    EPSP22 = extr VIT_PO EP02 PB00 ;
  160.    EPSP33 = extr VIT_PO EP03 PB00 ;
  161.    EPSP12 = extr VIT_PO EP04 PB00 ;
  162.    EPSP13 = extr VIT_PO EP05 PB00 ;
  163.    EPSP23 = extr VIT_PO EP06 PB00 ;
  164. *
  165.    mess ;
  166.    mess 'SIGXX SIGYY SIGZZ :    ' SIGXX SIGYY SIGZZ ;
  167.    mess 'SIGXY SIGXZ SIGYZ :    ' SIGXY SIGXZ SIGYZ ;
  168.    mess ;
  169.    mess 'EPSXX EPSYY EPSZZ :    ' EPSXX EPSYY EPSZZ ;
  170.    mess 'EPSXY EPSXZ EPSYZ :    ' EPSXY EPSXZ EPSYZ ;
  171.    mess ;
  172.    mess 'EPSP11 EPSP22 EPSP33 : ' EPSP11 EPSP22 EPSP33 ;
  173.    mess 'EPSP12 EPSP13 EPSP23 : ' EPSP12 EPSP13 EPSP23 ;
  174.    mess ;
  175. *
  176. * -----------------------------------------------------
  177.    SIGZZ1 = 486970389. ;
  178.    EPSP331 = 0.01513029 ;
  179.    YOUNGX = 1.E11 ; YOUNGY = 1.E11 ; YOUNGZ = 1.E11 ;
  180.    POISYZ = 0.2 ; POISZX = 0.4 ;
  181. * -----------------------------------------------------
  182.    EPSEZZ1 = SIGZZ1/YOUNGZ ;
  183.    EPSEXX1 = (-1.)*(POISZX/YOUNGZ)*SIGZZ1 ;
  184.    EPSEYY1 = (-1.)*(POISYZ/YOUNGY)*SIGZZ1 ;
  185.    EPSP111 = (-0.6)*EPSP331 ;
  186.    EPSP221 = (-0.4)*EPSP331 ;
  187.    EPSXX1 = EPSEXX1 + EPSP111 ;
  188.    EPSYY1 = EPSEYY1 + EPSP221 ;
  189.    EPSZZ1 = EPSEZZ1 + EPSP331 ;
  190. *
  191.    ERSIGZZ = ABS(SIGZZ/SIGZZ1 - 1.) ;
  192. *
  193.    EREPSXX = EPSXX/EPSXX1 - 1. ;
  194.    EREPSYY = EPSYY/EPSYY1 - 1. ;
  195.    EREPSZZ = EPSZZ/EPSZZ1 - 1. ;
  196.    P_ER = prog EREPSXX EREPSYY EREPSZZ ;
  197.    EREPSMA = maxi P_ER 'ABS' ;
  198. *
  199.    EREPSP11 = EPSP11/EPSP111 - 1. ;
  200.    EREPSP22 = EPSP22/EPSP221 - 1. ;
  201.    EREPSP33 = EPSP33/EPSP331 - 1. ;
  202.    P_ER = prog EREPSP11 EREPSP22 EREPSP33 ;
  203.    EREPSPMA = maxi P_ER 'ABS' ;
  204. *
  205.    si (ERSIGZZ > ERMAX) ;
  206.     mess ;
  207.     mess 'ABS(erreur relative) sur la contrainte > ' ERMAX ;
  208.     mess  ERSIGZZ ;
  209.    finsi ;
  210.    si (EREPSMA > ERMAX) ;
  211.     mess ;
  212.     mess 'ABS(erreur relative) sur une deformation totale > ' ERMAX ;
  213.     mess EREPSXX EREPSYY EREPSZZ ;
  214.    finsi ;
  215.    si (EREPSPMA > ERMAX) ;
  216.     mess ;
  217.     mess 'ABS(erreur relative) sur une deformation plastique > ' ERMAX ;
  218.     mess EREPSP11 EREPSP22 EREPSP33 ;
  219.     mess ;
  220.    finsi ;
  221.    P_ER = prog ERSIGZZ EREPSMA EREPSPMA ;
  222.    ERMA = maxi P_ER ;
  223.    si (ERMA > ERMAX) ;
  224.     ERRE 5 ;
  225.    finsi ;
  226.  
  227.    fin ;
  228.  
  229.  
  230.  
  231.  
  232.  
  233.  
  234.  
  235.  
  236.  
  237.  
  238.  
  239.  
  240.  
  241.  
  242.  
  243.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales