Télécharger joi22.dgibi

Retour à la liste

Numérotation des lignes :

  1. * fichier : joi22.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4. * Test Joi22.dgibi: Jeux de données *
  5. * --------------------------------- *
  6. * *
  7. OPTI ECHO 0 ;
  8. SAUT PAGE ;
  9. MESS'!==============================================!';
  10. MESS'! !';
  11. MESS'! TEST JOI22 !';
  12. MESS'! !';
  13. MESS'! ESSAI DE TRACTION SUR UN JOINT 2D !';
  14. MESS'! !';
  15. MESS'! Un joint 2D JOI2 a son bord inferieur !';
  16. MESS'! encastre. !';
  17. MESS'! Son bord superieur est libre. Un effort de !';
  18. MESS'! traction est exercé sur son bord superieur. !';
  19. MESS'! !';
  20. MESS'! !';
  21. MESS'! Solution analytique : !';
  22. MESS'! !';
  23. MESS'! En ecrivant le principe des travaux !';
  24. MESS'! virtuels,on montre que le deplacement delta !';
  25. MESS'! en chaque noeud est egal, dans le cas d un !';
  26. MESS'! essai de traction uniaxial, a : !';
  27. MESS'! F !';
  28. MESS'! delta = ---------------- !';
  29. MESS'! k * L * l !';
  30. MESS'! ou !';
  31. MESS'! F = force totale exercee sur la structure !';
  32. MESS'! k = raideur !';
  33. MESS'! L = longueur de l element joint !';
  34. MESS'! l = largeur de l element joint !';
  35. MESS'! !';
  36. MESS'! Application numerique : !';
  37. MESS'! !';
  38. MESS'! F = 100000.0 !';
  39. MESS'! k = 4.2E10 !';
  40. MESS'! L = 2.0 !';
  41. MESS'! l = 1.0 !';
  42. MESS'! !';
  43. MESS'! Delta = 100000 / (4.2E10 * 2.0 * 1.0) !';
  44. MESS'! = 1.19047619E-6 !';
  45. MESS'! !';
  46. MESS'!==============================================!';
  47. OPTION DIME 2 ;
  48. OPTION ELEM SEG2 MODE PLAN CONT ;
  49. *
  50. SOLANA = 1.190476E-6 ;
  51. SOLNUL = 0.0 ;
  52. *
  53. * ------- DEFINITION DE LA SURFACE TOP DU JOINT -------
  54. *
  55. A1 = 0.00 0.00 ;
  56. B1 = 2.00 0.00 ;
  57. *
  58. * ---------- MAILLAGE ----------
  59. *
  60. H1 = A1 DROIT 1 B1 ;
  61. *
  62. L1 = H1 ;
  63. *
  64. * ------ DEFINITION DE LA SURFACE BOT DU JOINT --------
  65. *
  66. IA1 = 0.00 0.00 ;
  67. IB1 = 2.00 0.00 ;
  68. *
  69. * ---------- MAILLAGE ----------
  70. *
  71. IH1 = IA1 DROIT 1 IB1 ;
  72. *
  73. IL1 = IH1 ;
  74. *
  75. * ---------- CREATION DU JOINT JOI2 ----------
  76. *
  77. OPTION ELEM RAC2 ;
  78. VOL = RACCORD 0.00001 L1 IL1 ;
  79. *
  80. * --------- DEFINITION DES CONDITIONS LIMITES ---------
  81. *
  82. CL11 = BLOQ IA1 UX ;
  83. CL12 = BLOQ IA1 UY ;
  84. CL1 = CL11 ET CL12 ;
  85. *
  86. CL21 = BLOQ IB1 UX ;
  87. CL22 = BLOQ IB1 UY ;
  88. CL2 = CL21 ET CL22 ;
  89. *
  90. CL = CL1 ET CL2 ;
  91. *
  92. * ----- DEFINITION DU MODELE DU JOINT ---------
  93. *
  94. MOD1 =MODE VOL 'MECANIQUE' 'ELASTIQUE' 'ISOTROPE' JOI2;
  95. MA1 = MATE MOD1 KS 4.2E08 KN 4.2E10 ;
  96. *
  97. * ------------- MATRICE DE HOOK ------------
  98. *
  99. HOO1 = HOOKE MOD1 MA1 ;
  100. ******LIST HOO1 ;
  101. *
  102. * ---------- MATRICE DE RIGIDITE ---------
  103. *
  104. ******RI1 = RIGI MOD1 MA1 ;
  105. RI1 = RIGI MOD1 HOO1 ;
  106. RI2 = RI1 ET CL ;
  107. *
  108. * ---------- FORCE DE TRACTION ---------
  109. *
  110. FO1 = FORCE ( 0. 100000.0 ) L1 ;
  111. *
  112. * --------- RESOLUTION ----------
  113. *
  114. RE = RESO RI2 FO1 ;
  115. MESS ' ' ;
  116. MESS ' ' ;
  117. MESS ' Solution Analytique :' ;
  118. MESS ' ' ;
  119. MESS ' UX =' SOLNUL ;
  120. MESS ' UY =' SOLANA ;
  121. MESS ' ' ;
  122. MESS ' ' ;
  123. MESS ' ' ;
  124. MESS ' Solution Calculee :' ;
  125. MESS ' ' ;
  126. LIST RE ;
  127. *
  128. * ---------- CODE DE FONCTIONNEMENT ----------
  129. *
  130. DEPA1 = EXTR RE UY A1 ;
  131. RESI = ABS( (DEPA1-SOLANA)/SOLANA ) ;
  132. *
  133. SI (RESI <EG 1E-4 ) ;
  134. ERRE 0 ;
  135. SINO;
  136. ERRE 5 ;
  137. FINSI ;
  138. *
  139. * ---------- CALCUL DES DEFORMATIONS ----------
  140. *
  141. EPS1 = EPSI MOD1 RE ;
  142. LIST EPS1 ;
  143. *
  144. * ---------- CALCUL DES CONTRAINTES ----------
  145. *
  146. SIG1 = SIGMA MOD1 MA1 RE ;
  147. LIST SIG1 ;
  148. *
  149. FIN ;
  150.  
  151.  
  152.  
  153.  
  154.  
  155.  
  156.  
  157.  
  158.  
  159.  
  160.  
  161.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales