Télécharger elas1.dgibi

Retour à la liste

Numérotation des lignes :

  1. * fichier : elas1.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4.  
  5. *******************************************************
  6. * Test elas1.dgibi: Jeux de données *
  7. * --------------------------------- *
  8. *******************************************************
  9.  
  10. * SI GRAPH = N PAS DE GRAPHIQUE AFFICHE
  11. * SINON SI GRAPH DIFFERENT DE N TOUS
  12. * LES GRAPHIQUES SONT AFFICHES
  13.  
  14. GRAPH = 'N' ;
  15.  
  16. SAUT PAGE;
  17. SI (NEG GRAPH 'N') ;
  18. OPTI ECHO 1 ;
  19. OPTI TRAC PSC ;
  20. SINO ;
  21. OPTI ECHO 1 ;
  22. FINSI ;
  23.  
  24. *______________________________________________________
  25. * TEST ELAS1
  26. *
  27. * Une calotte sph}rique est soumise :
  28. * - @ une pression interne
  29. * - @ son poids propre
  30. * - @ une force radiale en tete
  31. *
  32. * En élasticité et en supposant le probleme
  33. * axisymétrique, on se propose de calculer le
  34. * déplacement radial en tete de la calotte.
  35. *
  36. * Pour résoudre ce probleme on utilise le principe
  37. * de superposition. Les forces équivalentes pour chaque
  38. * chargement sont calculées puis ajoutées avant de
  39. * résoudre le systeme.
  40. *
  41. * Le déplacement radial en tete calculé est comparé à
  42. * la valeur théorique égale à 4.677 microns.
  43. *
  44. *______________________________________________________
  45. TITRE 'CALOTTE SPHERIQUE SOUS PLUSIEURS TYPES
  46. DE CHARGEMENT';
  47. OPTION DIME 2 ELEM SEG2 MODE AXIS ;
  48.  
  49. *______________________________________________________
  50. *------------------ DEFINITION DE LA GEOMETRIE --------
  51. *______________________________________________________
  52. *
  53. A = 0 0 ;
  54. B = 1 1 ;
  55. O = 0 1 ;
  56. *
  57. L1 = CERC 100 A O B ;
  58. *
  59. SI (NEG GRAPH 'N');
  60. TRAC (L1 ET O) 'QUAL' ;
  61. FINSI;
  62.  
  63. *______________________________________________________
  64. *----- DEFINITION DES CONDITIONS AUX LIMITES ---------
  65. *______________________________________________________
  66.  
  67. CL1 = BLOQ B UZ ;
  68. CL2 = BLOQ A UR ;
  69. CL = CL1 ET CL2 ;
  70.  
  71. *______________________________________________________
  72. * DEFINITION DU MODELE, DU MATERIAU
  73. * ET DES CARACTERISTIQUES
  74. *______________________________________________________
  75. MO = MODE L1 MECANIQUE ELASTIQUE COQ2 ;
  76.  
  77. MA = MATE MO YOUN 2.1E11 NU 0.3 RHO 7.85E4 ;
  78. CA = CARA MO EPAI 0.02 ;
  79. MA=MA ET CA;
  80. *______________________________________________________
  81. *------- CALCUL DE LA MATRICE DE RIGIDITE -------------
  82. *______________________________________________________
  83. RI1 = RIGI MO MA ;
  84. RI2 = RI1 ET CL ;
  85. *______________________________________________________
  86. *-------------- DEFINITION DES CHARGES ----------------
  87. *______________________________________________________
  88. *
  89. *
  90. *------------ PRESSION INTERNE UNIFORME ---------------
  91. *
  92. MOP = 'MODE' L1 'CHARGEMENT' 'PRESSION' 'COQ2' ;
  93. MAP = 'MATE' MOP 'EPAI' 0.02 ;
  94. CHP = 'PRES' MOP 'PRES' -10000 ;
  95. FO1 = 'BSIG' MOP CHP ;
  96. *
  97. * -- POIDS PROPRE (IL FAUT CALCULER LA MATRICE MASSE) -
  98. *
  99. MAS = MASSE MO MA;
  100. EL1 = CHANGE L1 POI1 ;
  101. POP = MANU CHPO EL1 1 UZ -1 ;
  102. FO2 = MAS*POP ;
  103. *
  104. *------------- FORCE RADIALE EN TETE ------------------
  105. *
  106. F=1000*2*PI;
  107. FO3 = FORC FR F B ;
  108. *
  109. FO = FO1 + FO2 + FO3 ;
  110. *______________________________________________________
  111. *--CALCUL PAR RESO DES DEPLACEMENTS ET POST-TRAITEMENT-
  112. *______________________________________________________
  113. RE = RESO RI2 FO ;
  114. DR = EXTR RE UR B ;
  115. DR = 1000000*DR ;
  116. SAUT PAGE ;
  117. MESS ' DEPLACEMENT RADIAL EN TETE THEORIQUE
  118. CALCULE ' ;
  119. MESS ' UR=4.677 MICRON
  120. UR =' DR 'MICRON';
  121. TEMPS ;
  122. *______________________________________________________
  123. *--------- CODE DE BON FONCTIONNEMENT -----------------
  124. *______________________________________________________
  125.  
  126. ERR=100*(ABS(4.677 -DR)/4.677);
  127. SI (ERR < 5);
  128. ERRE 0;
  129. SINON;
  130. ERRE 5;
  131. FINSI;
  132.  
  133. FIN;
  134.  
  135.  
  136.  
  137.  
  138.  
  139.  
  140.  
  141.  
  142.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales