Télécharger la plaquette Cast3M


fr en

Télécharger maj_epaicoq2.dgibi

Retour à la liste

Numérotation des lignes : 

  1. * fichier : maj_epaicoq2.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4. *----------------------------------------------------------------------*
  5. * Exemple de calcul elastoplastique avec des coques prenant en compte  *
  6. * la diminution de l'epaisseur des coques au cours du calcul.          *
  7. *                                                                      *
  8. * Pour cela, on fait appel a la procedure PERSO1 de PASAPAS.           *
  9. * En cours de calcul, l'epaisseur est calculee en considerant que      *
  10. * l'ecoulement plastique se fait a volume contant.                     *
  11. *                                                                      *
  12. * Le cas de calcul est une plaque vue par sa tranche (ligne en 2D),    *
  13. * dont on bloque la base et sur laquelle on impose un effort en tete.  *
  14. * La comportement materiau est 'ELASTIQUE' 'PLASTIQUE' 'ISOTROPE'.     *
  15. *                                                                      *
  16. * On compare la solution "coque" a la solution avec des elts. massifs. *
  17. *                                                                      *
  18. *----------------------------------------------------------------------*
  19. *                                                                      *
  20. * ITRAC1   = VRAI : traces actives                                     *
  21. * ISMPLAN1 = VRAI : calcul en contraintes planes                       *
  22. ITRAC1   = faux ;
  23. ISMPLAN1 = VRAI ;
  24. *                                                                      *
  25. *-------------------------- Procedure PERSO1 --------------------------*
  26. *                                                                      *
  27. 'DEBP' PERSO1 TU1*'TABLE' ;
  28. * Appel avant 1er calcul de MECANIQUE (indicateur 'EGAL' a 1) :*;
  29. * => on passe                                                          *
  30. 'SI' (TU1 . 'PERSO1_APPEL' 'EGA' 1) ;
  31.   'QUIT' PERSO1 ;
  32. 'FINS' ;
  33. * DEP1   : Les deplacements en fin de PAS (courants) :                 *
  34. DEP1     = TU1 . 'ESTIMATION' . 'DEPLACEMENTS' ;
  35. * On sauve la configuration courante :                                 *
  36. CONFC1   = 'FORM' ;
  37. * On se place dans la configuration intiale (FOR0), puis dans la       *
  38. * la config. en  fin de PAS grace a DEP1 :                             *
  39. 'FORM' (TU1 . 'WTABLE' . 'FOR0') ;
  40. 'FORM' DEP1 ;
  41. * Calcul surface courante des coques : on integre un champ de 1 dans   *
  42. * la configuration deformee (DEP1) :                                   *
  43. MODX1    = TU1 . 'DATA_PERSO' . 'MODX1' ;
  44. CHAM1    = TU1 . 'DATA_PERSO' . 'CHAM1' ;
  45. S1       = 'INTG' MODX1 CHAM1 'ELEM' ;
  46. * On se remet dans la config. courante :                               *
  47. 'FORM' CONFC1 ;
  48. * Surface initiale des coques (S0) :                                   *
  49. S0       = TU1 . 'DATA_PERSO' . 'S0' ;
  50. 'SI' ('EGA' ('VALE' 'MODE') 'PLANCONT') ;
  51.   CHPAR1   = (S0 / (S0 + (0.5 * (S1 - S0)))) ;
  52. 'SINO' ;
  53.   CHPAR1   = S0 / S1 ;
  54. 'FINS' ;
  55. CHPAR1   = CHPAR1 'NOMC' 'PAR1' ;
  56. * Mise a jour du parametre dans le chargement :                        *
  57. EV0      = TU1 . 'DATA_PERSO' . 'EV0' ;
  58. CGP1     = 'CHAR' 'PAR1' CHPAR1 EV0 ;
  59. * On reconstruit le chargement en ajoutant le nouveau CGP1 aux autres  *
  60. * chargements du probleme passes a l'indice  DATA_PERSO.CG0 :          *
  61. WTAB.'CHARGEMENT_I' = TU1 . 'DATA_PERSO' . 'CG0' 'ET' CGP1 ;
  62. WTAB.'CHARGEMENT'   = TU1 . 'DATA_PERSO' . 'CG0' 'ET' CGP1 ;
  63. 'FINP' ;
  64. *                                                                      *
  65. *----------------------------------------------------------------------*
  66. *                                 COQ2                                 *
  67. *----------------------------------------------------------------------*
  68. *                                                                      *
  69. 'OPTI' 'DIME' 2 'ELEM' 'QUA4' ;
  70. *                                                                      *
  71. 'SI' ISMPLAN1 ;
  72.   'OPTI' 'MODE' 'PLAN' 'CONT' ;
  73. 'FINS' ;
  74. *                                                                      *
  75. *------------------------------ Maillage ------------------------------*
  76. *                                                                      *
  77. P1       = 0 0 ;
  78. P2       = 0 1 ;
  79. L1       = P1 'DROI' 10 P2 ;
  80. *                                                                      *
  81. 'SI' ITRAC1 ; 
  82.   'TRAC' 'QUAL' (L1 'ET' P1 'ET' P2)
  83.     'TITR' ' Modelisation coque 1D : P1 bloque, Fy imposee en P2 ' ;
  84. 'FINS' ;
  85. *                                                                      *
  86. *--------------------- Modele - Caracteristiques ----------------------*
  87. *                                                                      *
  88. CTRA1    = 'EVOL' 'MANU' 'EPSI' ('PROG' 0. 0.0015 0.1)
  89.                          'SIGM' ('PROG' 0. 300.E6  1000.E6) ;
  90. leps1    = extr ctra1 absc ;
  91. lsig1    = extr ctra1 ordo ;
  92. lsig1    = lsig1 enle 1 ;
  93. lep1     = (leps1 enle 1) - (lsig1 / 200.E9) ;
  94. ECRO1    = evol vert manu epsp lep1 sig lsig1 ;
  95. si ITRAC1 ;
  96.   dess (ctra1 et ecro1) titr ' Courbes de traction et d ecrouissage' ;
  97. fins ;
  98. EVEP1    = 'EVOL' 'MANU' 'PAR1' ('PROG' 0.1 1. 2.)
  99.                          'EPAI' ('PROG' 0.001 0.01 0.02) ;
  100. MO1      = 'MODE' L1 'MECANIQUE' 'ELASTIQUE' 'PLASTIQUE' 'COQ2' ;
  101. MA1      = 'MATE' MO1 'YOUN' 200.E9 'NU' 0.3 'ECRO' ECRO1
  102.                       'EPAI' EVEP1 ;
  103. *                                                                      *
  104. *------------------------- C.L. - Chargements -------------------------*
  105. *                                                                      *
  106. CL1      = 'BLOQ' 'DEPL' 'ROTA' P1 ;
  107. *                                                                      *
  108. VF1      = 8.E6 ;
  109. F1       = 'FORC' (0. VF1) P2 ;
  110. EV1      = 'EVOL' 'MANU' 'TEMP' ('PROG' 0. 1.) ('PROG' 0. 1.) ;
  111. CG1      = 'CHAR' 'MECA' EV1 F1 ;
  112. *                                                                      *
  113. * L'epaisseur depend du parametre PAR1 : on donne sa valeur initiale   *
  114. CHAM1    = 'MANU' 'CHML' MO1 'PAR1' 1. 'RIGIDITE' ;
  115. EV0      = 'EVOL' 'MANU' ('PROG' 0. 1.) ('PROG' 1. 1.) ;
  116. CGEP1    = 'CHAR' 'PAR1' EV0 CHAM1 ;
  117. *
  118. * "Surface" initiale des coques :
  119. CHS0     = 'INTG' MO1 CHAM1 'ELEM' ;
  120. *
  121. *----------------------------- Resolution -----------------------------*
  122. *                                                                      *
  123. * Liste des temps de calcul :                                          *
  124. 'SI' ('EGA' ('VALE' 'MODE') 'PLANDEFO') ;
  125.   LTPS1    = 'PROG' 0. 0.3 'PAS' 0.015 1. ;
  126. 'FINS' ;
  127. 'SI' ('EGA' ('VALE' 'MODE') 'PLANCONT') ;
  128.   LTPS1    = 'PROG' 0. 0.3 'PAS' 0.025 1. ;
  129. 'FINS' ;
  130. *                                                                      *
  131. * Table PASAPAS :                                                      *
  132. TAB1                         = 'TABL' 'PASAPAS' ;
  133. TAB1 . 'MODELE'              = MO1 ;
  134. TAB1.  'PRECISION'           = 1d-6;
  135. TAB1 . 'CARACTERISTIQUES'    = MA1 ;
  136. TAB1 . 'BLOCAGES_MECANIQUES' = CL1 ;
  137. TAB1 . 'CHARGEMENT'          = CG1 'ET' CGEP1 ;
  138. TAB1 . 'GRANDS_DEPLACEMENTS' = VRAI ;
  139. TAB1 . 'TEMPS_CALCULES'      = LTPS1 ;
  140. *                                                                      *
  141. * Donnees pour laprocedure PERSO1 :                                    *
  142. TAB1 . 'PROCEDURE_PERSO1'    = VRAI ;
  143. TAB1 . 'DATA_PERSO'          = 'TABL' ;
  144. TAB1 . 'DATA_PERSO' . 'S0'   = CHS0 ;
  145. TAB1 . 'DATA_PERSO' . 'MODX1'= MO1 ;
  146. TAB1 . 'DATA_PERSO' . 'CHAM1'= CHAM1 ;
  147. TAB1 . 'DATA_PERSO' . 'EV0'  = EV0 ;
  148. TAB1 . 'DATA_PERSO' . 'CG0'  = CG1 ;
  149. *                                                                      *
  150. PASAPAS TAB1 ;
  151. *                                                                      *
  152. *----------------------------------------------------------------------*
  153. *                                MASSIFS                               *
  154. *----------------------------------------------------------------------*
  155. *                                                                      *
  156. *------------------------------ Maillage ------------------------------*
  157. *                                                                      *
  158. S1       = L1 'TRAN' 1 (0.01 0.) ;
  159. L2       = (S1 'COTE' 2) 'COUL' 'ROUG' ;
  160. L4       = (S1 'COTE' 4) 'COUL' 'VERT' ;
  161. *                                                                      *
  162. 'SI' ITRAC1 ; 
  163.   CHVISU1  = ((S1 'COOR' 1) * 5.) 'NOMC' 'UX' ;
  164.   'FORM' CHVISU1 ;
  165.   'TRAC' 'QUAL' (S1 'ET' L2 'ET' L4) 
  166.     'TITR' ' Modelisation 2D : L4 bloquee, Fy imposee en L2 ' ;
  167.   'FORM' (-1. * CHVISU1) ;
  168. 'FINS' ;
  169. *                                                                      *
  170. *--------------------- Modele - Caracteristiques ----------------------*
  171. *                                                                      *
  172. MO2      = 'MODE' S1 'MECANIQUE' 'ELASTIQUE' 'PLASTIQUE' ;
  173. MA2      = 'MATE' MO2 'YOUN' 200.E9 'NU' 0.3 'ECRO' ECRO1 ;
  174. *                                                                      *
  175. *------------------------- C.L. - Chargements -------------------------*
  176. *                                                                      *
  177. CL2      = ('BLOQ' 'UY' L4) 'ET' ('BLOQ' 'UX' P1) ;
  178. *                                                                      *
  179. F2       = 'FORC' (0. VF1) L2 ;
  180. CG2      = 'CHAR' 'MECA' EV1 F2 ;
  181. *                                                                      *
  182. *----------------------------- Resolution -----------------------------*
  183. *                                                                      *
  184. TAB2                         = 'TABL' 'PASAPAS' ;
  185. TAB2 . 'MODELE'              = MO2 ;
  186. TAB2.  'PRECISION'           = 1d-6;
  187. TAB2 . 'CARACTERISTIQUES'    = MA2 ;
  188. TAB2 . 'BLOCAGES_MECANIQUES' = CL2 ;
  189. TAB2 . 'CHARGEMENT'          = CG2 ;
  190. TAB2 . 'GRANDS_DEPLACEMENTS' = VRAI ;
  191. TAB2 . 'TEMPS_CALCULES'      = LTPS1 ;
  192. TAB2 . 'LAGRANGIEN'          = 'MOT' 'REACTUALISE' ;
  193. TAB2 . 'STABILITE'           = FAUX ;
  194. *                                                                      *
  195. PASAPAS TAB2 ;
  196. *                                                                      *
  197. *----------------------------------------------------------------------*
  198. *                              VALIDATION                              *
  199. *----------------------------------------------------------------------*
  200. *                                                                      *
  201. * Evolution du deplacement Uy du point P2 :                            *
  202. EVUP2_1  = 'EVOL' 'ROUG' 'TEMP' TAB1 'DEPLACEMENTS' 'UY' P2 ;
  203. EVUP2_2  = 'EVOL' 'VERT' 'TEMP' TAB2 'DEPLACEMENTS' 'UY' P2 ;
  204. *                                                                      *
  205. * calcul de l'erreur relative entre COQ2 / Massifs                     *
  206. ERR1     = 'MAXI' 'ABS' ('EXTR' (EVUP2_1 - EVUP2_2) 'ORDO') ;
  207. ERR1     = ERR1 / ('MAXI' 'ABS' ('EXTR' EVUP2_2'ORDO')) ;
  208. *                                                                      *
  209. VECH1    = 'VALE' 'ECHO' ;
  210. 'OPTI' 'ECHO' 0 ;
  211. 'SAUT' 1 'LIGN' ;
  212. 'MESS' ' ****** Erreur relative sur deplacement Uy(P2) = '
  213.   (100. * ERR1) ' %' ;
  214. 'SAUT' 1 'LIGN' ;
  215. 'OPTI' 'ECHO' VECH1 ;
  216. *                                                                      *
  217. 'SI' ITRAC1 ;
  218.   TDESS1   = 'TABL' ;
  219.   TDESS1 . 2 = 'MOT' 'MARQ CROI NOLI' ;
  220.   TDESS1 . 'TITRE' = 'TABL' ;
  221.   TDESS1 . 'TITRE' . 1 = 'Modele coque 1D ' ;
  222.   TDESS1 . 'TITRE' . 2 = 'Modele massif 2D ' ;
  223.   MOT1     = 'CHAI'
  224.     ' Uy(P2/L2) : modele coque (rouge) / massif (vert) (err.:'
  225.     'FORMAT' '(F5.2)' (100. * ERR1) '%)' ;
  226.   'DESS' TDESS1 (EVUP2_1 'ET' EVUP2_2) 'TITR' MOT1 'LEGE' ;
  227. 'FINS' ;
  228. *
  229. * Erreur si > 1 %
  230. si (ERR1 > 0.01) ;
  231.   erre 5 ;
  232. fins ;
  233. *                                                                      *
  234. 'FIN' ;
  235. 'OPTI' 'ECHO' 1 ;
  236.  
  237.  
  238.  
  239.  
  240.  
  241.  
  242.  
  243.  
  244.  
  245.  
  246.  
  247.  
  248.  
  249.  
  250.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales