Télécharger la plaquette Cast3M


fr en

Télécharger elas7.dgibi

Retour à la liste

Numérotation des lignes : 

  1. * fichier :  elas7.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4.  
  5. *******************************************************
  6. *           Test elas7.dgibi: Jeux de données         *
  7. *           ---------------------------------         *
  8. *******************************************************
  9. * CAS TEST DU 91/06/13     PROVENANCE : TEST
  10.  
  11. * SI GRAPH = N PAS DE GRAPHIQUE AFFICHE
  12. * SINON SI GRAPH DIFFERENT DE N TOUS
  13. * LES GRAPHIQUES SONT AFFICHES
  14.  
  15. GRAPH = 'N' ;
  16.  
  17. SAUT PAGE;
  18. SI (NEG GRAPH 'N') ;
  19.   OPTI ECHO 1   ;
  20.   OPTI TRAC PSC ;
  21. SINO ;
  22.   OPTI ECHO 1   ;
  23. FINSI ;
  24.  
  25. SAUT PAGE;
  26. *______________________________________________________
  27. *   TEST ELAS7                                        *
  28. *                                                     *
  29. *   COQUE AVEC BRANCHEMENT                            *
  30. *                                                     *
  31. *   TEST ELEMENTAIRE NAFEMS : ANALYSE LINEAIRE        *
  32. *                                     ELASTIQUE       *
  33. *           numero LE9                AXISYMETRIQUE   *
  34. *                                                     *
  35. *       L'enceinte est constituee par un cylindre et  *
  36. *   par une sphere (demie), reposant sur un cylindre. *
  37. *   L'enceinte est soumise a une pression interne     *
  38. *   uniforme de 1e6Pa.                                *
  39. *      On cherche la contrainte axiale sur la surface *
  40. *   exterieure du cylindre superieure au point C. La  *
  41. *   contrainte obtenue est comparee au resultat       *
  42. *   theorique.                                        *
  43. *                                                     *
  44. *______________________________________________________
  45. *
  47. OPTI MODE AXIS;
  48. OPTI ELEM SEG2;
  49. *
  50. *=====================================================*
  51. *             geometrie : maillage                    *
  52. *=====================================================*
  53. *
  54. * Dimension en metres
  55. *
  56. * Points
  57. *
  58. COS75 = COS 7.5; COS375 = COS 37.5; COS45 = COS 45;
  59. SIN75 = SIN 7.5; SIN375 = SIN 37.5; SIN45 = SIN 45;
  60. R = 2 ** -.5;
  61. *
  62. RA = R; ZA = 0.; PA = RA ZA;
  63. RB = 0; ZB = COS45; PB = RB ZB;
  64. RC = R; ZC = 1.; PC = RC ZC;
  65. RD = R; ZD = 2.; PD = RD ZD;
  66. RO = 0; ZO = 1 + COS45; PO = RO ZO;
  67. PA1 = PC PLUS (0 -0.125);
  68. PD1 = PC PLUS (0 0.125);
  69. PB1 = PB PLUS (SIN375 (1 - COS375));
  70. *
  71. * Droites, cercles et lignes
  72. *
  73. * coefficient de finesse du maillage
  74. *
  75. K = 1;
  76. *
  77. SI (K EGA 1);
  78.   TITR ' LE9 : MAILLAGE GROSSIER';
  79. SINON;
  80.   TITR ' LE9 : MAILLAGE FIN';
  81. FINSI;
  82. *
  83. N1 = 4 * K;
  84. AA1 = PA  DROI N1 PA1;
  85. A1C = PA1 DROI N1 PC;
  86. CD1 = PC  DROI N1 PD1;
  87. D1D = PD1 DROI N1 PD;
  88. B1C = PB1 CERC N1 PO PC;
  89. *
  90. N2 = 5 * K;
  91. BB1 = PB CERC N2 PO PB1;
  92. *
  93. * Maillage
  94. *
  95. SUR1 = BB1 ET B1C;
  96. SUR2 = CD1 ET D1D;
  97. SUR3 = AA1 ET A1C;
  98. SURF1 = SUR1 ET SUR2 ET SUR3;
  99. *
  100. SI (NEG GRAPH 'N');
  101.    TITR 'ELAS7 : MAILLAGE';
  102.    TRAC QUAL SURF1;
  103. FINSI;
  104. *
  105. ELSURF1 = NBEL SURF1;
  106. NOSURF1 = NBNO SURF1;
  107. *
  108. *=====================================================*
  109. *   modele - affecte - materiau - caracteristique     *
  110. *       rigidite - conditions aux limites             *
  111. *=====================================================*
  112. *
  113. MODL1 = MODE SUR1 MECANIQUE ELASTIQUE ISOTROPE COQ2;
  114. MODL2 = MODE SUR2 MECANIQUE ELASTIQUE ISOTROPE COQ2;
  115. MODL3 = MODE SUR3 MECANIQUE ELASTIQUE ISOTROPE COQ2;
  116. *
  117. MATR1 = MATE MODL1 YOUN 210E9 NU 0.3 EPAI 0.01;
  118. MATR2 = MATE MODL2 YOUN 210E9 NU 0.3 EPAI 0.01;
  119. MATR3 = MATE MODL3 YOUN 210E9 NU 0.3 EPAI 0.01;
  120. *
  121. RI1 = RIGI MODL1 MATR1;
  122. RI2 = RIGI MODL2 MATR2;
  123. RI3 = RIGI MODL3 MATR3;
  124. *
  125. * Conditions aux limites
  126. *    - point pa : encastrement complet.
  127. *
  128. CL1 = BLOQ ROTA DEPL PA;
  129. *
  130. RIG1 = RI1 ET RI2 ET RI3 ET CL1;
  131. *
  132. *=====================================================*
  133. *               Chargement                            *
  134. *=====================================================*
  135. *
  136. *   Pression interne uniforme de 1e6Pa.
  137. *
  138. MOP1  = 'MODE' SUR1 'CHARGEMENT' 'PRESSION' 'COQ2' ;
  139. MAP1  = 'PRES' MOP1 'PRES' -1.E6 ;
  140. CH1   = 'BSIG' MOP1 MAP1 ;
  141. MOP2  = 'MODE' SUR2 'CHARGEMENT' 'PRESSION' 'COQ2' ;
  142. MAP2  = 'PRES' MOP2 'PRES' -1.E6 ;
  143. CH2   = 'BSIG' MOP2 MAP2 ;
  144. CHA1  = CH1 ET CH2;
  145. *
  146. *=====================================================*
  147. *        resolution : champs de deplacements          *
  148. *=====================================================*
  149. *
  150. DEP1 = RESO RIG1 CHA1;
  151. *
  152. * Trace facultatif de la deformee et des reactions
  153. *
  154. SI (NEG GRAPH 'N');
  155.   AMPVEC = .4E-6;
  156.   REA1 = REAC DEP1 RIG1;
  157.   VECT1 = VECT CHA1 (AMPVEC * 1) FR FZ ROUGE;
  158.   VECT2 = VECT REA1 (AMPVEC * 1) FR FZ BLEU ;
  159.   DEF0 = DEFO 0. DEP1 SURF1;
  160.   DEF1 = DEFO 40. DEP1 SURF1 (VECT1 ET VECT2) VERT;
  161.   TITR 'ELAS7 : DEFORMEE, CHARGEMENT, REACTIONS';
  162.   TRAC SURF1 (DEF0 ET DEF1);
  163. FINSI;
  164. *
  165. *=====================================================*
  166. *              extraction d'une contrainte            *
  167. *       et comparaison avec solution analytique       *
  168. *=====================================================*
  169. *
  170. *      On cherche la contrainte axiale sur la surface
  171. * exterieure du cylindre superieure au point C.
  172. *
  173. *    Calcul du champs de contraintes generalisees
  174. * uniquement sur le cylindre superieur (sur2).
  175. *
  176. * Reduction du chpoint des deplacements au cylindre
  177. * superieur.
  178. *
  179. DEP2 = REDU DEP1 SUR2;
  180. CHAM1 = SIGM MODL2 MATR2 DEP2;
  181. *
  182. * Calcul du champs de contraintes au sens des milieux
  183. * continus. Pour cela on utilise l'operateur CALP .
  184. *
  185. CHAM2 = CALP CHAM1 MATR2 MODL2 INFE;
  186. *
  187. * Calcul des contraintes aux noeuds du maillage
  188. *
  189. CHAM3 = CHAN NOEUD MODL2 CHAM2;
  190. CHPO3 = CHAN CHPO MODL2 CHAM3;
  191. *
  192. * Extraction de la contrainte recherchee
  193. *
  194. SMZZC = EXTR CHPO3 SMXX PC;
  195. SMZZC = SMZZC / 1.E6;
  196. *
  197. SMZZC1 = -319.9;
  198. *
  199. * Calcul de l'ecart avec la solution de reference
  200. *
  201. ERGZZC = 100 * (ABS ((SMZZC - SMZZC1) / SMZZC1));
  202. *
  203. *=====================================================*
  204. *           affichage des resultats                   *
  205. *=====================================================*
  206. *
  207. MESS ' RESULTATS : TEST ELAS7 ';
  208. MESS ' ---------------------- ';
  210. *
  211. MESS '   On cherche la contrainte axiale sur la surface exterieure';
  212. MESS ' du cylindre superieure au point C.';
  213. MESS ' Elle est comparee a une valeur theorique obtenue analytiquement.';
  215. MESS ' Contrainte axiale theorique en C:' SMZZC1 'MPa';
  217. MESS ' Contrainte axiale calculee en C :' SMZZC 'MPa';
  219. MESS '          Soit un ecart de :' ERGZZC '%';
  221. *
  222. SI (K EGA 1);
  223.   MESS ' MAILLAGE GROSSIER';
  224. SINON;
  225.   MESS ' MAILLAGE FIN';
  226. FINSI;
  227. *
  228. MESS '    Nombre d elements :' ELSURF1;
  229. MESS '    Nombre de noeuds  :' NOSURF1;
  230. MESS '       soit ' (NOSURF1 * 3) 'd.d.l.';
  231. *
  232. *=====================================================*
  233. *             code fonctionnement                     *
  234. *=====================================================*
  235. *
  236. *  L'ecart maximum entre valeur theorique et calculee
  237. * doit etre inferieure a 2.5%.
  238. *
  240. SI (ERGZZC <EG 2.5);
  241.     ERRE 0;
  242. SINON;
  243.     ERRE 5;
  244. FINSI;
  245. *
  246. *=====================================================*
  247. *           Temps de calcul et fin                    *
  248. *=====================================================*
  249. *
  251. TEMPS;
  253. *
  254. FIN;
  255.  
  256.  
  257.  
  258.  
  259.  
  260.  
  261.  
  262.  
  263.  
  264.  
  265.  
  266.  
  267.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales