Télécharger metallurgie_06.dgibi

Retour à la liste

Numérotation des lignes :

  1. * fichier : metallurgie_06.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4.  
  5. *__________________________________________________________________*
  6. * TEST METALLURGIE_06 *
  7. * *
  8. * CALCUL DES PROPORTIONS DE PHASE METALLURGIQUE *
  9. * *
  10. * Un MODELE thermo-metallurgique est cree et l'essai JOMINY *
  11. * est simule en 2D Axisymétrique *
  12. * *
  13. * Utilisation de PASAPAS et d'une procedure utilisateur : *
  14. * - Procédure PARATHER : Mise a jour du matériaux THERMIQUE *
  15. * avec la proportion de phase. *
  16. * *
  17. * Le modèle métallurgique contient 5 phases ayant des cinétiques *
  18. * de transformation différentes *
  19. * - Metal de Base (MB) *
  20. * - Austénite *
  21. * - Martensite *
  22. * - Bainite *
  23. * - Ferrite *
  24. *__________________________________________________________________*
  25. * MAILLAGE : *
  26. * - Eprouvette cylindrique de hauteur 100mm et de rayon 12,5mm *
  27. * P4 _____ P3 *
  28. * | J | ^ *
  29. * | O | | *
  30. * | M | | *
  31. * | I | | h0 Y *
  32. * | N | | ^ *
  33. * | Y | | | *
  34. * P1 _____ P2 v o --> X *
  35. * *
  36. * <-----> r0 *
  37. * Origine du repere : P1 *
  38. * *
  39. * CHARGEMENT : *
  40. * - Montee lineaire en temperature depuis 25°C à 900°C en 1200s *
  41. * - Maintient à 900°C jusqu'a 3000s *
  42. * - Refroidissement par convection par la face cylindrique *
  43. * inférieure jusqu'à 3600s *
  44. * *
  45. * CL : *
  46. * - Blocage de la temperature (T imposee jusqu'a 3000s) *
  47. * - Convection de 3000s à 3600s avec h=0,1 [W.mm-2.K-1] *
  48. *__________________________________________________________________*
  49. OPTI DIME 2 MODE AXIS ELEM QUA4 ;
  50.  
  51. 'OPTI' 'TRAC' PSC 'EPTR' 10 ;
  52.  
  53. TMAX = 900.;
  54. TMIN = 25. ;
  55. HCON = 0.1 ;
  56.  
  57. ************************************************************************
  58. * Pour faire des beaux DESSINS
  59. ************************************************************************
  60. * LISTMOTS contenant les couleurs
  61. LESCOUL = 'MOTS' 'VIOL' 'VERT' 'CYAN' 'BRIQ' 'BOUT' 'JAUN' 'OLIV'
  62. 'ORAN' 'ROUG' 'BLEU' 'BRUN' 'CARA' 'GRIS' 'NOIR' ;
  63. NBCOUL = 'DIME' LESCOUL;
  64.  
  65. * LISTMOTS contenant les marques dans DESS
  66. LESMARQ = 'MOTS' 'CROI' 'PLUS' 'MOIN' 'BARR' 'ETOI' 'CARR'
  67. 'LOSA' 'ROND' 'TRID' 'TRIU' 'TRIL' 'TRIR';
  68. NBMARQ = 'DIME' LESMARQ;
  69. ************************************************************************
  70.  
  71. ************************************************************************
  72. * Debut de la procedure PARATHER
  73. ************************************************************************
  74. 'DEBP' PARATHER PRECED*'TABLE' TPS1*'FLOTTANT';
  75. ************************************************************************
  76. * PROCEDURE PARATHER :
  77. * DESCRIPTION :
  78. * -------------
  79. * Cette procedure permet de modifier le materiaux avant l'appel a
  80. * VARI 'NUAG' dans TRANSNON.
  81. * - Les composantes K, C et RHO sont une moyenne arithméthique
  82. * pondérée par la fraction de phase des Ki, Ci et RHOi
  83. * L'indice ETAB.'MAT_TOT' est remplacé
  84. * L'indice ETAB . 'CHARGEMENT' est remplacé
  85. *
  86. * ENTREES :
  87. * ---------
  88. * - PRECED : TABLE complete de PASAPAS
  89. * - TPS1 : Temps courant
  90. *
  91. * SORTIES :
  92. * ---------
  93. * - Aucune
  94. *
  95. ************************************************************************
  96.  
  97. *I - Mise a jour du materiau Thermique avec les proportions de phases
  98. ETAB = PRECED.'WTABLE';
  99. MOD1 = ETAB.'MOD_TOT' ;
  100. T1 = ETAB.'THER_COURANT' ;
  101. T1 ='CHAN' 'CHAM' T1 MOD1 'RIGIDITE' 'CARACTERISTIQUES';
  102.  
  103. MAT_ORIG= ETAB.'MAT_TOT';
  104. COMPORIG='EXTR' MAT_ORIG 'COMP';
  105. NBCOMP ='DIME' COMPORIG;
  106.  
  107. MAT0 ='VIDE' 'MCHAML';
  108. REPE SURCOM NBCOMP;
  109. II = &SURCOM;
  110. LACOMP ='EXTR' COMPORIG II;
  111. SI(('NEG' LACOMP 'K' ) 'ET'
  112. ('NEG' LACOMP 'RHO') 'ET'
  113. ('NEG' LACOMP 'C' ));
  114. MAT0 = MAT0 'ET' ('EXCO' LACOMP MAT_ORIG);
  115. FINS;
  116. FIN SURCOM;
  117.  
  118. * Instanciation du matériaux de chaque phase
  119. MATPHAS ='REDU' MOD1 MATPHAS ;
  120. MAT2 ='VARI' 'NUAG' MOD1 MATPHAS T1 'RIGIDITE';
  121.  
  122. * On fait ensuite la moyenne qui nous interesse (Ponderation par la
  123. * proportion de phase)
  124. NPA ='DIME' PRECED.'TEMPS';
  125. SI ('EXIS' PRECED.'PROPORTIONS_PHASES' NPA ) ;
  126. MCHPHA = PRECED.'PROPORTIONS_PHASES' . NPA ;
  127. SINO ;
  128. MCHPHA = PRECED.'PROPORTIONS_PHASES' .(NPA - 1);
  129. PRECED.'PROPORTIONS_PHASES' . NPA = MCHPHA ;
  130. FINS ;
  131.  
  132. MCHPHA = 'CHAN' 'CONS' MCHPHA 'MAT1' ;
  133. MCHPHA = 'REDU' MCHPHA ETAB.'MOD_COND' ;
  134. MCHPHA ='CHAN' 'RIGIDITE' MCHPHA MOD1 ;
  135. MCHPHA ='CHAN' 'TYPE' MCHPHA 'CARACTERISTIQUES' ;
  136.  
  137. MOPROP1='EXTR' MCHPHA 'COMP' ;
  138. MOMAT2 ='EXTR' MAT2 'COMP' ;
  139.  
  140. MCHK ='CHAN' 'TYPE' ('VIDE' 'MCHAML') 'CARACTERISTIQUES' ;
  141. MCHR ='CHAN' 'TYPE' ('VIDE' 'MCHAML') 'CARACTERISTIQUES' ;
  142. MCHC ='CHAN' 'TYPE' ('VIDE' 'MCHAML') 'CARACTERISTIQUES' ;
  143.  
  144. * Boucle sur les phases
  145. NBPHA = 'DIME' MOPROP1;
  146. REPE SURP NBPHA;
  147. IP = &SURP ;
  148. PROPIP ='EXCO' MCHPHA ('EXTR' MOPROP1 IP) 'SCAL' ; 'COMM' 'Prop de la phase numero IP' ;
  149.  
  150. * Moyenne sur les K
  151. IB = IP;
  152. RATIO = 'EXCO' MAT2 ('EXTR' MOMAT2 IB) 'SCAL';
  153. MCHK = (PROPIP * RATIO) + MCHK ;
  154.  
  155. * Moyenne sur les RHO
  156. IB = IB + NBPHA;
  157. RATIO2 = 'EXCO' MAT2 ('EXTR' MOMAT2 IB) 'SCAL';
  158. MCHR = (PROPIP * RATIO2) + MCHR ;
  159.  
  160. * Moyenne sur les CP
  161. IB = IB + NBPHA;
  162. RATIO3 = 'EXCO' MAT2 ('EXTR' MOMAT2 IB) 'SCAL';
  163. MCHC = (PROPIP * RATIO3) + MCHC ;
  164. FIN SURP;
  165.  
  166. MCHK ='CHAN' 'COMP' 'K' MCHK ;
  167. MCHR ='CHAN' 'COMP' 'RHO' MCHR ;
  168. MCHC ='CHAN' 'COMP' 'C' MCHC ;
  169.  
  170. * REMPLACEMENT DU MATERIAUX
  171. ETAB.'MAT_TOT' = MCHK 'ET' MCHR 'ET' MCHC 'ET' MAT0 ;
  172.  
  173.  
  174. 'FINP';
  175. ************************************************************************
  176. * Fin de la procedure PARATHER
  177. ************************************************************************
  178.  
  179. *MAILLAGE
  180. h0 = 100. ; COMM 'hauteur du cylindre' ;
  181. r0 = 12.5 ; COMM 'rayon du cylindre' ;
  182. dens0 = 1. ; COMM 'densité maillage' ;
  183.  
  184. axes = @repere (0. 0.) ('PROG' 25. 25.) 'ROUG' ;
  185. P1 = POIN 0. 0. ;
  186. P2 = POIN r0 0. ;
  187. P3 = POIN r0 h0 ;
  188. P4 = POIN 0. h0 ;
  189.  
  190. L1 = DROI P1 P2 'DINI' dens0 'DFIN' dens0 ;
  191. L2 = DROI P2 P3 'DINI' dens0 'DFIN' dens0 ;
  192. L3 = DROI P3 P4 'DINI' dens0 'DFIN' dens0 ;
  193. L4 = DROI P4 P1 'DINI' dens0 'DFIN' dens0 ;
  194.  
  195. MAILT = (DALL L1 L2 L3 L4) COUL 'BLEU' ;
  196. ELIM MAILT 1.e-3 ;
  197. CONTT = CONT MAILT ;
  198. PTBAS = CONTT POIN 'DROIT' P1 P2 1.e-3 ;
  199. SURFBAS = CONTT ELEM 'APPUYE' 'STRICTEMENT' PTBAS ;
  200.  
  201. *MODELE
  202. MODTHE = MODE MAILT 'THERMIQUE' 'CONDUCTION' 'QUA4' 'CONS' 'MAT1' ;
  203. MODCON = MODE SURFBAS 'THERMIQUE' 'CONVECTION' 'SEG2';
  204. MODTHERM = MODTHE 'ET' MODCON;
  205.  
  206. ************************************************************************
  207. * Definition de la metallurgie : DEBUT
  208. ************************************************************************
  209. * 1- Métal de base 100% initialement
  210. * 2- Martensite
  211. * 3- Bainite
  212. * 4- Ferrite
  213. * 5- Austénite
  214.  
  215. * Evolution des proprietes thermiques pour les phases pures
  216. MCHK = VIDE 'MCHAML';
  217. MCHRHO = VIDE 'MCHAML';
  218. MCHC = VIDE 'MCHAML';
  219. CTYP = MOT 'CARACTERISTIQUES';
  220. ********************
  221. * 1- Métal de base *
  222. ********************
  223. IPAHS = 1;
  224. CPHAS = CHAI 'K' IPAHS;
  225. LTKP1 = PROG 0 55 113 162 191 243 293 392
  226. 457 507 605 655 756 795 840 856
  227. 900 950 1000 1101 1202 1303 1400 1500
  228. 1502 1600 ;
  229. LKP1 = PROG 0.0376 0.0389 0.0401 0.0407 0.0407 0.0404 0.0398 0.038
  230. 0.0364 0.0352 0.0329 0.0317 0.0291 0.0273 0.0252 0.0248
  231. 0.0253 0.0261 0.027 0.0283 0.0299 0.0314 0.0328 0.0343
  232. 0.05 0.05;
  233. EVKP1 = EVOL 'MANU' 'T' LTKP1 CPHAS LKP1;
  234. MCHK = MCHK ET (MANU 'CHML' MODTHE CPHAS EVKP1 'TYPE' CTYP) ;
  235.  
  236. CPHAS = CHAI 'R' IPAHS;
  237. LTRHOP1= PROG 0 20 100 200 300 400
  238. 500 600 700 800 900 1440
  239. 2500 ;
  240. LRHOP1 = PROG 7852.D-9 7852.D-9 7815.D-9 7778.D-9 7741.D-9 7705.D-9
  241. 7668.D-9 7633.D-9 7595.D-9 7562.D-9 7527.D-9 7345.D-9
  242. 7011.D-9 ;
  243. EVRHOP1 = EVOL 'MANU' 'T' LTRHOP1 CPHAS LRHOP1;
  244. MCHRHO = MCHRHO ET (MANU 'CHML' MODTHE CPHAS EVRHOP1 'TYPE' CTYP) ;
  245.  
  246. CPHAS = CHAI 'C' IPAHS;
  247. LTCP1 = PROG 21 50 150 200 250 300 350 450 550
  248. 650 700 750 850 1000 1200 1300 1400 1440
  249. 1465 1490 1540 1590 1615 1640 2500 ;
  250. LCP1 = PROG 460.5 485.6 519.1 531.6 556.7 573.5 598.6 661.4 749.3
  251. 845.6 1431.6 950.2 900 845.6 800 815 840 850
  252. 1210 1840 2470 1840 1210 840 707 ;
  253. EVCP1 = EVOL 'MANU' 'T' LTCP1 CPHAS LCP1;
  254. MCHC = MCHC ET (MANU 'CHML' MODTHE CPHAS EVCP1 'TYPE' CTYP) ;
  255.  
  256. *****************
  257. * 2- Martensite *
  258. *****************
  259. IPAHS = 2;
  260. CPHAS = CHAI 'K' IPAHS;
  261. EVKP1 = EVOL 'MANU' 'T' LTKP1 CPHAS LKP1;
  262. MCHK = MCHK ET (MANU 'CHML' MODTHE CPHAS EVKP1 'TYPE' CTYP) ;
  263.  
  264. CPHAS = CHAI 'R' IPAHS;
  265. EVRHOP1 = EVOL 'MANU' 'T' LTRHOP1 CPHAS LRHOP1;
  266. MCHRHO = MCHRHO ET (MANU 'CHML' MODTHE CPHAS EVRHOP1 'TYPE' CTYP) ;
  267.  
  268. CPHAS = CHAI 'C' IPAHS;
  269. EVCP1 = EVOL 'MANU' 'T' LTCP1 CPHAS LCP1;
  270. MCHC = MCHC ET (MANU 'CHML' MODTHE CPHAS EVCP1 'TYPE' CTYP) ;
  271.  
  272. **************
  273. * 3- Bainite *
  274. **************
  275. IPAHS = 3;
  276. CPHAS = CHAI 'K' IPAHS;
  277. EVKP1 = EVOL 'MANU' 'T' LTKP1 CPHAS LKP1;
  278. MCHK = MCHK ET (MANU 'CHML' MODTHE CPHAS EVKP1 'TYPE' CTYP) ;
  279.  
  280. CPHAS = CHAI 'R' IPAHS;
  281. EVRHOP1 = EVOL 'MANU' 'T' LTRHOP1 CPHAS LRHOP1;
  282. MCHRHO = MCHRHO ET (MANU 'CHML' MODTHE CPHAS EVRHOP1 'TYPE' CTYP) ;
  283.  
  284. CPHAS = CHAI 'C' IPAHS;
  285. EVCP1 = EVOL 'MANU' 'T' LTCP1 CPHAS LCP1;
  286. MCHC = MCHC ET (MANU 'CHML' MODTHE CPHAS EVCP1 'TYPE' CTYP) ;
  287.  
  288. **************
  289. * 4- Ferrite *
  290. **************
  291. IPAHS = 4;
  292. CPHAS = CHAI 'K' IPAHS;
  293. EVKP1 = EVOL 'MANU' 'T' LTKP1 CPHAS LKP1;
  294. MCHK = MCHK ET (MANU 'CHML' MODTHE CPHAS EVKP1 'TYPE' CTYP) ;
  295.  
  296. CPHAS = CHAI 'R' IPAHS;
  297. EVRHOP1 = EVOL 'MANU' 'T' LTRHOP1 CPHAS LRHOP1;
  298. MCHRHO = MCHRHO ET (MANU 'CHML' MODTHE CPHAS EVRHOP1 'TYPE' CTYP) ;
  299.  
  300. CPHAS = CHAI 'C' IPAHS;
  301. EVCP1 = EVOL 'MANU' 'T' LTCP1 CPHAS LCP1;
  302. MCHC = MCHC ET (MANU 'CHML' MODTHE CPHAS EVCP1 'TYPE' CTYP) ;
  303.  
  304. ****************
  305. * 5- Austénite *
  306. ****************
  307. IPAHS = 5;
  308. CPHAS = CHAI 'K' IPAHS;
  309. LTKP5 = PROG 0 20 100 200 400 600 800 856
  310. 900 1000 1200 1500 1502 1600 ;
  311. LKP5 = PROG 0.0121 0.0124 0.0136 0.015 0.018 0.021 0.0239 0.0248
  312. 0.0254 0.0269 0.0298 0.0343 0.05 0.05;
  313. EVKP5 = EVOL 'MANU' 'T' LTKP5 CPHAS LKP5;
  314. MCHK = MCHK ET (MANU 'CHML' MODTHE CPHAS EVKP5 'TYPE' CTYP) ;
  315.  
  316. CPHAS = CHAI 'R' IPAHS;
  317. LTRHOP5= PROG 0 20 100 200 300 400
  318. 500 600 700 800 900 1440
  319. 2500 ;
  320. LRHOP5 = PROG 7852.D-9 7841.D-9 7794.D-9 7736.D-9 7680.D-9 7624.D-9
  321. 7569.D-9 7514.D-9 7458.D-9 7408.D-9 7356.D-9 7087.D-9
  322. 6613.D-9 ;
  323. EVRHOP5 = EVOL 'MANU' 'T' LTRHOP5 CPHAS LRHOP5;
  324. MCHRHO = MCHRHO ET (MANU 'CHML' MODTHE CPHAS EVRHOP5 'TYPE' CTYP);
  325.  
  326.  
  327. CPHAS = CHAI 'C' IPAHS;
  328. LTCP5 = PROG 21 50 150 200 250 300 350 475 575 675 800
  329. 950 1000 1100 1200 1300 1400 1440 1465 1490 1540 1590
  330. 1615 1640 2500 ;
  331. LCP5 = PROG 460.5 485.6 519.1 531.6 556.7 573.5 598.6 652 671 685 715
  332. 742 750 774 795 815 840 850 1210 1840 2470 1840
  333. 1210 840 707 ;
  334. EVCP5 = EVOL 'MANU' 'T' LTCP5 CPHAS LCP5;
  335. MCHC = MCHC ET (MANU 'CHML' MODTHE CPHAS EVCP5 'TYPE' CTYP) ;
  336.  
  337.  
  338. TPHASE = TABL;
  339. * Liste des transformations existantes dans un LISTENTIE
  340. TPHASE . 'PHASES' = MOTS 'MB ' 'MART' 'BAIN' 'FERR' 'AUST' ;
  341. TPHASE . 'REACTIFS' = MOTS 'MB ' 'MART' 'BAIN' 'FERR' 'AUST' 'AUST' 'AUST' ;
  342. TPHASE . 'PRODUITS' = MOTS 'AUST' 'AUST' 'AUST' 'AUST' 'MART' 'BAIN' 'FERR' ;
  343. TPHASE . 'TYPE' = MOTS 'LEBL' 'LEBL' 'LEBL' 'LEBL' 'KOIS' 'LEBL' 'LEBL' ;
  344.  
  345. MODCP1 = MODE MAILT 'METALLURGIE' 'PHASES' (TPHASE . 'PHASES')
  346. 'REACTIFS' (TPHASE . 'REACTIFS')
  347. 'PRODUITS' (TPHASE . 'PRODUITS')
  348. 'TYPE' (TPHASE . 'TYPE')
  349. 'QUA4' ;
  350.  
  351. PROG_T = 'PROG' 716. 802. ;
  352. PROG_TPO = 'PROG' -1.D-6 0. ;
  353. PROG_PEQ = 'PROG' 0. 1. ;
  354. PROG_F = 'PROG' 0. 1. ;
  355. PROG_TAU = 'PROG' 12. 0.5 ;
  356.  
  357. *1ere transformation :
  358. PEQ1 = EVOL 'MANU' 'T' PROG_T 'PEQ1' PROG_PEQ ;
  359. F1 = EVOL 'MANU' 'TPOI'PROG_TPO 'F1' PROG_F ;
  360. TAU1 = EVOL 'MANU' 'T' PROG_T 'TAU1' PROG_TAU ;
  361. *2eme transformation : parametres identiques a la premiere
  362. PEQ2 = EVOL 'MANU' 'T' PROG_T 'PEQ2' PROG_PEQ ;
  363. F2 = EVOL 'MANU' 'TPOI'PROG_TPO 'F2' PROG_F ;
  364. TAU2 = EVOL 'MANU' 'T' PROG_T 'TAU2' PROG_TAU ;
  365. *3eme transformation : parametres identiques a la premiere
  366. PEQ3 = EVOL 'MANU' 'T' PROG_T 'PEQ3' PROG_PEQ ;
  367. F3 = EVOL 'MANU' 'TPOI'PROG_TPO 'F3' PROG_F ;
  368. TAU3 = EVOL 'MANU' 'T' PROG_T 'TAU3' PROG_TAU ;
  369. *4eme transformation : parametres identiques a la premiere
  370. PEQ4 = EVOL 'MANU' 'T' PROG_T 'PEQ4' PROG_PEQ ;
  371. F4 = EVOL 'MANU' 'TPOI'PROG_TPO 'F4' PROG_F ;
  372. TAU4 = EVOL 'MANU' 'T' PROG_T 'TAU4' PROG_TAU ;
  373. *5eme transformation
  374. MS5 = 380. ;
  375. KM5 = 0.0247 ;
  376.  
  377. *6eme transformation
  378. PEQ6 = EVOL 'MANU' 'T' (PROG 375 380 405 600)
  379. 'PEQ6' (PROG 0. 1. 1. 0. );
  380.  
  381. F6 = 'EVOL' 'MANU' 'TPOI' (PROG -100. -80. -60. -50. -40. -30. -25. -20. -18. -15. -12. -10. -9. -5. -1. -0.05 0.D0 1.D-6)
  382. 'F6' (PROG 0.005 1.573 2.857 3.417 3.982 4.583 4.833 5.26 5.472 6.033 7.675 11.4 18.45 17.1 0.328 0.00238 0.00238 0.) ;
  383.  
  384. TAU6 = EVOL 'MANU' 'T' (PROG 375 380)
  385. 'TAU6' (PROG 1.D6 20 );
  386.  
  387. *7eme transformation
  388. PEQ7 = 'EVOL' 'MANU' 'T' (PROG 625 630 730 735 )
  389. 'PEQ7' (PROG 0 1 1 0 );
  390.  
  391. F7 = 'EVOL' 'MANU' 'TPOI' (PROG -8.5 -6.2 -4.7 0. 1.D-6)
  392. 'F7' (PROG 0.001 0.13 1.5 1.5 0. );
  393.  
  394. TAU7 = EVOL 'MANU' 'T' (PROG 625 630 )
  395. 'TAU7' (PROG 1.D6 5 );
  396.  
  397. MATCP1 = 'MATE' MODCP1 'PEQ1' PEQ1 'TAU1' TAU1 'F1' F1
  398. 'PEQ2' PEQ2 'TAU2' TAU2 'F2' F2
  399. 'PEQ3' PEQ3 'TAU3' TAU3 'F3' F3
  400. 'PEQ4' PEQ4 'TAU4' TAU4 'F4' F4
  401. 'MS5' MS5 'KM5' KM5
  402. 'PEQ6' PEQ6 'TAU6' TAU6 'F6' F6
  403. 'PEQ7' PEQ7 'TAU7' TAU7 'F7' F7;
  404.  
  405. ************************************************************************
  406. * Definition de la metallurgie : FIN
  407. ************************************************************************
  408.  
  409. MODTOT = MODTHE 'ET' MODCP1 'ET' MODCON ;
  410.  
  411. ************************************************************************
  412. * Phase 1 et 2 :
  413. * Rampe de temperature jusqu'à 900°C d'une durée de 20min
  414. * Palier isotherme à 900°C d'une durée de 30min
  415. ************************************************************************
  416.  
  417. *TEMPERATURE INITIALE
  418. CHPTINI = MANU 'CHPO' MAILT 1 'T' TMIN 'NATU' 'DIFFUS' ;
  419.  
  420. CTYP ='CHAI' 'VARIABLES_INTERNES';
  421. MCHPHA = MANU 'CHML' MODCP1 'MB ' 0.1 'MART' 0.2 'BAIN' 0.3
  422. 'FERR' 0.4 'AUST' 0.0
  423. 'TYPE' CTYP 'NOEUD' ;
  424.  
  425. *MATERIAUX
  426. MATPHAS = MCHK 'ET' MCHRHO 'ET' MCHC ;
  427. MATCONV ='MATE' MODCON 'H' 0.D0 ;
  428. MATCOND ='MATE' MODTHE 'K' 0.D0 'RHO' 0.D0 'C' 0.D0;
  429. MATTOT = MATCOND 'ET' MATCONV 'ET' MATCP1 ;
  430.  
  431. ************************************************************************
  432. * CONDITIONS aux LIMITES
  433. ************************************************************************
  434. * TEMPERATURE IMPOSE EN BAS
  435. CLTHE = BLOQ 'T' MAILT ;
  436. TIMPO = DEPI 1. CLTHE ;
  437.  
  438. * CHARGEMENT THERMIQUE 'T'
  439. LTPSCHA = PROG 0. 1200. 3000. ;
  440. LTCHA = PROG TMIN TMAX TMAX ;
  441. EVT = EVOL 'MANU' LTPSCHA LTCHA;
  442. CHAR1 = CHAR 'TIMP' TIMPO EVT ;
  443.  
  444. *TEMPS_CALCULES
  445. LTCAL1 = PROG 0. 'PAS' 300. 3000. ;
  446.  
  447. *PASAPAS
  448. TPASAP ='TABL' ;
  449. TPASAP.'MODELE' = MODTOT ;
  450. TPASAP.'CARACTERISTIQUES' = MATTOT ;
  451. TPASAP.'BLOCAGES_THERMIQUES' = CLTHE ;
  452. TPASAP.'CHARGEMENT' = CHAR1 ;
  453. TPASAP.'TEMPS_CALCULES' = LTCAL1 ;
  454.  
  455. TPASAP.'TEMPS' ='TABL' ;
  456. TPASAP.'TEMPERATURES' ='TABL' ;
  457. TPASAP.'PROPORTIONS_PHASES' ='TABL' ;
  458. TPASAP.'TEMPS' . 0 ='EXTR' LTCAL1 1;
  459. TPASAP.'TEMPERATURES' . 0 = CHPTINI ;
  460. TPASAP.'PROPORTIONS_PHASES' . 0 = MCHPHA ;
  461. TPASAP.'PROCESSEURS' ='MOT' 'MONO_PROCESSEUR';
  462.  
  463. * PROCEDURES Utilisateurs
  464. TPASAP.'PROCEDURE_PARATHER' = VRAI ;
  465.  
  466. PASAPAS TPASAP ;
  467.  
  468. ************************************************************************
  469. * Phase 3 :
  470. * Refroidissement par convection sur un des bords
  471. ************************************************************************
  472. * MATERIAU
  473. MATCONV ='MATE' MODCON 'H' HCON ;
  474. MATTOT = MATCOND 'ET' MATCONV ;
  475.  
  476. MATTOT = MATCOND 'ET' MATCONV 'ET' MATCP1 ;
  477.  
  478. * CHARGEMENT Thermque 'T'
  479. LTPSCHA = PROG 0.D0 1.D6 ;
  480. LTCHA = PROG 1.D0 1.D0 ;
  481. EVTECO = EVOL 'MANU' LTPSCHA LTCHA;
  482. CHPTECO ='MANU' 'CHPO' SURFBAS 1 'T' 20. ;
  483. CHAR1 = CHAR 'TECO' CHPTECO EVTECO ;
  484.  
  485. *TEMPS_CALCULES
  486. MTPS1 ='MAXI' LTCAL1 ;
  487. MTPS2 = MTPS1 + 600. ;
  488. LTCAL2 ='PROG' 3000. 'PAS' 1. 3040. 'PAS' 4. 3160. 'PAS' 8. 3320. 'PAS' 16. MTPS2 ;
  489.  
  490. * Remplacement des indices dans la TABLE TPASAP
  491. TPASAP.'BLOCAGES_THERMIQUES'='VIDE' 'RIGIDITE';
  492. TTPS = TPASAP.'TEMPS';
  493. ID_IND=('DIME' TTPS) - 1;
  494. MCHPHA= TPASAP.'PROPORTIONS_PHASES' . ID_IND ;
  495. ID2 = ID_IND + 1 ;
  496.  
  497. TPASAP.'CARACTERISTIQUES' = MATTOT ;
  498. TPASAP.'CHARGEMENT' = CHAR1 ;
  499. TPASAP.'TEMPS_CALCULES' = LTCAL2 ;
  500. TPASAP.'PROPORTIONS_PHASES' . ID2 = MCHPHA ;
  501.  
  502. PASAPAS TPASAP ;
  503.  
  504. ************************************************************************
  505. * POST-TRAITEMENT des résultats
  506. ************************************************************************
  507. fic_sauv = 'CHAI' 'JOMINY.sauv' ;
  508. OPTI SAUV fic_sauv ;
  509.  
  510. * Initialisations pour le POST-TRAITEMENT
  511. LISCOM ='EXTR' MCHPHA 'COMP' ;
  512. NBCOMP ='DIME' LISCOM ;
  513. TABPHA ='TABL';
  514. REPE SURPHA NBCOMP;
  515. IPH = &SURPHA;
  516. TABPHA . IPH ='VIDE' 'LISTREEL' ;
  517. FIN SURPHA;
  518. LTPS ='VIDE' 'LISTREEL';
  519.  
  520. REPE BLOC0 ('DIME' TPASAP.'TEMPS') ;
  521. I = &BLOC0 - 1 ;
  522. CHT = TPASAP.'TEMPERATURES' . I ;
  523. CHPHA = TPASAP.'PROPORTIONS_PHASES'. I ;
  524. LTPS = LTPS 'ET' (TPASAP.'TEMPS' . I) ;
  525.  
  526. * Extraction pour chaque phase de la valeur courante
  527. REPE SURPHA NBCOMP;
  528. IPH = &SURPHA;
  529. NOMP='EXTR' LISCOM IPH;
  530. Pi ='EXTR' CHPHA NOMP 1 1 1 ;
  531. TABPHA . IPH = TABPHA . IPH 'ET' Pi;
  532. FIN SURPHA;
  533. FIN BLOC0 ;
  534.  
  535. *Reconstitution des EVOL
  536. EVTOTa ='VIDE' 'EVOLUTIO';
  537. TDESS1 ='TABL' ;
  538. TDESS1 . 'TITRE' ='TABL' ;
  539. EVOPHAS ='VIDE' 'EVOLUTIO';
  540. CPPHAS ='CHAN' 'CHPO' CHPHA MODTOT;
  541.  
  542. REPE SURPHA NBCOMP;
  543. IPH = &SURPHA;
  544. NOMP ='EXTR' LISCOM IPH;
  545. ICOUL = @MOD IPH NBCOUL;
  546. COUL1 ='EXTR' LESCOUL ICOUL;
  547. Lpi = TABPHA. IPH ;
  548. TABPHA . IPH ='EVOL' COUL1 'MANU' 'TEMP' LTPS NOMP Lpi;
  549. EVTOTa = EVTOTa 'ET' TABPHA . IPH ;
  550. IMARQ = @MOD IPH NBMARQ;
  551. LAMAR ='EXTR' IMARQ LESMARQ;
  552. TDESS1 . 'TITRE' . IPH = NOMP;
  553. * TDESS1 . IPH ='CHAI' 'MARQ ' LAMAR ' REGU';
  554. EVOPHAS = EVOPHAS 'ET' ('EVOL' COUL1 'CHPO' CPPHAS NOMP L2);
  555. FIN SURPHA;
  556.  
  557. EVTOTa = 'CHAN' 'NOMORD' EVTOTa 'PROP';
  558. 'DESS' EVTOTa 'LEGE' TDESS1 'TITR' ('CHAI' 'Evolution des Props en fonction du temps' ) 'YBOR' 0. 1. ;
  559.  
  560. EVOPHAS = 'CHAN' 'NOMORD' EVOPHAS 'PROP';
  561. 'DESS' EVOPHAS 'LEGE' TDESS1 'TITR' ('CHAI' 'Props a Temps final' ) 'YBOR' 0. 1. ;
  562.  
  563. list (temp horl / 100.) ;
  564.  
  565. FIN ;
  566.  
  567.  
  568.  
  569.  
  570.  
  571.  
  572.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales