Télécharger weib.dgibi

Retour à la liste

Numérotation des lignes :

  1. * fichier : weib.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4. opti echo 0;
  5. opti epsilon lineaire;
  6. *--------------------------------------------------------------------
  7. *
  8. * TRAVE CARICATA PER FLESSIONE A QUATTRO PUNTI ; DETERMINAZIONE
  9. * DELLA PROBABILITA' DI ROTTURA SECONDO LA STATISTICA DI WEIBULL:
  10. *
  11. *--------------------------------------------------------------------
  12. *
  13. ************** CARATTERISTICHE GEOMETRICHE DELLA TRAVE ****************
  14. *
  15. TITRE 'TRAVE CARICATA PER FLESSIONE A QUATTRO PUNTI';
  16. OPTION DIME 2 ELEM QUA8;
  17. L1= 4.5e1 ; comm 'lunghezza trave' ;
  18. D1= 4.0e1 ; comm 'distanza tra gli appoggi' ;
  19. D2= 2.0e1 ; comm 'distanza tra i carichi' ;
  20. H = 3.0 ; comm 'altezza trave' ;
  21. S = 4.0 ; comm 'spessore trave' ;
  22. *
  23. ******* CARICO PER UNITA' DI SPESSORE ED AGENTE SU META' TRAVE ********
  24. *
  25. PP1= -1.05E+2 ;
  26. *
  27. ********************* CARATTERISTICHE DEL MATERIALE *******************
  28. *
  29. YO1= 3.0e+5 ;
  30. NU1= .23 ;
  31. *
  32. ****** VALORI DEL MODULO DI WEIBULL E DELLA SIGMA-ZERO ****************
  33. ****** DETERMINATI A PARTIRE DA UN SET DI PROVE SPERIMENTALI **********
  34. *
  35. * dati sperimentali
  36. lis1 = prog
  37. 427.9555 852.2001 800.0194 445.7708 740.6716 827.7161 827.3882 590.6464
  38. 750.3228 746.3323 446.1818 875.4909 630.5025 604.9180 648.6437 832.6529
  39. 648.8641 785.7595 754.6536 697.0067 904.4279 807.3849 717.4614 690.0081
  40. 600.4105 742.2141 893.2710 795.1147 697.7165 798.2668 ;
  41. *
  42. * determinazione dei parametri statistici
  43. MESS '========================================';
  44. MESS '== WEIBULL STATISTICS ==';
  45. MESS '========================================';
  46. EW1 SU1 = weip lis1 40. 20. (3. * 4.) ;
  47. MESS '========================================';
  48. MESS ' Weibull modulus : ' EW1 ;
  49. MESS ' Sigma zero : ' SU1 ;
  50. MESS '========================================';
  51. *
  52. ******* VALORI DELLA TENSIONE DI RIFER. E DEL FATTORE D'INTEGRAZIONE **
  53. SMR1= 0. ; comm 'nulla per materiali ceramici' ;
  54. V0 = 2.0 * S ; comm '1 condizione di simmetria + spessore' ;
  55. ***********************************************************************
  56. A0= 0. 0.;
  57. A1= ((L1-D1)/2.) 0. ;
  58. A2= (L1/2.) 0. ;
  59. A3= ((L1-D2)/2.) 0. ;
  60. p3= ((L1-D2)/2.) h ;
  61. V1= 0. H ;
  62. P2= (L1/2.) H ;
  63. AT1= D 5 A0 A1 D 40 A2;
  64. S1=AT1 TRAN 6 V1 ;
  65. CT2= COTE 2 S1 ;
  66. P3= S1 POINT PROC P3 ;
  67. TASS S1;
  68. *
  69. ****************************** FORMULAZIONE ***************************
  70. *
  71. OPTION MODE PLAN CONT ;
  72. OBJ= MODE S1 MECANIQUE ELASTIQUE QUA8;
  73. *
  74. ******************************** MATERIALE ****************************
  75. *
  76. MAT1=MATE OBJ YOUN YO1 NU NU1 ;
  77. *
  78. **************************** RIGIDEZZA E VINCOLI **********************
  79. *
  80. ENC1= BLOQUE UY A1 ;
  81. ENC2= SYMT DEPL A2 P2 S1 0.0001;
  82. RIG1= RIGI MAT1 OBJ;
  83. RIGT =RIG1 ET ENC1 ET ENC2;
  84. *
  85. ********************************* CARICHI *****************************
  86. *
  87. FP3= FORC FY PP1 P3 ;
  88. *
  89. ******************************* RISOLUZIONE ***************************
  90. *
  91. DE1 =RESOU RIGT FP3 ;
  92. *
  93. ***************************** CAMPO DI TENSIONI ***********************
  94. *
  95. SE1 = SIGMA DE1 OBJ MAT1 ;
  96. *
  97. *********** STATEMENT DI RICHIAMO DELLA PROCEDURA 'WEIBULL' **********
  98. *
  99. PROT1 CHEL2 = WEIBULL SE1 OBJ V0 SMR1 SU1 EW1;
  100. *
  101. PROS = 1. - PROT1;
  102. MESS '========================================';
  103. MESS 'PROBAB. DI SOPRAVVIVENZA:' PROS ;
  104. MESS 'PROBAB. DI ROTTURA :' PROT1 ;
  105. MESS '========================================';
  106. MESS ' ';
  107. *
  108. pr2 = pros * 100. ;
  109. ERR1 = ABS (100 * ( 60.20 - pr2 ) / 60.20 ) ;
  110. *
  111. MESS '========================================';
  112. MESS '== SURVIVAL PROBABILITY ==';
  113. MESS '========================================';
  114. MESS ' SOLUTION ANALYTIQUE 60.20 % ';
  115. MESS ' SOLUTION CALCULEE 'pr2 ' % ';
  116. MESS ' ERREUR DE 'ERR1 ' % ';
  117. MESS '========================================';
  118. *
  119. SI (ERR1 < 5 );
  120. ERRE 0;
  121. SINON;
  122. ERRE 5;
  123. FINSI;
  124. *
  125. FIN;
  126.  
  127.  
  128.  
  129.  
  130.  
  131.  
  132.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales