Télécharger elas15.dgibi

Retour à la liste

Numérotation des lignes :

  1. * fichier : elas15.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4. graph='N';
  5. saut page;
  6. ********************************************************************
  7. * Etude d'une poutre a un element, encastree d'un cote
  8. *
  9. *
  10. * encastrement sollicitation
  11. *
  12. * |-------------------------------------*
  13. *
  14. * p1 p2
  15. *
  16. ********************************************************************
  17. *
  18. * verification de solutions elementaires en flexion et en
  19. * cisaillement, pour deux orientations des axes locaux Ox et
  20. * Oz.
  21. *
  22. ********************************************************************
  23. *
  24. opti dime 3 elem seg2;
  25. *
  26. * 1) maillage avec 2 orientations de Ox opposees
  27. *
  28. p1 = 0 0 0; p2 = 1 0 0;
  29. d1= p1 d 1 p2;
  30. d2= p2 d 1 p1;
  31. *
  32. * 2) modeles, materiaux et caracteristiques
  33. *
  34. modti1=MODE d1 mecanique elastique timo;
  35. modti2=MODE d2 mecanique elastique timo;
  36. *
  37. mater1=MATE modti1 'YOUN' 1. 'NU' .3;
  38. section=2.6; inery=1.; inerz=1.; torsion=1.;
  39. carac1= 'CARA' modti1 'SECT' section 'INRY' inery 'INRZ' inerz
  40. 'SECY' section 'SECZ' section 'TORS' torsion;
  41. mc1=carac1 et mater1;
  42. *
  43. mater2=MATE modti2 'YOUN' 1. 'NU' .3;
  44. carac2= 'CARA' modti2 'SECT' section 'INRY' inery 'INRZ' inerz
  45. 'SECY' section 'SECZ' section 'TORS' torsion;
  46. mc2=carac2 et mater2;
  47. *
  48. * 3) rigidite
  49. *
  50. rigti1=rigi modti1 mc1;
  51. rigti2=rigi modti2 mc2;
  52. *
  53. * 4) etat de flexion 'positif' EN ANGLE en Z
  54. *
  55. * 4.1) solution theorique
  56. *
  57. uty=.5; rtz=1.; motz=1.;
  58. *
  59. * 4.2) definition des blocages et des rigidites totales
  60. *
  61. bloqtot=bloq d1 'UZ' 'RX' 'RY';
  62. bloqp1 =bloq p1 'UX' 'UY' 'RZ';
  63. rigtti1=rigti1 et bloqtot et bloqp1;
  64. rigtti2=rigti2 et bloqtot et bloqp1;
  65. fext=moment 'MZ' 1. p2;
  66. *
  67. * 4.3) resolutions
  68. *
  69. depti1=reso rigtti1 fext;
  70. depti2=reso rigtti2 fext;
  71. *
  72. * 4.4) contraintes
  73. *
  74. sigti1=sigma modti1 mc1 depti1;
  75. sigti2=sigma modti2 mc2 depti2;
  76. *
  77. * 4.5) messages
  78. *
  79. uuy1=extr depti1 'UY' p2; rrz1=extr depti1 'RZ' p2;
  80. uuy2=extr depti2 'UY' p2; rrz2=extr depti2 'RZ' p2;
  81. * WARNING: l'axe local Oz change de signe
  82. mmz1=extr sigti1 'MOMZ' 1 1 1; mmz2=(-1)*(extr sigti2 'MOMZ' 1 1 1);
  83. message 'flexion en Z';
  84. message 'UY (orient 1) UY (orient 2) Uth' uuy1 uuy2 uty;
  85. message 'RZ (orient 1) RZ (orient 2) Rth' rrz1 rrz2 rtz;
  86. message 'mz (orient 1) mz (orient 2) mth' mmz1 mmz2 motz;
  87. *
  88. * 4.6) erreur
  89. *
  90. errr=uuy1 + uuy2 - (2*uty) + rrz1 + rrz2 - (2*rtz) +
  91. mmz1 + mmz2 - (2*motz);
  92. si ((abs errr) > 1.d-6); erre 5;
  93. sinon; erre 0; finsi;
  94. *
  95. * 5) etat de flexion positif EN ANGLE en Y
  96. *
  97. * 5.1) solution theorique
  98. *
  99. utz=-.5; rty=1.; moty=1.;
  100. *
  101. * 5.2) definition des blocages et des rigidites totales
  102. *
  103. bloqtot=bloq d1 'UY' 'RX' 'RZ';
  104. bloqp1 =bloq p1 'UX' 'UZ' 'RY';
  105. rigtti1=rigti1 et bloqtot et bloqp1;
  106. rigtti2=rigti2 et bloqtot et bloqp1;
  107. fext=moment 'MY' 1. p2;
  108. *
  109. * 5.3) resolutions
  110. *
  111. depti1=reso rigtti1 fext;
  112. depti2=reso rigtti2 fext;
  113. *
  114. * 5.4) contraintes
  115. *
  116. sigti1=sigma modti1 mc1 depti1;
  117. sigti2=sigma modti2 mc2 depti2;
  118. *
  119. * 5.5) messages
  120. *
  121. message 'flexion en Y';
  122. uuz1=extr depti1 'UZ' p2; rry1=extr depti1 'RY' p2;
  123. uuz2=extr depti2 'UZ' p2; rry2=extr depti2 'RY' p2;
  124. mmy1=extr sigti1 'MOMY' 1 1 1; mmy2=extr sigti2 'MOMY' 1 1 1;
  125. message 'UZ (orient 1) UZ (orient 2) Uth' uuz1 uuz2 utz;
  126. message 'RY (orient 1) RY (orient 2) Rth' rry1 rry2 rty;
  127. message 'my (orient 1) my (orient 2) mth' mmy1 mmy2 moty;
  128. *
  129. * 5.6) erreur
  130. *
  131. errr=uuz1 + uuz2 - (2*utz) + rry1 + rry2 - (2*rty) +
  132. mmy1 + mmy2 - (2*moty);
  133. si ((abs errr) > 1.d-6); erre 5;
  134. sinon; erre 0; finsi;
  135. *
  136. * 6) etat de cisaillement positif en Y
  137. *
  138. * 6.1) solution theorique
  139. *
  140. uty=1.; rtz=0.; fty=1.;
  141. *
  142. * 6.2) definition des blocages et des rigidites totales
  143. *
  144. bloqtot=bloq d1 'UZ' 'RX' 'RY';
  145. bloqp1 =bloq p1 'UX' 'UY' 'RZ';
  146. rigtti1=rigti1 et bloqtot et bloqp1;
  147. rigtti2=rigti2 et bloqtot et bloqp1;
  148. fext=(force 'FY' 1. p2) et (moment 'MZ' -.5 p2);
  149. *
  150. * 6.3) resolutions
  151. *
  152. depti1=reso rigtti1 fext;
  153. depti2=reso rigtti2 fext;
  154. *
  155. * 6.4) contraintes
  156. *
  157. sigti1=sigma modti1 mc1 depti1;
  158. sigti2=sigma modti2 mc2 depti2;
  159. *
  160. * 6.5) messages
  161. *
  162. message 'cisaillement en Y';
  163. uuy1=extr depti1 'UY' p2; rrz1=extr depti1 'RZ' p2;
  164. uuy2=extr depti2 'UY' p2; rrz2=extr depti2 'RZ' p2;
  165. ffy1=extr sigti1 'EFFY' 1 1 1; ffy2=extr sigti2 'EFFY' 1 1 1;
  166. message 'UY (orient 1) UY (orient 2) Uth' uuy1 uuy2 uty;
  167. message 'RZ (orient 1) RZ (orient 2) Rth' rrz1 rrz2 rtz;
  168. message 'fy (orient 1) fy (orient 2) mth' ffy1 ffy2 fty;
  169. *
  170. * 6.6) erreur
  171. *
  172. errr=uuy1 + uuy2 - (2*uty) + rrz1 + rrz2 - (2*rtz) +
  173. ffy1 + ffy2 - (2*fty);
  174. si ((abs errr) > 1.d-6); erre 5;
  175. sinon; erre 0; finsi;
  176. *
  177. * 7) etat de cisaillement positif en Z
  178. *
  179. * 7.1) solution theorique
  180. *
  181. utz=1.; rty=0.; fty=1.;
  182. *
  183. * 7.2) definition des blocages et des rigidites totales
  184. *
  185. bloqtot=bloq d1 'UY' 'RX' 'RZ';
  186. bloqp1 =bloq p1 'UX' 'UZ' 'RY';
  187. rigtti1=rigti1 et bloqtot et bloqp1;
  188. rigtti2=rigti2 et bloqtot et bloqp1;
  189. fext=(force 'FZ' 1. p2) et (moment 'MY' .5 p2);
  190. *
  191. * 7.3) resolutions
  192. *
  193. depti1=reso rigtti1 fext;
  194. depti2=reso rigtti2 fext;
  195. *
  196. * 7.4) contraintes
  197. *
  198. sigti1=sigma modti1 mc1 depti1;
  199. sigti2=sigma modti2 mc2 depti2;
  200. *
  201. * 7.5) messages
  202. *
  203. message 'cisaillement en Z';
  204. uuz1=extr depti1 'UZ' p2; rry1=extr depti1 'RY' p2;
  205. uuz2=extr depti2 'UZ' p2; rry2=extr depti2 'RY' p2;
  206. * WARNING: l'axe local Oz change de signe
  207. ffz1=extr sigti1 'EFFZ' 1 1 1; ffz2=(-1)*(extr sigti2 'EFFZ' 1 1 1);
  208. message 'UZ (orient 1) UZ (orient 2) Uth' uuz1 uuz2 utz;
  209. message 'RY (orient 1) RY (orient 2) Rth' rry1 rry2 rty;
  210. message 'fz (orient 1) fz (orient 2) mth' ffz1 ffz2 fty;
  211. *
  212. * 7.6) erreur
  213. *
  214. errr=uuz1 + uuz2 - (2*utz) + rry1 + rry2 - (2*rty) +
  215. ffy1 + ffy2 - (2*fty);
  216. si ((abs errr) > 1.d-6); erre 5;
  217. sinon; erre 0; finsi;
  218. *
  219. fin;
  220.  
  221.  
  222.  
  223.  
  224.  
  225.  
  226.  
  227.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales