Télécharger Oxydation_Chimique_01.dgibi

Retour à la liste

Numérotation des lignes :

  1. * fichier : Oxydation_Chimique_01.dgibi
  2.  
  3. ************************************************************************
  4. ************************************************************************
  5.  
  6. ************************************************************************
  7. * JEU DE DONNEES :
  8. * DESCRIPTION :
  9. * -------------
  10. * - Simule la diffusion chimique d'une espece conduisant a la formation
  11. * d'une couche d'oxyde
  12. * L'espece diffuse a travers l'oxyde et passe dans le metal
  13. * La couche d'oxyde croit lorsque le potentiel chimique le permet
  14. ************************************************************************
  15.  
  16.  
  17. ************************************************************************
  18. 'DEBP' PARATHER PRECED*'TABLE' TEMM*'FLOTTANT';
  19. ************************************************************************
  20. * PROCEDURE PARATHER :
  21. * DESCRIPTION :
  22. * -------------
  23. * Cette procedure permet de modifier le materiaux en l'exprimant au temps 'TEMM'
  24. * - Les composantes KD, CDIF
  25. *
  26. * ENTREES :
  27. * ---------
  28. * - PRECED : TABLE complete de PASAPAS
  29. * - TEMM : Temps 'MOYEN' (tient compte de la 'RELAXATION_THETA')
  30. *
  31. * SORTIES :
  32. * ---------
  33. * - Aucune
  34. *
  35. ************************************************************************
  36. ETAB = PRECED.'WTABLE';
  37. MOD_DIF = ETAB.'MOD_DIF' ;
  38. MAT_DIF = ETAB.'MAT_DIF' ;
  39.  
  40. Mu1 = 'EXCO' ETAB.'THER_COURANT' 'MU' 'MU';
  41. Mu1 = 'CHAN' 'CHAM' Mu1 MOD_DIF 'NOEUD' ;
  42.  
  43. Prop1 ='CHAN' 'CONS' ('NOMC' PROPHA1 'SCAL') CONS1;
  44. Prop1 ='CHAN' 'TYPE' Prop1 'SCALAIRE';
  45.  
  46. MASQ11 ='MASQ' Prop1 'INFE' 1.D-8 ;
  47. MASQ21 ='MASQ' Prop1 'SUPE' (1.D0 - 1.D-8) ;
  48. MASQC1 ='MASQ' (MASQ11 + MASQ21) 'INFE' 0.5 ;
  49.  
  50. GA11 =('IPOL' Mu1 EVG1) 'NOMC' 'SCAL';
  51. DI11 =('IPOL' Mu1 EVD1) 'NOMC' 'SCAL';
  52. CO11 =('IPOL' Mu1 EVC1) 'NOMC' 'SCAL';
  53.  
  54. GA21 =('IPOL' Mu1 EVG2) 'NOMC' 'SCAL';
  55. DI21 =('IPOL' Mu1 EVD2) 'NOMC' 'SCAL';
  56. CO21 =('IPOL' Mu1 EVC2) 'NOMC' 'SCAL';
  57.  
  58. * Combinaison du metal et de l'oxyde avec les MASQUES
  59. GA1 =(GA11*MASQ11) + (GA21*MASQ21) + (GA21*MASQC1);
  60. CO1 =(CO11*MASQ11) + (CO21*MASQ21) + (CO21*MASQC1);
  61. DI1 =(DI11*MASQ11) + (DI21*MASQ21) + (DI21*MASQC1);
  62.  
  63. Mu1 ='NOMC' Mu1 'SCAL';
  64. Ci1 = CO1/GA1*('EXP' ( Mu1 / (R_gaz * T_ini)));
  65.  
  66. MCHTMP1 = Ci1 / (R_gaz * T_ini) ;
  67. MCHCDIF1='CHAN' 'COMP' 'CDIF' MCHTMP1 ;
  68. MCHKD1 ='CHAN' 'COMP' 'KD' (MCHTMP1 * DI1) ;
  69.  
  70. * REMPLACEMENT DU MATERIAUX
  71. MCHCDIF1 ='CHAN' 'RIGIDITE' MOD_DIF MCHCDIF1 ;
  72. MCHKD1 ='CHAN' 'RIGIDITE' MOD_DIF MCHKD1 ;
  73. ETAB.'MAT_DIF' = MCHKD1 'ET' MCHCDIF1 ;
  74. ETAB.'MAT_TOT' = ETAB.'MAT_DIF' 'ET' ETAB.'MAT_PHA' ;
  75. 'FINP';
  76.  
  77. ************************************************************************
  78. 'DEBP' CHARTHER PRECED*'TABLE' tt*'FLOTTANT' ;
  79. ************************************************************************
  80. * PROCEDURE CHARTHER :
  81. * DESCRIPTION :
  82. * -------------
  83. * - met a jour le second membre
  84. * - met a jour la rigidite
  85. ************************************************************************
  86. ETAB = PRECED.'WTABLE' ;
  87. MOD_DIF = ETAB.'MOD_DIF' ;
  88. MAT_DIF = ETAB.'MAT_DIF' ;
  89. TETA = ETAB.'RELAXATION_THETA';
  90. Dt = ETAB.'DT' ;
  91.  
  92. * Second membre du au changement de variable
  93. Mu0CHP ='EXCO' PRECED.'CONTINUATION'.'CONCENTRATIONS' 'MU' 'MU' ;
  94. Mu0 ='CHAN' 'CHAM' Mu0CHP MOD_DIF 'NOEUD';
  95.  
  96. Mu1CHP ='EXCO' ETAB.'THER_COURANT' 'MU' 'MU';
  97. Mu1 ='CHAN' 'CHAM' Mu1CHP MOD_DIF 'NOEUD' ;
  98.  
  99. Prop1 ='CHAN' 'CONS' ('NOMC' PROPHA1 'SCAL') CONS1;
  100. Prop1 ='CHAN' 'TYPE' Prop1 'SCALAIRE';
  101.  
  102. MASQ11 ='MASQ' Prop1 'INFE' 1.D-8 ;
  103. MASQ21 ='MASQ' Prop1 'SUPE' (1.D0 - 1.D-8) ;
  104. MASQC1 ='MASQ' (MASQ11 + MASQ21) 'INFE' 0.5 ;
  105.  
  106. GA10 =('IPOL' Mu0 EVG1) 'NOMC' 'SCAL';
  107. CO10 =('IPOL' Mu0 EVC1) 'NOMC' 'SCAL';
  108. GA20 =('IPOL' Mu0 EVG2) 'NOMC' 'SCAL';
  109. CO20 =('IPOL' Mu0 EVC2) 'NOMC' 'SCAL';
  110.  
  111. GA11 =('IPOL' Mu1 EVG1) 'NOMC' 'SCAL';
  112. CO11 =('IPOL' Mu1 EVC1) 'NOMC' 'SCAL';
  113. GA21 =('IPOL' Mu1 EVG2) 'NOMC' 'SCAL';
  114. CO21 =('IPOL' Mu1 EVC2) 'NOMC' 'SCAL';
  115.  
  116. dlnCGdt =(('LOG' (CO11/GA11)) - ('LOG' (CO10/GA10))) +
  117. (('LOG' (CO21/GA21)) - ('LOG' (CO20/GA20))) / Dt ;
  118.  
  119. * Combinaison du metal et de l'oxyde avec les MASQUES
  120. GA1 =(GA11*MASQ11) + (GA21*MASQ21) + (GA21*MASQC1);
  121. CO1 =(CO11*MASQ11) + (CO21*MASQ21) + (CO21*MASQC1);
  122.  
  123. * Mu0 ='NOMC' Mu0 'SCAL';
  124. Mu1 ='NOMC' Mu1 'SCAL';
  125.  
  126. * Ci0 = CONS0/GA0*(EXP ( Mu0 / (R_gaz * T_ini)));
  127. Ci1 = CO1/GA1*('EXP' ( Mu1 / (R_gaz * T_ini)));
  128.  
  129. * SOUR0 ='SOUR' MOD_DIF (-1.D0 * Ci0 * dlnCGdt) ;
  130. SOUR1 ='SOUR' MOD_DIF (-1.D0 * Ci1 * dlnCGdt) ;
  131.  
  132. * Second membre et RIGIDITE du a la condition de CONVECTION au bord
  133. * RIG2 = 'COND' MOD2 MAT2 ;
  134. * RIG2 = 'CHAN' 'INCO' RIG2 ('MOTS' 'T') ('MOTS' 'MU') ('MOTS' 'Q') ('MOTS' 'QM');
  135.  
  136. * Mu_ext = 'IPOL' EVMu_Ext TEMM ;
  137. * SOUR2 = 'CONV' MOD2 MAT2 'T' Mu_ext;
  138. * SOUR2 = 'CHAN' 'COMP' 'QM' SOUR2;
  139.  
  140. * Remplissage des indices de sortie : ADDI_MATRICE ET ADDI_SECOND
  141. TAA ='TABL';
  142. * TAA.'ADDI_MATRICE'= RIG2 ;
  143. * TAA.'ADDI_SECOND' = ((1.D0 - THETA)*SOUR1) + (THETA*SOUR1);
  144. * TAA.'ADDI_SECOND' = SOUR1 'ET' SOUR2 ;
  145. TAA.'ADDI_SECOND' = SOUR1 ;
  146. 'FINP' TAA;
  147. ************************************************************************
  148.  
  149. 'OPTI' 'DIME' 2 'ELEM' 'QUA4' ;
  150. 'OPTI' 'SAUV' 'Potentiel_Chimique_1.sauv';
  151.  
  152. * MAILLAGE *
  153. DX1 = 30. ;
  154. DY = 1. ;
  155.  
  156. P1 = 0. 0. ;
  157. P2 = P1 'PLUS' (0. DY);
  158. NBE1 = 1 ;
  159. L1 ='DROI' NBE1 P1 P2 ;
  160. L2 = L1 'PLUS' (DX1 0.);
  161.  
  162. NBE2 = 100 ;
  163. S1 ='REGL' L1 NBE2 L2 'COUL' ROUG;
  164. STOT = S1;
  165.  
  166. P3 = 'POIN' 1 L2;
  167. CONT1 = 'CONT' STOT;
  168. L4 = 'POIN' CONT1 'DROI' P1 P3 1.D-4;
  169. L4 = 'ELEM' CONT1 'APPU' 'STRI' L4 ;
  170. L4 =('INVE' L4) 'COUL' 'BOUT' ;
  171. L5 = 'DROI' (NBE2 * 2) P1 P3 ;
  172.  
  173. * MODELE *
  174. CONS1 ='MOT' 'TOTO';
  175.  
  176. MOD1 ='MODE' S1 'DIFFUSION' 'INCO' 'MU' 'QM' 'CONS' CONS1;
  177. MOD2 ='MODE' L1 'THERMIQUE' 'CONVECTION';
  178. MOD3 ='MODE' S1 'CHANGEMENT_PHASE' 'PARFAIT' 'INCO' 'MU' 'QM' 'CONS' 'CHP1';
  179. MODTOT = MOD1 'ET' MOD3 ;
  180.  
  181. * MATERIAU *
  182. R_gaz = 8.314 ;
  183. T_ini = 273.15 + 30. ;
  184.  
  185. ************************************************************************
  186. * Indice 1 : Dans le METAL (ie : Mu <= Mu_ChPh)
  187. * Indice 2 : Dans l' OXYDE (ie : Mu >= Mu_ChPh)
  188. ************************************************************************
  189. Mu_ChPh=-15000.D0 ;
  190. Mu_mini=-20000.D0 ;
  191. Mu_maxi=-10000.D0 ;
  192.  
  193. * Proprietes dans le METAL
  194. LMU1 ='PROG' Mu_mini Mu_ChPh ;
  195. C1 = 3300. ;
  196. LC1 = C1 * (LMU1**0) ;
  197. EVC1 ='EVOL' 'CYAN' 'MANU' 'MU' LMU1 'C1' LC1;
  198.  
  199. Xi_eq = 0.05 ; 'COMM' 'Fraction molaire a saturation' ;
  200. G1 =('EXP' (Mu_ChPh /(R_gaz*T_ini))) / Xi_eq ;
  201. LG1 = G1 * (LMU1**0) ;
  202. EVG1 ='EVOL' 'VERT' 'MANU' 'MU' LMU1 'G1' LG1;
  203.  
  204. EaD1 = 65000. ;
  205. LnD1 = -22. ;
  206. D1 ='EXP'((EaD1 /(R_gaz*T_ini)) + LnD1) ;
  207. LD1 = D1 * (LMU1**0) ;
  208. EVD1 ='EVOL' 'ROUG' 'MANU' 'MU' LMU1 'D1' LD1;
  209.  
  210. * Proprietes dans l'OXYDE
  211. PAMU2 = 10. ;
  212. LMU2 ='PROG' Mu_ChPh 'PAS' PAMU2 Mu_maxi ;
  213. C2 = 2800. ;
  214. LC2 = C2 * (LMU2**0) ;
  215. EVC2 ='EVOL' 'BLEU' 'MANU' 'MU' LMU2 'C2' LC2;
  216.  
  217. Xi_ox = 2./3. ; 'COMM' 'Fraction molaire dans l oxyde' ;
  218. G2 =('EXP' (LMU2 /(R_gaz*T_ini))) / Xi_ox ;
  219. LG2 = G2 * (LMU2**0) ;
  220. EVG2 ='EVOL' 'BOUT' 'MANU' 'MU' LMU2 'G2' LG2;
  221.  
  222. EaD2 = 55000. ;
  223. LnD2 = -20. ;
  224. D2 ='EXP'((EaD2 /(R_gaz*T_ini)) + LnD2) ;
  225. LD2 = D2 * (LMU2**0) ;
  226. EVD2 ='EVOL' 'BRIQ' 'MANU' 'MU' LMU2 'D2' LD2;
  227.  
  228. * Quelques DESSINS
  229. *OPTI TRAC 'PSC';
  230. *DESS (EVC1 ET EVC2) ;
  231. *DESS ((LOG EVG1) ET (LOG EVG2) ) ;
  232. *DESS (EVG1 ET EVG2) ;
  233. *DESS (EVD1 ET EVD2);
  234.  
  235. * Materiau bidon (Change dans PARATHER)
  236. MAT1 ='MATE' MOD1 'KD' 1. 'CDIF' 1. ;
  237. MAT2 ='MATE' MOD2 'H' 1. ;
  238. MAT3 ='MATE' MOD3 'PRIM' Mu_ChPh 'DUAL' 1670. ;
  239. MATTOT = MAT1 'ET' MAT3 ;
  240.  
  241. * Conditions aux limites
  242. BLOQ1 ='BLOQ' 'MU' L1 ;
  243. *BLOQ2 = BLOQ 'MU' L2 ;
  244. BLOTOT= BLOQ1 ;
  245.  
  246. * Chargement
  247. Mu_imp1 = Mu_maxi ;
  248. Mu_imp2 = Mu_mini ;
  249. CHP1 ='DEPI' 1.D0 BLOQ1 ;
  250. EVO1 ='EVOL' 'MANU' 'TEMP' ('PROG' 0. 2.0 2.001 4.) 'MU' ('PROG' Mu_imp1 Mu_imp1 Mu_imp1 Mu_imp1) ;
  251. CHAR1 ='CHAR' 'CIMP' CHP1 EVO1 ;
  252.  
  253. *CHP2 = DEPI Mu_imp2 BLOQ2 ;
  254. *EVO2 = EVOL 'MANU' 'TEMP' (PROG 0. 1.D10) 'MU' (PROG 1. 1.) ;
  255. *CHAR2 = CHAR 'CIMP' CHP2 EVO2 ;
  256. *CHATOT= CHAR1 ET CHAR2;
  257. CHATOT = CHAR1;
  258.  
  259. * Potentiel chimique 'au loin'
  260. *EVMu_Ext ='EVOL' 'MANU' 'TEMP' ('PROG' 0. 2.5 2.501 4.) 'T' ('PROG' Mu_imp1 Mu_imp1 Mu_imp2 Mu_imp2);
  261.  
  262. * CONDITIONS INITIALES
  263. Mu_ini = Mu_mini ;
  264. CHMUini ='MANU' 'CHPO' STOT 1 'MU' Mu_ini 'NATU' 'DIFFUS';
  265. CHPini ='ZERO' MOD3 'VARINTER';
  266.  
  267. * PASAPAS
  268. LTPS1 = PROG 0. 'PAS' 0.005 0.05 'PAS' 0.05 3.;
  269. LTPS2 = PROG 0. 'PAS' 0.05 3.;
  270. LTPS2 = LTPS1;
  271.  
  272. TAB1 = TABL ;
  273. TAB1.'MODELE' = MODTOT ;
  274. TAB1.'CARACTERISTIQUES' = MATTOT ;
  275. TAB1.'BLOCAGES_DIFFUSIONS' = BLOTOT ;
  276. TAB1.'CHARGEMENT' = CHATOT ;
  277.  
  278. TAB1.'CONCENTRATIONS' ='TABL' ;
  279. TAB1.'CONCENTRATIONS'. 0 = CHMUini;
  280.  
  281. TAB1.'PROPORTIONS_PHASE' ='TABL' ;
  282. TAB1.'PROPORTIONS_PHASE'. 0 = CHPini ;
  283.  
  284. TAB1.'TEMPS_CALCULES' = LTPS1 ;
  285. TAB1.'TEMPS_SAUVES' = LTPS2 ;
  286. TAB1.'TEMPS_SAUVEGARDES' = LTPS2 ;
  287. TAB1.'ECONOMIQUE' = VRAI ;
  288.  
  289. TAB1.'PROCEDURE_PARATHER' = VRAI ;
  290. TAB1.'PROCEDURE_CHARTHER' = VRAI ;
  291. TAB1.'PROCESSEURS' ='MONO_PROCESSEUR' ;
  292. TAB1.'PRECISION' = 1.D-6 ;
  293. TAB1.'MAXITERATION' = 25 ;
  294.  
  295. * AUGMENTATION EN CAS DE NON CONVERGENCE :
  296. *MAT_AUG='MATE' MOD1 'KD' 0.4 'CDIF' 0.8 ;
  297. *CAPA1 ='CAPA' MODTOT MAT_AUG ;
  298. *KDIF1 ='COND' MODTOT MATTOT ;
  299. *FLOT1 = XTMX CHMUini CAPA1 ;
  300. *FLOT2 = XTMX CHMUini KDIF1 ;
  301. *MESS FLOT1 FLOT2;
  302. *TAB1.'DIFFUSION_AUGMENTEE'= CAPA1 * 1.D2 ;
  303.  
  304. 'SAUV';
  305. PASAPAS TAB1;
  306. 'SAUV';
  307.  
  308. * Post-Traitement
  309. 'OPTI' 'REST' 'Potentiel_Chimique_1.sauv';
  310. 'REST';
  311. 'OPTI' 'SAUV' 'Potentiel_Chimique_1.sauv';
  312. 'SAUV';
  313. 'OPTI' 'TRAC' 'PSC';
  314.  
  315. G_ini_1 ='MINI' LG1;
  316. G_ini_2 ='MAXI' LG1;
  317. LTPSCAL ='PROG' ;
  318. LXFRONT ='PROG' ;
  319.  
  320. MODloc ='MODE' ('CHAN' 'TRI3' S1 ) 'DIFFUSION' 'INCO' 'MU' 'QM' 'CONS' CONS1; 'COMM' 'Pour ISOV...';
  321. EvCHPH ='EVOL' 'NOIR' 'MANU' 'ABS' ('PROG' 0. DX1) 'MU' ('PROG' Mu_ChPh Mu_ChPh);
  322. 'REPE' SURI (DIME TAB1.'TEMPS');
  323. III = &SURI ;
  324. Mui = TAB1.'CONCENTRATIONS'. (III - 1) ;
  325. Pi = TAB1.'PROPORTIONS_PHASE'. (III - 1) ;
  326. Tps = TAB1.'TEMPS' . (III - 1) ;
  327.  
  328. Mui ='EXCO' Mui 'MU' 'MU';
  329.  
  330. * Recherche de l'interface par interpolation lineaire
  331. Moy1 =('INTG' Pi MOD3) / ('INTG' (Pi ** 0) MOD3);
  332. COXi = Moy1*DX1;
  333.  
  334. LTPSCAL = LTPSCAL 'ET' Tps ;
  335. LXFRONT = LXFRONT 'ET' COXi ;
  336.  
  337.  
  338. Mu1 = 'CHAN' 'CHAM' Mui MOD1 'NOEUD' ;
  339.  
  340. Prop1 ='CHAN' 'CONS' ('NOMC' Pi 'SCAL') CONS1;
  341. Prop1 ='CHAN' 'TYPE' Prop1 'SCALAIRE';
  342.  
  343. MASQ1 ='MASQ' Prop1 'INFE' 1.D-8 ;
  344. MASQ2 ='MASQ' Prop1 'SUPE' (1.D0 - 1.D-8) ;
  345. MASQC ='MASQ' (MASQ1 + MASQ2) 'INFE' 0.5 ;
  346.  
  347. GA11 =('IPOL' Mu1 EVG1) 'NOMC' 'SCAL';
  348. DI11 =('IPOL' Mu1 EVD1) 'NOMC' 'SCAL';
  349. CO11 =('IPOL' Mu1 EVC1) 'NOMC' 'SCAL';
  350.  
  351. GA21 =('IPOL' Mu1 EVG2) 'NOMC' 'SCAL';
  352. DI21 =('IPOL' Mu1 EVD2) 'NOMC' 'SCAL';
  353. CO21 =('IPOL' Mu1 EVC2) 'NOMC' 'SCAL';
  354.  
  355.  
  356. * Combinaison du metal et de l'oxyde avec les MASQUES
  357. GA1 =(GA11*MASQ1) + (GA21*MASQ2) + (GA21*MASQC);
  358. CO1 =(CO11*MASQ1) + (CO21*MASQ2) + (CO21*MASQC);
  359. DI1 =(DI11*MASQ1) + (DI21*MASQ2) + (DI21*MASQC);
  360.  
  361. Mu1 = 'NOMC' Mu1 'SCAL';
  362. Xi1 =('EXP' ( Mu1 / (R_gaz * T_ini))) / GA1;
  363. Ci1 = CO1*Xi1 ;
  364. XiPROI =('PROI' L5 Xi1) 'NOMC' 'Xi' ;
  365. CiPROI =('PROI' L5 Ci1) 'NOMC' 'Ci' ;
  366. COPROI =('PROI' L5 CO1) 'NOMC' 'CONS';
  367. GaPROI =('PROI' L5 GA1) 'NOMC' 'GAMM';
  368.  
  369. EvMui ='EVOL' 'BLEU' 'CHPO' Mui 'MU' L4 ;
  370. EvXi ='EVOL' 'BOUT' 'CHPO' XiPROI 'Xi' L5 ;
  371. EvCi ='EVOL' 'BOUT' 'CHPO' CiPROI 'Ci' L5 ;
  372. EvCO ='EVOL' 'BOUT' 'CHPO' COPROI 'CONS' L5 ;
  373. EvGa ='EVOL' 'ROUG' 'CHPO' GaPROI 'GAMM' L5 ;
  374.  
  375. 'OPTI' 'EPTR' 0;
  376. 'TRAC' Pi MOD3 ('CONT' S1);
  377. 'OPTI' 'EPTR' 10;
  378. 'DESS' (EvMui 'ET' EvCHPH) 'GRIL' 'TIRC' 'GRIS' 'XBOR' 0. DX1 'YBOR' Mu_mini Mu_maxi 'YGRA' ((Mu_maxi-Mu_mini) / 10.);
  379. 'DESS' EvXi 'GRIL' 'TIRC' 'GRIS' 'XBOR' 0. DX1 'YBOR' 0.D0 0.7D0 'YGRA' 0.1D0 ;
  380. 'DESS' EvCi 'GRIL' 'TIRC' 'GRIS' 'XBOR' 0. DX1 'YBOR' 0.D0 2000. 'YGRA' 200. ;
  381. 'DESS' EvCO 'GRIL' 'TIRC' 'GRIS' 'XBOR' 0. DX1 ;
  382. 'DESS' EvGa 'GRIL' 'TIRC' 'GRIS' 'XBOR' 0. DX1 ;
  383.  
  384. 'FIN' SURI;
  385.  
  386.  
  387. EVXFRONa ='EVOL' 'ROUG' 'MANU' 'TEMP' LTPSCAL 'X**2' (LXFRONT ** 2);
  388. EVXFRONb ='EVOL' 'ROUG' 'MANU' 'TEMP' LTPSCAL 'X' LXFRONT ;
  389.  
  390. * Solution du probleme Quasi-Stationnaire 1D
  391. * Reaction consideree : M + Nu.O <=> MO_Nu
  392. Xi_2 = 1./3. ;
  393. Nu = Xi_2/(1. - Xi_2);
  394. Csat = C1/('IPOL' Mu_ChPh EVG1)*('EXP' ( Mu_ChPh / (R_gaz * T_ini)));
  395.  
  396. Alpha = 1.D0;
  397. LXFRONQS=(2*Alpha*C2*D2*(Mu_imp1 - Mu_ChPh) * LTPSCAL /
  398. (R_gaz*T_ini*(C2-(Csat/Nu)))) ** 0.5 ;
  399. EVQSa1 ='EVOL' 'BOUT' 'MANU' 'TEMP' LTPSCAL 'X**2' (LXFRONQS ** 2);
  400. EVQSb1 ='EVOL' 'BOUT' 'MANU' 'TEMP' LTPSCAL 'X' LXFRONQS ;
  401.  
  402. Alpha = 0.5D0;
  403. LXFRONQS=(2*Alpha*C2*D2*(Mu_imp1 - Mu_ChPh) * LTPSCAL /
  404. (R_gaz*T_ini*(C2-(Csat/Nu)))) ** 0.5 ;
  405. EVQSa2 ='EVOL' 'BLEU' 'MANU' 'TEMP' LTPSCAL 'X**2' (LXFRONQS ** 2);
  406. EVQSb2 ='EVOL' 'BLEU' 'MANU' 'TEMP' LTPSCAL 'X' LXFRONQS ;
  407.  
  408. DESS (EVXFRONa ET EVQSa1 ET EVQSa2) 'GRIL' 'TIRC' 'GRIS' ;
  409. DESS (EVXFRONb ET EVQSb1 ET EVQSb2) 'GRIL' 'TIRC' 'GRIS' ;
  410. OPTI 'SAUV' 'Potentiel_Chimique_1.sauv';
  411. FIN;
  412.  
  413.  
  414.  
  415.  
  416.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales