Télécharger lire_med_02.dgibi

Retour à la liste

Numérotation des lignes :

  1. * fichier : lire_med_02.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4.  
  5. * Presentation : Ce cas-test permet de :
  6. * SORTIR des MAILLAGES, CHPOINT, MCHAML et TABLE PASAPAS
  7. * au format MED
  8. * LIRE les fichiers MED generes
  9. * VERIFIE et VALIDE les echanges au format MED
  10. * - Les valeurs lues sont identiques aux valeurs
  11. * attendues (Champs de coordonnees facile a comparer)
  12. *
  13. * Ameliorations a prevoir :
  14. * - Sortir et lire les MCHAML en d'autres points supports
  15. * - Sortir et lire les CONSTITUANTS dans les MCHAML
  16. * - Sortir et lire les NATURES dans les CHPOINT
  17. *
  18. * Creation : 17/02/2017
  19. * Createur : C. BERTHINIER
  20. *
  21. * Modifications :
  22. * CB215821 01/02/2018 : Sortie, Relecture & Validation des MAILLAGES
  23. * : Sortie, Relecture & Validation des CHPOINTS
  24. * : Sortie, Relecture & Validation des MCHAML
  25. * - Aux GRAVITE
  26. * - Aux NOEUDS
  27. * CB215821 13/03/2019 : Sortie, Relecture & Validation des TABLES PASAPAS
  28. ************************************************************************
  29.  
  30. 'OPTI' 'TRAC' 'PSC';
  31.  
  32. ************************************************************************
  33. * PROCEDURE POUR VERIFIER UN MAILLAGE
  34. ************************************************************************
  35. 'DEBP' VERMAI M_CAS*'MAILLAGE' M_MED*'MAILLAGE' NOM_MAI*'MOT';
  36. * TRACE des MAILLAGES
  37. CHAI1 ='CHAI' 'MAILLAGE' ' ' NOM_MAI ' ' 'CAST3M';
  38. CHAI2 ='CHAI' 'MAILLAGE' ' ' NOM_MAI ' ' 'LU MED';
  39. 'TRAC' 'QUAL' M_CAS 'TITR' CHAI1;
  40. 'TRAC' 'QUAL' M_MED 'TITR' CHAI2;
  41.  
  42. * Nombre d''elements
  43. NE_CAS ='NBEL' M_CAS;
  44. NE_MED ='NBEL' M_MED;
  45. 'ELIM' M_MED M_CAS 1.D-6;
  46. NE_DIF ='NBEL' ('DIFF' M_CAS M_MED);
  47.  
  48. * Nombre de noeuds
  49. NN_CAS ='NBNO' M_CAS;
  50. NN_MED ='NBNO' M_MED;
  51.  
  52. * Verification Nombre d''elements
  53. 'SI' (NE_CAS 'NEG' NE_MED);
  54. 'OPTI' 'ECHO' 0;
  55. 'MESS' '############################################################';
  56. 'MESS' '# LE MAILLAGES MED RELUS N EST PAS CONFORME #';
  57. 'MESS' '# ERREUR NOMBRE ELEMENTS #';
  58. 'MESS' '############################################################';
  59. 'OPTI' 'ECHO' 1;
  60. 'ERRE' 5;
  61. 'FINS';
  62. * Verification Nombre de Noeuds
  63. 'SI' (NN_CAS 'NEG' NN_MED);
  64. 'OPTI' 'ECHO' 0;
  65. 'MESS' '############################################################';
  66. 'MESS' '# LE MAILLAGES MED RELUS N EST PAS CONFORME #';
  67. 'MESS' '# ERREUR NOMBRE DE NOEUDS #';
  68. 'MESS' '############################################################';
  69. 'OPTI' 'ECHO' 1;
  70. 'ERRE' 5;
  71. 'FINS';
  72. * Verification coordonnees identiques
  73. 'SI' (NE_DIF 'NEG' 0);
  74. 'OPTI' 'ECHO' 0;
  75. 'MESS' CHAI2;
  76. 'MESS' '############################################################';
  77. 'MESS' '# LE MAILLAGES MED RELUS N EST PAS CONFORME #';
  78. 'MESS' '# ERREUR CONNECTIVITE #';
  79. 'MESS' '############################################################';
  80. 'OPTI' 'ECHO' 1;
  81. 'ERRE' 5;
  82. 'FINS';
  83. 'FINP';
  84. ************************************************************************
  85. * PROCEDURE POUR VERIFIER UN CHPOINT
  86. ************************************************************************
  87. 'DEBP' VERCHP CHP_CAS*'CHPOINT' CHP_MED*'CHPOINT' NOM_CHP*'MOT';
  88. * A FAIRE !!!
  89. 'FINP';
  90. ************************************************************************
  91. * PROCEDURE POUR VERIFIER UN MCHAML
  92. ************************************************************************
  93. 'DEBP' VERCHM CHM_CAS*'MCHAML' CHM_MED*'MCHAML' LIEU*'MOT' NOM_CHM*'MOT' LENT1*'LISTENTI' LMOT1*'LISTMOTS' XTEMPS*'FLOTTANT';
  94. MOD_CAS ='MODE' ('EXTR' CHM_CAS 'MAILLAGE') 'MECANIQUE' 'CONS' 'MED';
  95. MOD_MED ='MODE' ('EXTR' CHM_MED 'MAILLAGE') 'MECANIQUE' 'CONS' 'MED';
  96. CHM_CAS ='CHAN' 'CONS' CHM_CAS 'MED';
  97.  
  98. CHAI1 ='CHAI' 'MCHAML' ' ' LIEU ' ' NOM_CHM ' ' 'CAST3M';
  99. CHAI2 ='CHAI' 'MCHAML' ' ' LIEU ' ' NOM_CHM ' ' 'LU MED';
  100. 'TRAC' MOD_CAS CHM_CAS 'TITR' CHAI1;
  101. 'TRAC' MOD_MED CHM_MED 'TITR' CHAI2;
  102.  
  103. * Verification : Le champ lu est un champ de coordonnees, on le recree
  104. CHM_TMP='MANU' 'CHML' MOD_MED 'SCAL' 1.0 'TYPE' 'SCALAIRE' LIEU ;
  105. CHM_VER='VIDE' 'MCHAML';
  106. 'REPE' SURI (DIME LMOT1);
  107. ID ='EXTR' LENT1 &SURI;
  108. IMO ='EXTR' LMOT1 &SURI;
  109. CHM_VER=('NOMC' (('COOR' ID CHM_TMP) * (1.D0 + XTEMPS)) IMO) 'ET' CHM_VER ;
  110. 'FIN' SURI;
  111. XDIFF ='MAXI' 'ABS' (CHM_MED - CHM_VER) ;
  112.  
  113. 'SI' (XDIFF 'NEG' 0.D0);
  114. 'OPTI' 'ECHO' 0;
  115. 'MESS' CHAI2;
  116. 'MESS' '############################################################';
  117. 'MESS' '# LE MCHAML MED RELUS N EST PAS CONFORME #';
  118. 'MESS' '# ERREUR DE VALEURS #';
  119. 'MESS' '############################################################';
  120. 'ERRE' 5;
  121. 'FINS';
  122. 'FINP';
  123.  
  124. ***********************************************************************
  125. * Lecture d'un MAILLAGE 'NASTRAN' avec plusieurs types d'elements
  126. ***********************************************************************
  127. TAB2 ='LIRE' 'NAS' '/u2/castem/divers/nastran_long.nas' ;
  128. TAB21 ='INDE' (TAB2.'MAILLAGES');
  129.  
  130. ***********************************************************************
  131. * Fabrication des MAILLAGES avant d'exporter au format MED *
  132. ***********************************************************************
  133. MAILTOT ='VIDE' 'MAILLAGE';
  134. 'REPE' SURI ('DIME' TAB21);
  135. MAILTOT = MAILTOT 'ET' (TAB2.'MAILLAGES' . (TAB21 . &SURI));
  136. 'FIN' SURI;
  137.  
  138. * Le MAILLAGE MAILTOT contient 11 types d'elements :
  139. * - 29 element(S) de type SEG2
  140. * - 93 element(S) de type TRI3
  141. * - 164 element(S) de type QUA4
  142. * - 271 element(S) de type TET4
  143. * - 36 element(S) de type PRI6
  144. * - 84 element(S) de type CUB8
  145. *
  146. * - 29 element(S) de type TRI6
  147. * - 27 element(S) de type QUA8
  148. * - 271 element(S) de type TE10
  149. * - 24 element(S) de type PR15
  150. * - 12 element(S) de type CU20
  151.  
  152. P1 = 'NOEU' 1 ;
  153. P2 = 'NOEU' 10 ;
  154. P3 = 'NOEU' 100 ;
  155.  
  156. MSEG2 ='ELEM' MAILTOT 'SEG2';
  157. MTRI3 ='ELEM' MAILTOT 'TRI3';
  158. MQUA4 ='ELEM' MAILTOT 'QUA4';
  159. MTET4 ='ELEM' MAILTOT 'TET4';
  160. MPRI6 ='ELEM' MAILTOT 'PRI6';
  161. MCUB8 ='ELEM' MAILTOT 'CUB8';
  162. MTRI6 ='ELEM' MAILTOT 'TRI6';
  163. MQUA8 ='ELEM' MAILTOT 'QUA8';
  164. MTE10 ='ELEM' MAILTOT 'TE10';
  165. MPR15 ='ELEM' MAILTOT 'PR15';
  166. MCU20 ='ELEM' MAILTOT 'CU20';
  167.  
  168. ***********************************************************************
  169. * Sortie MED des MAILLAGES (SIMPLES & COMPLEXES)
  170. ***********************************************************************
  171. 'OPTI' 'SORT' 'MED_MAILLAGE_simple.med';
  172. 'SORT' 'MED' MTRI3 ;
  173.  
  174. 'OPTI' 'SORT' 'MED_MAILLAGE_complexe.med';
  175. 'SORT' 'MED' MAILTOT ;
  176.  
  177. ***********************************************************************
  178. * Sortie MED des CHPOINTS
  179. ***********************************************************************
  180. CHPX1 ='CHAN' 'COMP' ('COOR' 1 MTRI3 ) 'UX';
  181. CHPY1 ='CHAN' 'COMP' ('COOR' 2 MAILTOT) 'UY';
  182.  
  183. CHPTOT= CHPX1 'ET' CHPY1 ;
  184. 'OPTI' 'SORT' 'MED_CHPOIN_simple.med';
  185. 'SORT' 'MED' CHPX1;
  186.  
  187. 'OPTI' 'SORT' 'MED_CHPOIN_complexe.med';
  188. 'SORT' 'MED' CHPTOT;
  189.  
  190. 'OPTI' 'SORT' 'MED_CHPOIN_melange.med';
  191. 'SORT' 'MED' CHPX1 CHPY1 CHPTOT;
  192.  
  193. ***********************************************************************
  194. * Sortie MED des MCHAML
  195. ***********************************************************************
  196. * MCHAML au GRAVITE (1 SOUS-ZONE et 11 SOUS-ZONES)
  197. MOD1a ='MODE' MTRI3 'MECANIQUE' ;
  198. MOD1b ='MODE' MAILTOT 'MECANIQUE' ;
  199. CHA1a ='MANU' 'CHML' MOD1a 'SCAL' 1.0 'GRAVITE';
  200. CHA1b ='MANU' 'CHML' MOD1b 'SCAL' 1.0 'GRAVITE';
  201.  
  202. CHAX1 ='NOMC' ('COOR' 1 CHA1a) 'UX';
  203. CHAY1 ='NOMC' ('COOR' 2 CHA1b) 'UY';
  204.  
  205. 'OPTI' 'SORT' 'MED_MCHAML_GRAVITE_SZ1.med';
  206. 'SORT' 'MED' CHAX1 ;
  207.  
  208. 'OPTI' 'SORT' 'MED_MCHAML_GRAVITE_SZ11.med';
  209. 'SORT' 'MED' CHAY1 ;
  210.  
  211. * MCHAML au NOEUD (1 SOUS-ZONE et 11 SOUS-ZONES)
  212. CHA2a ='MANU' 'CHML' MOD1a 'SCAL' 1.0 'NOEUD';
  213. CHA2b ='MANU' 'CHML' MOD1b 'SCAL' 1.0 'NOEUD';
  214. CHAZ1 ='NOMC' ('COOR' 3 CHA2a) 'UZ';
  215. CHAZ2 ='NOMC' ('COOR' 3 CHA2b) 'UZ';
  216.  
  217. 'OPTI' 'SORT' 'MED_MCHAML_NOEUD_SZ1.med';
  218. 'SORT' 'MED' CHAZ1 ;
  219.  
  220. 'OPTI' 'SORT' 'MED_MCHAML_NOEUD_SZ11.med';
  221. 'SORT' 'MED' CHAZ2;
  222.  
  223. * MCHAML melange (NOEUD & GRAVITE, 1 SOUS-ZONE et 11 SOUS-ZONES)
  224. 'OPTI' 'SORT' 'MED_MCHAML_melange.med';
  225. 'SORT' 'MED' CHAX1 CHAY1 CHAZ1 CHAZ2;
  226.  
  227.  
  228.  
  229. ***********************************************************************
  230. * Sortie MED d'une TABLE de SOUS-TYPE PASAPAS
  231. ***********************************************************************
  232. COO1 COO2 COO3 ='COOR' MAILTOT;
  233. COO1 ='NOMC' COO1 'CX';
  234. COO2 ='NOMC' COO2 'CY';
  235. COO3 ='NOMC' COO3 'CZ';
  236. COOCHP = COO1 'ET' COO2 'ET' COO3 ;
  237.  
  238. COO1 COO2 COO3 ='COOR' CHA1b ;
  239. COO1 ='NOMC' COO1 'MX';
  240. COO2 ='NOMC' COO2 'MY';
  241. COO3 ='NOMC' COO3 'MZ';
  242. COOCHMG = COO1 'ET' COO2 'ET' COO3 ;
  243.  
  244. COO1 COO2 COO3 ='COOR' CHA2b ;
  245. COO1 ='NOMC' COO1 'NX';
  246. COO2 ='NOMC' COO2 'NY';
  247. COO3 ='NOMC' COO3 'NZ';
  248. COOCHMN = COO1 'ET' COO2 'ET' COO3 ;
  249.  
  250. LTPS1 ='PROG' 0.D0 'PAS' 0.5D0 1.5D0 ;
  251. NBTPS ='DIME' LTPS1;
  252.  
  253. TPASAP ='TABL';
  254. TPASAP.'SOUSTYPE'='MOT' 'PASAPAS' ;
  255. TPASAP.'MODELE' = MOD1b ;
  256.  
  257. TPASAP.'TEMPS' ='TABL' ;
  258. TPASAP.'COORDONNEES_CHPOINT1'='TABL' ;'COMM' 'Un seul MSOUPO dans le CHPOINT';
  259. TPASAP.'MCHAML_GRAVI1' ='TABL' ;'COMM' 'Un seul constituant dans le MCHAML aux GRAVITE';
  260. TPASAP.'MCHAML_NOEUD1' ='TABL' ;'COMM' 'Un seul constituant dans le MCHAML aux NOEUDS' ;
  261. 'REPE' SURI NBTPS;
  262. II =&SURI;
  263. Xtps ='EXTR' LTPS1 II ;
  264.  
  265. TPASAP.'TEMPS' . (II - 1) = Xtps ;
  266. TPASAP.'COORDONNEES_CHPOINT1'. (II - 1) =(COOCHP + 1.D0) * ( 1.D0 + Xtps) ;
  267. TPASAP.'MCHAML_GRAVI1' . (II - 1) =(COOCHMG + 1.D0) * ( 1.D0 + Xtps) ;
  268. TPASAP.'MCHAML_NOEUD1' . (II - 1) =(COOCHMN + 1.D0) * ( 1.D0 + Xtps) ;
  269. 'FIN' SURI;
  270.  
  271. * TABLE de SOUSTYPE 'PASAPAS' avec CHPOINT, MCHAML (GRAVITE & NOEUDS)
  272. 'OPTI' 'SORT' 'MED_PASAPAS.med';
  273. 'SORT' 'MED' TPASAP ;
  274.  
  275.  
  276. *#####################################################################*
  277. * Verification relecture des MAILLAGES
  278. *#####################################################################*
  279. TAB1 ='LIRE' 'MED' 'MED_MAILLAGE_simple.med' ;
  280. TAB2 ='LIRE' 'MED' 'MED_MAILLAGE_complexe.med';
  281.  
  282. *#####################################################################*
  283. * Validation relecture des MAILLAGES
  284. *#####################################################################*
  285. 'LIST' TAB1;
  286. MTRI3a = TAB1.'MTRI3' ;
  287. VERMAI MTRI3 MTRI3a 'MTRI3';
  288.  
  289. 'LIST' TAB2;
  290. MAILTOTa= TAB2.'MAILTOT';
  291. MSEG2a = TAB2.'MSEG2' ;
  292. MCU20a = TAB2.'MCU20' ;
  293. MPR15a = TAB2.'MPR15' ;
  294. MTE10a = TAB2.'MTE10' ;
  295. MQUA8a = TAB2.'MQUA8' ;
  296. MTRI6a = TAB2.'MTRI6' ;
  297. MCUB8a = TAB2.'MCUB8' ;
  298. MPRI6a = TAB2.'MPRI6' ;
  299. MTET4a = TAB2.'MTET4' ;
  300. MQUA4a = TAB2.'MQUA4' ;
  301. MTRI3a = TAB2.'MTRI3' ;
  302.  
  303. VERMAI MAILTOT MAILTOTa 'MAILTOT';
  304. VERMAI MSEG2 MSEG2a 'MSEG2' ;
  305. VERMAI MCU20 MCU20a 'MCU20' ;
  306. VERMAI MPR15 MPR15a 'MPR15' ;
  307. VERMAI MTE10 MTE10a 'MTE10' ;
  308. VERMAI MQUA8 MQUA8a 'MQUA8' ;
  309. VERMAI MTRI6 MTRI6a 'MTRI6' ;
  310. VERMAI MCUB8 MCUB8a 'MCUB8' ;
  311. VERMAI MPRI6 MPRI6a 'MPRI6' ;
  312. VERMAI MTET4 MTET4a 'MTET4' ;
  313. VERMAI MQUA4 MQUA4a 'MQUA4' ;
  314. VERMAI MTRI3 MTRI3a 'MTRI3' ;
  315.  
  316. *#####################################################################*
  317. * Verification relecture des CHPOINT
  318. *#####################################################################*
  319. TAB3 ='LIRE' 'MED' 'MED_CHPOIN_simple.med' ;
  320. TAB4 ='LIRE' 'MED' 'MED_CHPOIN_complexe.med';
  321. TAB5 ='LIRE' 'MED' 'MED_CHPOIN_melange.med' ;
  322.  
  323. *#####################################################################*
  324. * Validation relecture des CHPOINT
  325. *#####################################################################*
  326. * CONTROLE VISUEL POUR LE MOMENT, COMPARER LES VALEURS !!! A FAIRE !!!
  327. 'LIST' TAB3;
  328. CHPX2 = TAB3.'CHPX1';
  329. 'TRAC' CHPX1 MTRI3 'TITR' 'CHPOINT_SIMPLE CAST3M';
  330. 'TRAC' CHPX2 TAB3.'MTRI3' 'TITR' 'CHPOINT_SIMPLE LU MED';
  331.  
  332. *Verification : Le champ lu est un champ de coordonnees, on le recree
  333. MMED ='EXTR' CHPX2 'MAILLAGE' ;
  334. MORI ='EXTR' CHPX1 'MAILLAGE' ;
  335. NBMED ='NBEL' MMED;
  336. NBORI ='NBEL' MORI;
  337. 'SI' ('NEG' NBMED NBORI);
  338. 'OPTI' 'ECHO' 0;
  339. 'MESS' '############################################################';
  340. 'MESS' '# LE CHPOINT MED CHPX1 RELUS EST NON CONFORMES AU #';
  341. 'MESS' '# CHPOINT EXPORTE : NOMBRE ELEMENTS INCORRECT #';
  342. CHA1 ='CHAI' '# :' NBORI ':' NBMED ':';
  343. 'MESS' CHA1 ;
  344. 'MESS' '############################################################';
  345. 'OPTI' 'ECHO' 1;
  346. 'ERRE' 5;
  347. 'FINS';
  348.  
  349. CHPX2v ='CHAN' 'COMP' ('COOR' 1 MMED ) 'UX';
  350. ValX2 ='MAXI' 'ABS' (CHPX2 - CHPX2v) ;
  351. 'SI' ('NEG' ValX2 0.D0);
  352. 'OPTI' 'ECHO' 0;
  353. 'MESS' '############################################################';
  354. 'MESS' '# LE CHPOINT MED CHPX1 RELUS EST NON CONFORMES AU #';
  355. 'MESS' '# CHPOINT EXPORTE : VALEURS INCORRECTES #';
  356. 'MESS' '############################################################';
  357. 'OPTI' 'ECHO' 1;
  358. 'ERRE' 5;
  359. 'FINS';
  360.  
  361. 'LIST' TAB4;
  362. CHPTO2 = TAB4.'CHPTOT_1' 'ET' TAB4.'CHPTOT_2';
  363. CHPX2 ='CHAN' 'COMP' ('COOR' 1 TAB4.'MTRI3' ) 'UX';
  364. CHPY2 ='CHAN' 'COMP' ('COOR' 2 TAB4.'MAILTOT') 'UY';
  365. 'TRAC' CHPX1 MTRI3 'TITR' 'CHPOINT_COMPLEXE CAST3M, UX';
  366. 'TRAC' CHPX2 TAB4.'MTRI3' 'TITR' 'CHPOINT_COMPLEXE LU MED, UX';
  367. 'TRAC' CHPY1 MAILTOT 'TITR' 'CHPOINT_COMPLEXE CAST3M, UY';
  368. 'TRAC' CHPY2 TAB4.'MAILTOT' 'TITR' 'CHPOINT_COMPLEXE LU MED, UY';
  369.  
  370. *Verification : Le champ lu est un champ de coordonnees, on le recree
  371. CHPX2v ='CHAN' 'COMP' ('COOR' 1 ('EXTR' CHPX2 'MAILLAGE')) 'UX';
  372. CHPY2v ='CHAN' 'COMP' ('COOR' 2 ('EXTR' CHPY2 'MAILLAGE')) 'UY';
  373. ValX2 ='MAXI' 'ABS' (CHPX2 - CHPX2v);
  374. ValY2 ='MAXI' 'ABS' (CHPY2 - CHPY2v);
  375.  
  376. 'SI' ('NEG' ValX2 0.D0);
  377. 'OPTI' 'ECHO' 0;
  378. 'MESS' '############################################################';
  379. 'MESS' '# LE CHPOINT MED CHPX1 RELUS EST NON CONFORMES AU #';
  380. 'MESS' '# CHPOINT EXPORTE : VALEURS INCORRECTES #';
  381. 'MESS' '############################################################';
  382. 'OPTI' 'ECHO' 1;
  383. 'ERRE' 5;
  384. 'FINS';
  385. 'SI' ('NEG' ValY2 0.D0);
  386. 'OPTI' 'ECHO' 0;
  387. 'MESS' '############################################################';
  388. 'MESS' '# LE CHPOINT MED CHPY1 RELUS EST NON CONFORMES AU #';
  389. 'MESS' '# CHPOINT EXPORTE : VALEURS INCORRECTES #';
  390. 'MESS' '############################################################';
  391. 'OPTI' 'ECHO' 1;
  392. 'ERRE' 5;
  393. FINS ;
  394.  
  395. 'LIST' TAB5;
  396. CHPX2 = TAB5.'CHPX1';
  397. CHPY2 = TAB5.'CHPY1';
  398. CHPTOX ='EXCO' (TAB5.'CHPTOT_1' 'ET' TAB5.'CHPTOT_2') 'UX' 'UX';
  399. CHPTOY ='EXCO' (TAB5.'CHPTOT_1' 'ET' TAB5.'CHPTOT_2') 'UY' 'UY';
  400. 'TRAC' CHPX1 MTRI3 'TITR' 'MED CHPOIN MELANGE : CHPX1 CAST3M' ;
  401. 'TRAC' CHPX2 TAB5.'MTRI3' 'TITR' 'MED CHPOIN MELANGE : CHPX1 LU MED' ;
  402. 'TRAC' CHPY1 MAILTOT 'TITR' 'MED CHPOIN MELANGE : CHPY1 CAST3M' ;
  403. 'TRAC' CHPY2 TAB5.'MAILTOT' 'TITR' 'MED CHPOIN MELANGE : CHPY1 LU MED' ;
  404. 'TRAC' CHPX1 MTRI3 'TITR' 'MED CHPOIN MELANGE : CHPTOT CAST3M, UX';
  405. 'TRAC' CHPTOX TAB5.'MTRI3' 'TITR' 'MED CHPOIN MELANGE : CHPTOT LU MED, UX';
  406. 'TRAC' CHPY1 MAILTOT 'TITR' 'MED CHPOIN MELANGE : CHPTOT CAST3M, UY';
  407. 'TRAC' CHPTOY TAB5.'MAILTOT' 'TITR' 'MED CHPOIN MELANGE : CHPTOT LU MED, UY';
  408.  
  409. *#####################################################################*
  410. * Verification relecture des MCHAML
  411. *#####################################################################*
  412. TAB6 ='LIRE' 'MED' 'MED_MCHAML_GRAVITE_SZ1.med' ;
  413. TAB7 ='LIRE' 'MED' 'MED_MCHAML_GRAVITE_SZ11.med';
  414. TAB8 ='LIRE' 'MED' 'MED_MCHAML_NOEUD_SZ1.med' ;
  415. TAB9 ='LIRE' 'MED' 'MED_MCHAML_NOEUD_SZ11.med' ;
  416. TAB10='LIRE' 'MED' 'MED_MCHAML_melange.med' ;
  417.  
  418. *#####################################################################*
  419. * Validation relecture des MCHAML
  420. *#####################################################################*
  421. 'LIST' TAB6;
  422. CHAX1a = TAB6.'CHAX1';
  423. VERCHM CHAX1 CHAX1a 'GRAVITE' 'CHAX1' (LECT 1) (MOTS 'UX') 0.D0;
  424.  
  425. 'LIST' TAB7;
  426. CHAY1a = TAB7.'CHAY1';
  427. VERCHM CHAY1 CHAY1a 'GRAVITE' 'CHAY1' (LECT 2) (MOTS 'UY') 0.D0;
  428.  
  429. 'LIST' TAB8;
  430. CHAZ1a = TAB8.'CHAZ1';
  431. VERCHM CHAZ1 CHAZ1a 'NOEUD' 'CHAZ1' (LECT 3) (MOTS 'UZ') 0.D0;
  432.  
  433. 'LIST' TAB9;
  434. CHAZ2a = TAB9.'CHAZ2';
  435. VERCHM CHAZ2 CHAZ2a 'NOEUD' 'CHAZ2' (LECT 3) (MOTS 'UZ') 0.D0;
  436.  
  437. 'LIST' TAB10;
  438. CHAX1a = TAB10.'CHAX1';
  439. CHAY1a = TAB10.'CHAY1';
  440. CHAZ1a = TAB10.'CHAZ1';
  441. CHAZ2a = TAB10.'CHAZ2';
  442.  
  443. VERCHM CHAX1 CHAX1a 'GRAVITE' 'CHAX1' (LECT 1) (MOTS 'UX') 0.D0;
  444. VERCHM CHAY1 CHAY1a 'GRAVITE' 'CHAY1' (LECT 2) (MOTS 'UY') 0.D0;
  445. VERCHM CHAZ1 CHAZ1a 'NOEUD' 'CHAZ1' (LECT 3) (MOTS 'UZ') 0.D0;
  446. VERCHM CHAZ2 CHAZ2a 'NOEUD' 'CHAZ2' (LECT 3) (MOTS 'UZ') 0.D0;
  447.  
  448. *#####################################################################*
  449. * Verification relecture des TABLES de SOUSTYPE 'PASAPAS'
  450. *#####################################################################*
  451. TAB11='LIRE' 'MED' 'MED_PASAPAS.med';
  452. 'LIST' TAB11;
  453.  
  454. *#####################################################################*
  455. * Validation relecture des TABLES de SOUSTYPE 'PASAPAS'
  456. *#####################################################################*
  457.  
  458. FIN;
  459.  
  460.  
  461.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales