Télécharger metallurgie_14.dgibi

Retour à la liste

Numérotation des lignes :

  1. * fichier : metallurgie_06.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4.  
  5. *__________________________________________________________________*
  6. * TEST METALLURGIE_14 *
  7. * *
  8. * CALCUL DES PROPORTIONS DE PHASE METALLURGIQUE *
  9. * *
  10. * Un MODELE thermo-metallurgique est cree et l'essai JOMINY *
  11. * est simule en 2D Axisymétrique *
  12. * *
  13. * Le modèle métallurgique est codé en ESOPE (Cast3m) *
  14. * Utilisation de PASAPAS et d'une procedure utilisateur : *
  15. * - Procédure PARATHER : Mise a jour du matériaux THERMIQUE *
  16. * avec la proportion de phase. *
  17. * Mise a jour du chargement 'TPOI' *
  18. * *
  19. * Le modèle métallurgique contient 5 phases ayant des cinétiques *
  20. * de transformation différentes *
  21. * - Metal de Base (MB) *
  22. * - Austénite *
  23. * - Martensite *
  24. * - Bainite *
  25. * - Ferrite *
  26. *__________________________________________________________________*
  27. * MAILLAGE : *
  28. * - Eprouvette cylindrique de hauteur 100mm et de rayon 12,5mm *
  29. * P4 _____ P3 *
  30. * | J | ^ *
  31. * | O | | *
  32. * | M | | *
  33. * | I | | h0 Y *
  34. * | N | | ^ *
  35. * | Y | | | *
  36. * P1 _____ P2 v o --> X *
  37. * *
  38. * <-----> r0 *
  39. * Origine du repere : P1 *
  40. * *
  41. * CHARGEMENT : *
  42. * - Montee lineaire en temperature depuis 25°C à 900°C en 1200s *
  43. * - Maintient à 900°C jusqu'a 3000s *
  44. * - Refroidissement par convection par la face cylindrique *
  45. * inférieure jusqu'à 3600s *
  46. * *
  47. * CL : *
  48. * - Blocage de la temperature (T imposee jusqu'a 3000s) *
  49. * - Convection de 3000s à 3600s avec h=0,1W.mm-2.K-1 *
  50. *__________________________________________________________________*
  51. OPTI DIME 2 MODE AXIS ELEM QUA4 ;
  52.  
  53. 'OPTI' 'TRAC' PSC 'EPTR' 10 ;
  54.  
  55. TMAX = 900. ;
  56. TMIN = 25. ;
  57. HCON = 0.1 ;
  58.  
  59. ************************************************************************
  60. * Pour faire des beaux DESSINS
  61. ************************************************************************
  62. * LISTMOTS contenant les couleurs
  63. LESCOUL = 'MOTS' 'VIOL' 'VERT' 'CYAN' 'BRIQ' 'BOUT' 'JAUN' 'OLIV'
  64. 'ORAN' 'ROUG' 'BLEU' 'BRUN' 'CARA' 'GRIS' 'NOIR' ;
  65. NBCOUL = 'DIME' LESCOUL;
  66.  
  67. * LISTMOTS contenant les marques dans DESS
  68. LESMARQ = 'MOTS' 'CROI' 'PLUS' 'MOIN' 'BARR' 'ETOI' 'CARR'
  69. 'LOSA' 'ROND' 'TRID' 'TRIU' 'TRIL' 'TRIR';
  70. NBMARQ = 'DIME' LESMARQ;
  71. ************************************************************************
  72.  
  73. ************************************************************************
  74. * Debut de la procedure PARATHER
  75. ************************************************************************
  76. 'DEBP' PARATHER PRECED*'TABLE' TPS1*'FLOTTANT';
  77. ************************************************************************
  78. * PROCEDURE PARATHER :
  79. * DESCRIPTION :
  80. * -------------
  81. * Cette procedure permet de modifier le materiaux avant l'appel a
  82. * VARI 'NUAG' dans TRANSNON.
  83. * - Les composantes K, C et RHO sont une moyenne arithméthique
  84. * pondérée par la fraction de phase des Ki, Ci et RHOi
  85. * L'indice ETAB.'MAT_TOT' est remplacé
  86. * Cette procedure permet de modifier le chargement 'TPOI' avant
  87. * l'appel a VARI 'NUAG' dans TRANSNON.
  88. * L'indice ETAB . 'CHARGEMENT' est remplacé
  89. *
  90. * ENTREES :
  91. * ---------
  92. * - PRECED : TABLE complete de PASAPAS
  93. * - TPS1 : Temps courant
  94. *
  95. * SORTIES :
  96. * ---------
  97. * - Aucune
  98. *
  99. ************************************************************************
  100.  
  101. *I - Mise a jour du materiau Thermique avec les proportions de phases
  102. ETAB = PRECED.'WTABLE';
  103. MOD1 = ETAB.'MOD_TOT' ;
  104. T1 = ETAB.'THER_COURANT' ;
  105. T1 ='CHAN' 'CHAM' T1 MOD1 'RIGIDITE' 'CARACTERISTIQUES';
  106.  
  107. MAT_ORIG= ETAB.'MAT_TOT';
  108. COMPORIG='EXTR' MAT_ORIG 'COMP';
  109. NBCOMP ='DIME' COMPORIG;
  110.  
  111. MAT0 ='VIDE' 'MCHAML';
  112. REPE SURCOM NBCOMP;
  113. II = &SURCOM;
  114. LACOMP ='EXTR' COMPORIG II;
  115. SI(('NEG' LACOMP 'K' ) 'ET'
  116. ('NEG' LACOMP 'RHO') 'ET'
  117. ('NEG' LACOMP 'C' ));
  118. MAT0 = MAT0 'ET' ('EXCO' LACOMP MAT_ORIG);
  119. FINS;
  120. FIN SURCOM;
  121.  
  122. * Instanciation du matériaux de chaque phase
  123. MATPHAS ='REDU' MOD1 MATPHAS ;
  124. MAT2 ='VARI' 'NUAG' MOD1 MATPHAS T1 'RIGIDITE';
  125.  
  126. * On fait ensuite la moyenne qui nous interesse (Ponderation par la
  127. * proportion de phase)
  128. NPA ='DIME' PRECED.'TEMPS';
  129. SI ('EXIS' PRECED.'PROPORTIONS_PHASES' NPA ) ;
  130. MCHPHA = PRECED.'PROPORTIONS_PHASES' . NPA ;
  131. SINO ;
  132. MCHPHA = PRECED.'PROPORTIONS_PHASES' .(NPA - 1);
  133. PRECED.'PROPORTIONS_PHASES' . NPA = MCHPHA ;
  134. FINS ;
  135.  
  136. MCHPHA = 'CHAN' 'CONS' MCHPHA 'MAT1' ;
  137. MCHPHA = 'REDU' MCHPHA ETAB.'MOD_COND' ;
  138. MCHPHA ='CHAN' 'RIGIDITE' MCHPHA MOD1 ;
  139. MCHPHA ='CHAN' 'TYPE' MCHPHA 'CARACTERISTIQUES' ;
  140.  
  141. MOPROP1='EXTR' MCHPHA 'COMP' ;
  142. MOMAT2 ='EXTR' MAT2 'COMP' ;
  143.  
  144. MCHK ='CHAN' 'TYPE' ('VIDE' 'MCHAML') 'CARACTERISTIQUES' ;
  145. MCHR ='CHAN' 'TYPE' ('VIDE' 'MCHAML') 'CARACTERISTIQUES' ;
  146. MCHC ='CHAN' 'TYPE' ('VIDE' 'MCHAML') 'CARACTERISTIQUES' ;
  147.  
  148. * Boucle sur les phases
  149. NBPHA = 'DIME' MOPROP1;
  150. REPE SURP NBPHA;
  151. IP = &SURP ;
  152. PROPIP ='EXCO' MCHPHA ('EXTR' MOPROP1 IP) 'SCAL' ; 'COMM' 'Prop de la phase numero IP' ;
  153.  
  154. * Moyenne sur les K
  155. IB = IP;
  156. RATIO = 'EXCO' MAT2 ('EXTR' MOMAT2 IB) 'SCAL';
  157. MCHK = (PROPIP * RATIO) + MCHK ;
  158.  
  159. * Moyenne sur les RHO
  160. IB = IB + NBPHA;
  161. RATIO2 = 'EXCO' MAT2 ('EXTR' MOMAT2 IB) 'SCAL';
  162. MCHR = (PROPIP * RATIO2) + MCHR ;
  163.  
  164. * Moyenne sur les CP
  165. IB = IB + NBPHA;
  166. RATIO3 = 'EXCO' MAT2 ('EXTR' MOMAT2 IB) 'SCAL';
  167. MCHC = (PROPIP * RATIO3) + MCHC ;
  168. FIN SURP;
  169.  
  170. MCHK ='CHAN' 'COMP' 'K' MCHK ;
  171. MCHR ='CHAN' 'COMP' 'RHO' MCHR ;
  172. MCHC ='CHAN' 'COMP' 'C' MCHC ;
  173.  
  174. * REMPLACEMENT DU MATERIAUX
  175. ETAB.'MAT_TOT' = MCHK 'ET' MCHR 'ET' MCHC 'ET' MAT0 ;
  176.  
  177.  
  178. *II - Mise a jour du Chargement TPOI avec les champs de temperatures initiaux et finaux
  179.  
  180. * On recupere le modele complet : Conduction + Convection + Metallurgie :
  181. MODTOT = ETAB.'MOD_TOT';
  182.  
  183. ETAB = PRECED . 'WTABLE';
  184. CHARG = ETAB . 'CHARGEMENT';
  185.  
  186. * On modifie uniquement le chargement TPOI, on conserve les autres chargements.
  187. CHAR_T = 'ENLE' CHARG 'TPOI';
  188.  
  189. * On recupere tempINI et tempFIN
  190. NPA ='DIME' PRECED.'TEMPS';
  191. temps0 = PRECED.'TEMPS'.(NPA - 1);
  192. temps1 = TPS1 ;
  193.  
  194. * On recupere T_INI et T_FIN
  195. T_CHPO1 ='EXCO' PRECED.'CONTINUATION'.'TEMPERATURES' 'T' 'SCAL' ;
  196. T_CHPO2 ='EXCO' ETAB .'THER_COURANT' 'T' 'SCAL' ;
  197. T_CHAM1 ='CHAN' 'CHAM' T_CHPO1 MODTOT 'RIGIDITE';
  198. T_CHAM2 ='CHAN' 'CHAM' T_CHPO2 MODTOT 'RIGIDITE';
  199.  
  200. * Dependance temporelle du chargement TPOI :
  201. LTPSCHA ='PROG' temps0 temps1 ;
  202. LTPOI ='PROG' 1.D0 1.D0 ;
  203. EVT ='EVOL' 'MANU' LTPSCHA LTPOI ;
  204.  
  205. * Dependance spatiale du chargement TPOI :
  206. TPOIN = 'EXCO' ( ( T_CHPO2 - T_CHPO1 ) / (temps1 - temps0) ) 'SCAL' 'TPOI' ;
  207.  
  208. * Le chargement TPOI :
  209. CHAR_TPO ='CHAR' 'TPOI' TPOIN EVT ;
  210.  
  211. * Le chargement complet (TPOI + le reste) :
  212. CHAR_TOT = CHAR_T 'ET' CHAR_TPO ;
  213.  
  214. * Mise a jour du chargement :
  215. ETAB . 'CHARGEMENT' = CHAR_TOT ;
  216.  
  217. 'FINP';
  218. ************************************************************************
  219. * Fin de la procedure PARATHER
  220. ************************************************************************
  221.  
  222. *MAILLAGE
  223. h0 = 100. ; COMM 'hauteur du cylindre' ;
  224. r0 = 12.5 ; COMM 'rayon du cylindre' ;
  225. dens0 = 1. ; COMM 'densité maillage' ;
  226.  
  227. axes = @repere (0. 0.) ('PROG' 25. 25.) 'ROUG' ;
  228. P1 = POIN 0. 0. ;
  229. P2 = POIN r0 0. ;
  230. P3 = POIN r0 h0 ;
  231. P4 = POIN 0. h0 ;
  232.  
  233. L1 = DROI P1 P2 'DINI' dens0 'DFIN' dens0 ;
  234. L2 = DROI P2 P3 'DINI' dens0 'DFIN' dens0 ;
  235. L3 = DROI P3 P4 'DINI' dens0 'DFIN' dens0 ;
  236. L4 = DROI P4 P1 'DINI' dens0 'DFIN' dens0 ;
  237.  
  238. MAILT = (DALL L1 L2 L3 L4) COUL 'BLEU' ;
  239. ELIM MAILT 1.e-3 ;
  240. CONTT = CONT MAILT ;
  241. PTBAS = CONTT POIN 'DROIT' P1 P2 1.e-3 ;
  242. SURFBAS = CONTT ELEM 'APPUYE' 'STRICTEMENT' PTBAS ;
  243.  
  244. *MODELE
  245. MODTHE = MODE MAILT 'THERMIQUE' 'CONDUCTION' 'QUA4' 'CONS' 'MAT1' ;
  246. MODCON = MODE SURFBAS 'THERMIQUE' 'CONVECTION' 'SEG2';
  247. MODTHERM = MODTHE 'ET' MODCON;
  248.  
  249. ************************************************************************
  250. * Definition de la metallurgie : DEBUT
  251. ************************************************************************
  252. * 1- Métal de base 100% initialement
  253. * 2- Martensite
  254. * 3- Bainite
  255. * 4- Ferrite
  256. * 5- Austénite
  257.  
  258. * Evolution des proprietes thermiques pour les phases pures
  259. MCHK = VIDE 'MCHAML';
  260. MCHRHO = VIDE 'MCHAML';
  261. MCHC = VIDE 'MCHAML';
  262. CTYP = MOT 'CARACTERISTIQUES';
  263. ********************
  264. * 1- Métal de base *
  265. ********************
  266. IPAHS = 1;
  267. CPHAS = CHAI 'K' IPAHS;
  268. LTKP1 = PROG 0 55 113 162 191 243 293 392
  269. 457 507 605 655 756 795 840 856
  270. 900 950 1000 1101 1202 1303 1400 1500
  271. 1502 1600 ;
  272. LKP1 = PROG 0.0376 0.0389 0.0401 0.0407 0.0407 0.0404 0.0398 0.038
  273. 0.0364 0.0352 0.0329 0.0317 0.0291 0.0273 0.0252 0.0248
  274. 0.0253 0.0261 0.027 0.0283 0.0299 0.0314 0.0328 0.0343
  275. 0.05 0.05;
  276. EVKP1 = EVOL 'MANU' 'T' LTKP1 CPHAS LKP1;
  277. MCHK = MCHK ET (MANU 'CHML' MODTHE CPHAS EVKP1 'TYPE' CTYP) ;
  278.  
  279. CPHAS = CHAI 'R' IPAHS;
  280. LTRHOP1= PROG 0 20 100 200 300 400
  281. 500 600 700 800 900 1440
  282. 2500 ;
  283. LRHOP1 = PROG 7852.D-9 7852.D-9 7815.D-9 7778.D-9 7741.D-9 7705.D-9
  284. 7668.D-9 7633.D-9 7595.D-9 7562.D-9 7527.D-9 7345.D-9
  285. 7011.D-9 ;
  286. EVRHOP1 = EVOL 'MANU' 'T' LTRHOP1 CPHAS LRHOP1;
  287. MCHRHO = MCHRHO ET (MANU 'CHML' MODTHE CPHAS EVRHOP1 'TYPE' CTYP) ;
  288.  
  289. CPHAS = CHAI 'C' IPAHS;
  290. LTCP1 = PROG 21 50 150 200 250 300 350 450 550
  291. 650 700 750 850 1000 1200 1300 1400 1440
  292. 1465 1490 1540 1590 1615 1640 2500 ;
  293. LCP1 = PROG 460.5 485.6 519.1 531.6 556.7 573.5 598.6 661.4 749.3
  294. 845.6 1431.6 950.2 900 845.6 800 815 840 850
  295. 1210 1840 2470 1840 1210 840 707 ;
  296. EVCP1 = EVOL 'MANU' 'T' LTCP1 CPHAS LCP1;
  297. MCHC = MCHC ET (MANU 'CHML' MODTHE CPHAS EVCP1 'TYPE' CTYP) ;
  298.  
  299. *****************
  300. * 2- Martensite *
  301. *****************
  302. IPAHS = 2;
  303. CPHAS = CHAI 'K' IPAHS;
  304. EVKP1 = EVOL 'MANU' 'T' LTKP1 CPHAS LKP1;
  305. MCHK = MCHK ET (MANU 'CHML' MODTHE CPHAS EVKP1 'TYPE' CTYP) ;
  306.  
  307. CPHAS = CHAI 'R' IPAHS;
  308. EVRHOP1 = EVOL 'MANU' 'T' LTRHOP1 CPHAS LRHOP1;
  309. MCHRHO = MCHRHO ET (MANU 'CHML' MODTHE CPHAS EVRHOP1 'TYPE' CTYP) ;
  310.  
  311. CPHAS = CHAI 'C' IPAHS;
  312. EVCP1 = EVOL 'MANU' 'T' LTCP1 CPHAS LCP1;
  313. MCHC = MCHC ET (MANU 'CHML' MODTHE CPHAS EVCP1 'TYPE' CTYP) ;
  314.  
  315. **************
  316. * 3- Bainite *
  317. **************
  318. IPAHS = 3;
  319. CPHAS = CHAI 'K' IPAHS;
  320. EVKP1 = EVOL 'MANU' 'T' LTKP1 CPHAS LKP1;
  321. MCHK = MCHK ET (MANU 'CHML' MODTHE CPHAS EVKP1 'TYPE' CTYP) ;
  322.  
  323. CPHAS = CHAI 'R' IPAHS;
  324. EVRHOP1 = EVOL 'MANU' 'T' LTRHOP1 CPHAS LRHOP1;
  325. MCHRHO = MCHRHO ET (MANU 'CHML' MODTHE CPHAS EVRHOP1 'TYPE' CTYP) ;
  326.  
  327. CPHAS = CHAI 'C' IPAHS;
  328. EVCP1 = EVOL 'MANU' 'T' LTCP1 CPHAS LCP1;
  329. MCHC = MCHC ET (MANU 'CHML' MODTHE CPHAS EVCP1 'TYPE' CTYP) ;
  330.  
  331. **************
  332. * 4- Ferrite *
  333. **************
  334. IPAHS = 4;
  335. CPHAS = CHAI 'K' IPAHS;
  336. EVKP1 = EVOL 'MANU' 'T' LTKP1 CPHAS LKP1;
  337. MCHK = MCHK ET (MANU 'CHML' MODTHE CPHAS EVKP1 'TYPE' CTYP) ;
  338.  
  339. CPHAS = CHAI 'R' IPAHS;
  340. EVRHOP1 = EVOL 'MANU' 'T' LTRHOP1 CPHAS LRHOP1;
  341. MCHRHO = MCHRHO ET (MANU 'CHML' MODTHE CPHAS EVRHOP1 'TYPE' CTYP) ;
  342.  
  343. CPHAS = CHAI 'C' IPAHS;
  344. EVCP1 = EVOL 'MANU' 'T' LTCP1 CPHAS LCP1;
  345. MCHC = MCHC ET (MANU 'CHML' MODTHE CPHAS EVCP1 'TYPE' CTYP) ;
  346.  
  347. ****************
  348. * 5- Austénite *
  349. ****************
  350. IPAHS = 5;
  351. CPHAS = CHAI 'K' IPAHS;
  352. LTKP5 = PROG 0 20 100 200 400 600 800 856
  353. 900 1000 1200 1500 1502 1600 ;
  354. LKP5 = PROG 0.0121 0.0124 0.0136 0.015 0.018 0.021 0.0239 0.0248
  355. 0.0254 0.0269 0.0298 0.0343 0.05 0.05;
  356. EVKP5 = EVOL 'MANU' 'T' LTKP5 CPHAS LKP5;
  357. MCHK = MCHK ET (MANU 'CHML' MODTHE CPHAS EVKP5 'TYPE' CTYP) ;
  358.  
  359. CPHAS = CHAI 'R' IPAHS;
  360. LTRHOP5= PROG 0 20 100 200 300 400
  361. 500 600 700 800 900 1440
  362. 2500 ;
  363. LRHOP5 = PROG 7852.D-9 7841.D-9 7794.D-9 7736.D-9 7680.D-9 7624.D-9
  364. 7569.D-9 7514.D-9 7458.D-9 7408.D-9 7356.D-9 7087.D-9
  365. 6613.D-9 ;
  366. EVRHOP5 = EVOL 'MANU' 'T' LTRHOP5 CPHAS LRHOP5;
  367. MCHRHO = MCHRHO ET (MANU 'CHML' MODTHE CPHAS EVRHOP5 'TYPE' CTYP);
  368.  
  369.  
  370. CPHAS = CHAI 'C' IPAHS;
  371. LTCP5 = PROG 21 50 150 200 250 300 350 475 575 675 800
  372. 950 1000 1100 1200 1300 1400 1440 1465 1490 1540 1590
  373. 1615 1640 2500 ;
  374. LCP5 = PROG 460.5 485.6 519.1 531.6 556.7 573.5 598.6 652 671 685 715
  375. 742 750 774 795 815 840 850 1210 1840 2470 1840
  376. 1210 840 707 ;
  377. EVCP5 = EVOL 'MANU' 'T' LTCP5 CPHAS LCP5;
  378. MCHC = MCHC ET (MANU 'CHML' MODTHE CPHAS EVCP5 'TYPE' CTYP) ;
  379.  
  380.  
  381. TPHASE = TABL;
  382. * Liste des transformations existantes dans un LISTENTIE
  383. TPHASE . 'PHASES' = MOTS 'MB ' 'MART' 'BAIN' 'FERR' 'AUST' ;
  384. TPHASE . 'REACTIFS' = MOTS 'MB ' 'MART' 'BAIN' 'FERR' 'AUST' 'AUST' 'AUST' ;
  385. TPHASE . 'PRODUITS' = MOTS 'AUST' 'AUST' 'AUST' 'AUST' 'MART' 'BAIN' 'FERR' ;
  386. TPHASE . 'TYPE' = MOTS 'LEBL' 'LEBL' 'LEBL' 'LEBL' 'KOIS' 'LEBL' 'LEBL' ;
  387.  
  388. MODCP1 = MODE MAILT 'METALLURGIE' 'PHASES' (TPHASE . 'PHASES')
  389. 'REACTIFS' (TPHASE . 'REACTIFS')
  390. 'PRODUITS' (TPHASE . 'PRODUITS')
  391. 'TYPE' (TPHASE . 'TYPE')
  392. 'QUA4' ;
  393.  
  394. PROG_T = 'PROG' 716. 802. ;
  395. PROG_TPO = 'PROG' -1.D-6 0. ;
  396. PROG_PEQ = 'PROG' 0. 1. ;
  397. PROG_F = 'PROG' 0. 1. ;
  398. PROG_TAU = 'PROG' 12. 0.5 ;
  399.  
  400. *1ere transformation :
  401. PEQ1 = EVOL 'MANU' 'T' PROG_T 'PEQ1' PROG_PEQ ;
  402. F1 = EVOL 'MANU' 'TPOI'PROG_TPO 'F1' PROG_F ;
  403. TAU1 = EVOL 'MANU' 'T' PROG_T 'TAU1' PROG_TAU ;
  404. *2eme transformation : parametres identiques a la premiere
  405. PEQ2 = EVOL 'MANU' 'T' PROG_T 'PEQ2' PROG_PEQ ;
  406. F2 = EVOL 'MANU' 'TPOI'PROG_TPO 'F2' PROG_F ;
  407. TAU2 = EVOL 'MANU' 'T' PROG_T 'TAU2' PROG_TAU ;
  408. *3eme transformation : parametres identiques a la premiere
  409. PEQ3 = EVOL 'MANU' 'T' PROG_T 'PEQ3' PROG_PEQ ;
  410. F3 = EVOL 'MANU' 'TPOI'PROG_TPO 'F3' PROG_F ;
  411. TAU3 = EVOL 'MANU' 'T' PROG_T 'TAU3' PROG_TAU ;
  412. *4eme transformation : parametres identiques a la premiere
  413. PEQ4 = EVOL 'MANU' 'T' PROG_T 'PEQ4' PROG_PEQ ;
  414. F4 = EVOL 'MANU' 'TPOI'PROG_TPO 'F4' PROG_F ;
  415. TAU4 = EVOL 'MANU' 'T' PROG_T 'TAU4' PROG_TAU ;
  416. *5eme transformation
  417. MS5 = 380. ;
  418. KM5 = 0.0247 ;
  419.  
  420. *6eme transformation
  421. PEQ6 = EVOL 'MANU' 'T' (PROG 375 380 405 600)
  422. 'PEQ6' (PROG 0. 1. 1. 0. );
  423.  
  424. F6 = 'EVOL' 'MANU' 'TPOI' (PROG -100. -80. -60. -50. -40. -30. -25. -20. -18. -15. -12. -10. -9. -5. -1. -0.05 0.D0 1.D-6)
  425. 'F6' (PROG 0.005 1.573 2.857 3.417 3.982 4.583 4.833 5.26 5.472 6.033 7.675 11.4 18.45 17.1 0.328 0.00238 0.00238 0.) ;
  426.  
  427. TAU6 = EVOL 'MANU' 'T' (PROG 375 380)
  428. 'TAU6' (PROG 1.D6 20 );
  429.  
  430. *7eme transformation
  431. PEQ7 = 'EVOL' 'MANU' 'T' (PROG 625 630 730 735 )
  432. 'PEQ7' (PROG 0 1 1 0 );
  433.  
  434. F7 = 'EVOL' 'MANU' 'TPOI' (PROG -8.5 -6.2 -4.7 0. 1.D-6)
  435. 'F7' (PROG 0.001 0.13 1.5 1.5 0. );
  436.  
  437. TAU7 = EVOL 'MANU' 'T' (PROG 625 630 )
  438. 'TAU7' (PROG 1.D6 5 );
  439.  
  440. MATCP1 = 'MATE' MODCP1 'PEQ1' PEQ1 'TAU1' TAU1 'F1' F1
  441. 'PEQ2' PEQ2 'TAU2' TAU2 'F2' F2
  442. 'PEQ3' PEQ3 'TAU3' TAU3 'F3' F3
  443. 'PEQ4' PEQ4 'TAU4' TAU4 'F4' F4
  444. 'MS5' MS5 'KM5' KM5
  445. 'PEQ6' PEQ6 'TAU6' TAU6 'F6' F6
  446. 'PEQ7' PEQ7 'TAU7' TAU7 'F7' F7;
  447.  
  448. ************************************************************************
  449. * Definition de la metallurgie : FIN
  450. ************************************************************************
  451.  
  452. MODTOT = MODTHE 'ET' MODCP1 'ET' MODCON ;
  453.  
  454. ************************************************************************
  455. * Phase 1 et 2 :
  456. * Rampe de temperature jusqu'à 900°C d'une durée de 20min
  457. * Palier isotherme à 900°C d'une durée de 30min
  458. ************************************************************************
  459.  
  460. *TEMPERATURE INITIALE
  461. CHPTINI = MANU 'CHPO' MAILT 1 'T' TMIN 'NATU' 'DIFFUS' ;
  462.  
  463. CTYP ='CHAI' 'VARIABLES_INTERNES';
  464. MCHPHA = MANU 'CHML' MODCP1 'MB ' 0.1 'MART' 0.2 'BAIN' 0.3
  465. 'FERR' 0.4 'AUST' 0.0
  466. 'TYPE' CTYP 'NOEUD' ;
  467.  
  468. *MATERIAUX
  469. MATPHAS = MCHK 'ET' MCHRHO 'ET' MCHC ;
  470. MATCONV ='MATE' MODCON 'H' 0.D0 ;
  471. MATCOND ='MATE' MODTHE 'K' 0.D0 'RHO' 0.D0 'C' 0.D0;
  472. MATTOT = MATCOND 'ET' MATCONV 'ET' MATCP1 ;
  473.  
  474.  
  475. ************************************************************************
  476. * Fabrication du diagramme TRC (Pour vérification de la mise en donnee)
  477. ************************************************************************
  478. * Calcul automatique de la liste des vitesses de refroidissement
  479. VIT1 = 250. ;
  480. VIT2 = 1. ;
  481. NBVI = 50 ;
  482. VLOG1 = 'LOG' VIT1;
  483. VLOG2 = 'LOG' VIT2;
  484.  
  485. PASLOG = (VLOG2 - VLOG1) / (NBVI - 1);
  486. LRELOG ='PROG' VLOG1 'PAS' PASLOG VLOG2;
  487. LISTVIT='EXP' LRELOG;
  488.  
  489. * Liste manuelle des vitesses de refroidissement
  490. LISTVIT = PROG 250. 50. 10. 7. 4. ;
  491. ************************************************************************
  492.  
  493. *CLs
  494. *TEMPERATURE IMPOSE EN BAS
  495. CLTOT = BLOQ 'T' MAILT ;
  496. TIMPO = DEPI 1. CLTOT ;
  497.  
  498. * CHARGEMENT Thermque 'T'
  499. LTPSCHA = PROG 0. 1200. 3000. ;
  500. LTCHA = PROG TMIN TMAX TMAX ;
  501. EVT = EVOL 'MANU' LTPSCHA LTCHA;
  502. CHAR1 = CHAR 'TIMP' TIMPO EVT ;
  503.  
  504. * CHARGEMENT 'TPOI'. Ce chargement est mis a jour dans PARATHER
  505. TPS0 = 0.D0 ;
  506. TPS1 = 3000.D0 ;
  507. VREFROI= 10 ;
  508. VREFROI= ( TMAX - TMIN ) / (1200. - 0.) ;
  509.  
  510. VITESSE = -1 * VREFROI ;
  511. LTPSCHA ='PROG' 0. 1200. 1201. 3000. ;
  512. LTPOI ='PROG' VITESSE VITESSE 0. 0. ;
  513. EVT ='EVOL' 'MANU' LTPSCHA LTPOI ;
  514. TPOIN = 'MANU' 'CHPO' MAILT 1 'TPOI' 1.D0 ; 'COMM' 'Le chargement vaut 1 * chargement(temps) partout !';
  515. CHAR2 ='CHAR' 'TPOI' TPOIN EVT ;
  516.  
  517. *CHARGEMENT Total
  518. CHARTOT = CHAR1 'ET' CHAR2 ;
  519.  
  520. *TEMPS_CALCULES
  521. LTCAL1 = PROG 0. 'PAS' 100. 945. 'PAS' 2. 1100.
  522. 'PAS' 5. 1200. 'PAS' 50. 3000. ;
  523.  
  524. *PASAPAS
  525. TPASAP ='TABL' ;
  526. TPASAP.'MODELE' = MODTOT ;
  527. TPASAP.'CARACTERISTIQUES' = MATTOT ;
  528. TPASAP.'BLOCAGES_THERMIQUES' = CLTOT ;
  529. TPASAP.'CHARGEMENT' = CHARTOT ;
  530. TPASAP.'TEMPS_CALCULES' = LTCAL1 ;
  531.  
  532. TPASAP.'TEMPS' ='TABL' ;
  533. TPASAP.'TEMPERATURES' ='TABL' ;
  534. TPASAP.'PROPORTIONS_PHASES' ='TABL' ;
  535. TPASAP.'TEMPS' . 0 ='EXTR' LTCAL1 1;
  536. TPASAP.'TEMPERATURES' . 0 = CHPTINI ;
  537. TPASAP.'PROPORTIONS_PHASES' . 0 = MCHPHA ;
  538. TPASAP.'PROCESSEURS' ='MOT' 'MONO_PROCESSEUR';
  539.  
  540. * PROCEDURES Utilisateurs
  541. TPASAP.'PROCEDURE_PARATHER' = VRAI ;
  542.  
  543. PASAPAS TPASAP ;
  544.  
  545. ************************************************************************
  546. * Phase 3 :
  547. * Refroidissement par convection sur un des bords
  548. ************************************************************************
  549. * MATERIAU
  550. MATCONV ='MATE' MODCON 'H' HCON ;
  551. MATTOT = MATCOND 'ET' MATCONV ;
  552.  
  553. MATTOT = MATCOND 'ET' MATCONV 'ET' MATCP1 ;
  554.  
  555. * CHARGEMENT Thermque 'T'
  556. LTPSCHA = PROG 0.D0 1.D6 ;
  557. LTCHA = PROG 1.D0 1.D0 ;
  558. EVTECO = EVOL 'MANU' LTPSCHA LTCHA;
  559. CHPTECO ='MANU' 'CHPO' SURFBAS 1 'T' 20. ;
  560. CHAR1 = CHAR 'TECO' CHPTECO EVTECO ;
  561.  
  562. * CHARGEMENT 'TPOI'. Ce chargement est mis a jour dans PARATHER
  563. VITESSE = -1 * VREFROI ;
  564. LTPSCHA = 'PROG' 0.D0 1.D6 ;
  565. LTPOI ='PROG' 0. 0. ;
  566. EVT ='EVOL' 'MANU' LTPSCHA LTPOI ;
  567. TPOIN = 'MANU' 'CHPO' MAILT 1 'TPOI' 1.D0 ;
  568. CHAR2 ='CHAR' 'TPOI' TPOIN EVT ;
  569.  
  570. *CHARGEMENT Total
  571. CHARTOT = CHAR1 'ET' CHAR2 ;
  572.  
  573. *TEMPS_CALCULES
  574. MTPS1 ='MAXI' LTCAL1 ;
  575. MTPS2 = MTPS1 + 600. ;
  576. LTCAL2 ='PROG' 3000. 'PAS' 1. 3040. 'PAS' 2 3160. 'PAS' 4. 3370.
  577. 'PAS' 20. MTPS2 ;
  578.  
  579. * Remplacement des indices dans la TABLE TPASAP
  580. TPASAP.'BLOCAGES_THERMIQUES'='VIDE' 'RIGIDITE';
  581. TTPS = TPASAP.'TEMPS';
  582. ID_IND=('DIME' TTPS) - 1;
  583. MCHPHA=TPASAP.'PROPORTIONS_PHASES' . ID_IND ;
  584. ID2 = ID_IND + 1 ;
  585.  
  586. TPASAP.'CARACTERISTIQUES' = MATTOT ;
  587. TPASAP.'CHARGEMENT' = CHARTOT;
  588. TPASAP.'TEMPS_CALCULES' = LTCAL2 ;
  589. TPASAP.'PROPORTIONS_PHASES' . ID2 = MCHPHA ;
  590.  
  591. PASAPAS TPASAP ;
  592.  
  593. ************************************************************************
  594. * POST-TRAITEMENT des résultats
  595. ************************************************************************
  596. fic_sauv = 'CHAI' 'JOMINY.sauv' ;
  597. OPTI SAUV fic_sauv ;
  598.  
  599. * Initialisations pour le POST-TRAITEMENT
  600. LISCOM ='EXTR' MCHPHA 'COMP' ;
  601. NBCOMP ='DIME' LISCOM ;
  602. TABPHA ='TABL';
  603. REPE SURPHA NBCOMP;
  604. IPH = &SURPHA;
  605. TABPHA . IPH ='VIDE' 'LISTREEL' ;
  606. FIN SURPHA;
  607. LTPS ='VIDE' 'LISTREEL';
  608.  
  609. REPE BLOC0 ('DIME' TPASAP.'TEMPS') ;
  610. I = &BLOC0 - 1 ;
  611. CHT = TPASAP.'TEMPERATURES' . I ;
  612. CHPHA = TPASAP.'PROPORTIONS_PHASES'. I ;
  613. LTPS = LTPS 'ET' (TPASAP.'TEMPS' . I) ;
  614.  
  615. * Extraction pour chaque phase de la valeur courante
  616. REPE SURPHA NBCOMP;
  617. IPH = &SURPHA;
  618. NOMP='EXTR' LISCOM IPH;
  619. * Pi ='EXTR' CHPHA NOMP 1 1288 1 ;
  620. * Pi ='EXTR' CHPHA NOMP 1 378 1 ;
  621. Pi ='EXTR' CHPHA NOMP 1 1 1 ;
  622. TABPHA . IPH = TABPHA . IPH 'ET' Pi;
  623. FIN SURPHA;
  624. FIN BLOC0 ;
  625.  
  626. *Reconstitution des EVOL
  627. EVTOTa ='VIDE' 'EVOLUTIO';
  628. TDESS1 ='TABL' ;
  629. TDESS1 . 'TITRE' ='TABL' ;
  630. EVOPHAS ='VIDE' 'EVOLUTIO';
  631. CPPHAS = 'CHAN' 'CHPO' CHPHA MODTOT;
  632.  
  633. REPE SURPHA NBCOMP;
  634. IPH = &SURPHA;
  635. NOMP ='EXTR' LISCOM IPH;
  636. ICOUL = @MOD IPH NBCOUL;
  637. COUL1 ='EXTR' LESCOUL ICOUL;
  638. Lpi = TABPHA. IPH ;
  639. TABPHA . IPH ='EVOL' COUL1 'MANU' 'TEMP' LTPS NOMP Lpi;
  640. EVTOTa = EVTOTa 'ET' TABPHA . IPH ;
  641. IMARQ = @MOD IPH NBMARQ;
  642. LAMAR ='EXTR' IMARQ LESMARQ;
  643. TDESS1 . 'TITRE' . IPH = NOMP;
  644. * TDESS1 . IPH ='CHAI' 'MARQ ' LAMAR ' REGU';
  645. EVOPHAS = EVOPHAS 'ET' ('EVOL' COUL1 'CHPO' CPPHAS NOMP L2);
  646. FIN SURPHA;
  647.  
  648. EVTOTa = 'CHAN' 'NOMORD' EVTOTa 'PROP';
  649. 'DESS' EVTOTa 'LEGE' TDESS1 'TITR' ('CHAI' 'Evolution des Props en fonction du temps' ) 'YBOR' 0. 1. ;
  650.  
  651. EVOPHAS = 'CHAN' 'NOMORD' EVOPHAS 'PROP';
  652. 'DESS' EVOPHAS 'LEGE' TDESS1 'TITR' ('CHAI' 'Props a Temps final' ) 'YBOR' 0. 1. ;
  653.  
  654. FIN ;
  655.  
  656.  
  657.  
  658.  
  659.  
  660.  
  661.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales