Télécharger la plaquette Cast3M


fr en

Télécharger burgerNC.dgibi

Retour à la liste

Numérotation des lignes : 

  1. * fichier :  burgerNC.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4.  
  5. COMPLET = FAUX ;
  6. SI ( COMPLET ) ;
  7.       NX = 30 ; NY = 30 ;
  8.       NITER = 500 ;
  9.       CFL = 0.8 ;
  10. SINON ;
  11.       NX = 10 ; NY = 10 ;
  12.       NITER = 180 ;
  13.       CFL = 0.8 ;
  14. FINSI ;
  15. GRAPH = 'N' ;
  16.  
  17. ***********************************************************
  18. * EQUATION DE CONVECTION NON-LINEAIRE Ut + div (F(U)) = 0 *
  19. * RESOLUE SOUS FORME NON-CONSERVATIVE                     *
  20. *       dU/dt + lambda . nabla U = 0 avec lambda = dF/dU  *
  21. * AVEC OPTION SUPGDC (par défaut)                         *
  22. ***********************************************************
  23.  
  24. ********************************
  25. * PROCEDURE POUR TRACER COUPES *
  26. ********************************
  27.  
  28. DEBPROC TRCE ;
  29. ARGU M*'MAILLAGE' ;
  30. nb = nbel M ;
  31. R = (M poin 1) droi 1 (M poin 2) ;
  32. i=2 ; itma = nb-2 ;
  33. repeter bloc1 itma ;
  34. R = R et ((M poin i) droi 1 (M poin (i+1))) ;
  35. i=i+1 ;
  36. fin bloc1 ;
  37. FINPROC R ;
  38.  
  39. ***********************************************
  40. * PROCEDURE POUR CALCULER CHAMP DE VITESSE ET *
  41. * TESTER LA CONVERGENCE                       *
  42. ***********************************************
  43.  
  44. DEBPROC CALCUL ;
  45. ARGU RVX*'TABLE' ;
  46.  
  47. RV = RVX.'EQEX' ;
  48. CN = RV.INCO.'CN' ;
  49.  
  50. DD = RV.PASDETPS.'NUPASDT' ;
  51. NN = DD/5 ;
  52. LO = (DD-(5*NN)) EGA 0 ;
  53. SI ( LO ) ;
  54.  
  55. ERR = KOPS (RV.INCO.'CN') - (RV.INCO.'CNM1') ;
  56.  
  57. ELI = MAXI ERR 'ABS' ;
  58. ELI = (LOG (ELI + 1.0E-20))/(LOG 10.) ;
  59. MESSAGE 'ITER ' RV.PASDETPS.'NUPASDT' '   ERREUR LINF ' ELI ;
  60. IT = PROG RV.PASDETPS.'NUPASDT' ;
  61. ER = PROG ELI ;
  62. RV.INCO.'IT' = (RV.INCO.'IT') ET IT ;
  63. RV.INCO.'ER' = (RV.INCO.'ER') ET ER ;
  64. FINSI ;
  65.  
  66. VY = KCHT $DOMTOT 'SCAL' 'SOMMET' 'COMP' 'UY' 1.0 ; 
  67. VX = NOMC 'UX' CN ;
  68. VV = KCHT $DOMTOT 'VECT' 'SOMMET' 'COMP' (MOTS 'UX' 'UY')
  69.         (VX ET VY) ;
  70. RV.INCO.'VITESSE' = VV ;
  71.  
  72. RV.INCO.'CNM1' = KCHT $DOMTOT 'SCAL' 'SOMMET' (RV.INCO.'CN') ;
  73. as2 ama1  = 'KOPS' 'MATRIK' ;
  74. FINPROC as2 ama1 ;
  75.  
  76. ****************************************************
  77.  
  79. opti elem tri3 ;
  81. titre 'Equation de Burger' ;
  82.  
  83. *************
  84. * DIFFUSION *
  85. *************
  86. DIF = 1.0E-10 ;
  87.  
  88. ************
  89. * MAILLAGE *
  90. ************
  91.  
  92. A1 = 0.0 0.0 ;
  93. A2 = 1.0 0.0 ;
  94. A3 = 1.0 1.0 ;
  95. A4 = 0.0 1.0 ;
  96.  
  97. FBAS = A1 'DROI' NX A2 ;
  98. FDRO = A2 'DROI' NY A3 ;
  99. FHAU = A3 'DROI' NX A4 ;
  100. FGAU = A4 'DROI' NY A1 ;
  101.  
  102. PA1 = FBAS POIN 'PROC' A1 ;
  103. PA2 = FBAS POIN 'PROC' A2 ;
  104. P12 = CHAN POI1 FBAS ;
  105. MA1 = P12 ELEM 'CONTENANT' PA1 ;
  106. MA2 = P12 ELEM 'CONTENANT' PA2 ;
  107.  
  108. SI ( COMPLET ) ;
  109. * maillage regulier 
  110. DOMTOT = 'DALL' FBAS FDRO FHAU FGAU 'PLAN' ;
  111. SINON ;
  112. * maillage non-structuré
  113. DOMTOT = (FBAS ET FDRO ET FHAU ET FGAU) 'SURF' 'PLAN' ;
  114. FINSI ;
  115.  
  116. ***********************************
  117. * CREATION MODELES NAVIERS_STOKES *
  118. ***********************************
  119.  
  120. XDOMTOT= DOMTOT CHAN QUAF ;
  121. XFBAS  = FBAS   CHAN QUAF ;
  122. ELIM XDOMTOT XFBAS 1.E-3 ;
  123.  
  124. $DOMTOT = MODE XDOMTOT 'NAVIER_STOKES' LINE ;
  125. $FBAS   = MODE XFBAS   'NAVIER_STOKES' LINE ;
  126.  
  127. **************************************
  128. * INITIALISATION DU CHAMP DE VITESSE *
  129. **************************************
  130.  
  131. VX = KCHT $DOMTOT 'SCAL' 'SOMMET' 'COMP' 'UX' 0.0 ;
  132. VY = KCHT $DOMTOT 'SCAL' 'SOMMET' 'COMP' 'UY' 1.0 ;
  133. CHVIT=KCHT $DOMTOT 'VECT' 'SOMMET' 'COMP' (MOTS 'UX' 'UY') (VX ET VY) ;
  134.  
  135. ************************************
  136. * PROFIL DE LA SOLUTION A L'ENTREE *
  137. ************************************
  138.  
  139. XBAS = COOR 1 FBAS ;
  140. XBAS = NOMC 'UX' XBAS ;
  141. SOLUTION = 1.5 - (2.0*XBAS) ;
  142. CHP1 = KCHT $FBAS 'SCAL' 'SOMMET' 'COMP' 'UX' SOLUTION ;
  143. CHP1 = NOMC 'CN' CHP1 ;
  144.  
  145. ***********************
  146. * TABLE DE RESOLUTION *
  147. ***********************
  148.  
  149. RV = EQEX $DOMTOT 'ITMA' NITER 'ALFA' CFL
  150.         'ZONE' $DOMTOT 
  151.         'OPER' CALCUL 
  152.         'OPER' TSCAL DIF 'VITESSE' 0.0 'INCO' 'CN'
  153.         'OPTI' 'CENTREE'
  154.         'OPER' 'DFDT' 1.   'CN' 'DELTAT'    'INCO' 'CN'
  155.         'CLIM' 'CN' 'TIMP' FBAS CHP1 
  156.         'CLIM' 'CN' 'TIMP' FGAU 1.5
  157.         'CLIM' 'CN' 'TIMP' FDRO (-0.5)  
  158.         'CLIM' 'CN' 'TIMP' MA1 (-1.5) 
  159.         'CLIM' 'CN' 'TIMP' MA2 (0.5) ;
  160.  
  161. RV.INCO = TABLE 'INCO' ;
  162. RV.INCO.'CN' = KCHT $DOMTOT 'SCAL' 'SOMMET' 0. ;
  163. RV.INCO.'VITESSE'= CHVIT ;
  164.  
  165. RV.INCO.'CNM1' = KCHT $DOMTOT 'SCAL' 'SOMMET' 1. ;
  166. RV.INCO.'IT' = PROG 1 ;
  167. RV.INCO.'ER' = PROG 0. ;
  168.  
  169. EXEC RV ;
  170.  
  171. *************************
  172. * ANALYSE DES RESULTATS *
  173. *************************
  174.  
  175. MESSAGE 'MAX = ' (MAXI RV.INCO.'CN') 'MAXTHEORIQUE = 1.5 ' ;
  176. MESSAGE 'MIN = ' (MINI RV.INCO.'CN') 'MINTHEORIQUE = -0.5 ' ;
  177.  
  178. SI ( (MINI RV.INCO.'ER') > -3.0 ) ;
  179.             ERREUR 5 ;
  180. FINSI ;
  181. SI ( (MAXI RV.INCO.'CN') > 1.75 ) ;
  182.             ERREUR 5 ;
  183. FINSI ;
  184. SI ( (MINI RV.INCO.'CN') < -0.60 ) ;
  185.             ERREUR 5 ;
  186. FINSI ;
  187.  
  188. ***********************
  189. * TRACE DES RESULTATS *
  190. ***********************
  191.  
  192. SI ( 'EGA' graph 'O') ;
  193.  
  194. UEXACT = KCHT $DOMTOT 'SCAL' 'SOMMET' 0. ;
  195. XX YY = 'COOR' (DOMA $DOMTOT SOMMET) ;
  196. REPETER BLOC1 (NBNO DOMTOT) ;
  197. P1 = (DOMA $DOMTOT SOMMET) POIN &BLOC1 ;
  198. X1 = 'EXTR' XX 'SCAL' P1 ;
  199. Y1 = 'EXTR' YY 'SCAL' P1 ;
  200. D1 = Y1 - (0.5*X1/0.75) ;
  201. D2 = Y1 - (2.0*(1.0-X1)) ;
  202. D3 = Y1 - 1.0 - (2.0*(X1-1.0)) ;
  203. BO1 = ( D1 > 0.) ;
  204. BO2 = ( D2 > 0.) ;
  205. BO3 = ( D3 > 0.) ;
  206. SI ( BO1 ET BO3 ) ;
  207. U1 = 1.5 ;
  208. SINON ;
  209. SI ( (NON BO1) ET (NON BO2) );
  210. U1 = (1.5-(2.0*X1))/(1.-(2.0*Y1)) ;
  211. SINON ;
  212. U1 = -0.5 ;
  213. FINSI ;
  214. FINSI ;
  215. C1 = MANU 'CHPO' P1 1 SCAL U1 ;
  216. C2 = KCHT $DOMTOT 'SCAL' 'SOMMET' C1 ;
  217. UEXACT = (UEXACT ET C2) ;
  218. FIN BLOC1 ;
  219.  
  220.  
  221. TRACE DOMTOT ;
  222. MESSAGE 'MAX = ' (MAXI RV.INCO.'CN') 
  223.         'MIN = ' (MINI RV.INCO.'CN') ;
  224. TRAC DOMTOT (RV.INCO.'CN') (CONT DOMTOT) ;
  225.  
  226. SI ( COMPLET ) ;
  227. P1 = DOMTOT POIN 'PROC' (0.0 0.7) ;
  228. P2 = DOMTOT POIN 'PROC' (1.0 0.7) ;
  229. P1P2 = DOMTOT POIN 'DROI' P1 P2 0.01 ;
  230. LI12 = TRCE P1P2 ;
  231.  
  232. XX = COOR 1 LI12 ;
  233.  
  234. EVOL1 = EVOL 'CHPO' (RV.INCO.'CN') SCAL LI12 ;
  235. EVOL2 = EVOL 'CHPO' XX SCAL LI12 ;
  236.  
  237. LIX = 'EXTR' EVOL2 ORDO ;
  238. LIU = 'EXTR' EVOL1 ORDO ;
  239. EVOL3 = EVOL 'MANU' 'X' LIX 'U(X)' LIU ;
  240.  
  241. EVOL4 = EVOL 'CHPO' UEXACT SCAL LI12 ;
  242. LIUEX = 'EXTR' EVOL4 ORDO ;
  243. EVOL5 = EVOL 'MANU' 'X' LIX 'UEXACT(X)' LIUEX ;
  244.  
  245. TAB1 = TABLE ;
  246. TAB1.1 = 'MARQ LOSA' ;
  247. DESS (EVOL3 ET EVOL5) 'XBOR' 0.0 1.0 'YBOR' -1. 2.
  248.                 'TITR' 'Coupe a y=0.7' TAB1 ; 
  249. FINSI ;
  250.  
  251. EVOL4 = EVOL 'MANU' 'ITERATIONS' (RV.INCO.'IT') 'LOG|E|inf'
  252.            (RV.INCO.'ER') ;
  253. DESS EVOL4 'XBOR' 0. 2000. 'YBOR' -20.0 0.0 ;
  254.  
  255. FINSI ;
  256.  
  257. FIN ;
  258.  
  259.  
  260.  
  261.  
  262.  
  263.  
  264.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales