Télécharger Dynasp.dgibi

Retour à la liste

Numérotation des lignes :

  1. *****************************************************
  2. ************************************************************************
  3. ************************************************************************
  4. * fichier : dynasp.dgibi *
  5. ** modifie le 15/06/2014 passage EQPR -> EQEX *
  6. ** Il a été nécessaire de modifier aussi FROT *
  7. ** soi yfrot.eso et yfrti.eso *
  8. *****************************************************
  9. * fichier : dynasp.dgibi
  10. * Test DYNASP K-epsilon
  11.  
  12. GRAPH = 'N' ;
  13. complet = FAUX ;
  14.  
  15. DISCR = 'LINE' ;
  16. KPRESS= 'CENTRE' ;
  17. BETAP = 1. ;
  18.  
  19. titolo_g = chaine 'Dynasp-35 ' ;
  20. titolo = chaine titolo_g ;
  21. titr titolo ;
  22.  
  23. opti dime 2 elem qua4 ;
  24.  
  25. si ( complet ) ;
  26. n1 = 4 ; n2 = 4*n1 ; n3 = -10*n1 ;
  27. sinon ;
  28. n1 = 2 ; n2 = 4*n1 ; n3 = -5*n1 ;
  29. finsi ;
  30.  
  31. n4 = -1*n1 ; n5 = -1*n2 ;
  32. dmed = 2.000/n3 ; dmin = dmed/1.5 ; dmax = dmed*1.5 ;
  33.  
  34. pa0 = 0.000 0.000 ; pb0 = 0.0435 0.000 ; pc0 = 0.200 0.000 ;
  35. pa1 = 0.000 1.000 ; pb1 = 0.0435 1.000 ; pc1 = 0.200 1.000 ;
  36. pa2 = 0.000 2.000 ; pb2 = 0.0435 2.000 ; pc2 = 0.200 2.000 ;
  37. pa3 = 0.000 0.500 ; pb3 = 0.0435 0.500 ; pc3 = 0.200 0.500 ;
  38. pa4 = 0.000 1.500 ; pb4 = 0.0435 1.500 ; pc4 = 0.200 1.500 ;
  39.  
  40. axei = pa0 droi n3 pa1 dini dmin dfin dmax ;
  41. verti = pb0 droi n3 pb1 dini dmin dfin dmax ;
  42. sidei = pc0 droi n3 pc1 dini dmin dfin dmax ;
  43. axes = pa1 droi n3 pa2 dini dmax dfin dmin ;
  44. verts = pb1 droi n3 pb2 dini dmax dfin dmin ;
  45. sides = pc1 droi n3 pc2 dini dmax dfin dmin ;
  46.  
  47. weti = axei regl n1 verti ;
  48. dryi = verti regl n2 sidei ;
  49. wets = axes regl n1 verts ;
  50. drys = verts regl n2 sides ;
  51.  
  52. bot = (cote 4 weti) et (cote 4 dryi) ;
  53. hori = (cote 4 wets) et (cote 4 drys) ;
  54. in = (cote 2 wets) ;
  55. dtop = (cote 2 drys) ;
  56. top = in et dtop ;
  57.  
  58. wet = weti et wets ;
  59. dry = dryi et drys ;
  60. axe = axei et axes ;
  61. side = sidei et sides ;
  62. mt = dry et wet ;
  63. elim mt 0.00001 ;
  64. mt = orie mt ;
  65. cnt = cont mt ;
  66. wall = bot et side et dtop ;
  67. ppa3 = mt poin proc pa3 ;
  68. ppb3 = mt poin proc pb3 ;
  69. ppc3 = mt poin proc pc3 ;
  70. ppa4 = mt poin proc pa4 ;
  71. ppb4 = mt poin proc pb4 ;
  72. ppc4 = mt poin proc pc4 ;
  73. sez3 = ppa3 droi n1 ppb3 droi n2 ppc3 ;
  74. sez4 = ppa4 droi n1 ppb4 droi n2 ppc4 ;
  75. elim (mt et sez3 et sez4) 0.00001 ;
  76. tass mt ;
  77.  
  78.  
  79. C = 3.50e-2 ;
  80. Vi = 0.16 ;
  81. Dp = 4.70e-4 ;
  82. S = 0.400*0.087 ;
  83. C_s = C/S ;
  84.  
  85. * Options
  86.  
  87.  
  88. * Reading mesh
  89.  
  90. yp = 0.010 ;
  91. rapp = (0.400 - yp)/0.400 ;
  92. depl mt affi rapp (0.0 0.0) (1.0 0.0) ;
  93. * trac mt ;
  94.  
  95. * Dominions
  96.  
  97. Mmt = 'CHAN' 'QUAF' mt ;
  98. Mbot = 'CHAN' 'QUAF' bot ;
  99. Maxe = 'CHAN' 'QUAF' axe ;
  100. Mside = 'CHAN' 'QUAF' side ;
  101. Mtop = 'CHAN' 'QUAF' top ;
  102. Min = 'CHAN' 'QUAF' in ;
  103. Mcnt = 'CHAN' 'QUAF' cnt ;
  104. Mwet = 'CHAN' 'QUAF' wet ;
  105. Mdry = 'CHAN' 'QUAF' dry ;
  106. Mwall = 'CHAN' 'QUAF' wall ;
  107. Mdtop = 'CHAN' 'QUAF' dtop ;
  108.  
  109. 'ELIM' (Mmt et Mbot et Maxe et Mside et Mtop et Min et Mcnt et Mwet
  110. et Mdry et Mwall et Mdtop) 1.e-5 ;
  111.  
  112. $mt = 'MODE' Mmt 'NAVIER_STOKES' DISCR ;
  113. 'DOMA' $mt 'IMPR' ;
  114. $bot = 'MODE' Mbot 'NAVIER_STOKES' DISCR ;
  115. $axe = 'MODE' Maxe 'NAVIER_STOKES' DISCR ;
  116. $side = 'MODE' Mside 'NAVIER_STOKES' DISCR ;
  117. $top = 'MODE' Mtop 'NAVIER_STOKES' DISCR ;
  118. $in = 'MODE' Min 'NAVIER_STOKES' DISCR ;
  119. $cnt = 'MODE' Mcnt 'NAVIER_STOKES' DISCR ;
  120. $wet = 'MODE' Mwet 'NAVIER_STOKES' DISCR ;
  121. $dry = 'MODE' Mdry 'NAVIER_STOKES' DISCR ;
  122. $wall = 'MODE' Mwall 'NAVIER_STOKES' DISCR ;
  123. $dtop = 'MODE' Mdtop 'NAVIER_STOKES' DISCR ;
  124. volmt = doma $mt volume ;
  125.  
  126. mt = 'DOMA' $mt 'MAILLAGE' ;
  127. bot = 'DOMA' $bot 'MAILLAGE' ;
  128. axe = 'DOMA' $axe 'MAILLAGE' ;
  129. side = 'DOMA' $side 'MAILLAGE' ;
  130. top = 'DOMA' $top 'MAILLAGE' ;
  131. in = 'DOMA' $in 'MAILLAGE' ;
  132. cnt = 'DOMA' $cnt 'MAILLAGE' ;
  133. wet = 'DOMA' $wet 'MAILLAGE' ;
  134. dry = 'DOMA' $dry 'MAILLAGE' ;
  135. wall = 'DOMA' $wall 'MAILLAGE' ;
  136. dtop = 'DOMA' $dtop 'MAILLAGE' ;
  137.  
  138. * Physical properties
  139.  
  140. condf = 2.62e-2 ;
  141. nuf = 1.50e-5 ;
  142. rof = 1.20e-0 ;
  143. cpf = 1.00e+3 ;
  144. diff = condf/(rof*cpf) ;
  145. nup = 1.00e-20 ;
  146. rop = 2.50e+3 ;
  147. cpp = 8.40e+2 ;
  148. difp = nup ;
  149. rrho = rof/rop ;
  150. qvol = 0.00 ;
  151. gx = 0.00e+0 ;
  152. gy = -9.81e+0 ;
  153. gdr = 0.0 (-9.81*(rop-rof)/rop) ;
  154. zero = 0.0 0.0 ;
  155. beta = 1.0 1.0 ;
  156. * alpha = (3.14/6.0)*n_dot*(Dp**3.0)/Vi ;
  157. alpha = C_s/rop/Vi ;
  158. n_dot = (6.0/3.14)*C_s/(rop*(Dp**3.0)) ;
  159. ustella = 30.0*nuf/yp ;
  160.  
  161. L0 = 0.30 ;
  162. K0 = 1.0e-4 ;
  163. Rec = 50.0 ;
  164. Uref = 4. ;
  165.  
  166. * mess 'Cs' C_s 'Dp' Dp 'n_dot' n_dot ; opti donn 5 ;
  167.  
  168. tabbil = table ;
  169. tabbil.'TF' = mot 'TF' ;
  170. tabbil.'TP' = mot 'TP' ;
  171. tabbil.'VP' = mot 'VN' ;
  172. tabbil.'ALPHA' = mot 'A' ;
  173. tabbil.'ROCPF' = (rof*cpf) ;
  174. tabbil.'ROCPP' = (rop*cpp) ;
  175. tabbil.'VOL' = volmt ;
  176. tabbil.'CNT' = $cnt ;
  177. tabbil.'TOP' = $top ;
  178. tabbil.'BOT' = $bot ;
  179.  
  180. * Table for bif
  181.  
  182. tabbif = table ;
  183. tabbif.'RHOF' = rof ;
  184. tabbif.'RHOP' = rop ;
  185. tabbif.'DPART' = Dp ;
  186. tabbif.'NUF' = nuf ;
  187. tabbif.'ALPHA' = mot 'A' ;
  188. tabbif.'UFLUID' = mot 'UN' ;
  189. tabbif.'UPART' = mot 'VN' ;
  190. tabbif.'KFLUID' = mot 'KFL' ;
  191. tabbif.'KPART' = mot 'KPR' ;
  192.  
  193. * tabbif.'HPART' = mot 'HP' ;
  194. * tabbif.'HFLUID' = mot 'HF' ;
  195. * tabbif.'LAMBDAF' = condf ;
  196. * tabbif.'ROCPP' = (rop*cpp) ;
  197. * tabbif.'ROCPF' = (rof*cpf) ;
  198. * tabbif.'TGASN' = mot 'TF' ;
  199. * tabbif.'TGASE' = mot 'TFE' ;
  200. * tabbif.'TPARTN' = mot 'TP' ;
  201. * tabbif.'TPARTE' = mot 'TPE' ;
  202.  
  203. * Points for time histories
  204.  
  205. nc = 10 ;
  206. npti = nbno mt ;
  207. ps = npti / nc ;
  208. pf = ps * nc ;
  209. lh = elem (doma $mt sommet) 'POI1' (lect ps pas ps pf) ;
  210. 'UN' 1 lh 'UN' 2 lh
  211. 'VN' 1 lh 'VN' 2 lh
  212. 'KN' lh 'EN' lh
  213. * 'TP' lh 'TF' lh
  214. 'A' lh
  215. ;
  216.  
  217. si ( complet ) ;
  218. nbit = 10000 ;
  219. sinon ;
  220. nbit = 800 ;
  221. * nbit = 20 ;
  222. finsi ;
  223.  
  224. * Equations + boudary conditions
  225.  
  226. * Navier-Stokes + K-epsilon + particle mass conservation
  227.  
  228. rv = EQEX $mt ITMA nbit ALFA 0.70
  229. * ZONE $mt OPER NS nuf zero INCO UN
  230. OPTI 'NOCONS' 'SUPG' 'MMPG'
  231. ZONE $mt OPER NSKE nuf 'NT' zero INCO UN KN EN
  232. ZONE $wall OPER FPU nuf 'USTAR' yp INCO UN KN EN
  233. ZONE $mt OPER NS nup gdr INCO VN
  234. OPTI 'CONS' 'SUPG'
  235. ZONE $mt OPER TSCA nup 'VN' qvol 'TN' INCO A
  236. ;
  237.  
  238. * Coupling terms on q.d.m equations
  239.  
  240. rv = EQEX rv
  241. OPTI 'NOCONS' 'EFM1'
  242. * OPTI 'IMPL'
  243. ZONE $mt OPER FROT 'KFL' beta 'VN' INCO UN
  244. * OPTI 'IMPL'
  245. ZONE $mt OPER FROT 'KPR' beta 'UN' INCO VN
  246. ;
  247. rv = EQEX rv
  248. ZONE $mt OPER FILTREKE Uref L0 INCO KN EN
  249. ZONE $mt OPER PPRE 'VN' rrho INCO VN
  250. ZONE $mt OPER BIF tabbif INCO VN
  251. ;
  252.  
  253. * Coupling terms on energy equations
  254.  
  255. * rv = EQEX rv
  256. * ZONE $mt OPER TSCA difp 'VN' qvol INCO TP
  257. * ZONE $mt OPER TSCA diff 'UN' qvol INCO TF
  258. * ZONE $mt OPER ECHI 'HP' 'TFE' INCO TP
  259. * ZONE $mt OPER ECHI 'HF' 'TPE' INCO TF
  260. * ZONE $mt OPER BILA tabbil
  261. ;
  262. RV=EQEX RV OPTI EFM1 'CENTREE'
  263. 'ZONE' $MT 'OPER' 'DFDT' 1. 'UN' 'DELTAT' 'INCO' 'UN'
  264. 'ZONE' $MT 'OPER' 'DFDT' 1. 'VN' 'DELTAT' 'INCO' 'VN'
  265. 'ZONE' $MT 'OPER' 'DFDT' 1. 'KN' 'DELTAT' 'INCO' 'KN'
  266. 'ZONE' $MT 'OPER' 'DFDT' 1. 'EN' 'DELTAT' 'INCO' 'EN'
  267. 'ZONE' $MT 'OPER' 'DFDT' 1. 'A' 'DELTAT' 'INCO' 'A'
  268. ;
  269.  
  270. * Boundary coditions
  271.  
  272. rv = EQEX rv
  273. * CLIM UN UIMP cnt 0.0 UN VIMP side 0.0
  274. CLIM UN VIMP top 0.0 UN VIMP bot 0.0
  275. CLIM UN UIMP axe 0.0 UN UIMP side 0.0
  276. CLIM VN UIMP axe 0.0 VN UIMP side 0.0
  277. CLIM VN VIMP in (-1*Vi) VN VIMP dtop 0.0
  278. CLIM A TIMP in alpha A TIMP dtop 0.0
  279. * CLIM TP TIMP in 20.0
  280. ;
  281.  
  282. * Pressure equation
  283.  
  284. RVP = EQEX 'OPTI' 'EF' KPRESS
  285. 'ZONE' $MT OPER KBBT -1. betap INCO 'UN' 'PRES'
  286. ;
  287.  
  288. rvp.'METHINV'.TYPINV=1 ;
  289. rvp.'METHINV'.IMPINV=0 ;
  290. rvp.'METHINV'.NITMAX=300;
  291. rvp.'METHINV'.PRECOND=3 ;
  292. rvp.'METHINV'.RESID =1.e-8 ;
  293. rvp.'METHINV' . 'FCPRECT'=100 ;
  294. rvp.'METHINV' . 'FCPRECI'=100 ;
  295.  
  296. RV.'PROJ' =RVP ;
  297.  
  298. * Initial conditions
  299.  
  300. alphaw = kcht $wet scal sommet (alpha ) ;
  301. tpwet = kcht $wet scal sommet (20.0 ) ;
  302. rv.titolo = titolo ;
  303. rv.INCO = table INCO ;
  304. rv.INCO.'UN' = kcht $mt vect sommet (1.0e-5 1.0e-5) ;
  305. rv.INCO.'PRES' = kcht $mt scal kpress 0. ;
  306. rv.INCO.'VN' = kcht $mt vect sommet (1.0e-5 (-1*Vi)) ;
  307. rv.INCO.'KN' = kcht $mt scal sommet (1.0e-5 ) ;
  308. rv.INCO.'EN' = kcht $mt scal sommet (1.0e-5 ) ;
  309. rv.INCO.'NT' = kcht $mt scal centre nuf ;
  310. rv.INCO.'A' = kcht $mt scal sommet (0.0 ) alphaw ;
  311. rv.INCO.'TN' = kcht $mt scal sommet (0.0 ) ;
  312. * rv.INCO.'TP' = kcht $mt scal sommet (0.0 ) tpwet ;
  313. * rv.INCO.'TF' = kcht $mt scal sommet (0.0 ) ;
  314. * rv.INCO.'TPE' = kcht $mt scal centre (0.0 ) ;
  315. * rv.INCO.'TFE' = kcht $mt scal centre (0.0 ) ;
  316. rv.INCO.'KFL' = kcht $mt vect centre (0.0 0.0 ) ;
  317. rv.INCO.'KPR' = kcht $mt vect centre (0.0 0.0 ) ;
  318. * rv.INCO.'HF' = kcht $mt scal centre (0.0 ) ;
  319. * rv.INCO.'HP' = kcht $mt scal centre (0.0 ) ;
  320. rv.INCO.'USTAR' = kcht $wall scal centre ustella ;
  321. rv.'HIST' = tran ;
  322. rv.'YP' = yp ;
  323. rv.'NUF' = nuf ;
  324.  
  325. * Executing
  326.  
  327. exec rv ;
  328.  
  329. * Saving results
  330.  
  331. * repix rv ;
  332. * sauv rv ;
  333.  
  334. * Procedura test
  335.  
  336. debproc test ;
  337. argu rv*table complet*logique ;
  338. pt1 = mt poin proc (0.0 1.260) ;
  339. pt2 = mt poin proc (0.0 0.740) ;
  340. u2 = exco uy (rv.inco.'UN') uy ;
  341. v2 = exco uy (rv.inco.'VN') uy ;
  342. upt1 = abs (extr (rv.inco.'UN') uy pt1) ;
  343. upt2 = abs (extr (rv.inco.'UN') uy pt2) ;
  344. vpt1 = abs (extr (rv.inco.'VN') uy pt1) ;
  345. vpt2 = abs (extr (rv.inco.'VN') uy pt2) ;
  346. apt1 = abs (extr (rv.inco.'A') scal pt1) ;
  347. apt2 = abs (extr (rv.inco.'A') scal pt2) ;
  348.  
  349. si ( complet ) ;
  350. upt1_l = 0.53580 ;
  351. upt2_l = 0.59501 ;
  352. vpt1_l = 3.0245 ;
  353. vpt2_l = 3.5610 ;
  354. apt1_l = 1.18535E-03 ;
  355. apt2_l = 1.00603E-03 ;
  356. sinon ;
  357. upt1_l = 0.43961 ;
  358. upt2_l = 0.38635 ;
  359. vpt1_l = 3.0859 ;
  360. vpt2_l = 3.4686 ;
  361. apt1_l = 6.78202E-04 ;
  362. apt2_l = 5.94036E-04 ;
  363. finsi ;
  364.  
  365. upt1_e = abs ((upt1 - upt1_l)/upt1_l) ;
  366. upt2_e = abs ((upt2 - upt2_l)/upt2_l) ;
  367. vpt1_e = abs ((vpt1 - vpt1_l)/vpt1_l) ;
  368. vpt2_e = abs ((vpt2 - vpt2_l)/vpt2_l) ;
  369. apt1_e = abs ((apt1 - apt1_l)/apt1_l) ;
  370. apt2_e = abs ((apt2 - apt2_l)/apt2_l) ;
  371.  
  372. erlim = 5.00e-2 ;
  373. si (upt1_e > erlim) ;
  374. mess 'Error on Ugas : err_Upt1= ' upt1_e ' > ' erlim ;
  375. erreur 5 ;
  376. finsi ;
  377.  
  378. si (upt2_e > erlim) ;
  379. mess 'Error on Ugas : err_Upt2= ' upt2_e ' > ' erlim ;
  380. erreur 5 ;
  381. finsi ;
  382.  
  383. si (vpt1_e > erlim) ;
  384. mess 'Error on Vpart: err_Vpt1= ' vpt1_e ' > ' erlim ;
  385. erreur 5 ;
  386. finsi ;
  387.  
  388. si (vpt2_e > erlim) ;
  389. mess 'Error on Vpart: err_Vpt2= ' vpt2_e ' > ' erlim ;
  390. erreur 5 ;
  391. finsi ;
  392.  
  393. si (apt1_e > erlim) ;
  394. mess 'Error on alpha: err_Apt1= ' apt1_e ' > ' erlim ;
  395. erreur 5 ;
  396. finsi ;
  397.  
  398. si (apt2_e > erlim) ;
  399. mess 'Error on alpha: err_Apt2= ' apt2_e ' > ' erlim ;
  400. erreur 5 ;
  401. finsi ;
  402.  
  403. mess 'upt1' upt1 'upt2' upt2 'vpt1' vpt1 'vpt2' vpt2 ;
  404. mess 'apt1' apt1 'apt2' apt2 ;
  405. finproc ;
  406.  
  407. * Procedura visu
  408.  
  409. debproc visu rv*table ;
  410. titr rv.titolo ;
  411. tdom = $mt ;
  412. mesh = doma $mt 'MAILLAGE' ;
  413. cmesh = cont mesh ;
  414.  
  415. pt1 = poin mesh proc (0.0 0.740) ;
  416. pt2 = poin mesh proc (0.4 0.740) ;
  417. pt3 = poin mesh proc (0.0 1.260) ;
  418. pt4 = poin mesh proc (0.4 1.260) ;
  419.  
  420. pt12 = poin mesh droit pt2 pt1 0.0001 ;
  421. pt34 = poin mesh droit pt3 pt4 0.0001 ;
  422. meshl = chan mesh lign ;
  423. line1 = elem meshl appuye pt12 ;
  424. line2 = elem meshl appuye pt34 ;
  425. line1 = inve line1 ;
  426. line2 = inve line2 ;
  427.  
  428. f1 = kcht $wet scal sommet 1.0 ;
  429. filtro = kcht $mt scal sommet 0.0 f1 ;
  430.  
  431. un = rv.inco.'UN' ;
  432. vn = rv.inco.'VN' ;
  433. vn = vn * filtro ;
  434. a = rv.inco.'A' ;
  435. * tp = rv.inco.'TP' ;
  436. * tf = rv.inco.'TF' ;
  437. u1 = exco ux un ux ;
  438. u2 = exco uy un uy ;
  439. v1 = exco ux vn ux ;
  440. v2 = exco uy vn uy ;
  441.  
  442. unvt = vect un 5.0e-2 ux uy jaun ;
  443. vnvt = vect vn 5.0e-3 ux uy roug ;
  444.  
  445. titr (chaine titolo_g 'Uair') ; trac unvt mesh cmesh ;
  446. titr (chaine titolo_g 'Upart') ; trac vnvt mesh cmesh ;
  447.  
  448. txa = mot 'axe (m)' ;
  449. txo = mot 'X (m)' ;
  450. * txl = mot 'section 0.74 (m)' ;
  451. tyu = mot 'velocity (m/s)' ;
  452. tyua = mot 'air velocity (m/s)' ;
  453. tyup = mot 'u_I (m/s)' ;
  454. tynt = mot 'nu_t (m^2/s)' ;
  455. tya = mot 'alpha' ;
  456. tyt = mot 'temp. (C)' ;
  457. t1 = chaine titolo_g 'U;V /axe ' ;
  458. t2 = chaine titolo_g 'Z=0.74 (m)' ;
  459. t3 = chaine titolo_g 'Z=1.26 (m)' ;
  460. t4 = chaine titolo_g 'Air veloc.' ;
  461. t5 = chaine titolo_g 'Alpha/axe ' ;
  462. t6 = chaine titolo_g 'Alpha ' ;
  463. t7 = chaine titolo_g 'Y+' ;
  464.  
  465. tab1 = table ;
  466. tab1.1 = 'MARQ CROI REGU ' ;
  467. tab1.2 = 'MARQ LOSA REGU ' ;
  468. tab1.'TITRE' = table ;
  469. tab1.'TITRE'. 1 = mot 'AIR' ;
  470. tab1.'TITRE'. 2 = mot 'PARTICLE' ;
  471.  
  472. tab2 = table ;
  473. tab2.1 = 'MARQ LOSA REGU ' ;
  474. tab2.2 = 'MARQ TRIA REGU ' ;
  475. tab2.3 = 'MARQ CARR REGU ' ;
  476. tab2.4 = 'MARQ ETOI REGU ' ;
  477. tab2.'TITRE' = table ;
  478. tab2.'TITRE'. 1 = mot 'H=1.50M' ;
  479. tab2.'TITRE'. 2 = mot 'H=1.00M' ;
  480. tab2.'TITRE'. 3 = mot 'H=0.50M' ;
  481. tab2.'TITRE'. 4 = mot 'H=0.74M' ;
  482.  
  483. tab3 = table ;
  484. tab3.1 = 'MARQ LOSA REGU ' ;
  485. tab3.2 = 'MARQ TRIA REGU ' ;
  486. tab3.'TITRE' = table ;
  487. tab3.'TITRE'. 1 = mot 'H=0.74M' ;
  488. tab3.'TITRE'. 2 = mot 'H=1.26M' ;
  489.  
  490. u2axe = evol chpo u2 uy axe ;
  491. v2axe = evol chpo v2 uy axe ;
  492. u2top = evol chpo u2 uy top ;
  493. v2top = evol chpo v2 uy top ;
  494. u2int = evol chpo u2 uy (inve hori) ;
  495. v2int = evol chpo v2 uy (inve hori) ;
  496. u2ln1 = evol chpo u2 uy line1 ;
  497. v2ln1 = evol chpo v2 uy line1 ;
  498. u2ln2 = evol chpo u2 uy line2 ;
  499. v2ln2 = evol chpo v2 uy line2 ;
  500.  
  501. * tpaxe = evol chpo tp scal axe ;
  502. * tfaxe = evol chpo tf scal axe ;
  503. * tpln1 = evol chpo tp scal line1 ;
  504. * tfln1 = evol chpo tf scal line1 ;
  505.  
  506. aaxe = evol chpo a scal axe ;
  507. atop = evol chpo a scal (top ) ;
  508. aln1 = evol chpo a scal line1 ;
  509. aln2 = evol chpo a scal line2 ;
  510. abot = evol chpo a scal (inve bot ) ;
  511.  
  512. dess (u2axe et v2axe) mima titx txa tity tyu titr t1 gril lege tab1 ;
  513. * @excel1 u2axe 'pp' ;
  514. dess (u2ln1 et v2ln1) mima titx txo tity tyu titr t2 gril lege tab1 ;
  515. dess (u2ln2 et v2ln2) mima titx txo tity tyu titr t3 gril lege tab1 ;
  516. dess (u2ln1 et u2ln2) mima titx txo tity tyua gril titr t4 lege tab3;
  517. dess (aaxe ) mima titx txa tity tya gril titr t5 ;
  518. dess (aln1 et aln2 ) mima titx txo tity tya gril titr t6 lege tab3;
  519. * dess (tfaxe et tpaxe) mima titx txa tity tyt gril lege tab1 ;
  520. * dess (tfln et tpln ) mima titx txl tity tyt gril lege tab1 ;
  521.  
  522.  
  523. si (exist rv 'INCO' 'USTAR') ;
  524. yp = rv.'YP' ;
  525. nuf = rv.'NUF' ;
  526. ue = rv.'INCO'.'USTAR' ;
  527. us = elno $wall ue ;
  528. Yplus = us * yp / nuf ;
  529. Ype = evol chpo Yplus scal wall ;
  530. dess Ype mima tity 'Y+' gril titr t7 ;
  531. finsi ;
  532.  
  533. si (exist rv 'INCO' 'HP' ) ;
  534. titr (chaine rv.titolo ' Hp' ) ;
  535. trac (elno tdom (rv.'INCO'.'HP' )) mesh cmesh ;
  536. finsi ;
  537. si (exist rv 'INCO' 'HF' ) ;
  538. titr (chaine rv.titolo ' Hf' ) ;
  539. trac (elno tdom (rv.'INCO'.'HF' )) mesh cmesh ;
  540. finsi ;
  541. si (exist rv 'INCO' 'H' ) ;
  542. titr (chaine rv.titolo ' H ' ) ;
  543. trac (rv.'INCO'.'H') mesh cmesh ;
  544. finsi ;
  545. si (exist rv 'INCO' 'TF') ;
  546. titr (chaine rv.titolo ' Tf' ) ;
  547. trac (rv.inco.'TF') mesh cmesh ;
  548. finsi ;
  549. si (exist rv 'INCO' 'TP') ;
  550. titr (chaine rv.titolo ' Tp' ) ;
  551. trac (rv.inco.'TP') mesh cmesh ;
  552. finsi ;
  553. si (exist rv 'INCO' 'A') ;
  554. titr (chaine rv.titolo ' alpha') ;
  555. trac (rv.inco.'A' ) mesh cmesh ;
  556. finsi ;
  557. si (exist rv 'INCO' 'KN') ;
  558. kn = rv.inco.'KN' ;
  559. en = rv.inco.'EN' ;
  560. L0 = (kops (kops kn '**' 1.5) '*' (kops en '**' (-1.0))) ;
  561. titr (chaine rv.titolo ' kn') ;
  562. trac kn mesh cmesh ;
  563. titr (chaine rv.titolo ' en') ;
  564. trac en mesh cmesh ;
  565. mess 'min L0' (mini L0) ; mess 'max L0' (maxi L0) ;
  566. titr (chaine rv.titolo ' L0') ;
  567. trac L0 mesh cmesh ;
  568. * up = kn * 2.0 / 3.0 ;
  569. * up = up ** 0.5 ;
  570. * unor = kops un 'PSCA' un ;
  571. ** up = up / unor ;
  572. * upln = evol chpo up scal line1 ;
  573. * dess (upln ) mima titx txl tity tyup gril ;
  574. finsi ;
  575. si (exist rv 'INCO' 'NT') ;
  576. nt = elno tdom (rv.inco.'NT') ;
  577. titr (chaine rv.titolo ' nt') ;
  578. nte1 = evol chpo nt scal line1 ;
  579. nte2 = evol chpo nt scal line2 ;
  580. nte = nte1 et nte2 ;
  581. dess (nte ) titx txo tity tynt gril lege tab3 ;
  582. nr = nt / nuf ;
  583. trac nt mesh cmesh ;
  584. titr (chaine rv.titolo ' nr') ;
  585. trac nr mesh cmesh ;
  586. finsi ;
  587.  
  588. * evoluzioni nel tempo
  589.  
  590. si (exist rv 'HIST' '1UN') ;
  591. dess rv.hist.'1UN' ;
  592. dess rv.hist.'2UN' ;
  593. finsi ;
  594. si (exist rv 'HIST' '1VN') ;
  595. dess rv.hist.'1VN' ;
  596. dess rv.hist.'2VN' ;
  597. finsi ;
  598. si (exist rv 'HIST' 'KN') ;
  599. dess rv.hist.'KN' ;
  600. dess rv.hist.'EN' ;
  601. finsi ;
  602. si (exist rv 'HIST' 'A' ) ;
  603. dess rv.hist.'A' ;
  604. finsi ;
  605. si (exist rv 'HIST' 'TF') ;
  606. dess rv.hist.'TF' ;
  607. finsi ;
  608. si (exist rv 'HIST' 'TP') ;
  609. dess rv.hist.'TP' ;
  610. finsi ;
  611.  
  612. finproc ;
  613.  
  614.  
  615. test rv complet ;
  616.  
  617. si ( 'EGA' graph 'O' );
  618. visu rv ;
  619. finsi ;
  620. fin ;
  621.  
  622.  
  623.  
  624.  
  625.  
  626.  
  627.  
  628.  
  629.  
  630.  
  631.  
  632.  
  633.  
  634.  
  635.  
  636.  
  637.  
  638.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales