Télécharger xfem02.dgibi

Retour à la liste

Numérotation des lignes :

  1. ************************************************************************
  2. ************************************************************************
  3. ********************************************************************
  4. *
  5. * xfem02.dgibi
  6. *
  7. * calcul avec elements xfem (XQ4R)
  8. * d'une plaque elasto plastique en traction
  9. * avec fissure droite
  10. *
  11. * création : bp, le 24.09.2009
  12. * ajout g_theta : bp, 08.06.2010
  13. *
  14. ********************************************************************
  15. *opti echo 1 ;
  16. *graph = vrai; opti trac PSC ; opti EPTR 5;
  17. graph = faux;
  18. fllong = faux;
  19.  
  20. *******************************************************
  21. *** Options de calcul : 2D
  22. opti dime 2 elem qua4 mode plan defo;
  23.  
  24.  
  25. *******************************************************
  26. *** Maillage : Plaque rectangulaire saine
  27.  
  28. * dimensions
  29. * bord droit, gauche, hauteur
  30. b= 0.050 ; bg = -0.25 * b ; hb1= 0.6 * b ;
  31. hgoup= 0.35 * b;
  32.  
  33. * finesse
  34. * ici, nx1 doit etre un multiple de 2 et de 5
  35. nx1 = 20;
  36. si(fllong); nx1 = 40; fins;
  37. dx1 = (b-bg) / (flot nx1) ;
  38. na1 = enti (b / dx1);
  39. na6 = nx1 - na1;
  40. na2 = 2;
  41. ha1 = (flot na2) * dx1;
  42.  
  43. * demi-zone centrale
  44. DENS (dx1) ;
  45. pa1 = (0.) (0.*ha1) ;
  46. pa2 = (b ) (0.*ha1) ;
  47. pa3 = (b) (ha1) ;
  48. pa4 = (0.) (ha1) ;
  49. pa5 = (bg) (ha1) ;
  50. pa6 = (bg) (0.*ha1) ;
  51. da1 = pa1 droi na1 pa2;
  52. da2 = pa2 droi na2 pa3;
  53. da3 = pa3 droi na1 pa4;
  54. da4 = pa4 droi na6 pa5;
  55. da5 = pa5 droi na2 pa6;
  56. da6 = pa6 droi na6 pa1;
  57. da61 = (da6 et da1);
  58. da34 = (da3 et da4);
  59. sa1 = dall da61 da2 da34 da5;
  60.  
  61. * zone de transition
  62. dx2 = (2.*dx1);
  63. DENS (dx2);
  64. pb3 = pa3 plus (0. dx2);
  65. pb4 = pa4 plus (0. dx2);
  66. pb5 = pa5 plus (0. dx2);
  67. nb3 = na1 / 2;
  68. nb4 = na6 / 2;
  69. db3 = pb3 droi (nb3) pb4;
  70. db4 = pb4 droi (nb4) pb5;
  71. db34 = db3 et db4;
  72. nb34 = nb3 + nb4;
  73.  
  74. * procedure maillage 2 pour 1 entre 2 lignes : lgros et lfine
  75. lfine = da34;
  76. lgros = db34;
  77. nbmotif1= nbel lgros;
  78. if1 = 1; ig1 = 1;
  79. logpm2 = vrai;
  80. repe bmotif1 nbmotif1;
  81. pf1 = lfine POIN if1;
  82. if1 = if1 + 1;
  83. pf3 = lfine POIN (if1);
  84. if1 = if1 + 1;
  85. pf2 = lfine POIN (if1);
  86. pg1 = lgros POIN ig1;
  87. ig1 = ig1 + 1;
  88. pg2 = lgros POIN (ig1);
  89. pg3 = 0.5 * (pg1 plus pg2);
  90. pm3 = 0.5 * (pf3 plus pg3);
  91. si(logpm2);
  92. logpm2 = faux;
  93. pm2 = 0.5 * (pf2 plus pg2);
  94. geo1 = (manu 'QUA4' pf1 pf3 pm3 pg1)
  95. et (manu 'QUA4' pf3 pf2 pm2 pm3)
  96. et (manu 'QUA4' pm3 pm2 pg2 pg1);
  97. sino;
  98. logpm2 = vrai;
  99. geo1 = (manu 'QUA4' pf1 pf3 pm3 pm2)
  100. et (manu 'QUA4' pf3 pf2 pg2 pm3)
  101. et (manu 'QUA4' pm2 pm3 pg2 pg1);
  102. finsi;
  103. si(&bmotif1 ega 1); motif1 = geo1;
  104. sino; motif1 = motif1 et geo1;
  105. fins;
  106. fin bmotif1;
  107. * on recupere motif1
  108. sb1 = motif1;
  109.  
  110. * zone "grossiere"
  111. DENS (dx2);
  112. pc3 = (b) (hgoup);
  113. pc5 = (bg) (hgoup);
  114. dc34 = pc3 droi nb34 pc5;
  115. sc1 = regl db34 dc34;
  116.  
  117. pd3 = ( b) (hb1);
  118. pd5 = (bg) (hb1);
  119. dd34 = pd3 droi nb34 pd5;
  120. sd1 = regl dc34 dd34;
  121.  
  122. * symetrie et assemblages
  123. sa2 sb2 sc2 sd2 = sa1 sb1 sc1 sd1 SYME 'DROIT' pa6 pa2 ;
  124.  
  125. * satot = sa1 et sa2;
  126. * sbtot = (sb1 et sc1 et sd1) et (sb2 et sc2 et sd2);
  127. satot = (sa1 et sb1) et (sa2 et sb2);
  128. sbtot = (sc1 et sd1) et (sc2 et sd2);
  129.  
  130. stot0 = satot et sbtot;
  131. ELIM stot0 (1.E-5*dx1);
  132.  
  133. mess 'maillage central ext total' ;
  134. mess 'nbno= ' (nbno satot) (nbno stot0);
  135. mess 'nbel= ' (nbel satot) (nbel stot0);
  136.  
  137.  
  138. *******************************************************
  139. *** Maillage de la fissure
  140.  
  141. * longueur de la fissure
  142. a0 = 0.025 ;
  143.  
  144. * finesse du maillage de la fissure
  145. na0 = 10;
  146. da0 = a0 / (flot na0) ;
  147.  
  148. * maillage
  149. DENS (da0) ;
  150. ptip0 = (bg) (0.);
  151. ptip1 = (a0) (0.);
  152. lcrack0 = (ptip0 droi na0 ptip1) coul 'ROUG';
  153.  
  154. * table (+ pratique pour gérer la propa)
  155. TXFEM = tabl;
  156. TXFEM . 0 = tabl;
  157. TXFEM . 0 . 'POINTE1' = ptip1;
  158. TXFEM . 0 . 'FISSURE' = lcrack0;
  159.  
  160. * creation des level set
  161. psi0 phi0 = PSIPHI satot lcrack0 'DEUX' ptip1;
  162. isolv7 = ( prog (-1.*a0) (-5.*dx1) PAS dx1 (-1.*dx1)
  163. PAS (0.2*dx1) dx1 PAS dx1 (5.*dx1) a0 );
  164. si(graph);
  165. *opti isov lign;
  166. TRAC phi0 (stot0 et lcrack0) isolv7 ;
  167. TRAC psi0 (stot0 et lcrack0) isolv7;
  168. *opti isov surf;
  169. finsi;
  170.  
  171.  
  172. *******************************************************
  173. *** Modeles et materiaux
  174.  
  175. * definition des models elementaires
  176. mod1a = MODE satot mecanique elastique isotrope plastique xq4R;
  177. mod1b = MODE sbtot mecanique elastique isotrope;
  178.  
  179. * enrichissement
  180. Che1X = tabl;
  181. Che1X . 0 = TRIE mod1a psi0 phi0;
  182. Rel1X = tabl;
  183.  
  184. * constructionsion des blocages des ddl X-fem non actifs dans
  185. * les éléments de transition.
  186. Rel1x . 0 = RELA mod1a;
  187. * on crée le ou les materiau et on les assemble
  188. Ey1 = 5.520E+8 '/' 2.627E-3 ;
  189. nu1 = 0.3 ;
  190. rho1= 7800. ;
  191.  
  192. Epsprog0 = (PROG
  193. 0.000E+0 2.627E-3 2.967E-3 3.276E-3
  194. 3.585E-3 5.129E-3 8.221E-3 1.132E-2 1.442E-2
  195. 1.754E-2 3.334E-2 5.006E-2 6.914E-2 9.391E-2
  196. 1.314E-1 1.956E-1 3.134E-1 5.336E-1) ;
  197. Sigprog0 = (PROG
  198. 0.000E+0 5.520E+2 5.530E+2 5.540E+2
  199. 5.550E+2 5.600E+2 5.700E+2 5.800E+2 5.900E+2
  200. 6.000E+2 6.500E+2 7.000E+2 7.500E+2 8.000E+2
  201. 8.500E+2 9.000E+2 9.500E+2 1.000E+3) * 1.E6 ;
  202. Tcurve = EVOL 'MANU' 'Epsilon' Epsprog0 'Sigma' Sigprog0 ;
  203.  
  204. mata = MATE mod1a 'YOUN' Ey1 'NU' nu1 'RHO' rho1 'TRAC' Tcurve;
  205. matb = MATE mod1b 'YOUN' Ey1 'NU' nu1 'RHO' rho1 ;
  206.  
  207. * apres cela on assemble
  208. mod1tot = mod1a et mod1b;
  209. mat1tot = mata et matb ;
  210.  
  211.  
  212. *******************************************************
  213. *** CL et chargement
  214.  
  215. * on bloque les depl de corps rigides
  216. pgoup1 = sbtot POIN 'PROC' (0. hgoup);
  217. pgoup2 = sbtot POIN 'PROC' (0. (-1.*hgoup));
  218. pgouptot = pgoup1 et pgoup2;
  219. cl1x = BLOQ 'UX' (pgouptot);
  220. cl1y = BLOQ 'UY' (pgouptot);
  221.  
  222. cl1tot = cl1x et cl1y;
  223.  
  224. * deplacement impose
  225.  
  226. * evolution
  227. du0 = 0.10E-3 ;
  228. *ufin0 = 0.5E-3 ;
  229. ufin0 = 1.E-3 ;
  230. uval0 = PROG 0. 'PAS' du0 ufin0 ;
  231. tval0 = uval0 * 1.E-2 ;
  232. dtval0 = du0 * 1.E-2 ;
  233. Nmax0 = DIME tval0 ;
  234. uev0 = EVOL 'ROUG' 'MANU' 't' tval0 'u' uval0 ;
  235.  
  236. * chpoint
  237. uchp0 = (MANU 'CHPO' pgoup1 2 'UX' 0. 'UY' 1. 'NATU' 'DIFFUS')
  238. ET (MANU 'CHPO' pgoup2 2 'UX' 0. 'UY' -1. 'NATU' 'DIFFUS');
  239. fchp0 = DEPI cl1tot uchp0;
  240.  
  241. * chargement
  242. uimp1 = CHAR 'DIMP' fchp0 uev0 ;
  243.  
  244. tdess1 = tabl;
  245. tdess1 . 1 = mot 'MARQ PLUS';
  246. si(graph);
  247. dess uev0 tdess1;
  248. trac (vect uchp0 'DEPL' 'VERT') (stot0 et lcrack0);
  249. finsi;
  250.  
  251.  
  252. *******************************************************
  253. *** MISE EN CHARGE AVEC PASAPAS ***
  254.  
  255. * temps de mise en charge
  256. tcalc0 = PROG 0. 'PAS' dtval0 (3.*dtval0);
  257. Ncalc0 = DIME tcalc0;
  258.  
  259. * Initialisation de la table
  260. TAB1 = TABL;
  261. TAB1.'MODELE' = mod1tot;
  262. TAB1.'CARACTERISTIQUES' = mat1tot;
  263. TAB1.'BLOCAGES_MECANIQUES' = cl1tot et(Rel1x . 0) ;
  264. TAB1.'CHARGEMENT' = uimp1;
  265. TAB1.'PRECISION' = 1E-05;
  266. TAB1.'PRECISINTER' = 1E-05;
  267. *TAB1. 'TEMPS0' = 0. ;
  268. *TAB1. 'PROCESSEURS' = 'MONO';
  269. TAB1.'TEMPS_CALCULES' = tcalc0 ;
  270. TAB1.'TEMPS_SAUVES' = tcalc0 ;
  271.  
  272. * Resolution non-lineaire ******
  273. PASAPAS TAB1;
  274.  
  275. * Mise a Jour de la table TXFEM (a terme devra etre inclus dans PASAPAS)
  276. i = 0 ;
  277. repe BOUX0 (Ncalc0 - 1);
  278. i = i + 1;
  279. TXFEM . i = TXFEM . (i - 1);
  280. Che1X . i = Che1X . (i - 1);
  281. fin BOUX0;
  282.  
  283.  
  284. * calcul de l integrale J *****
  285.  
  286. * * J local
  287. * si (fllong);
  288. * SUPTAB = TABL ;
  289. * SUPTAB.'OBJECTIF' = MOT 'J';
  290. * SUPTAB.'PSI' = psi0;
  291. * SUPTAB.'PHI' = phi0;
  292. * SUPTAB.'FRONT_FISSURE' = ptip1 ;
  293. * SUPTAB.'SOLUTION_PASAPAS' = TAB1;
  294. * SUPTAB.'COUCHE' = 2;
  295. * G_THETA SUPTAB;
  296. * si(graph);
  297. * q7 = (SUPTAB . 'CHAMP_THET1') ;
  298. * vq7 = VECT q7 AZUR ;
  299. * trac vq7 (stot0 et lcrack0);
  300. * fins;
  301. * fins;
  302.  
  303. * calcul de l integrale J global
  304. JTAB = TABL;
  305. JTAB.'OBJECTIF' = MOT 'J';
  306. JTAB.'PSI' = psi0;
  307. JTAB.'PHI' = phi0;
  308. JTAB.'FRONT_FISSURE' = ptip1 ;
  309. JTAB.'SOLUTION_PASAPAS' = TAB1;
  310. *definition dun champ_theta perso pour calcul de j global
  311. sared = ELEM satot 'APPUYE' 'LARGEMEMENT' (CONT satot);
  312. sared = (satot DIFF sared) coul vert;
  313. monch1 = MANU 'CHPO' sared 'UX' 1. 'UY' 0.;
  314. monvec1 = vect monch1 vert;
  315. si(graph);
  316. trac monvec1 (stot0 et lcrack0);
  317. * trac (exco 'UX' monch1) (stot0 et lcrack0);
  318. fins;
  319. JTAB.'CHAMP_THETA' = monch1;
  320. G_THETA JTAB;
  321.  
  322.  
  323. *******************************************************
  324. *** PROPAGATION élémentaire de fissure ***
  325. *rem: + tard, prevoir procedure surtout pour le 3d
  326. NBPROPA = 2;
  327. da1 = 1.5 * dx1;
  328.  
  329. repe BPROPA NBPROPA;
  330.  
  331. i = i + 1;
  332.  
  333. *** Maillage de la fissure ***
  334. ptip1 = ptip1 plus (da1 0.);
  335. lcrack1 = (lcrack0 droi ptip1) coul 'ROUG';
  336. TXFEM . i = tabl;
  337. TXFEM . i . 'POINTE1' = ptip1;
  338. TXFEM . i . 'FISSURE' = lcrack1;
  339.  
  340. *** Actualisations ***
  341. * des level set
  342. psi1 phi1 = PSIPHI satot lcrack1 'DEUX' ptip1 ;
  343. si(graph);
  344. *opti isov lign;
  345. trac (stot0 et lcrack1);
  346. TRAC phi1 (stot0 et lcrack1) isolv7 ;
  347. TRAC psi1 (stot0 et lcrack1) isolv7;
  348. *opti isov surf;
  349. finsi;
  350. * du modele, de la rigidite,... (inutile pour le materiau)
  351. Che1X . i = TRIE mod1a psi1 phi1;
  352.  
  353. * des blocages des ddl X-fem non actifs dans
  354. * les éléments de transition.
  355. Rel1X . i = RELA mod1a;
  356. mod1tot = mod1a et mod1b;
  357. TAB1.'MODELE' = mod1tot;
  358. TAB1.'BLOCAGES_MECANIQUES' = cl1tot et (Rel1x . i) ;
  359.  
  360. *** resolution non-lineaire PASaPAS ***
  361. tlast1 = extr TAB1.'TEMPS_CALCULES' (dime TAB1.'TEMPS_CALCULES');
  362. tcalc1 = TAB1.'TEMPS_CALCULES' et (PROG (tlast1 + dtval0));
  363. Ncalc1 = dime tcalc1;
  364.  
  365. TAB1.'TEMPS_CALCULES' = tcalc1 ;
  366. TAB1.'TEMPS_SAUVES' = tcalc1 ;
  367.  
  368. PASAPAS TAB1;
  369.  
  370. *** calcul de l integrale J global (le contour ne change pas) ***
  371. JTAB.'PSI' = psi1;
  372. JTAB.'PHI' = phi1;
  373. JTAB.'FRONT_FISSURE' = ptip1 ;
  374. *JTAB.'CHAMP_THETA' = JTAB.'CHAMP_THET1';
  375. JTAB.'CHAMP_THETA' = monch1;
  376. * on utilise la reprise car le contour ne change pas
  377. G_THETA JTAB;
  378.  
  379. * si (fllong);
  380. * *** calcul de l integrale J local, de K1, de K2 ***
  381. * * a chaque propa il faut une nouvelle table, car le contour change...
  382. * SUPTAB = TABL ;
  383. * SUPTAB.'OBJECTIF' = MOT 'J';
  384. * SUPTAB.'PSI' = psi1;
  385. * SUPTAB.'PHI' = phi1;
  386. * SUPTAB.'FRONT_FISSURE' = ptip1 ;
  387. * SUPTAB.'SOLUTION_PASAPAS' = TAB1;
  388. * SUPTAB.'COUCHE' = 2;
  389. *
  390. * G_THETA SUPTAB;
  391. * q7 = (SUPTAB . 'CHAMP_THET1') ;
  392. *
  393. * si(graph);
  394. * vq7 = VECT q7 AZUR ;
  395. * trac vq7 (stot0 et lcrack1);
  396. * fins;
  397. * fins;
  398.  
  399. * i etant l indice de la table de PASAPAS TAB1,
  400. * il faut l'incrementer avant et apres chaque appel a pasapas
  401. i = i + 1;
  402. TXFEM . i = TXFEM . (i - 1);
  403. Che1X . i = Che1X . (i - 1);
  404.  
  405. fin BPROPA;
  406.  
  407.  
  408.  
  409. ******************************************************
  410. *** POST TRAITEMENT ***
  411.  
  412. * courbe J global - t (le contour ne change pas) ***
  413. si(graph);
  414. dess JTAB . EVOLUTION_RESULTATS 'TITR' 'Jglobal - t';
  415. finsi;
  416.  
  417. * courbe force ouverture ****************************
  418. cod1 = prog;
  419. for1 = prog;
  420. ipost = -1;
  421. Npost = i;
  422. repe BPOST1 (Npost + 1);
  423. ipost = ipost + 1;
  424. u1i = TAB1 . 'DEPLACEMENTS' . ipost;
  425. cod1i = extr u1i 'AY' pa1;
  426. cod1 = cod1 et (prog cod1i);
  427. frea1i = TAB1 . 'REACTIONS' . ipost;
  428. for1i = extr frea1i 'FY' pgoup1;
  429. for1 = for1 et (prog for1i);
  430. fin BPOST1;
  431. evfcod1 = EVOL 'VERT' 'MANU' 'ouverture' cod1 'force' for1 ;
  432. si(graph);
  433. dess evfcod1 tdess1 'TITR' 'Force - Ouverture';
  434. finsi;
  435.  
  436. * quelques tracés ****************************
  437. u1i = TAB1 . 'DEPLACEMENTS' . i;
  438. u1phy = XFEM 'RECO' u1i mod1tot ;
  439. var1i = TAB1 . 'VARIABLES_INTERNES' . i;
  440. sig1i = TAB1 . 'CONTRAINTES' . i;
  441. def1i = ELAS mod1tot sig1i mat1tot;
  442. si(graph);
  443. TRAC var1i mod1tot (DEFO u1phy stot0 20.) 'TITR' 'EPSE';
  444. TRAC (exco EPYY def1i) mod1tot (DEFO u1phy stot0 20.) 'TITR' 'EPYY';
  445. finsi;
  446.  
  447.  
  448. *
  449. *opti donn 5 ;
  450. fin;
  451.  
  452.  
  453.  
  454.  
  455.  
  456.  
  457.  
  458.  
  459.  
  460.  
  461.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales