Télécharger flamhms.dgibi

Retour à la liste

Numérotation des lignes :

  1. * fichier : flamhms.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4. GRAPH = FAUX ;
  5.  
  6. ***********************************************************
  7. * COMBUSTION EN REGIME LAMINAIRE - MODELE TRAVIS *
  8. * ON TESTE LES VALEURS DE PRESSION ET DE TEMPERATURE AICC *
  9. ***********************************************************
  10.  
  11. opti elem qua8 ;
  12. opti isov suli ;
  13.  
  14. nx = 8 ;
  15. ny = 8 ;
  16.  
  17. p1 = -1. 0 ;
  18. p2 = 1. 0 ;
  19. p3 = 1. 2.0 ;
  20. p4 = -1. 2.0 ;
  21. bas = p1 d nx p2 ;
  22. dro = p2 d ny p3 ;
  23. hau = p3 d nx p4 ;
  24. gau = p4 d ny p1 ;
  25.  
  26. MT = 'DALLER' BAS DRO HAU GAU 'PLAN' ;
  27.  
  28. ***************************
  29. * MODELES 'NAVIER_STOKES' *
  30. ***************************
  31.  
  32. MMT = CHAN MT QUAF ;
  33. $MT = 'MODE' MMT 'NAVIER_STOKES' 'MACRO' ;
  34. DOMA $MT 'IMPR' ;
  35. mt = doma $mt maillage ;
  36. CNT = CONT MT ;
  37.  
  38. WALL = (BAS ET DRO ET HAU ET GAU) CHAN QUAF ;
  39. ELIM (WALL ET MMT) 1.E-4;
  40.  
  41. $WALL = 'MODE' WALL 'NAVIER_STOKES' 'MACRO' ;
  42.  
  43. VOL = 'DOMA' $MT 'VOLUME' ;
  44. VOLT = 'SOMT' VOL ;
  45.  
  46. **********************
  47. * LIEU DE L'ALLUMAGE *
  48. **********************
  49.  
  50. PA = (DOMA $MT SOMMET) POIN 'PROC' (0. 0.2) ;
  51.  
  52. *********************************************************************
  53. * PROCEDURE CALCUL1
  54. *********************************************************************
  55. DEBPROC CALCUL1 ;
  56. ARGU RVX*'TABLE' ;
  57.  
  58. RV = RVX.'EQEX' ;
  59. RVP = RV.'PRESSION' ;
  60.  
  61. SI ( RV.PASDETPS.'NUPASDT' < 30 ) ;
  62. RV.PASDETPS.'DELTAT' = 0.001 ;
  63. FINSI ;
  64.  
  65. * filtres sur fractions massiques et calcul de la fraction massique d'azote
  66.  
  67. YH2 = RV.INCO.'YH2' ;
  68. YO2 = RV.INCO.'YO2' ;
  69. YH2O = RV.INCO.'YH2O' ;
  70. YH2 = KOPS YH2 '|<' 0. ;
  71. YO2 = KOPS YO2 '|<' 0. ;
  72. YH2O = KOPS YH2O '|<' 0. ;
  73.  
  74. RV.INCO.'YH2' = YH2 ;
  75. RV.INCO.'YO2' = YO2 ;
  76. RV.INCO.'YH2O' = YH2O ;
  77. RV.INCO.'YN2' = KOPS 1.0 '-' RV.INCO.'YH2O' ;
  78. RV.INCO.'YN2' = KOPS RV.INCO.'YN2' '-' RV.INCO.'YH2' ;
  79. RV.INCO.'YN2' = KOPS RV.INCO.'YN2' '-' RV.INCO.'YO2' ;
  80.  
  81. * calcul de la constante des gaz et de la temperature
  82.  
  83. R = KOPS (KOPS YH2 '*' RH2) '+' (KOPS YO2 '*' RO2) ;
  84. R = KOPS R '+' (KOPS RV.INCO.'YN2' '*' RN2) ;
  85. R = KOPS R '+' (KOPS YH2O '*' RH2O) ;
  86. RV.INCO.'R' = KCHT $MT 'SCAL' 'SOMMET' R ;
  87. T = KOPS RV.INCO.'PSIN' '/' R ;
  88. RV.INCO.'TN' = KCHT $MT 'SCAL' 'SOMMET' T ;
  89.  
  90. * calcul de rho à partir de la loi d'état des gaz parfaits
  91.  
  92. RV.INCO.'RHO' = KOPS (RV.INCO.'PM') '/' (RV.INCO.'PSIN') ;
  93. RV.INCO.'RHOC' = NOEL $MT RV.INCO.'RHO' ;
  94. RV.INCO.'RHOC' = KCHT $MT 'SCAL' 'CENTRE' (RV.INCO.'RHOC') ;
  95. RHOM = (SOMT (KOPS RV.INCO.'RHOC' '*' VOL))/VOLT ;
  96. RV.INCO.'RHOM' = RHOM ;
  97.  
  98. * calcul du terme (rho-rhom)*g de la QDM
  99.  
  100. DRHO = KOPS (RV.INCO.'RHOC') '-' (RV.INCO.'RHOM') ;
  101. rogx = KCHT $MT SCAL CENTRE 0. ;
  102. rogy = KCHT $MT SCAL CENTRE (-9.81*DRHO) ;
  103. rogx = nomc 'UX' rogx 'NATU' 'DISCRET' ;
  104. rogy = nomc 'UY' rogy 'NATU' 'DISCRET' ;
  105. RV.INCO.'ROG' = KCHT $MT VECT CENTRE (rogx ET rogy) ;
  106.  
  107. * calcul la vitesse à partir de la qdm
  108.  
  109. GN = RV.INCO.'GN' ;
  110. gnx= kcht $MT scal sommet (exco 'UX' gn) ;
  111. gny= kcht $MT scal sommet (exco 'UY' gn) ;
  112. unx = kops gnx '/' RV.INCO.'RHO' ;
  113. uny = kops gny '/' RV.INCO.'RHO' ;
  114. unx = nomc 'UX' unx 'NATU' 'DISCRET' ;
  115. uny = nomc 'UY' uny 'NATU' 'DISCRET' ;
  116. un = kcht $MT vect sommet (unx et uny) ;
  117. RV.INCO.'UN' = un ;
  118.  
  119. as2 ama1 = 'KOPS' 'MATRIK' ;
  120. FINPROC as2 ama1 ;
  121.  
  122. *********************************************************************
  123. * PROCEDURE CALCUL2
  124. *********************************************************************
  125. DEBPROC CALCUL2 ;
  126. ARGU RVX*'TABLE' ;
  127.  
  128. RV = RVX.'EQEX' ;
  129. RVP = RV.'PRESSION' ;
  130.  
  131. * on récupère le pas de temps
  132.  
  133. Dt = RV.PASDETPS.'DELTAT' ;
  134. Dt = Dt * RV.'ALFA' ;
  135.  
  136. * combustion et mise a jour du cp et (gamma-1)/gamma
  137.  
  138. YH2 YO2 YN2 YH2O Q = 'FLAM' 'LAMINAIR'
  139. (RV.INCO.'RHO') (RV.INCO.'CV') 'LINEAIRE' (RV.INCO.'R')
  140. (RV.INCO.'YH2') (RV.INCO.'YO2') (RV.INCO.'YN2')
  141. (RV.INCO.'YH2O') (RV.INCO.'TN') Dt ;
  142.  
  143. RV.INCO.'YH2' = KCHT $MT SCAL SOMMET YH2 ;
  144. RV.INCO.'YO2' = KCHT $MT SCAL SOMMET YO2 ;
  145. RV.INCO.'YN2' = KCHT $MT SCAL SOMMET YN2 ;
  146. RV.INCO.'YH2O' = KCHT $MT SCAL SOMMET YH2O ;
  147. RV.INCO.'Q' = KCHT $MT SCAL SOMMET Q ;
  148.  
  149. RC = NOEL $MT RV.INCO.'R' ;
  150. CVC = NOEL $MT RV.INCO.'CV' ;
  151. CPC = KOPS RC '+' CVC ;
  152.  
  153. RV.INCO.'alpha' = KOPS lambda '/' RV.INCO.'RHOC' ;
  154. RV.INCO.'alpha' = KOPS RV.INCO.'alpha' '/' CPC ;
  155. RV.INCO.'zuzu' = KOPS RC '/' CPC ;
  156.  
  157. * calcul l'intégrale se trouvant dans le terme Dp/Dt.
  158.  
  159. ZT = KOPS (RV.INCO.'PSIN') '-' (RV.INCO.'PSI1') ;
  160. ZT = KOPS ZT '/' Dt ;
  161. ZT = KOPS ZT '/' (RV.INCO.'PSIN') ;
  162.  
  163. ZZ = KOPS ZT '*' RV.INCO.'RHO' ;
  164. ZZ = NOEL $MT ZZ ;
  165. ZZ = KCHT $MT 'SCAL' 'CENTRE' ZZ ;
  166. ZZT = SOMT ( KOPS ZZ '*' VOL ) ;
  167.  
  168. RV.INCO.'PSI1' = KCHT $MT 'SCAL' 'SOMMET' (RV.INCO.'PSIN') ;
  169.  
  170. * Evolution de la pression moyenne
  171.  
  172. dPdt = ZZT ;
  173. dPdt = dPdt*(RV.INCO.'PM')/VOLT/RV.INCO.'RHOM' ;
  174. MESSAGE 'dPdt = ' dPdt ;
  175.  
  176. * terme source de l'équation d'énergie
  177.  
  178. QC = NOEL $MT RV.INCO.'Q' ;
  179. QC = KCHT $MT 'SCAL' 'CENTRE' QC ;
  180. TOTO = KOPS QC '+' dPdt ;
  181. TOTO = KOPS TOTO '/' RV.INCO.'RHOC' ;
  182. TOTO = KOPS TOTO '*' RV.INCO.'zuzu' ;
  183. RV.INCO.'S' = KCHT $MT 'SCAL' 'CENTRE' TOTO ;
  184.  
  185. * terme source équation de Poisson
  186.  
  187. Z1 = dPdt/RV.INCO.'PM' ;
  188. ZP = KOPS RV.INCO.'RHOC' '*' Z1 ;
  189. ZS = KOPS ZP '-' ZZ ;
  190. ZZS = KOPS ZS '*' VOL ;
  191. ZZS = ZZS * (-1.0) ;
  192. RV.INCO.'ZS' = KCHT $MT 'SCAL' 'CENTRE' ZZS ;
  193.  
  194. * calcul de l'évolution de la pression
  195.  
  196. RV.INCO.'PM' = RV.INCO.'PM' + (dPdt*dt) ;
  197.  
  198. * affichage informations toutes les 5 iterations
  199.  
  200. DD = RV.PASDETPS.'NUPASDT' ;
  201. NN = DD/5 ;
  202. LO = (DD-(5*NN)) EGA 0 ;
  203. SI ( LO ) ;
  204. MESSAGE '==========================================================' ;
  205. MESSAGE 'TEMPS = ' RV.'PASDETPS'.'TPS' 'PRESSION = ' RV.INCO.'PM'
  206. 'MIN TEMP = ' (MINI RV.INCO.'TN') 'MAX TEMP = ' (MAXI RV.INCO.'TN') ;
  207. MESSAGE 'MASSE INITIALE = ' MASINI ' MASSE ACTUELLE = '
  208. (RV.INCO.'RHOM'*VOLT) ;
  209. PP = PROG RV.INCO.'PM' ;
  210. PT = PROG RV.PASDETPS.'TPS' ;
  211. RV.INCO.'TEMPS' = RV.INCO.'TEMPS' ET PT ;
  212. RV.INCO.'PRESS' = RV.INCO.'PRESS' ET PP ;
  213. MESSAGE '==========================================================' ;
  214. FINSI ;
  215.  
  216. as2 ama1 = 'KOPS' 'MATRIK' ;
  217. FINPROC as2 ama1 ;
  218.  
  219. *========================================================*
  220. * DONNEES DU CALCUL DE DISTRIBUTION *
  221. *========================================================*
  222.  
  223. *--------------------------------------
  224. * masses molaires et constantes des gaz
  225. *--------------------------------------
  226. MH2 = 2.0E-3 ;
  227. MO2 = 32.0E-3 ;
  228. MN2 = 28.0E-3 ;
  229. MH2O = 18.0E-3 ;
  230.  
  231. Rg = 8.313 ;
  232.  
  233. RH2 = Rg/MH2 ;
  234. RO2 = Rg/MO2 ;
  235. RN2 = Rg/MN2 ;
  236. RH2O = Rg/MH2O ;
  237.  
  238. *----------------------------------------------------------
  239. * fractions molaires des differents constituants du melange
  240. *----------------------------------------------------------
  241. XH2 = 0.075 ;
  242. XH2O = 0. ;
  243. XO2 = 0.21*(1.0 - XH2 - XH2O) ;
  244. XN2 = 1.0 - XH2 - XH2O - XO2 ;
  245.  
  246. *---------------------------------------------
  247. * masse molaire du melange et constante du gaz
  248. *---------------------------------------------
  249. M = (XH2*MH2) + (XO2*MO2) + (XN2*MN2) + (XH2O*MH2O) ;
  250. R = Rg/M ;
  251.  
  252. *------------------------------------------------------------
  253. * pression, temperature et densite du melange (loi d'etat GP)
  254. *------------------------------------------------------------
  255. P = 0.9E5 ;
  256. T = 400.0 ;
  257. PSI = R*T ;
  258. RHO = P/PSI ;
  259. PSIWALL = PSI ;
  260.  
  261. *------------------------------------------------
  262. * fractions massiques des differents constituants
  263. *------------------------------------------------
  264. YH2 = XH2*MH2/M ;
  265. YO2 = XO2*MO2/M ;
  266. YN2 = XN2*MN2/M ;
  267. YH2O = XH2O*MH2O/M ;
  268.  
  269. *------------------------------------------------------------------
  270. * Cp des différents constituants et du mélange (supposés constants)
  271. *------------------------------------------------------------------
  272. CPH2 = 13514.04 + (1.684537*T) ;
  273. CPH2O = 1715.632 + (0.552805*T) ;
  274. CPN2 = 1006.15 + (0.1387166*T) ;
  275. CPO2 = 907.580 + (0.1420522*T) ;
  276.  
  277. CP = (YH2*CPH2) + (YH2O*CPH2O) + (YO2*CPO2) + (YN2*CPN2) ;
  278.  
  279. gamma = CP/(CP-R) ;
  280.  
  281. *----------------------------------------------------
  282. * calcul d'une vitesse de référence (pour les tracés)
  283. *----------------------------------------------------
  284.  
  285. uref = gamma*R*T ;
  286. uref = uref**0.5 ;
  287. uref = 0.01*uref ;
  288. ampl = 1./uref ;
  289.  
  290.  
  291. *------------------------------------------------------------------------
  292. * Prandtl, Schmidt, viscosité (loi de Sutherland), conductivité thermique
  293. * coefficients de diffusion moléculaire
  294. *------------------------------------------------------------------------
  295. Pr = 0.7 ;
  296.  
  297. Mu = 1.716E-5*((T/273.0)**1.5)*(273.0+110.5)/(T+110.5) ;
  298. Nu = Mu/RHO ;
  299. Lambda = Mu*CP/Pr ;
  300.  
  301. alpha = Lambda/RHO/CP ;
  302.  
  303. DH2O = 2.55E-5 ;
  304. DH2 = 7.12E-5 ;
  305. DO2 = 2.06E-5 ;
  306. DIF = 1.E-9 ;
  307.  
  308. *==============================================================
  309. * TABLE EQEX CONTENANT LES EQUATIONS A RESOUDRE :
  310. * 0) FILTRE K-E
  311. * 1) QUANTITE DE MOUVEMENT --- OPERATEUR NSKE
  312. * 2) EQUATION DE L'ENERGIE --- OPERATEUR TSCAL
  313. * 3) TRANSPORT DES ESPECES --- OPERATEUR TSCAL
  314. * AINSI QUE 2 PROCEDURES (CALCUL1 ET CALCUL2) POUR L'ALGORITHME
  315. * 'FAIBLE MACH'
  316. * 4) CONDITIONS AUX LIMITES
  317. *==============================================================
  318.  
  319. RV = 'EQEX' $MT 'ITMA' 5000 'ALFA' 0.6 'TFINAL' 10.0
  320. 'ZONE' $MT 'OPER' 'CALCUL1'
  321. 'OPTI' 'CONS'
  322. 'ZONE' $MT 'OPER' 'NS' MU 'UN' 'ROG' 'INCO' 'GN'
  323. 'OPTI' 'NOCONS'
  324. 'ZONE' $MT 'OPER' 'TSCAL' 'alpha' 'UN' 'S' 'INCO' 'PSIN'
  325. ;
  326.  
  327. RV = 'EQEX' RV
  328. 'OPTI' 'NOCONS'
  329. 'ZONE' $MT 'OPER' 'TSCAL' DIF 'UN' 0.0 'INCO' 'YH2'
  330. 'OPTI' 'NOCONS'
  331. 'ZONE' $MT 'OPER' 'TSCAL' DIF 'UN' 0.0 'INCO' 'YO2'
  332. 'OPTI' 'NOCONS'
  333. 'ZONE' $MT 'OPER' 'TSCAL' DIF 'UN' 0.0 'INCO' 'YH2O'
  334. ;
  335. RV = 'EQEX' RV
  336. 'ZONE' $MT 'OPER' 'CALCUL2'
  337. 'OPTI' 'CENTREE'
  338. 'ZONE' $MT 'OPER' 'DFDT' 1. 'GN' 'DELTAT' 'INCO' 'GN'
  339. 'ZONE' $MT 'OPER' 'DFDT' 1. 'PSIN' 'DELTAT' 'INCO' 'PSIN'
  340. 'ZONE' $MT 'OPER' 'DFDT' 1. 'YH2' 'DELTAT' 'INCO' 'YH2'
  341. 'ZONE' $MT 'OPER' 'DFDT' 1. 'YO2' 'DELTAT' 'INCO' 'YO2'
  342. 'ZONE' $MT 'OPER' 'DFDT' 1. 'YH2O' 'DELTAT' 'INCO' 'YH2O'
  343. ;
  344.  
  345. RV = 'EQEX' RV
  346. 'CLIM' 'GN' 'UIMP' (DRO ET GAU) 0.0
  347. 'GN' 'VIMP' (HAU ET BAS) 0.0 ;
  348.  
  349. *===========================================================
  350. * TABLE EQPR POUR L'EQUATION DE POISSON (SOLVEUR ELLIPTIQUE)
  351. *===========================================================
  352.  
  353. RVP = 'EQPR' $MT KTYPI 1
  354. 'ZONE' $MT 'OPER' 'PRESSION' 'ZS'
  355. 'PIMP' 0. ;
  356.  
  357. *==========================================================
  358. * TABLE INCO CONTENANT LES INCONNUES ET DONNEES DU PROBLEME
  359. *==========================================================
  360.  
  361. RV.'PRESSION' = RVP ;
  362. RV.'NOMVI' = 'GN' ;
  363.  
  364. RV.'INCO' = 'TABLE' 'INCO' ;
  365. RVP.'INCO' = RV.'INCO' ;
  366.  
  367. * vitesse et quantité de mouvement
  368. RV.INCO.'UN' = kcht $MT VECT SOMMET (0. 1.E-5);
  369. RV.INCO.'GN' = kcht $MT VECT SOMMET (0. 1.E-5);
  370. * température
  371. RV.INCO.'PSIN' = kcht $MT SCAL SOMMET PSI ;
  372. RV.INCO.'PSI1' = kcht $MT SCAL SOMMET PSI ;
  373. RV.INCO.'TN' = kcht $MT SCAL SOMMET T ;
  374. RV.INCO.'R' = kcht $MT SCAL SOMMET R ;
  375. RV.INCO.'CV' = kcht $MT SCAL SOMMET (CP/gamma) ;
  376. * masse volumique
  377. RV.INCO.'RHO' = kcht $MT SCAL SOMMET RHO ;
  378. RV.INCO.'RHOC'= kcht $MT SCAL CENTRE RHO ;
  379. RV.INCO.'RHOM'= RHO ;
  380. * fractions massiques
  381. RV.INCO.'YH2' = kcht $MT SCAL SOMMET YH2 ;
  382. RV.INCO.'YO2' = kcht $MT SCAL SOMMET YO2 ;
  383. RV.INCO.'YN2' = kcht $MT SCAL SOMMET YN2 ;
  384. RV.INCO.'YH2O'= kcht $MT SCAL SOMMET YH2O ;
  385. * termes sources (Poisson/énergie/QDM)
  386. RV.INCO.'S'=kcht $MT SCAL CENTRE 0. ;
  387. RV.INCO.'Q'=kcht $MT SCAL SOMMET 0. ;
  388. RV.INCO.'ROG'=kcht $MT VECT CENTRE (0. 0.) ;
  389. RV.INCO.'ZS' = KCHT $MT SCAL CENTRE 0.0 ;
  390. * diffusivite thermique
  391. RV.INCO.'alpha' = KCHT $MT SCAL CENTRE alpha ;
  392. RV.INCO.'zuzu' = KCHT $MT SCAL CENTRE ((gamma-1)/gamma) ;
  393. * pression
  394. RV.INCO.'PM' = P ;
  395. * progressions contenant certaines données
  396. RV.INCO.'TEMPS' = PROG 0. ;
  397. RV.INCO.'PRESS' = PROG P ;
  398. RV.INCO.'MTOTA' = PROG (RHO*VOLT) ;
  399.  
  400. RV.INCO.'YH2u' = RV.INCO.'YH2' ;
  401.  
  402. M = KOPS (RV.INCO.'YH2'/MH2) '+' (RV.INCO.'YO2'/MO2) ;
  403. M = KOPS M '+' (RV.INCO.'YN2'/MN2) ;
  404. M = KOPS M '+' (RV.INCO.'YH2O'/MH2O) ;
  405. M = KOPS 1. '/' M ;
  406.  
  407. XH2 = KOPS RV.INCO.'YH2' '*' M ;
  408. XH2 = XH2/MH2 ;
  409. XH2 = XH2*100. ;
  410.  
  411. CA = MANU 'CHPO' PA 1 SCAL 3100. ;
  412. TA = KCHT $MT 'SCAL' 'SOMMET' CA ;
  413. RV.INCO.'TN' = (RV.INCO.'TN' ET TA) ;
  414.  
  415. SI ( GRAPH ) ;
  416. trace rv.inco.'TN' MT 14 'TITR' 'temperature initiale [K]' ;
  417. FINSI ;
  418.  
  419. RV.INCO.'PSIN' = KOPS RV.INCO.'R' '*' RV.INCO.'TN' ;
  420. RV.INCO.'RHO' = KOPS RV.INCO.'PM' '/' RV.INCO.'PSIN' ;
  421. RV.INCO.'RHOC' = NOEL $MT RV.INCO.'RHO' ;
  422.  
  423. VOL = DOMA $MT 'VOLUME' ;
  424. VOLT = SOMT VOL ;
  425.  
  426. MESSAGE 'VOLUME TOTAL = ' VOLT ;
  427. RHOM = SOMT (KOPS RV.INCO.'RHOC' '*' VOL) ;
  428. RHOM = RHOM/VOLT ;
  429. RHO = RHOM ;
  430.  
  431. MASINI = KOPS RV.INCO.'RHOC' '*' VOL ;
  432. MASINI = SOMT MASINI ;
  433. MESSAGE 'MASSE INITIALE = ' MASINI ;
  434.  
  435. RV.'TFINAL' = 1.0 ;
  436. exec rv ;
  437.  
  438. SI ( GRAPH ) ;
  439. M = KOPS (RV.INCO.'YH2'/MH2) '+' (RV.INCO.'YO2'/MO2) ;
  440. M = KOPS M '+' (RV.INCO.'YN2'/MN2) ;
  441. M = KOPS M '+' (RV.INCO.'YH2O'/MH2O) ;
  442. M = KOPS 1. '/' M ;
  443.  
  444. XH2 = KOPS RV.INCO.'YH2' '*' M ;
  445. XH2 = XH2/MH2 ;
  446. XH2 = XH2*100. ;
  447. TRACE XH2 MT CNT 14 'TITR' 'FRACTION VOL. HYDROGENE' ;
  448. FINSI ;
  449.  
  450. RV.'TFINAL' = 3.0 ;
  451. exec rv ;
  452.  
  453. SI ( GRAPH ) ;
  454. TAB1 = TABLE ;
  455. TAB1.1 = 'MARQ LOSA REGU' ;
  456. TAB1.'TITRE' = TABLE ;
  457. TAB1.'TITRE' . 1 = 'MOT' 'PRESSURE' ;
  458. EVOL1 = 'EVOL' 'MANU' 'TIME [s]' RV.INCO.'TEMPS'
  459. 'Press. [Pa]' RV.INCO.'PRESS' ;
  460. 'DESS' EVOL1 'LEGE' TAB1 'MIMA' ;
  461. FINSI ;
  462.  
  463. PM = RV.INCO.'PM' ;
  464. TM = NOEL $MT RV.INCO.'TN' ;
  465. TM = SOMT( KOPS TM '*' VOL) / VOLT ;
  466.  
  467. ERRP = (PM-2.574E5)/2.574E5 ;
  468. ERRP = 100.*(ABS ERRP) ;
  469. ERRT = (TM-1188.)/1188. ;
  470. ERRT = 100.*(ABS ERRT) ;
  471.  
  472. MESSAGE 'PAICC CALCULEE = ' PM 'ERREUR = ' (ERRP) '%' ;
  473. MESSAGE 'TAICC CALCULEE = ' TM 'ERREUR = ' (ERRT) '%' ;
  474.  
  475. SI ( ERRP > 2. ) ;
  476. ERREUR 5 ;
  477. FINSI ;
  478. SI ( ERRT > 2. ) ;
  479. ERREUR 5 ;
  480. FINSI ;
  481.  
  482. FIN ;
  483.  
  484.  
  485.  
  486.  
  487.  
  488.  
  489.  
  490.  
  491.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales