Télécharger harttrac.dgibi

Retour à la liste

Numérotation des lignes :

  1. * fichier : harttrac.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4. *======================================================================*
  5. * MODELE HYPERELASTIQUE HART-SMITH INCOMPRESSIBLE *
  6. * EN GRANDES TRANSFORMATIONS - CONTRAINTES PLANES *
  7. * *
  8. * TEST DE VALIDATION DU MODELE : TRACTION SELON LA DIRECTION Y *
  9. * COMPARAISON AVEC LA SOLUTION ANALYTIQUE *
  10. * *
  11. * Contribution de Laurent Gornet - Ecole Centrale de Nantes (2010) *
  12. *======================================================================*
  13. * Pour plus d'informations, voir la presentation de L. Gornet lors *
  14. * du Club Cast3m 2009, disponible sur le site Web de Cast3m. *
  15. *======================================================================*
  16. * Exemple d'utilisation d'un modele UMAT en grandes transformations *
  17. * *
  18. * Note : Actuellement en grandes deformations dans PASAPAS, le modele *
  19. * ne peut contenir que des modeles de type UMAT. On ne peut *
  20. * pas melanger les derivees objectives et les modeles de C3m. *
  21. *======================================================================*
  22.  
  23. 'OPTION' 'DIME' 2 'MODE' 'PLAN' 'CONT' 'ECHO' 0 ;
  24.  
  25. * Mettre VRAI si l'on souhaite divers traces.
  26. GRAPH = VRAI ;
  27. GRAPH = FAUX ;
  28. title = 'CHAINE' 'HART-SMITH - ' 'TRACTION UNIAXIALE Y' ;
  29.  
  30. *======================================================================*
  31. * Geometrie - Maillage *
  32. *======================================================================*
  33. * Longueur (direction x) de la plaque/membrane :
  34. Lg_x = 1. ;
  35. * Largeur (direction y) de la plaque/membrane :
  36. Lg_y = 1. ;
  37. * Nombre d'elements selon les directions x et y :
  38. Nel_x = 3;
  39. Nel_y = 4 ;
  40. * 'TRI6' 'TRI3' 'QUA8'
  41. 'OPTION' 'ELEM' 'QUA4' ;
  42. *
  43. P1 = 0. 0. ;
  44. P2 = Lg_x 0. ;
  45. P3 = Lg_x Lg_y ;
  46. P4 = 0. Lg_y ;
  47. *
  48. L1 = 'DROITE' Nel_x P1 P2 ;
  49. L2 = 'DROITE' Nel_y P2 P3 ;
  50. L3 = 'DROITE' Nel_x P3 P4 ;
  51. L4 = 'DROITE' Nel_y P4 P1 ;
  52. *
  53. SU = 'DALLER' L1 L2 L3 L4 ;
  54. 'SI' GRAPH ;
  55. 'TRACER' SU 'TITRE' ('CHAINE' title ' - MAILLAGE') ;
  56. 'FINSI' ;
  57.  
  58. *======================================================================*
  59. * Modele - Materiau - Caracteristiques (en Pa) *
  60. *======================================================================*
  61. 'SI' (('NEG' ('VALEUR' 'DIME') 2) 'OU'
  62. ('NEG' ('VALEUR' 'MODE') 'PLANCONT')) ;
  63. 'MESS' 'Ce modele ne fonctionne qu en 2D CONTRAINTES PLANES' ;
  64. 'ERREUR' 5 ;
  65. 'FINSI' ;
  66. * Calcul du Module d'Young
  67. * Ne pas oublier de definir les parametres lies a l'elasticite.
  68. * Meme si ce n'est pas utilise dans le modele, cela est utile pour
  69. * l'operateur de convergence mecanique de PASAPAS-INCREME.
  70. *
  71. LCMAT = MOTS 'YOUN' 'NU ' 'G' 'K1' 'K2' ;
  72. MO = MODE SU 'MECANIQUE' 'ELASTIQUE' 'ISOTROPE'
  73. 'NON_LINEAIRE' 'UTILISATEUR'
  74. 'NUME_LOI' 34 'C_MATERIAU' LCMAT ;
  75. *
  76. * Pour calculer le module d'Young, on utilise les
  77. * Coefficients du modele de Mooney-Rivlin (en MPa) :
  78. *
  79. C1 = 0.183 ; C2 = 0.0034 ;
  80. *
  81. * On fixe le coefficient de Poisson XNU a une valeur proche de 0.5
  82. * du fait de l'incompressibilite inherente au modele.
  83. * Le module de Young YOU est alors connu, car, pour ce modele, le
  84. * module de cisaillement MU vaut : MU = YOU/(2*(1+XNU)) = 2.(C1+C2)
  85. * Il s'agit de la valeur initiale et de la borne inferieure dans le cas
  86. * de la traction. En fonction du niveau de deformation atteinte en
  87. * traction, il faut augmenter cette valeur afin de pouvoir faire
  88. * converger les calculs (module tangent en fin de calculs).
  89. * Prendre des valeurs superieures n'entraine pas de modification des
  90. * resultats, cela modifie seulement le nombre d'iterations mecaniques.
  91. *
  92. XNU = 0.499 ;
  93. YOUini = 3.*(2.*(C1+C2)) ; YOU = 10000. * YOUini ;
  94. *
  95. *Parametres du modèle HS : essais Treloar/Kawabata MPa
  96. G = 0.175 ;
  97. K1 = 2.86E-4 ;
  98. K2 = 0.311 ;
  99. *
  100. MA = MATE MO 'YOUN' YOU 'NU ' XNU 'G' G 'K1' K1 'K2' K2 ;
  101. *
  102. *
  103. *======================================================================*
  104. * Conditions aux limites - Traction suivant UY *
  105. *======================================================================*
  106. BL1 = 'BLOQUER' 'UY ' L1 ;
  107. BL2 = 'BLOQUER' 'UY ' L3 ;
  108. BL4 = 'BLOQUER' 'UX ' P1 ;
  109. BLTOT = BL1 'ET' BL2 'ET' BL4 ;
  110. *
  111. * Definition des instants du chargement :
  112. t_deb = 0. ; t_fin = 10. ;
  113. L_tps = 'PROG' t_deb t_fin ;
  114. * Deplacement suivant Y :
  115. L_UY = 'PROG' 0. ( 7. * Lg_y) ;
  116. FF_y = 'DEPIMP' BL2 1. ;
  117. EV_y = 'EVOL' 'MANU' 'TEMPS' L_tps 'LAMY' L_UY ;
  118. *
  119. CHARTOT = 'CHARGEMENT' 'DIMP' FF_y EV_y ;
  120. *
  121. *======================================================================*
  122. * Initialisation de la table pour appel a PASAPAS *
  123. *======================================================================*
  124. TAB1 = 'TABLE' ;
  125. TAB1.'MODELE' = MO ;
  126. TAB1.'CARACTERISTIQUES' = MA ;
  127. TAB1.'BLOCAGES_MECANIQUES' = BLTOT ;
  128. TAB1.'CHARGEMENT' = CHARTOT ;
  129. ***** LG
  130. *TAB1 . 'DELTAITER' = 150;
  131. *TAB1.'PRECISION' = 1.E-5 ;
  132. *TAB1.'FTOL' = 1.E-5 ;
  133. *TAB1.'MTOL' = 1.E-5 ;
  134. *****
  135. TAB1.'CONVERGENCE_FORCEE' = FAUX ;
  136. TAB1.'GRANDS_DEPLACEMENTS' = VRAI ;
  137. TAB1.'HYPOTHESE_DEFORMATIONS' = MOT 'UTILISATEUR' ;
  138. TAB1.'TEMPS_CALCULES' = 'PROG' t_deb 'PAS' 0.1 t_fin ;
  139. TAB1.'TEMPS_SAUVES' = 'PROG' t_deb 'PAS' 0.5 t_fin ;
  140. tab1.'REAC_GRANDS'=500.;
  141. *
  142. L_abs = TAB1.'TEMPS_SAUVES' ;
  143. n_abs = 'DIMENSION' L_abs ;
  144. *
  145. PASAPAS TAB1 ;
  146. *
  147. * Quelques traces de controle apres calculs
  148. 'SI' GRAPH ;
  149. Defo_0 = 'DEFORMEE' SU (TAB1.'DEPLACEMENTS'.(n_abs-1)) 0. ;
  150. Defo_1 = 'DEFORMEE' SU (TAB1.'DEPLACEMENTS'.(n_abs-1)) 1. 'VERT' ;
  151. 'TRACER' (Defo_0 'ET' Defo_1)
  152. 'TITRE' ('CHAINE' title ' - DEFORMEES INITIALE ET FINALE') ;
  153. 'TRACER' MO (TAB1.'CONTRAINTES'.(n_abs-1))
  154. 'TITRE' ('CHAINE' title ' - CONTRAINTES EN FIN DE CALCUL') ;
  155. 'FINSI' ;
  156. *
  157. *======================================================================*
  158. * Construction de la solution analytique *
  159. *======================================================================*
  160. * Definitions :
  161. * - Allongement selon direction y : Lamy = 1 + (UY/Lg_y)
  162. * - Densite d'energie de deformation hyperelastique : W(I1,I2)
  163. * - I1, I2 : trois invariants du tenseur de Cauchy-Green droit
  164. * Dans le cas du modele de HART-SMITH :
  165. * dW/dI1 = G * exp (k1 * (I1 - 3)**2) et dW/dI2 = G * k2 * 1 / I2
  166. *
  167. * Les contraintes de Cauchy sont calculables analytiquement :
  168. * - SCxx = 0.
  169. * - SCyy = 2.(Lamy**2 - 1./Lamy).(dW/dI1 + 1./Lamy.dW/dI2)
  170. * - SCxy = 0 (pas de cisaillement)
  171. * - SCzz = 0 (hypothese des contraintes planes)
  172. *
  173. L_Un = 'PROG' n_abs '*' 1. ;
  174. Lamy = L_Un + (('IPOL' L_abs L_tps L_UY) / Lg_Y) ;
  175. *
  176. L_z1 = Lamy * Lamy ; L_z2 = L_Un / Lamy ;
  177. * LG modif hartsmith !! averifier
  178. L_tr = L_Un * 3.;
  179. I1 = L_z1 + (2. * L_z2);
  180. I2 = (2. * Lamy) + ( L_Un / L_z1 );
  181. **********************************************************************
  182. dWI1= G * (exp (k1 *((I1 - L_tr)**2)));
  183. dWI2= G * k2 * L_Un / I2;
  184. **********************************************************************
  185. SCxx_th = 0. * L_Un ;
  186. SCyy_th =(L_z1 - L_z2) * ((2.*dWI1*L_Un) + (2.*dWI2*L_z2)) ;
  187. SCxy_th = 0. * L_Un ;
  188. 'SI' GRAPH ;
  189. Evyy_th = 'EVOL' 'BLEU' 'MANU' 'LAMB' Lamy 'SCYY' SCyy_th ;
  190. *dess Evyy_th ;
  191. Evyy_thP= 'EVOL' 'BLEU' 'MANU' 'LAMB' Lamy 'SCYY' (SCyy_th/Lamy)
  192. @EXCEL1 Evyy_thP 'hartsmith-th' ;
  193. 'FINSI' ;
  194. *======================================================================*
  195. * Comparaison des resultats avec la solution analytique *
  196. *======================================================================*
  197. * La comparaison s'effectue entre les valeurs moyennes des contraintes
  198. * calculees et les solutions analytiques correspondantes.
  199. * On ne cherche pas a verifier l'uniformite du champ de contraintes.
  200. * (Faire le calcul en mettant GRAPH a VRAI et voir les isovaleurs !)
  201. *
  202. TabD = TAB1.'DEPLACEMENTS' ;
  203. TabS = TAB1.'CONTRAINTES' ;
  204. Confini = 'FORM' ;
  205. ChmUn = 'MANU' 'CHML' MO 'SCAL' 1. ;
  206. *
  207. SCxx = 'PROG' 0. ;
  208. SCyy = 'PROG' 0. ;
  209. SCxy = 'PROG' 0. ;
  210. 'REPETER' Boucle (n_abs - 1) ;
  211. 'FORM' (TabD.&Boucle) ;
  212. VolSU = 'INTG' MO ChmUn ;
  213. SCxx = SCxx 'ET' ('PROG' (('INTG' MO (TabS. &Boucle) 'SMXX')/VolSU)) ;
  214. SCyy = SCyy 'ET' ('PROG' (('INTG' MO (TabS. &Boucle) 'SMYY')/VolSU)) ;
  215. SCxy = SCxy 'ET' ('PROG' (('INTG' MO (TabS. &Boucle) 'SMXY')/VolSU)) ;
  216. 'FORM' Confini ;
  217. 'FIN' Boucle ;
  218. * LG lamb
  219. L_abs = Lamy;
  220. *
  221. 'SI' GRAPH ;
  222. tlege = 'TABLE' ;
  223. tlege. 1 = 'MARQ CROI' ;
  224. tlege.'TITRE' = 'TABLE' ;
  225. tlege.'TITRE'. 1 = 'Numerique' ;
  226. tlege.'TITRE'. 2 = 'Analytique' ;
  227. Evxx = 'EVOL' 'ROUG' 'MANU' 'LAMB' L_abs 'SCXX' SCxx ;
  228. Evxx_th = 'EVOL' 'BLEU' 'MANU' 'LAMB' L_abs 'SCXX' SCxx_th ;
  229. 'DESSIN' (Evxx 'ET' Evxx_th) 'LEGE' tlege
  230. 'TITRE' ('CHAINE' title ' - CONTRAINTE DE CAUCHY XX (MPa)') ;
  231. Evyy = 'EVOL' 'ROUG' 'MANU' 'LAMB' L_abs 'SCYY' SCyy ;
  232. Evyy_th = 'EVOL' 'BLEU' 'MANU' 'LAMB' L_abs 'SCYY' SCyy_th ;
  233. 'DESSIN' (Evyy 'ET' Evyy_th) 'LEGE' tlege
  234. 'TITRE' ('CHAINE' title ' - CONTRAINTE DE CAUCHY YY (MPa)') ;
  235. Evxy = 'EVOL' 'ROUG' 'MANU' 'LAMB' L_abs 'SCXY' SCxy ;
  236. Evxy_th = 'EVOL' 'BLEU' 'MANU' 'LAMB' L_abs 'SCXY' SCxy_th ;
  237. 'DESSIN' (Evxy 'ET' Evxy_th) 'LEGE' tlege
  238. 'TITRE' ('CHAINE' title ' - CONTRAINTE DE CAUCHY XY (MPa)');
  239.  
  240. *Essais PK1 Lamb pour essais
  241. Evyy_thP= 'EVOL' 'BLEU' 'MANU' 'LAMB' Lamy 'SCYY' (SCyy_th/Lamy)
  242. @EXCEL1 Evyy_thP 'hartsmith-th' ;
  243. 'FINSI' ;
  244. *
  245. * Tests de bon fonctionnement :
  246. r_z = 'MAXIMUM' ('ABS' SCyy_th) ;
  247. r_xx = 'MAXIMUM' ('ABS' (SCxx - SCxx_th)) / r_z ;
  248. r_yy = 'MAXIMUM' ('ABS' (SCyy - SCyy_th)) / r_z ;
  249. r_xy = 'MAXIMUM' ('ABS' (SCxy - SCxy_th)) / r_z ;
  250. *
  251. MESS ' RESULTATS : ' title ;
  252. MESS ' ------------------------------------------------- ';
  253. 'SAUTER' 1 'LIGNE' ;
  254. 'MESS' ' Tests de bon fonctionnement :' ;
  255. 'MESS' ' -------------------------------' ;
  256. 'MESS' ' Comparaison effectuee sur les contraintes de Cauchy' ;
  257. 'MESS' ' Ecart relatif maximal entre la valeur moyenne '
  258. 'calculee' ;
  259. 'MESS' ' et la '
  260. 'solution analytique associee' ;
  261. 'MESS' ' Composante XX : ' r_xx ;
  262. 'MESS' ' Composante YY : ' r_yy ;
  263. 'MESS' ' Composante XY : ' r_xy ;
  264. 'SAUTER' 1 'LIGNE' ;
  265. * Ecart relatif maximal tolere
  266. Sigref = 1.E-3 ;
  267. 'SI' ('>EG' ('MAXIMUM' ('PROG' r_xx r_yy r_xy)) Sigref) ;
  268. 'MESS' ' ---------------------' ;
  269. 'MESS' ' ECHEC DU CAS-TEST !' ;
  270. 'MESS' ' ---------------------' ;
  271. 'ERREUR' 5 ;
  272. 'SINON' ;
  273. 'MESS' ' ----------------------' ;
  274. 'MESS' ' SUCCES DU CAS-TEST !' ;
  275. 'MESS' ' ----------------------' ;
  276. 'FINSI' ;
  277. 'SAUTER' 1 'LIGNE' ;
  278.  
  279. 'FIN' ;
  280.  
  281.  
  282.  
  283.  
  284.  
  285.  
  286.  
  287.  
  288.  
  289.  
  290.  
  291.  
  292.  
  293.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales