Télécharger elas9.dgibi

Retour à la liste

Numérotation des lignes :

  1. * fichier : elas9.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4.  
  5. *******************************************************
  6. * Test elas9.dgibi: Jeux de données *
  7. * --------------------------------- *
  8. *******************************************************
  9. * CAS TEST DU 91/06/13 PROVENANCE : TEST
  10.  
  11. * POUR CALCUL COMPLET METTRE COMPLET = VRAI;
  12. complet = VRAI;
  13.  
  14. * SI GRAPH = N PAS DE GRAPHIQUE AFFICHE
  15. * SINON SI GRAPH DIFFERENT DE N TOUS
  16. * LES GRAPHIQUES SONT AFFICHES
  17.  
  18. GRAPH = 'N' ;
  19.  
  20. SAUT PAGE;
  21. SI (NEG GRAPH 'N') ;
  22. OPTI ECHO 1 ;
  23. OPTI TRAC PSC ;
  24. SINO ;
  25. OPTI ECHO 1 ;
  26. FINSI ;
  27.  
  28. SAUT PAGE;
  29. *___________________________________________________________________
  30. * TEST ELAS9 *
  31. * *
  32. * MEMBRANE EPAISSE ELLIPTIQUE CHARGEE EN PRESSION *
  33. * *
  34. * Test NAFEMS numero le10 *
  35. * Nom : THICK PLATE PRESSURE *
  36. * *
  37. * La plaque epaisse est maillee a l'aide d'elements CU20. *
  38. * Elle est chargee normalement par une pression de 1 MPa. *
  39. * On s'interesse a la contrainte smyy au point D *
  40. * *
  41. * La valeur calculee de la contrainte est ensuite comparee *
  42. * avec une valeur theorique obtenue avec un maillage plus fin. *
  43. * *
  44. *___________________________________________________________________
  45. *
  46. OPTI ELEM CU20;
  47. *
  48. *==================================================================*
  49. * geometrie : maillage *
  50. *==================================================================*
  51. *
  52. * Dimensions en metres.
  53. *
  54. * Pour obtenir des arcs d'ellipse on projete des arcs de cercle
  55. * sur le plan xOy.
  56. *
  57. * Corfficient de finesse du maillage.
  58. *
  59. si complet;
  60. K = 2;
  61. sinon;
  62. k= 1;
  63. finsi;
  64. *
  65. PB = 0. 2.75 0.;
  66. PB1 = 0. 2.75 (((3.25 ** 2) - (2.75 ** 2)) ** 0.5);
  67. PC = 3.25 0. 0.;
  68. *
  69. C1 = PC CERC (6 * K) (0. 0. 0.) PB1;
  70. C2 = C1 PROJ CYLI (0. 0. 1) PLAN (0 0 0) (1 0 0) (0 1 0);
  71. *
  72. PA = 0. 1. 0.;
  73. PA1 = 0. 1. (((2. ** 2) - (1. ** 2)) ** 0.5);
  74. PD = 2. 0. 0.;
  75. *
  76. C3 = Pd CERC (6 * K) (0. 0. 0.) PA1;
  77. C4 = C3 PROJ CYLI (0. 0. 1) PLAN (0 0 0) (1 0 0) (0 1 0);
  78. *
  79. D1 = PA DROI (2 * K) (0. 1.583 0.) DROI (2 * K) PB;
  80. D3 = PC DROI (2 * K) (2.417 0. 0.) DROI (2 * K) PD;
  81. *
  82. ELIM (D1 ET C2 ET D3 ET C4) 0.0001;
  83. SUR1 = DALL D1 C2 D3 C4 PLAN;
  84. *
  85. VOL1 = SUR1 VOLU (2 * K) TRAN (0. 0. -0.6);
  86. *
  87. * Surfaces et arc d'ellipse pour conditions aux limites
  88. *
  89. FACE1 = D1 TRAN (2 * K) (0. 0. -0.6);
  90. FACE2 = C2 TRAN (2 * K) (0. 0. -0.6);
  91. FACE3 = D3 TRAN (2 * K) (0. 0. -0.6);
  92. C2CL = C2 PLUS (0. 0. -0.3);
  93. *
  94. ELIM (VOL1 ET FACE1 ET FACE2 ET FACE3 ET C2CL) 0.0001;
  95. *
  96. SI (NEG GRAPH 'N');
  97. TITR 'ELAS9 : MAILLAGE';
  98. TRAC (-1000 -1000 1000) FACE QUAL (COUL VOL1 BLAN);
  99. FINSI;
  100. *
  101. *==================================================================*
  102. * modele - materiau - caracteristique *
  103. * rigidite - conditions aux limites *
  104. *==================================================================*
  105. *
  106. MODL1 = MODE VOL1 MECANIQUE ELASTIQUE ISOTROPE CU20;
  107. MATR1 = MATE MODL1 YOUN 2.1E11 NU 0.3;
  108. *
  109. MOP = 'MODE' SUR1 'CHARGEMENT' 'PRESSION' ;
  110. MAP = 'PRES' MOP 'PRES' 1.E6 ;
  111. MODLT = MODL1 ;
  112. *
  113. RIG1 = RIGI MODLT MATR1 ;
  114. *
  115. *==================================================================*
  116. * conditions aux limites *
  117. *==================================================================*
  118. *
  119. * - face dans le plan xOz : ux = 0.,
  120. * - face dans le plan yOz : uy = 0.;
  121. * - face elliptique exterieure : ux = uy = 0. et
  122. * uz = 0. le long de la surface moyenne.
  123. *
  124. CL1 = BLOQ UX FACE1;
  125. CL2 = BLOQ UY FACE3;
  126. CL3 = BLOQ UX FACE2;
  127. CL4 = BLOQ UY FACE2;
  128. CL5 = BLOQ UZ C2CL;
  129. *
  130. RIG1 = RIG1 ET CL1 ET CL2 ET CL3 ET CL4 ET CL5;
  131. *
  132. *==================================================================*
  133. * chargement mecanique *
  134. *==================================================================*
  135. *
  136. * La plaque est soumis a une pression uniforme normal de 1 MPa
  137. * sur la face superieure.
  138. *
  139. CHA1 = 'BSIG' MOP MAP ;
  140. *
  141. *==================================================================*
  142. * calcul du champ de deplacement *
  143. *==================================================================*
  144. *
  145. DEP1 = RESO RIG1 CHA1;
  146. *
  147. * Trace facultatif de la deformee.
  148. *
  149. SI (NEG GRAPH 'N');
  150. DEF0 = DEFO 0. DEP1 VOL1;
  151. DEF1 = DEFO 5.E2 DEP1 VOL1 VERT;
  152. TITR 'ELAS9 : DEFORMEE';
  153. TRAC (-1000 -1000 1000) CACH VOL1 (DEF0 ET DEF1);
  154. FINSI;
  155. *
  156. *==================================================================*
  157. * extraction d'une contrainte *
  158. * et comparaison avec solution analytique *
  159. *==================================================================*
  160. *
  161. * On cherche la contrainte smyy au point D (2. 0. 0.).
  162. *
  163. * Calcul du champs de contraintes.
  164. *
  165. CHAM1 = SIGM MODL1 MATR1 DEP1;
  166. *
  167. * Interpolation aux noeuds du maillage.
  168. *
  169. CHAM2 = CHAN NOEUD MODL1 CHAM1;
  170. CHPO2 = CHAN CHPO MODL1 CHAM2;
  171.  
  172. *
  173. * Trace facultatif des contraintes aux noeuds.
  174. *
  175. SI (NEG GRAPH 'N');
  176. TITR 'ELAS9 : Contraintes Nodales';
  177. TRAC (-1000 -1000 1000) CACH VOL1 ((EXCO CHPO2 SMYY)*1e-6);
  178. FINSI;
  179. *
  180. * Extraction de la contriante smyy au point D.
  181. *
  182. SMYYD = EXTR CHPO2 SMYY PD;
  183. SMYYD = SMYYD / 1.E6;
  184. *
  185. SMYYD1 = -5.38;
  186. *
  187. * Calcul de l'ecart avec la solution de reference.
  188. *
  189. ERG = 100 * (ABS ((SMYYD1 - SMYYD) / SMYYD1));
  190. *
  191. *==================================================================*
  192. * affichage des resultats *
  193. *==================================================================*
  194. *
  195. MESS ' RESULTATS ';
  196. MESS ' --------- ';
  197. *
  198. MESS ' Contrainte theorique SMYYD :' SMYYD1 'MPa';
  199. MESS ' Contrainte calculee SMYYD :' SMYYD 'MPa';
  200. MESS ' Soit un ecart de :' ERG '%';
  201. *
  202. *==================================================================*
  203. * code fonctionnement *
  204. *==================================================================*
  205. *
  206. si complet; ertes=3.; sinon; ertes=7. ; finsi;
  207. SI (ERG <EG ertes);
  208. ERRE 0;
  209. SINON;
  210. ERRE 5;
  211. FINSI;
  212. *
  213. TEMPS;
  214. *
  215. FIN;
  216.  
  217.  
  218.  
  219.  
  220.  
  221.  
  222.  
  223.  
  224.  
  225.  
  226.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales