Télécharger la plaquette Cast3M


fr en

Télécharger xfem_ecrouissage_cinematique.dgibi

Retour à la liste

Numérotation des lignes : 

  1. * Section : Mecanique Rupture
  2. ************************************************************************
  3. *      Cas-test de fonctionnement du comportement elastoplastique      *
  4. *    avec ecrouissage isotrope en combinaison avec des elements XQ4R   *
  5. *                                                                      *
  6. * Verification dans un cas trivial : solicitation parallele a la       *
  7. * fissure => fissure non sollicitee donc on doit retrouver la meme     *
  8. * chose avec des elements standards                                    *
  9. ************************************************************************
  10.  
  11. * OPTIONS ET BOOLEEN POUR LES TRACERS
  12. OPTI 'DIME' 2 'ELEM' 'QUA4' 'MODE' 'PLANCONT';
  13. BTRAC = FAUX;
  14.  
  15. * MAILLAGE
  16. NEL = 2;
  17.  
  18. P1 = 0. 0.;
  19. P2 = 1. 0.;
  20. D1 = DROI NEL P1 P2;
  21.  
  22. P5 = 0. 1.;
  23. P6 = 1. 1.;
  24. D2 = DROI NEL P5 P6;
  25.  
  26. S1 = D1 REGL NEL D2;
  27. SI BTRAC;
  28.     TRAC S1;
  29. FINSI;
  30.  
  31. * MODELE ET MATERIAU AVEC XQ4R
  32. MOD1 = MODE S1 'MECANIQUE' 'ELASTIQUE' 'PLASTIQUE' 'CINEMATIQUE' 'XQ4R';
  33. P3 = 0.5 0.;
  34. P4 = 0.5 0.5;
  35. D3 = DROI 1 P3 P4;
  36. PSI PHI = PSIPHI S1 D3 'DEUX' P4;
  37. TRIE MOD1 PSI PHI 'SAUT';
  38. MAT1 = MATE MOD1 'YOUN' 200.E9 'NU' 0.3 'SIGY' 120.E6 'H' 120.E8;
  39.  
  40. * MODELE ET MATERIAU AVEC ELEMENTS STANDARDS
  41. MOD2 = MODE S1 'MECANIQUE' 'ELASTIQUE' 'PLASTIQUE' 'CINEMATIQUE';
  42. MAT2 = MATE MOD2 'YOUN' 200.E9 'NU' 0.3 'SIGY' 120.E6 'H' 120.E8;
  43.  
  44. * CL EN DEPLACEMENTS
  45. RIG1 = BLOQ 'UY' D2;
  46. PDROI = (CONT S1) POIN 'DROI' P1 P5 1.E-5;
  47. RIG2 = BLOQ 'UX' PDROI;
  48. RIG3 = BLOQ 'UY' D1;
  49. UIMP = DEPI RIG1 1.5E-3;
  50. UDET = EVOL 'MANU' 'TEMPS' (PROG 0. 1. 2.) (PROG 0. 1. 0.);
  51.  
  52. * CALCUL AVEC XQ4R
  53. CALC1 = TABL;
  54. CALC1.'BLOCAGES_MECANIQUES' = RIG1 ET RIG2 ET RIG3 ET (RELA MOD1);
  55. CALC1.'CHARGEMENT' = CHAR 'DIMP' UIMP UDET;
  56. CALC1.'TEMPS_CALCULES' = (PROG 0. PAS 0.4 2.);
  57. CALC1.'MODELE' = MOD1;
  58. CALC1.'CARACTERISTIQUES' = MAT1;
  59. PASAPAS CALC1;
  60. * COURBE CONTRAINTE - DEPLACEMENT
  61. XSYY = EVOL 'TEMP' CALC1 'CONTRAINTES' 'SMYY' 1 1 1;
  62. XU = EVOL 'TEMP' CALC1 'DEPLACEMENTS' 'UY' P5;
  63. XS_DE_U = EVOL 'MANU' 'U' (EXTR XU 'ORDO') 'SIGM' (EXTR XSYY 'ORDO');
  64.  
  65. * CALCUL AVEC ELEMENTS STANDARDS
  66. CALC2 = TABL;
  67. CALC2.'BLOCAGES_MECANIQUES' = RIG1 ET RIG2 ET RIG3;
  68. CALC2.'CHARGEMENT' = CALC1.'CHARGEMENT';
  69. CALC2.'TEMPS_CALCULES' = CALC1.'TEMPS_CALCULES';
  70. CALC2.'MODELE' = MOD2;
  71. CALC2.'CARACTERISTIQUES' = MAT2;
  72. PASAPAS CALC2;
  73. * COURBE CONTRAINTE - DEPLACEMENT
  74. SYY = EVOL 'TEMP' CALC2 'CONTRAINTES' 'SMYY' 1 1 1;
  75. U = EVOL 'TEMP' CALC2 'DEPLACEMENTS' 'UY' P5;
  76. S_DE_U = EVOL 'MANU' 'U' (EXTR U 'ORDO') 'SIGM' (EXTR SYY 'ORDO');
  77.  
  78. * COMPARAISON
  79. SI BTRAC;
  80.     DESS (XS_DE_U ET S_DE_U);
  81. FINSI;
  82. ERR1 = (INTG (XSYY - SYY)**2)**0.5;
  83. SEUIL = ((INTG SYY**2)**0.5) / 100.;
  84. SI (ERR1 >EG SEUIL);
  85.     MESS 'ECART A LA REFERENCE :' ERR1;
  86.     MESS 'SEUIL ACCEPTE :' SEUIL;
  87.     ERRE 'ERREUR SUPERIEURE AU SEUIL ACCEPTE';
  88. FINSI;
  89.  
  90. FIN;
  91.  
  92.  
  93.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales