Télécharger la plaquette Cast3M


fr en

Télécharger weib.dgibi

Retour à la liste

Numérotation des lignes : 

  1. * fichier :  weib.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4. opti echo 0;
  5. *--------------------------------------------------------------------           
  6. *                                                                               
  7. *  TRAVE CARICATA PER FLESSIONE A QUATTRO PUNTI ; DETERMINAZIONE                
  8. *  DELLA PROBABILITA' DI ROTTURA SECONDO LA STATISTICA DI WEIBULL:              
  9. *                                                                               
  10. *--------------------------------------------------------------------           
  11. *                                                                               
  12. ************** CARATTERISTICHE GEOMETRICHE DELLA TRAVE ****************         
  13. *                                                                               
  14. TITRE  'TRAVE CARICATA PER FLESSIONE A QUATTRO PUNTI';                          
  15. OPTION  DIME 2 ELEM QUA8;                                                
  16. L1= 4.5e1   ; comm 'lunghezza trave' ;                                                                   
  17. D1= 4.0e1   ; comm 'distanza tra gli appoggi' ;                                                                  
  18. D2= 2.0e1   ; comm 'distanza tra i carichi' ;                                                                  
  19. H = 3.0     ; comm 'altezza trave' ;                                                                 
  20. S = 4.0     ; comm 'spessore trave' ;                                                                  
  21. *                                                                               
  22. ******* CARICO PER UNITA' DI SPESSORE ED AGENTE SU META' TRAVE ********         
  23. *                                                                               
  24. PP1= -1.05E+2 ;                                                                 
  25. *                                                                               
  26. ********************* CARATTERISTICHE DEL MATERIALE *******************         
  27. *                                                                               
  28. YO1= 3.0e+5  ;                                                                  
  29. NU1=  .23    ;                                                                  
  30. *                                                                               
  31. ****** VALORI DEL MODULO DI WEIBULL E DELLA SIGMA-ZERO **************** 
  32. ****** DETERMINATI A PARTIRE DA UN SET DI PROVE SPERIMENTALI **********
  33. *
  34. * dati sperimentali
  35.  lis1 = prog
  36.  427.9555 852.2001 800.0194 445.7708 740.6716 827.7161 827.3882 590.6464
  37.  750.3228 746.3323 446.1818 875.4909 630.5025 604.9180 648.6437 832.6529
  38.  648.8641 785.7595 754.6536 697.0067 904.4279 807.3849 717.4614 690.0081
  39.  600.4105 742.2141 893.2710 795.1147 697.7165 798.2668 ;
  40. *
  41. * determinazione dei parametri statistici 
  42. MESS '========================================'; 
  43. MESS '==       WEIBULL STATISTICS           =='; 
  44. MESS '========================================'; 
  45.  EW1 SU1 = weip lis1 40. 20. (3. * 4.) ;
  46. MESS '========================================'; 
  47. MESS ' Weibull modulus : ' EW1 ;
  48. MESS ' Sigma zero      : ' SU1 ;
  49. MESS '========================================'; 
  50. *                                                                               
  51. ******* VALORI DELLA TENSIONE DI RIFER. E DEL FATTORE D'INTEGRAZIONE ** 
  52. SMR1= 0.      ; comm 'nulla per materiali ceramici' ;                                                                       
  53. V0  = 2.0 * S ; comm '1 condizione di simmetria + spessore' ;
  54. ***********************************************************************
  55. A0= 0.  0.;                                                                     
  56. A1= ((L1-D1)/2.) 0. ;                                                           
  57. A2= (L1/2.)      0. ;                                                           
  58. A3= ((L1-D2)/2.) 0. ;                                                           
  59. p3= ((L1-D2)/2.) h ;                                                            
  60. V1=  0.          H  ;                                                           
  61. P2= (L1/2.)      H  ;                                                           
  62. AT1= D 5 A0 A1 D 40 A2;                                                         
  63. S1=AT1 TRAN 6 V1 ;                                                              
  64. CT2= COTE 2 S1   ;                                                              
  65. P3= S1 POINT PROC P3 ;                                                          
  66. TASS S1;                                                                        
  67. *                                                                               
  68. ****************************** FORMULAZIONE ***************************         
  69. *                                                                               
  70. OPTION MODE PLAN CONT ;                                                         
  71. OBJ= MODE  S1 MECANIQUE ELASTIQUE QUA8;                                         
  72. *                                                                               
  73. ******************************** MATERIALE ****************************         
  74. *                                                                               
  75. MAT1=MATE  OBJ  YOUN YO1  NU NU1  ;                                             
  76. *                                                                               
  77. **************************** RIGIDEZZA E VINCOLI **********************         
  78. *                                                                               
  79. ENC1= BLOQUE UY A1 ;                                                            
  80. ENC2= SYMT DEPL A2 P2  S1 0.0001;                                               
  81. RIG1= RIGI MAT1 OBJ;                                                            
  82. RIGT =RIG1 ET ENC1 ET ENC2;                                                     
  83. *                                                                               
  84. ********************************* CARICHI *****************************         
  85. *                                                                               
  86. FP3= FORC FY PP1 P3 ;                                                           
  87. *                                                                               
  88. ******************************* RISOLUZIONE ***************************         
  89. *                                                                               
  90. DE1 =RESOU RIGT FP3 ;                                                           
  91. *                                                                               
  92. ***************************** CAMPO DI TENSIONI ***********************         
  93. *                                                                               
  94. SE1 = SIGMA DE1 OBJ MAT1 ; 
  95. *                                        
  96. *********** STATEMENT DI RICHIAMO DELLA PROCEDURA 'WEIBULL' **********         
  97. *                                                                
  98. PROT1 CHEL2 = WEIBULL SE1 OBJ V0 SMR1 SU1 EW1;                
  99. *                                                           
  100. PROS = 1. - PROT1;                                          
  101. MESS '========================================';                 
  102. MESS 'PROBAB. DI SOPRAVVIVENZA:' PROS  ; 
  103. MESS 'PROBAB. DI ROTTURA      :' PROT1 ;
  104. MESS '========================================'; 
  105. MESS ' ';            
  106. *
  107. pr2  = pros * 100. ;
  108. ERR1 = ABS (100 * ( 60.20 - pr2 ) / 60.20 ) ;
  109. *
  110. MESS '========================================'; 
  111. MESS '==       SURVIVAL PROBABILITY         =='; 
  112. MESS '========================================'; 
  113. MESS ' SOLUTION ANALYTIQUE     60.20           %  ';
  114. MESS ' SOLUTION CALCULEE     'pr2 '  %  ';
  115. MESS ' ERREUR DE             'ERR1 '  %  ';
  116. MESS '========================================'; 
  117. *
  118. SI (ERR1 < 5 );
  119.   ERRE 0;
  120. SINON;
  121.   ERRE 5;
  122. FINSI;
  123. *                                                                               
  124. FIN;
  125.  
  126.  
  127.  
  128.  
  129.  
  130.  
  131.  
  132.  
  133.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales