Télécharger la plaquette Cast3M


fr en

Télécharger GLRC_DM.dgibi

Retour à la liste

Numérotation des lignes : 

  1. * fichier : GLRC_DM.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4. *******************************************************
  5. *  Cas test de l'implantation numérique du modele
  6. *  GLRC_DM
  7. *******************************************************
  8. * Développé par :  
  9. *     Benjamin Richard 
  10. * Contact :  
  11. *     Benjamin.Richard@lmt.ens-cachan.fr 
  12. * Institution : 
  13. *     CEA\DEN\DANS\DM2S\SEMT\EMSI
  14. *******************************************************
  15. * Choix du cas de charge
  16. * - 1 : Traction/compression - charge dech. (membrane)
  17. * - 2 : Idem - sens oppose
  18.  
  19. * - 3 : Traction/compression - charge dech. (flexion )
  20. * - 4 : Idem - sens oppose
  21. * - 5 : Idem avec le deux cycle en plus
  22.  
  23. * - 6 : Distorsion et cisaillement pur plan
  24.  
  25. * - 7 : Couplage traction/compression
  26. * - 8 : 
  27. * - 9 : 
  28. ******************************************************* 
  29. * Choix du cas de charge 
  30. ncas  = 1; 
  31. nfat  = 0;
  32. ******************************************************* 
  33. * Choix du modele
  34. ******************************************************* 
  35. SI (EGA nfat 0);
  36. ric0 = VRAI;
  37. sme0 = FAUX;
  38. FINSI;
  39.  
  40. SI (EGA nfat 1);
  41. sme0 = VRAI;
  42. ric0 = FAUX; 
  43. FINSI;
  44.  
  45. graph0 = 'N';
  46.  
  47. ******************************************************* 
  48. * Parametres materiaux
  49. ******************************************************* 
  50.  
  51. * Parametres physiquement accessibles------------------
  52.  
  53. * Proprietes elastiques du beton
  54. EBN  = 32308E6;
  55. NUBN = 0.2;
  56.  
  57. * Proprietes elastiques de l'acier
  58. EAN  = 200000E6;
  59. NUAN = 0.3;
  60.  
  61. * Epaisseur de la dalle (ou du voile)
  62. THN = 0.10;
  63.  
  64. * Section totale d'acier par metre lineaire
  65. XIA = 8.0E-4;
  66.  
  67. * Position relative de la nappe dans l'epaisseur
  68. EPR = 0.04;
  69.  
  70. * Resistance en traction du beton
  71. FTN = 3.4E6;
  72.  
  73. * Effort limite en compression par metre lineaire
  74. NMAX = 1.0E6;
  75.  
  76. * Parametres intrinseques au modele BA-----------------
  77. * Le parametre GAMMA_MT
  78. GAMMT = 0.02 ;
  79.  
  80. * Le parametre GAMMA_F
  81. GAMMF = 0.32 ;
  82.  
  83. * Parametres intrinseques au modele MAZARS-------------
  84. ** Le parametre AT
  85. *AT = 1.e0;
  86.  
  87. ** Le parametre AC
  88. *AC = 1.2e0;
  89.  
  90. ** Le parametre BT
  91. *BC = 1.7e+03;
  92.  
  93. ** Le parametre BC
  94. *BT = 10000.;
  95.  
  96. ** Le parametre de seuil EPSD0
  97. *EPSD0 = (FTN/EBN);
  98.  
  99. * Energie de fissuration
  100. gft  = 160;
  101.  
  102. * Resistance en compression
  103. fcn  = 10E6;
  104. *fcn  = 36E6;
  105.  
  106. * Energie de fissuration
  107. gfc  = 2000;
  108.  
  109.  
  110. ******************************************************* 
  111. * Options de calcul
  112. ******************************************************* 
  113. OPTION DIME 3 ELEM QUA4; 
  114. DENSITE 0.1;
  115.  
  116. ******************************************************* 
  117. * Maillage
  118. ******************************************************* 
  119. P1 = 0. 0. 0.; 
  120. P2 = 1. 0. 0.; 
  121. P3 = 1. 1. 0.; 
  122. P4 = 0. 1. 0.; 
  123.  
  124. L1 = P1 DROIT P2 ;
  125. L2 = P2 DROIT P3 ;
  126. L3 = P3 DROIT P4 ;
  127. L4 = P4 DROIT P1 ;
  128.  
  129. LTOT = L1 ET L2 ET L3 ET L4 ;
  130.  
  131. S1   = SURF LTOT PLANE;
  132.  
  133. SI (EGA graph0 'O');
  134. TRAC s1;
  135. FINSI;
  136.  
  137. ******************************************************* 
  138. * Conditions aux limites
  139. ******************************************************* 
  140.  
  141. * Conditions selon le chargement-----------------------
  142.  
  143. SI (ET (> ncas 0) (< ncas 3));
  144. CL1 = BLOQ L4 UX;
  145. CL2 = BLOQ P1 DEPL ROTA;
  146. CL3 = BLOQ L2 UX;
  147. CLTOT = CL1 ET CL2 ET CL3;
  148. D1    = DEPI CL3 1;
  149. FINSI;
  150.  
  151. SI (ET (> ncas 2) (< ncas 6));
  152. CL1 = BLOQ L4 RY UX ;
  153. CL2 = BLOQ P1 DEPL ROTA;
  154. CL3 = BLOQ L2 RY;
  155. CLTOT = CL1 ET CL2 ET CL3;
  156. D1    = DEPI CL3 1;
  157. FINSI;
  158.  
  159. SI (ET (> ncas 5) (< ncas 7));
  160.  
  161. CL1 = BLOQ P1 DEPL ROTA;
  162. NN = NBEL L4;
  163. D0 = 3.3E-4;
  164. CHPO1 = MANU CHPO (INVE L4) 1 'UX' 
  165. (PROG 0. PAS (1.0 / NN) 1.0);
  166. CHPO1 = CHPO1 * D0;
  167. CL21 = BLOQ L4 UY;
  168. CL22 = BLOQ L4 UX;
  169. D2  = DEPI CL22 CHPO1;
  170.  
  171. NN = NBEL L1;
  172. D0 = 3.3E-4;
  173. CHPO2 = MANU CHPO (L1) 1 'UY' 
  174. (PROG 0. PAS (1.0 / NN) 1.0);
  175. CHPO2 = CHPO2 * D0;
  176. CL31 = BLOQ L1 UX;
  177. CL32 = BLOQ L1 UY;
  178. D3  = DEPI CL32 CHPO2;
  179.  
  180. NN = NBEL L2;
  181. D0 = 3.3E-4;
  182. CHPO3 = MANU CHPO (L2) 1 'UX' 
  183. (PROG 0. PAS (1.0 / NN) 1.0);
  184. CHPO3 = CHPO3 * D0;
  185. CL41 = BLOQ L2 UX;
  186. CL42 = BLOQ L2 UY;
  187. D41  = DEPI CL41 CHPO3;
  188. D42  = DEPI CL42 D0;
  189.  
  190. NN = NBEL L3;
  191. D0 = 3.3E-4;
  192. CHPO4 = MANU CHPO (INVE L3) 1 'UY' 
  193. (PROG 0. PAS (1.0 / NN) 1.0);
  194. CHPO4 = CHPO4 * D0;
  195. CL51 = BLOQ L3 UX;
  196. CL52 = BLOQ L3 UY;
  197. D51  = DEPI CL51 D0;
  198. D52  = DEPI CL52 CHPO4;
  199.  
  200. DF1 = FORCE ((-1 * D0) 0 0) L1;
  201. DF2 = FORCE (0 D0 0) L2;
  202. DF3 = FORCE (D0 0 0) L3;
  203. DF4 = FORCE (0 (-1 * D0) 0) L4;
  204. DFT = DF1 ET DF2 ET DF3 ET DF4;
  206. SI (EGA graph0 'O');
  207. vect1 = vect chpo1 500 'DEPL' ROUG;
  208. vect2 = vect chpo2 500 'DEPL' VERT;
  209. vect3 = vect chpo3 500 'DEPL' BLEU;
  210. vect4 = vect chpo4 500 'DEPL' JAUN;
  211. TRAC S1 (VECT1 ET VECT2 ET VECT3 ET VECT4);
  212. FINSI;
  213.  
  214. CLTOT = CL1 ET CL21 ET CL22 ET CL31 ET CL32 ET CL41 ET
  215. CL42 ET CL51 ET CL52;
  216.  
  217. DTOT = D2 ET D3 ET D41 ET D42 ET D51 ET D52;
  218. FINSI;
  219.  
  220. SI (ET (> ncas 6) (< ncas 10));
  221. CL1 = BLOQ P1 DEPL ROTA;
  222. CL2 = BLOQ L4 UX RY;
  223. CL3 = BLOQ L2 RY;
  224. CL4 = BLOQ L2 UX;
  225. CLTOT = CL1 ET CL2 ET CL3 ET CL4;
  226. D1    = DEPI CL3 6.0E-3;
  227. D2    = DEPI CL4 2.0E-4;
  228. DTOT  = D1 ET D2;
  229. FINSI;
  230.  
  231. ******************************************************* 
  232. * Choix des modeles et des materiaux associes
  233. ******************************************************* 
  234.  
  235. * Cas du modele BA-------------------------------------
  236. SI (ric0);
  237.  
  238. * Identification automatique---------------------------
  239. EEQM NUM EEQF NUF0 XK0 GAMC0 XALFA  
  240. = IDENTI 'GLRC_DM' 
  241. EBN NUBN EAN NUAN THN XIA 
  242. EPR FTN NMAX GAMMT GAMMF 0.;
  243.  
  244. * Modele-----------------------------------------------
  245. MODTOT  = MODE S1 MECANIQUE ELASTIQUE ISOTROPE   
  246.           ENDOMMAGEMENT GLRC_DM DKT COQ4 CONS COUCHE1; 
  247.  
  248. * Materiaux--------------------------------------------   
  249. MATTOT  = MATE MODTOT YOUN  EEQM  NU   NUM 
  250.                       YOUF  (EEQF * 1.4)  NUF  NUF0
  251.                       GAMT  GAMMT GAMC GAMC0
  252.                       GAMF  GAMMF SEUI XK0
  253.                       ALF   XALFA;
  254.  
  255. CAR1 = CARA MODTOT EPAI THN;
  256. MATTOT = MATTOT ET CAR1;
  257. FINSI;
  258.  
  259.  
  260. * Cas du modele multicouche----------------------------
  261. SI (sme0);
  262.  
  263. MOD1=TABLE;
  264. mat1=TABLE;
  265. NCOUCH = 9;
  266. I=0;
  267. REPETER BOU1 NCOUCH;
  268. I=I+1;
  269. NAME = CHAINE 'BET' I;
  270. MOD1.I   = MODE S1 MECANIQUE ELASTIQUE 
  271. ENDOMMAGEMENT RICCOQ DKT COQ4 CONS NAME;
  272. EPI  = ((THN-XIA) / NCOUCH);
  273. CHAM1  = MANU CHML MOD1.I BTRA 1. TYPE CARACTERISTIQUES RIGIDITE;
  274. CHAM2  = INTG CHAM1 MOD1.I ELEM BTRA;
  275. TAIL1  = (2 ** (1.0 / 2.0)) * CHAM2 ** (1.0 / 2.0); 
  276. GFT = GFT / EPI;
  277. EPSUT = (TAIL1) / GFT;
  278. GFC = GFC / EPI;
  279. EPSUC = (TAIL1) / GFC;
  280.  
  281. mat1.I = MATE mod1.I YOUN EBN  NU   NUBN
  282.                   FT   ftn  EPUT EPSUT 
  283.                   FC   fcn  EPUC EPSUC;
  284.  
  285. EXCN = (4.0 * EPI) + (I - 1) * EPI;
  286.  
  287. car1 = CARA MOD1.I EPAI EPI EXCE EXCN;
  288. mat1.I = mat1.I et car1;
  289.  
  290. FIN BOU1;
  291.  
  292. MOD2   = MODE S1 MECANIQUE ELASTIQUE ISOTROPE
  293. DKT COQ4 CONS ACI1; 
  294.  
  295. MOD3   = MODE S1 MECANIQUE ELASTIQUE ISOTROPE 
  296. DKT COQ4 CONS ACI2; 
  297.  
  298. MODTOT = MOD2 ET MOD3;
  299.  
  300. mat2 = MATE mod2 YOUN EAN  NU NUAN;
  301. car2 = CARA MOD2 EPAI XIA EXCE (-1 * EPR);
  302. mat2 = mat2 et car2;
  303.  
  304. mat3 = MATE mod3 YOUN EAN  NU NUAN;
  305. car3 = CARA MOD3 EPAI XIA EXCE EPR;
  306. mat3 = mat3 et car3;
  307.  
  308. mattot = mat2 et mat3;
  309.  
  310. I=0;
  311. REPETER BOU1 NCOUCH;
  312. I=I+1;
  313. modtot = modtot et mod1.I;
  314. FIN BOU1;
  315.  
  316. I=0;
  317. REPETER BOU1 NCOUCH;
  318. I=I+1;
  319. mattot = mattot et mat1.I;
  320. FIN BOU1;
  321.  
  322. FINSI;
  323.  
  324. ******************************************************* 
  325. * Choix des cas de charge
  326. ******************************************************* 
  327. SI (EGA NCAS 1);
  328. LI1  = PROG 0. 1.   2.  3.   4.; 
  329. LI2  = PROG 0. 3E-4 0. -3E-4 0.; 
  330. LIS1 = PROG 0. pas 0.05 4;
  331. FINSI;
  332.  
  333. SI (EGA NCAS 2);
  334. LI1  = PROG 0. 1.   2.  3.   4.; 
  335. LI2  = PROG 0. -3E-4 0. 3E-4 0.; 
  336. LIS1 = PROG 0. pas 0.05 4;
  337. FINSI;
  338.  
  339. SI (EGA NCAS 3);
  340. LI1  = PROG 0. 1.   2.  3.   4.; 
  341. LI2  = PROG 0. 6E-3 0. -6E-3 0.; 
  342. LIS1 = PROG 0. pas 0.05 4;
  343. FINSI;
  344.  
  345. SI (EGA NCAS 4);
  346. LI1  = PROG 0. 1.   2.  3.   4.; 
  347. LI2  = PROG 0. -6E-3 0. 6E-3 0.; 
  348. LIS1 = PROG 0. pas 0.05 4;
  349. FINSI;
  350.  
  351. SI (EGA NCAS 5);
  352. LI1  = PROG 0. PAS 1 8; 
  353. LI2  = PROG 0. -6E-3 0. 6E-3 0. -6E-3 0. 6E-3 0.; 
  354. LIS1 = PROG 0. pas 0.05 8;
  355. FINSI;
  356.  
  357. SI (EGA NCAS 6);
  358. LI1  = PROG 0. 1. 2.  3. 4.; 
  359. LI2  = PROG 0. -1. 0. 1. 0.; 
  360. LIS1 = PROG 0. pas 0.05 4;
  361. FINSI;
  362.  
  363. SI (EGA NCAS 7);
  364. LI1  = PROG 0. 1. 2.  3. 4.; 
  365. LI2  = PROG 0. 1. 0. -1. 0.; 
  366. LIS1 = PROG 0. pas 0.05 4;
  367. EV   = EVOL MANU LI1  LI2;
  368. CHA1 = CHAR MECA DTOT EV;
  369. CHATOT = CHA1;
  370. FINSI;
  371.  
  372. SI (EGA NCAS 8);
  373. LI1  = PROG 0. 1. 2.  3. 4.; 
  374. LI2  = PROG 0. -1. 0. 1. 0.; 
  375. LIS1 = PROG 0. pas 0.05 4;
  376. EV   = EVOL MANU LI1  LI2;
  377. CHA1 = CHAR MECA DTOT EV;
  378. CHATOT = CHA1;
  379. FINSI;
  380.  
  381. SI (EGA NCAS 9);
  382. LI1  = PROG 0. PAS 1 8; 
  383. LI2  = PROG 0. 1 0. -1 0. 1 0. -1 0.; 
  384. LIS1 = PROG 0. pas 0.05 8;
  385. EV   = EVOL MANU LI1  LI2;
  386. CHA1 = CHAR MECA DTOT EV;
  387. CHATOT = CHA1;
  388. FINSI;
  389.  
  390. SI (< ncas 6);
  391. EV   = EVOL MANU LI1 LI2 ; 
  392. CHA1 = CHAR 'DIMP' D1 EV ; 
  393. CHATOT = CHA1;
  394. FINSI;
  395.  
  396. SI (ET (> ncas 5) (< ncas 7));
  397. EV   = EVOL MANU LI1 LI2 ; 
  398. CHA1 = CHAR 'DIMP' DTOT EV ; 
  399. CHA2 = CHAR 'MECA' DFT  EV ;
  400. CHATOT = CHA1 ET CHA2;
  401. FINSI;
  402.  
  403. ******************************************************* 
  404. * Preparation au calcul 
  405. ******************************************************* 
  406. TAB1                      = TABLE  ; 
  407. TAB1.BLOCAGES_MECANIQUES  = CLTOT  ; 
  408. TAB1.MODELE               = MODTOT ; 
  409. TAB1.MOVA                 = RIEN   ; 
  410. TAB1.CHARGEMENT           = CHATOT ;
  411. TAB1.CARACTERISTIQUES     = MATTOT ; 
  412. TAB1.TEMPS_CALCULES       = LIS1   ;
  413.  
  414. ******************************************************* 
  415. * Calcul
  416. ******************************************************* 
  417. PASAPAS TAB1 ; 
  418.  
  419. ******************************************************* 
  420. * Post traitement
  421. ******************************************************* 
  422. nn=dime tab1.deplacements;
  423. nn=nn-1;
  424.  
  425. SI (EGA graph0 'O');
  426. SI (ric0);
  427. trac modtot (exco tab1.variables_internes.nn 'XD1 ');
  428. trac modtot (exco tab1.variables_internes.nn 'XD2 ');
  429. FINSI;
  430.  
  431. SI (sme0);
  432. trac modtot (exco tab1.variables_internes.nn 'DT  ');
  433. FINSI;
  434. FINSI;
  435.  
  436. SI (OU (EGA ncas 1) (EGA ncas 2));
  437. ev2=@global tab1 CL3 EV FX;
  438. SI (EGA graph0 'O');
  439. DESS EV2; 
  440.  
  441. @excel1 ev2 (chaine 'f_delta_' nfat '.txt');
  442.  
  443. FINSI;
  444. FINSI;
  445.  
  446. SI (ET ( ET (> ncas 2) (< ncas 6)) (EGA nfat 1));
  447. evm = prog 0;
  448.  
  449. REPETER BOU3 nn;
  450. TPS = &bou3;
  451. CHPS1 = TABLE;
  452. CHPS2 = TABLE;
  453. CHPS3 = TABLE;
  454. CHPS4 = TABLE;
  455. I=0;
  456.  
  457. REPE BOU1 NCOUCH;
  458. I=I+1;
  459. CHPS1.I = REDU (TAB1.CONTRAINTES.TPS) (mod1.I);
  460. CHPS1.I = CHAN CHPO CHPS1.I MOD1.I;
  461. CHPS2.I = @TOTAL CHPS1.I S1 'N11 ';
  462. *CHPS3.I = REDU TAB1.REACTIONS.TPS (mod1.I);
  463. CHPS4.I = @TOTAL TAB1.REACTIONS.TPS L4 'MY  ';
  464. list CHPS4.I;
  465. FIN BOU1;
  466.  
  467. I=0;
  468. REPE BOU1 NCOUCH;
  469. I=I+1;
  470. EXCN = (4.0 * EPI) + (I - 1) * EPI;
  471. TOT=0;
  472. TOT=TOT+(CHPS2.I * EXCN) * 0.0 + CHPS4.I;
  473. FIN BOU1;
  474.  
  475.  
  476.  
  477. evm = evm ET (prog TOT);
  478.  
  479. fin bou3;
  480.  
  481. evg=@global tab1 CL3 EV FX;
  482. lis1 = extr evg 'ABSC';
  483. ev2 = evol manu lis1 evm;
  484. @excel1 ev2 (chaine 'f_delta_' nfat '.txt');
  485. SI (ega graph0 'O');
  486. dess ev2;
  487. FINSI;
  488. FINSI;
  489.  
  490. SI (ET (ega ncas 6) (EGA nfat 0));
  491. evm = prog 0;
  492. I = 1;
  493. REPETER BOU1 nn;
  494. *var0 = tab1.contraintes.I;
  495. *tot  = EXTR VAR0 'N12 ' 1 1 1;
  496. var0 = tab1.reactions.I;
  497. PPP = MANU P1 POI1;
  498. tot=@total var0 PPP 'FX  ';
  499. evm = evm et (prog tot);
  500. I = I + 1;
  501. FIN BOU1;
  502. ev2 = evol manu lis1 evm;
  503. SI (ega graph0 'O');
  504. dess ev2;
  505. FINSI;
  506. @excel1 ev2 (chaine 'f_delta_' nfat '.txt');
  507. FINSI;
  508.  
  509.  
  510.  
  511.  
  512.  
  513.  
  514.  
  515.  
  516. SI (ET (ega ncas 6) (EGA nfat 1));
  517. evm = prog 0;
  518. I = 1;
  519. REPETER BOU1 nn;
  520. var0 = tab1.reactions.I;
  521. *tot  = EXTR VAR0 'N12 ' 1 1 1;
  522. PPP = MANU P1 POI1;
  523. tot=@total var0 PPP 'FY  ';
  524. evm = evm et (prog tot);
  525. I = I + 1;
  526. FIN BOU1;
  527. ev2 = evol manu lis1 evm;
  528. SI (EGA graph0 'O');
  529. dess ev2;
  530. FINSI;
  531. @excel1 ev2 (chaine 'f_delta_' nfat '.txt');
  532. FINSI;
  533.  
  534.  
  535.  
  536.  
  537.  
  538.  
  539.  
  540.  
  541.  
  542.  
  543.  
  544.  
  545.  
  546. SI (ET ( ET (> ncas 2) (< ncas 6)) (EGA nfat 0));
  547. evm = prog 0;
  548. I=1;
  549.  
  550. REPETER BOU1 nn;
  551. var0=tab1.reactions.I;
  552. tot=@total var0 L4 'MY  ';
  553. evm=evm et (prog tot);
  554. i=i+1;
  555. fin bou1;
  556.  
  557. evg=@global tab1 cl3 ev fx;
  558. lis1=extr evg absc;
  559. ev2=evol manu lis1 evm;
  560. @excel1 ev2 (chaine 'f_delta_' nfat '.txt');
  561. SI (EGA graph0 'O');
  562. dess ev2;
  563. FINSI;
  564. FINSI;
  565.  
  566. SI (ET (> ncas 6) (< ncas 10));
  567. EVG1 = @GLOBAL TAB1 EV CL4 FX;
  568. LISG1 = EXTR EVG1 ABSC;
  569. LISG1 = (LISG1 * 2.0E-4);
  570.  
  571. EVG2 = @GLOBAL TAB1 EV CL3 FX;
  572. LISG2 = EXTR EVG2 ABSC;
  573. LISG2 = (LISG2 * 6E-3);
  574.  
  575. evm1 = prog 0;
  576. I = 1;
  577. REPETER BOU1 nn;
  578. var0 = tab1.reactions.I;
  579. tot  = @total var0 L4 'FX  ';
  580. evm1 = evm1 et (prog tot);
  581. I = I + 1;
  582. FIN BOU1;
  583.  
  584. evm2 = prog 0;
  585. I = 1;
  586. REPETER BOU1 nn;
  587. var0 = tab1.reactions.I;
  588. tot  = @total var0 L4 'MY  ';
  589. evm2 = evm2 et (prog tot);
  590. I = I + 1;
  591. FIN BOU1;
  592.  
  593. EV21 = EVOL MANU LISG1 evm1;
  594. EV22 = EVOL MANU LISG2 evm2;
  595.  
  596. SI (EGA graph0 'O');
  597. DESS EV21;
  598. DESS EV22;
  599. FINSI;
  600.  
  601. FINSI;
  602.  
  603. SI (EGA graph0 'O');
  604. def0 = defo s1 tab1.deplacements.nn 1 bleu;
  605. def1 = defo s1 tab1.deplacements.nn   rouge;
  606. trac (def0 et def1);
  607. FINSI;
  608.  
  609. ee=tab1.variables_internes.nn;
  610. aa=extr ee 'XD1 ' 1 1 1;
  611.  
  612. message 'erreur relative';
  613. err = (aa - 1.9650) / 1.9650;
  614. list err;
  615.  
  616. si (> err 1.0E-3);
  617. erreur(5);
  618. finsi;
  619.  
  620. ******************************************************* 
  621. * FIN DE L ANALYSE
  622. ******************************************************* 
  623. FIN;
  624.  
  625.  
  626.  
  627.  
  628.  
  629.  
  630.  
  631.  
  632.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales