Télécharger elas6.dgibi

Retour à la liste

Numérotation des lignes :

  1. * fichier : elas6.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4.  
  5. *******************************************************
  6. * Test elas6.dgibi: Jeux de données *
  7. * --------------------------------- *
  8. *******************************************************
  9. * CAS TEST DU 91/06/13 PROVENANCE : TEST
  10.  
  11. * SI GRAPH = N PAS DE GRAPHIQUE AFFICHE
  12. * SINON SI GRAPH DIFFERENT DE N TOUS
  13. * LES GRAPHIQUES SONT AFFICHES
  14.  
  15. GRAPH = 'N' ;
  16.  
  17. SAUT PAGE;
  18. SI (NEG GRAPH 'N') ;
  19. OPTI ECHO 1 ;
  20. OPTI TRAC PSC ;
  21. SINO ;
  22. OPTI ECHO 1 ;
  23. FINSI ;
  24.  
  25. SAUT PAGE;
  26. *___________________________________________________________________
  27. * TEST ELAS6 *
  28. * *
  29. * COQUE AXISYMETRIQUE *
  30. * *
  31. * cas-test NAFEMS : test numero LE8 *
  32. * *
  33. * La structure est constituee d'un cylindre surmonte d'une *
  34. * partie de tore et d'une partie de sphere. Elle est soumise a *
  35. * un pression interne de 1MPa. *
  36. * *
  37. * Le probleme presentant une symetrie axiale (geometrie et *
  38. * chargement), on se place en mode axisymetrique. *
  39. * *
  40. * On se propose de calculer la contrainte tangentielle au *
  41. * point D sur la surface exterieure. La valeur trouvee est *
  42. * ensuite comparee a une valeur theorique trouvee analytiquement.*
  43. *___________________________________________________________________
  44.  
  45. OPTI MODE AXIS;
  46. OPTI ELEM SEG2;
  47.  
  48. *==================================================================*
  49. * geometrie : maillage *
  50. *==================================================================*
  51. * Dimension en metres
  52. *
  53. * Points
  54. *
  55. RO2 = 0.; ZO2 = 0.75; PO2 = RO2 ZO2;
  56. RO1 = 0.25 - 0.0625; ZO1 = 0.5; PO1 = RO1 ZO1;
  57. *
  58. RA = 0.25; ZA = 0.; PA = RA ZA;
  59. RB = 0.25; ZB = 0.5; PB = RB ZB;
  60. RC = 0.25 - 0.0625; ZC = 0.5 + 0.0625; PC = RC ZC;
  61. RD = 0.25 - (0.0625 * (1 + (SIN 36))); ZD = 0.5 + (0.0625 * (COS 36));
  62. PD = RD ZD;
  63. RE = 0.; ZE = 0.5; PE = RE ZE;
  64.  
  65. * Droites, cercles et lignes
  66.  
  67. * coefficient de finesse du maillage
  68. K = 1;
  69.  
  70. SI (K EGA 1);
  71. TITR ' LE8 : MAILLAGE GROSSIER';
  72. SINON;
  73. TITR ' LE8 : MAILLAGE FIN';
  74. FINSI;
  75.  
  76. N1 = 6 * K;
  77. AB = PA DROI N1 PB;
  78. *
  79. N2 = 5 * K;
  80. BC = PB CERC N2 PO1 PC;
  81. *
  82. CD = PC CERC N1 PO1 PD;
  83. *
  84. N3 = 8 * K;
  85. DE = PD CERC N3 PO2 PE;
  86. *
  87. * Maillage
  88. *
  89. SUR1 = AB ET BC ET CD ET DE;
  90.  
  91. SI (NEG GRAPH 'N');
  92. TITR ' TEST ELAS6 : MAILLAGE';
  93. TRAC QUAL SUR1;
  94. FINSI;
  95. *
  96. ELSUR1 = NBEL SUR1;
  97. NOSUR1 = NBNO SUR1;
  98.  
  99. *==================================================================*
  100. * modele - affecte - materiau - caracteristique *
  101. * rigidite - conditions aux limites *
  102. *==================================================================*
  103.  
  104. MODL1 = MODE SUR1 MECANIQUE ELASTIQUE ISOTROPE COQ2;
  105. MATR1 = MATE MODL1 YOUN 210E9 NU 0.3 EPAI 0.01;
  106. RI1 = RIGI MODL1 MATR1;
  107.  
  108. * Conditions aux limites
  109. * - point pe : pas de deplacement radial et pas de rotation,
  110. * - point pa : pas de deplacement vertical.
  111.  
  112. CL1 = BLOQ ROTA PE;
  113. CL2 = BLOQ UR PE;
  114. CL3 = BLOQ UZ PA;
  115. *
  116. CLI1 = CL1 ET CL2 ET CL3;
  117. RIG1 = RI1 ET CLI1;
  118. *==================================================================*
  119. * Chargement *
  120. *==================================================================*
  121. * Pression interne uniforme de 1e6Pa.
  122. *
  123. MOP = 'MODE' SUR1 'CHARGEMENT' 'PRESSION' 'COQ2' ;
  124. MAP = 'PRES' MOP 'PRES' -1.E6 ;
  125. cha1 = bsig mop map ;
  126.  
  127. *==================================================================*
  128. * resolution : champs de deplacements *
  129. *==================================================================*
  130.  
  131. DEP1 = RESO RIG1 CHA1;
  132. *
  133. * Trace facultatif de la deformee et des reactions
  134. *
  135. SI (NEG GRAPH 'N');
  136. AMPVEC = .4E-6;
  137. REA1 = REAC DEP1 RIG1;
  138. VECT1 = VECT CHA1 (AMPVEC * 5) FR FZ ROUGE ;
  139. VECT2 = VECT REA1 (AMPVEC * 5) FR FZ BLEU ;
  140. DEF0 = DEFO 0. DEP1 SUR1;
  141. DEF1 = DEFO 20. DEP1 SUR1 (VECT1 ET VECT2) VERT;
  142. TITR 'ELAS6 : DEFORMEE, CHARGEMENT, REACTIONS';
  143. TRAC SUR1 (DEF0 ET DEF1);
  144. FINSI;
  145.  
  146. *==================================================================*
  147. * extraction d'une contrainte *
  148. * et comparaison avec solution analytique *
  149. *==================================================================*
  150. * On cherche la contrainte tangentielle sigtt au noeud pd et
  151. * sur la surface exterieure.
  152. *
  153. * Calcul du champs de contraintes generalisees.
  154. *
  155. CHAM1 = SIGM MODL1 MATR1 DEP1;
  156. *
  157. * Calcul du champs de contraintes au sens des milieux continus :
  158. * Utilisation l'operateur CALP.
  159. *
  160. CHAM2 = CALP CHAM1 MATR1 MODL1 INFE;
  161. *
  162. * Interpolation aux noeuds du maillage
  163. *
  164. CHAM3 = CHAN NOEUD MODL1 CHAM2;
  165. CHPO3 = CHAN CHPO MODL1 CHAM3;
  166. *
  167. * Extraction de la contrainte
  168. *
  169. SMTTD = EXTR CHPO3 SMYY PD;
  170. SMTTD = SMTTD / 1.E6;
  171. *
  172. SMTTD1 = 94.55;
  173. *
  174. * Calcul de l'ecart avec la solution de reference.
  175. *
  176. ERGTTD = 100 * (ABS ((SMTTD - SMTTD1) / SMTTD1));
  177.  
  178. *==================================================================*
  179. * affichage des resultats *
  180. *==================================================================*
  181. MESS ' Resultats du test ELAS6_2 ';
  182. MESS ' ------------------------- ';
  183. *
  184. MESS ' La valeur cherchee est la contrainte tangentielle au point D,';
  185. ' elle est comparee a une valeur theorique obtenue analytiquement.';
  186. MESS ' Contrainte tangentielle theorique en D :' SMTTD1 'MPa';
  187. MESS ' Contrainte tangentielle calculee en D :' SMTTD 'MPa';
  188. MESS ' Soit un ecart de :' ERGTTD '%';
  189. *
  190. SI (K EGA 1);
  191. MESS ' Maillage grossier';
  192. SINON;
  193. MESS ' Maillage fin';
  194. FINSI;
  195. *
  196. MESS ' Nombre d elements :' ELSUR1;
  197. MESS ' Nombre de noeuds :' NOSUR1;
  198. MESS ' soit ' (NOSUR1 * 3) 'd.d.l.';
  199.  
  200. *==================================================================*
  201. * code fonctionnement *
  202. *==================================================================*
  203. * L'ecart maximum entre valeur theorique et calculee doit etre
  204. * inferieure a 1,5%.
  205. *
  206. SAUT 2 LIGNE;
  207. SI (ERGTTD <EG 1.5);
  208. ERRE 0;
  209. SINON;
  210. ERRE 5;
  211. FINSI;
  212.  
  213. *==================================================================*
  214. * Temps de calcul et fin *
  215. *==================================================================*
  216. TEMPS;
  217.  
  218. FIN;
  219.  
  220.  
  221.  
  222.  
  223.  
  224.  
  225.  
  226.  
  227.  
  228.  
  229.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales