Télécharger elas14.dgibi

Retour à la liste

Numérotation des lignes :

  1. * fichier : elas14.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4. * SI GRAPH = N PAS DE GRAPHIQUE AFFICHE
  5. * SINON SI GRAPH DIFFERENT DE N TOUS LES GRAPHIQUES SONT AFFICHES
  6. *
  7.  
  8. opti trac bens;
  9.  
  10.  
  11. *-------------------------------------------------------------------*
  12. * TEST ELAS14 *
  13. * *
  14. * CONSOLE SOUS CHARGE CONCENTREE *
  15. * ----------------------------------- *
  16. * *
  17. * *
  18. * *
  19. * IL S'AGIT D'UNE CONSOLE SOUS CHARGE CONCENTREE A L'EXTREMITE *
  20. * libre .On etudie la variation de la fleche sous la charge en *
  21. * fonction de l'elancement L/H (L etant la longueur de la console *
  22. * et H son epaisseur ).On compare les resultats donnees par *
  23. * l'element coque DST a ceux de l'element coque DKT en tracant la *
  24. * variation des fleches sous la charge donnees par les deux elements*
  25. *(normalisees par la fleche theorique) en fonction de l'elancement .*
  26. * On constate que les resultats sont semblables que pour des *
  27. * elancements eleves .Dans la branche ou l'element DKT n'est plus *
  28. * satisfaisant l'element DST est en parfait accord avec la reponse *
  29. * theorique . *
  30. * Reference :I.CHAHROUR ,these de doctorat soutenue a INSA LYON *
  31. * septembre 1991 *
  32. * *
  33. *-------------------------------------------------------------------*
  34. graph = 'N';
  35. SAUT PAGE ;
  36. TITRE 'FLECHE SOUS LA CHARGE EN FONCTION DE L ELANCEMENT ';
  37. *________________________________________________________________________
  38. * GEOMETRIE
  39. *________________________________________________________________________
  40. OPTI DIME 3 ELEM TRI3 ECHO 1 DENS 0.5 ;
  41. B= 1. ; L=10. ;
  42. F = 500.*B ;
  43. NB =4/2; NB2=1;
  44. A1 = (L*0.75) 0. 0. ;A2=(L*0.75) B 0.0;
  45. B1 = L 0. 0. ; B2 = L B 0.0 ;
  46. C1 = (0.875*L) (B/2) 0.0 ;
  47. TR1 = MANU TRI3 A1 B1 C1 ;
  48. TR2 = MANU TRI3 B1 B2 C1 ;
  49. TR3 = MANU TRI3 B2 A2 C1 ;
  50. TR4 = MANU TRI3 A2 A1 C1 ;
  51. S1=TR1 ET TR2 ET TR3 ET TR4 ;
  52. DEPL=L/4 ;
  53. S2=MOINS S1 (DEPL 0. 0. );
  54. S3= S2 MOINS (DEPL 0. 0. );
  55. S4= S3 MOINS (DEPL 0. 0. );
  56. ST = S1 ET S2 ET S3 ET S4 ;
  57. ELIM ST 0.1 ;
  58. E=0.0 0.0 0.0 ;D=0.0 1. 0.0 ;
  59. DD1=POIN ST PROC D;
  60. EE1=POINT ST PROC E ;
  61. LB=DROIT 1 DD1 EE1 ;
  62. OEIL = 0 0 1000 ;
  63. SI (NEG GRAPH 'N') ;
  64. TRACE OEIL ST ;
  65. FINSI ;
  66. *________________________________________________________________________
  67. * INITIALISATION
  68. *________________________________________________________________________
  69. ITER=0 ;
  70. XABS=PROG ;
  71. FONC1=PROG;
  72. FONC2=PROG;
  73. FONC3=PROG;
  74. LSHM=100. ;LLSH=0. ;
  75. NB=10;DLLSH=(LOG (LSHM))/NB ;
  76. RP=0.0 ;
  77. *________________________________________________________________________
  78. * BOUCLE SUR LE NOMBRE DE CALCUL
  79. *________________________________________________________________________
  80. REPETE BLOC1 NB ;
  81. LLSH =ITER*DLLSH ;LSH=EXP LLSH ;EP=L/LSH;
  82. ITER=ITER+1;
  83. *________________________________________________________________________
  84. * MATERIAUX
  85. *________________________________________________________________________
  86. E=1.2E6 ;
  87. *
  88. MOD1=MODE ST MECANIQUE ELASTIQUE ISOTROPE DST ;
  89. MAT1=MATE MOD1 YOUN E NU 0. EPAI EP RHO 1. ;
  90. MOD2=MODE ST MECANIQUE ELASTIQUE ISOTROPE DKT ;
  91. MAT2=MATE MOD2 YOUN E NU 0. EPAI EP ;
  92. *________________________________________________________________________
  93. * CONDITIONS AUX LIMITES ET RIGIDITE
  94. *________________________________________________________________________
  95. RI1=RIGI MOD1 MAT1 ;
  96. RI2=RIGI MOD2 MAT2 ;
  97. CL1=BLOQ UX UY UZ RY RX RZ LB ;
  98. RIT1 = RI1 ET CL1 ;
  99. RIT2 = RI2 ET CL1 ;
  100. *________________________________________________________________________
  101. * FORCES IMPOSEES
  102. *________________________________________________________________________
  103. FO1 = FORC FZ F B1 ;
  104. FO2 = FORC FZ F B2 ;
  105. *________________________________________________________________________
  106. * CALCUL ET SORTIE
  107. *________________________________________________________________________
  108. *
  109. DEP1 = RESO RIT1 (FO1 ET FO2) ;
  110. DEP2 = RESO RIT2 (FO1 ET FO2) ;
  111. FLEC1 = EXTR DEP1 UZ B1;
  112. FLEC2 = EXTR DEP2 UZ B1;
  113. *__________________________________________________________
  114. * CALCUL DE LA FLECHE THEORIQUE
  115. *__________________________________________________________
  116. H=EP ;
  117. I=B*(H**3); I=I/12 ;FLET1=2*F*(L**3) ;EI=3*E*I;FLET1=FLET1/EI;
  118. TAU=(2.*F)/(B*H);G=E/2.;GAMA=TAU/G ;FLET2=GAMA*L*1.2 ;
  119. FLET=FLET1+FLET2 ;
  120. *__________________________________________________________
  121. * FORMATION DES LISTES REELS CONTENANT LES VALEURS DE L/H
  122. * ET LES VALEURS DE W/Wth
  123. *__________________________________________________________
  124. *
  125. XABS=INSER XABS ITER LLSH ;
  126. FONC1=INSER FONC1 ITER (FLEC1/FLET);
  127. FONC2=INSER FONC2 ITER (FLEC2/FLET) ;
  128. RP=ABS(1.-(FLEC1/FLET)) +RP;
  129. FIN BLOC1 ;
  130. TEMPS ;
  131. *__________________________________________________________
  132. * FIN DU BOUCLE ,TRACE DES COURBES W/WTH=F(Ln(L/H))
  133. *__________________________________________________________
  134. Si ( NEG GRAPH 'N');
  135. EV1=EVOL ROUGE MANU 'Ln L/H' XABS 'W/Wth' FONC1 ;
  136. EV2=EVOL BLEU MANU 'Ln L/H' XABS 'W/Wth' FONC2 ;
  137. SAUT PAGE ;
  138. DESSIN (EV1 ET EV2);
  139. finsi;
  140.  
  141. RPP=RP/NB ;
  142.  
  143. *__________________________________________________________
  144. * CODE FONCTIONNEMENT
  145. *__________________________________________________________
  146. *
  147. SI (RPP <EG 2E-2);
  148. ERRE 0 ;
  149. SINO;
  150. ERRE 5 ;
  151. FINSI;
  152. FIN ;
  153.  
  154.  
  155.  
  156.  
  157.  
  158.  
  159.  
  160.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales