Télécharger convection_axi.dgibi

Retour à la liste

Numérotation des lignes :

  1. * fichier : convection_axi.dgibi
  2.  
  3. *******************************************
  4. *******************************************
  5.  
  6. ************************************************************************
  7. * DESCRIPTION DE CONVECTION_AXI.DGIBI *
  8. ************************************************************************
  9. * Ce cas-test unitaire permet de VERIFIER et VALIDER le fonctionnement
  10. * de l'operateur 'CONV' dans les conditions suivantes :
  11. * MODE : Axisymetrique
  12. * MAILLAGE : Ligne verticale constituee de 1 element et de 2 noeuds
  13. * EF : COQ2, SEG2
  14. *
  15. * VERIFICATIONS : Le MMODEL CONTIENT 1 MMODEL DE CONVECTION CLASSIQUE
  16. * Le MMODEL CONTIENT 1 MMODEL DE CONVECTION COQUE INF
  17. * Le MMODEL CONTIENT 1 MMODEL DE CONVECTION COQUE SUP
  18. * Le MMODEL CONTIENT 2 MMODEL DE CONVECTION COQUE
  19. * Le MMODEL CONTIENT 3 MMODEL DE CONVECTION CLASSIQUE
  20. * COQUE
  21. *
  22. * VALIDATION : Calcul analytique du flux et comparaison a Cast3M
  23. *
  24. ************************************************************************
  25.  
  26.  
  27. ************************************************************************
  28. * OPTIONS *
  29. ************************************************************************
  30. OPTI DIME 2 MODE AXIS;
  31. OPTI ECHO 0 ;
  32.  
  33. ************************************************************************
  34. * PARAMETRES *
  35. ************************************************************************
  36. RAYO1 = 1.125 ;
  37. HAUT1 = 3.245 ;
  38. HCON = 1.568 ;
  39. HINF = 2.**0.5 ;
  40. HSUP = PI**0.33 ;
  41. TECONV= 1.456 ;
  42. TEINFE= 13.4568 ;
  43. TESUPE= 800. ;
  44.  
  45.  
  46. ************************************************************************
  47. * MAILLAGE *
  48. ************************************************************************
  49. P1 = RAYO1 0. ;
  50. P2 = RAYO1 HAUT1 ;
  51.  
  52. OPTI 'ELEM' 'SEG2' ;
  53. L1 = 'DROI' 1 P1 P2 ;
  54.  
  55. ************************************************************************
  56. * MODELE & MATERIAUX *
  57. ************************************************************************
  58. MODCON = MODE L1 'THERMIQUE' 'CONVECTION' ;
  59. MODINF = MODE L1 'THERMIQUE' 'CONVECTION' 'INFERIEURE' 'COQ2';
  60. MODSUP = MODE L1 'THERMIQUE' 'CONVECTION' 'SUPERIEURE' 'COQ2';
  61. MODTOT2= MODINF ET MODSUP ;
  62. MODTOT3= MODINF ET MODSUP ET MODCON ;
  63.  
  64. MATCON = MATE MODCON 'H' HCON ;
  65. MATINF = MATE MODINF 'H' HINF ;
  66. MATSUP = MATE MODSUP 'H' HSUP ;
  67. MATTOT2= MATINF ET MATSUP ;
  68. MATTOT3= MATINF ET MATSUP ET MATCON ;
  69.  
  70. ************************************************************************
  71. * APPEL A 'CONV' *
  72. ************************************************************************
  73. TECON = MANU 'CHPO' L1 1 'T ' TECONV 'NATU' 'DIFFUS';
  74. TEINF = MANU 'CHPO' L1 1 'TINF' TEINFE 'NATU' 'DIFFUS';
  75. TESUP = MANU 'CHPO' L1 1 'TSUP' TESUPE 'NATU' 'DIFFUS';
  76. TETOT2 = TEINF ET TESUP ;
  77. TETOT3 = TEINF ET TESUP ET TECON ;
  78.  
  79. FLUCON1 = CONV MODCON MATCON 'T' TECONV;
  80. FLUINF1 = CONV MODINF MATINF 'TINF' TEINFE;
  81. FLUSUP1 = CONV MODSUP MATSUP 'TSUP' TESUPE;
  82. FLUCON = CONV MODCON MATCON TECON ;
  83. FLUINF = CONV MODINF MATINF TEINF ;
  84. FLUSUP = CONV MODSUP MATSUP TESUP ;
  85. FLUTOT2 = CONV MODTOT2 MATTOT2 TETOT2 ;
  86. FLUTOT3 = CONV MODTOT3 MATTOT3 TETOT3 ;
  87.  
  88.  
  89. ************************************************************************
  90. * VALIDATION : COMPOSANTES ATTENDUES *
  91. ************************************************************************
  92. LCTES = EXTR FLUCON 'COMP';
  93. LCINF = EXTR FLUINF 'COMP';
  94. LCSUP = EXTR FLUSUP 'COMP';
  95. LCTOT2= EXTR FLUTOT2 'COMP';
  96. LCTOT3= EXTR FLUTOT3 'COMP';
  97.  
  98. * Nombre de composantes
  99. SI ((DIME LCINF) NEG 1 );
  100. MESS 'LE NOMBRE DE COMPOSANTES LCINF N EST PAS CORRECT ' (DIME LCINF);
  101. ERRE 5;
  102. FINS;
  103. SI ((DIME LCSUP) NEG 1 );
  104. MESS 'LE NOMBRE DE COMPOSANTES LCSUP N EST PAS CORRECT ' (DIME LCSUP);
  105. ERRE 5;
  106. FINS;
  107. SI ((DIME LCTOT2) NEG 2 );
  108. 'LE NOMBRE DE COMPOSANTES LCTOT2 N EST PAS CORRECT' (DIME LCTOT2) ;
  109. ERRE 5;
  110. FINS;
  111. SI ((DIME LCTOT3) NEG 3 );
  112. 'LE NOMBRE DE COMPOSANTES LCTOT3 N EST PAS CORRECT' (DIME LCTOT3) ;
  113. ERRE 5;
  114. FINS;
  115. * Noms des composantes
  116. SI (NEG (EXTR LCINF 1 ) 'QINF' );
  117. MESS 'LE NOM DE COMPOSANTES LCINF N EST PAS CORRECT ' (EXTR LCINF 1 );
  118. ERRE 5;
  119. FINS;
  120. SI (NEG (EXTR LCSUP 1 ) 'QSUP' );
  121. MESS 'LE NOM DE COMPOSANTES LCSUP N EST PAS CORRECT ' (EXTR LCSUP 1 );
  122. ERRE 5;
  123. FINS;
  124. SI ((NEG (EXTR LCTOT2 1 ) 'QSUP') OU (NEG (EXTR LCTOT2 2) 'QINF' )) ;
  125. MESS 'LE NOM DES COMPOSANTES LCTOT2 N EST PAS CORRECT '
  126. (EXTR LCTOT2 1 ) ' ' (EXTR LCTOT2 2 ) ;
  127. ERRE 5;
  128. FINS;
  129. SI ((NEG (EXTR LCTOT3 1) 'Q' ) OU (NEG (EXTR LCTOT3 2) 'QSUP' ) OU
  130. (NEG (EXTR LCTOT3 3) 'QINF' )) ;
  131. MESS 'LE NOM DES COMPOSANTES LCTOT3 N EST PAS CORRECT '
  132. (EXTR LCTOT3 1 ) ' ' (EXTR LCTOT3 2 ) ' ' (EXTR LCTOT3 3 );
  133. ERRE 5;
  134. FINS;
  135.  
  136.  
  137. ************************************************************************
  138. * VALIDATION : COMPARAISON A DES VALEURS ANALYTIQUES *
  139. ************************************************************************
  140. VANACON = 2*PI*RAYO1*HAUT1*HCON*TECONV/2;
  141. VANAINF = 2*PI*RAYO1*HAUT1*HINF*TEINFE/2;
  142. VANASUP = 2*PI*RAYO1*HAUT1*HSUP*TESUPE/2;
  143.  
  144. VCON1 = MAXI FLUCON;
  145. VCON2 = MINI FLUCON;
  146. VINF1 = MAXI FLUINF;
  147. VINF2 = MINI FLUINF;
  148. VSUP1 = MAXI FLUSUP;
  149. VSUP2 = MINI FLUSUP;
  150.  
  151. MESS 'CONVECTION FLUX CALCULE' VCON1
  152. 'FLUX THEORIQUE' VANACON
  153. 'ECART' (ABS (VCON1 - VANACON))
  154. 'RELATIF' (ABS ((VCON1 - VANACON)/VCON1));
  155.  
  156. MESS 'INFERIEUR FLUX CALCULE' VINF1
  157. 'FLUX THEORIQUE' VANAINF
  158. 'ECART' (ABS (VINF1 - VANAINF))
  159. 'RELATIF' (ABS ((VINF1 - VANAINF)/VINF1));
  160.  
  161. MESS 'SUPERIEUR FLUX CALCULE' VSUP1
  162. 'FLUX THEORIQUE' VANASUP
  163. 'ECART' (ABS (VSUP1 - VANASUP))
  164. 'RELATIF' (ABS ((VSUP1 - VANASUP)/VSUP1));
  165.  
  166.  
  167. SI ((ABS ((VINF1 - VINF2)/VINF1)) > 1e-15 );
  168. MESS 'VALEUR VINF1 ET VINF2 NON VALIDE' (ABS ((VINF1 - VINF2)/VINF1));
  169. ERRE 5;
  170. FINS;
  171. SI ((ABS ((VSUP1 - VSUP2)/VSUP1)) > 1e-15 );
  172. MESS 'VALEUR VSUP1 ET VSUP2 NON VALIDE' (ABS ((VSUP1 - VSUP2)/VSUP1));
  173. ERRE 5;
  174. FINS;
  175.  
  176. SI ((ABS ((VINF1 - VANAINF)/VINF1)) > 1e-15 );
  177. MESS 'VALEUR NON VALIDE' (ABS ((VINF1 - VANAINF)/VINF1));
  178. ERRE 5;
  179. FINS;
  180. SI ((ABS ((VSUP1 - VANASUP)/VSUP1)) > 1e-15 );
  181. MESS 'VALEUR NON VALIDE' (ABS ((VSUP1 - VANASUP)/VSUP1));
  182. ERRE 5;
  183. FINS;
  184.  
  185.  
  186. SI ((MAXI (ABS (FLUTOT2 - FLUINF - FLUSUP))) > 1e-15 );
  187. MESS 'VALEUR NON VALIDE DANS FLUTOT2'
  188. (MAXI (ABS (FLUTOT2 - FLUINF - FLUSUP)));
  189. ERRE 5;
  190. FINS;
  191.  
  192. SI ((MAXI (ABS (FLUTOT3 - FLUINF - FLUSUP - FLUCON))) > 1e-15 );
  193. MESS 'VALEUR NON VALIDE DANS FLUTOT3'
  194. (MAXI (ABS (FLUTOT3 - FLUINF - FLUSUP - FLUCON)));
  195. ERRE 5;
  196. FINS;
  197.  
  198. FIN;
  199.  
  200.  
  201.  
  202.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales