Télécharger elas17.dgibi

Retour à la liste

Numérotation des lignes :

  1. * fichier : elas17.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4. GRAPH='N';
  5. SAUT PAGE ;
  6. *************************************************************************
  7. * ANALYSE D'UN TREILLIS AVEC LE CHARGEMENT THERMIQUE
  8. *************************************************************************
  9. *
  10. * DESCRIPTION DU PROBLEME
  11. * -----------------------
  12. *
  13. * UN TREILLIS ARTICULE EST CHARGE PAR UNE FORCE A SON EXTREMITE LIBRE
  14. * ET SOUMIS A UN ECHAUFFEMENT SUR UN DE SES ELEMENTS.IL S'AGIT DE
  15. * CALCULER LES DEPLACEMENTS DES NOEUDS ET LES FORCES DANS LES BARRES.
  16. *
  17. * REFERENCE :
  18. * ----------
  19. * J. S. PRZEMIENIECKI,THEORY OF MATRIX STRUCTURAL ANALYSIS(NEW YORK:
  20. * MCGRAW-HILL BOOK COMPANY,1968),P. 155
  21. ************************************************************************
  22. OPTION ECHO 0 ;
  23. OPTIO DIME 3 ELEM SEG2 ;
  24. *
  25. * MAILLAGE
  26. *
  27. P1 = 20. 20. 0. ; P2 = 20. 0. 0. ;
  28. P3 = 0. 20. 0. ; P4 = 0. 0. 0. ;
  29. L1 = D 1 P3 P1 ; L2 = D 1 P4 P1 ;
  30. L3 = D 1 P1 P2 ; L4 = D 1 P3 P2 ;
  31. L5 = D 1 P4 P2 ; L6 = D 1 P3 P4 ;
  32. LA1 = L1 ET L5 ET L6 ;
  33. LA2 = L2 ET L4 ;LTOT = LA1 ET LA2 ET L3 ;
  34. *
  35. * MODELE
  36. *
  37. MOD1 = MODEL LA1 MECANIQUE ELASTIQUE BARR ;
  38. MOD2 = MODEL LA2 MECANIQUE ELASTIQUE BARR ;
  39. MOD3 = MODEL L3 MECANIQUE ELASTIQUE BARR ;
  40. MODT = MOD1 ET MOD2 ET MOD3 ;
  41. *
  42. * PROPRIETES DE MATERIAUX
  43. *
  44. MAT1 = MATER MOD1 YOUN 1.E7 NU 0.3 ALPHA 1.E-6 'TALP' 0. ;
  45. MAT2 = MATER MOD2 YOUN 1.E7 NU 0.3 ALPHA 1.E-6 'TALP' 0. ;
  46. MAT3 = MATER MOD3 YOUN 1.E7 NU 0.3 ALPHA 1.E-6 'TALP' 0. ;
  47. CAR1 = CARAC MOD1 SECT 1. ;
  48. CAR2 = CARAC MOD2 SECT 0.7071068 ;
  49. CAR3 = CARAC MOD3 SECT 1. ;
  50. MAT = MAT1 ET MAT2 ET MAT3 ; CAR = CAR1 ET CAR2 ET CAR3 ;
  51. *
  52. * CONDITIONS AUX LIMITES
  53. *
  54. CL1 = BLOQ L6 'DEPL' ;
  55. *
  56. * MATRICE DE RIGIDITE
  57. *
  58. RIG1 = RIGI MODT (MAT ET CAR) ;
  59. * 1)CHARGEMENT MECANIQUE
  60. *
  61. * CHARGEMENT MECANIQUE
  62. *
  63. F1 = FORCE (0. 1000. 0.) P1 ;
  64. *
  65. * RESOLUTION
  66. *
  67. DEPM = RESO (RIG1 ET CL1) F1 ;
  68. SIGM = SIGM MODT (MAT ET CAR) DEPM ;
  69. *2) CHARGEMENT THERMIQUE
  70. *
  71. * CHAMP DE TEMPERATURE
  72. *
  73. CTHER1 = MANU 'CHML' L3 'T' 100. TYPE 'TEMPERATURES' ;
  74. CTHER2 = MANU 'CHML' LA1 'T' 0. TYPE 'TEMPERATURES' ;
  75. CTHER3 = MANU 'CHML' LA2 'T' 0. TYPE 'TEMPERATURES' ;
  76. CTHER = CTHER1 ET CTHER2 ET CTHER3 ;
  77. SIGTH = THETA MODT (MAT ET CAR) CTHER ;
  78. FTH = BSIGM MODT SIGTH CAR ;
  79. DEPTH = RESO (RIG1 ET CL1) FTH ;
  80. SIGTH1 = SIGMA MODT DEPTH (MAT ET CAR) ;
  81. SIGTH2 = SIGTH1 - SIGTH ;
  82. *
  83. * MECANIQUE + THERMIQUE
  84. *
  85. DEP = DEPM + DEPTH ;
  86. SIG = SIGM + SIGTH2 ;
  87. *
  88. * COMPARAISON AVEC LES RESULTATS ANALYTIQUES
  89. *
  90. U1 = EXTR DEP UX P1 ;U1TH = -1.272727E-3 ;
  91. ERU1 =((U1 - U1TH) / (ABS U1TH))*100. ;
  92. V1 = EXTR DEP UY P1 ;V1TH = 6.363636E-3 ;
  93. ERV1 =((V1 - V1TH) / (ABS V1TH))*100. ;
  94. U2 = EXTR DEP UX P2 ;U2TH = 7.272727E-4 ;
  95. ERU2 =((U2 - U2TH) / (ABS U2TH))*100. ;
  96. V2 = EXTR DEP UY P2 ;V2TH = 3.636364E-3 ;
  97. ERV2 =((V2 - V2TH) / (ABS V2TH))*100. ;
  98. *
  99. MESS ' DEPLACEMENTS POINT P1 ' ;
  100. MESS 'U1 THEORIE 'U1TH 'CASTEM 'U1'%ERREUR 'ERU1 ;
  101. MESS 'V1 THEORIE 'V1TH 'CASTEM 'V1'%ERREUR 'ERV1 ;
  102. MESS ' DEPLACEMENTS POINT P3 ' ;
  103. MESS 'U2 THEORIE 'U2TH 'CASTEM 'U2'%ERREUR 'ERU2 ;
  104. MESS 'V2 THEORIE 'V2TH 'CASTEM 'V2'%ERREUR 'ERV2 ;
  105. *
  106. EF1 = EXTR SIG 1 1 1 EFFX ; EF1TH = -636.36 ;
  107. ERF1 = ((EF1 - EF1TH) / (ABS EF1TH)) * 100. ;
  108. EF2 = EXTR SIG 2 1 1 EFFX ; EF2TH = 899.95 ;
  109. ERF2 = ((EF2 - EF2TH) / (ABS EF2TH)) * 100. ;
  110. EF3 = EXTR SIG 3 1 1 EFFX ; EF3TH = 363.64 ;
  111. ERF3 = ((EF3 - EF3TH) / (ABS EF3TH)) * 100. ;
  112. EF4 = EXTR SIG 2 2 1 EFFX ; EF4TH = -514.26 ;
  113. ERF4 = ((EF4 - EF4TH) / (ABS EF4TH)) * 100. ;
  114. EF5 = EXTR SIG 1 2 1 EFFX ; EF5TH = 363.64 ;
  115. ERF5 = ((EF5 - EF5TH) / (ABS EF5TH)) * 100. ;
  116. EF6 = EXTR SIG 1 3 1 EFFX ; EF6TH = 0. ;
  117. ERF6 = EF6 - EF6TH ;
  118. *
  119. MESS ' EFFORTS DANS LES BARRES ' ;
  120. MESS'EFF1 THEORIE 'EF1TH'CASTEM 'EF1'%ERREUR 'ERF1 ;
  121. MESS'EFF2 THEORIE 'EF2TH'CASTEM 'EF2'%ERREUR 'ERF2 ;
  122. MESS'EFF3 THEORIE 'EF3TH'CASTEM 'EF3'%ERREUR 'ERF3 ;
  123. MESS'EFF3 THEORIE 'EF4TH'CASTEM 'EF4'%ERREUR 'ERF4 ;
  124. MESS'EFF4 THEORIE 'EF5TH'CASTEM 'EF5'%ERREUR 'ERF5 ;
  125. MESS'EFF5 THEORIE 'EF6TH'CASTEM 'EF6'%ERREUR 'ERF6 ;
  126. *
  127. * DEFORMEE
  128. *
  129. DEF1 = DEFORM DEP LTOT 100. ROUG ;
  130. DEF0 = DEFORM DEP LTOT 0. VERT ;
  131. SI (NEG GRAPH 'N');
  132. TRAC (0 0 10000)(DEF0 ET DEF1) ;
  133. FINSI ;
  134. *
  135. SI ((MAXI ABS
  136. (PROG ERF1 ERF2 ERF3 ERF4 ERF5 ERF6 ERV1 ERV2 )) < 5);
  137. ERRE 0;
  138. SINON;
  139. ERRE 5;
  140. FINSI;
  141. FIN ;
  142.  
  143.  
  144.  
  145.  
  146.  
  147.  
  148.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales