Télécharger vibr5.dgibi

Retour à la liste

Numérotation des lignes :

  1. * fichier : vibr5.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4.  
  5. *******************************************************
  6. * Test vibr5.dgibi: jeux de données *
  7. * --------------------------------- *
  8. *******************************************************
  9.  
  10. * SI GRAPH = N PAS DE GRAPHIQUE AFFICHE
  11. * SINON SI GRAPH DIFFERENT DE N TOUS
  12. * LES GRAPHIQUES SONT AFFICHES
  13.  
  14. GRAPH = 'N' ;
  15.  
  16. SAUT PAGE;
  17. SI (NEG GRAPH 'N') ;
  18. OPTI ECHO 1 ;
  19. OPTI TRAC PSC ;
  20. SINO ;
  21. OPTI ECHO 0 ;
  22. FINSI ;
  23.  
  24. SAUT PAGE;
  25. *********************************************************************
  26. * VIBR5
  27. *********************************************************************
  28. * *
  29. * Mots-clés : Vibrations, calcul modal, axisymetrique *
  30. * *
  31. * TEST VIBR5 *
  32. * *
  33. * CAS TEST DU 91/06/13 PROVENANCE : TEST *
  34. * *
  35. * CYLINDRE LIBRE : VIBRATION AXISYMETRIQUE *
  36. * *
  37. * Test NAFEMS numero FV41 *
  38. * *
  39. * On cherche les frequences et modes propres d'un cylindre *
  40. * libre. Le diametre interieur du cylindre est de 1.8 m, son *
  41. * diametre exterieur est de 2.2 m et sa hauteur est de 10.0 m *
  42. * *
  43. * Les valeurs trouvees sont ensuite comparees aux valeurs *
  44. * theoriques. *
  45. * *
  46. *********************************************************************
  47. OPTI MODE AXIS;
  48. OPTI ELEM QUA8;
  49. OPTI EPSI LINEAIRE;
  50. *================================================================*
  51. * geometries et maillages *
  52. *================================================================*
  53. *
  54. * Dimensions en metres
  55. *
  56. * Points
  57. *
  58. P0 = 0. 0.;
  59. P1 = 1.8 0.;
  60. P2 = 2.2 0.;
  61. P3 = 2.2 10.;
  62. P4 = 1.8 10.;
  63. *
  64. * Droites
  65. *
  66. N1 = 1; N2 = 8;
  67. D12 = P1 DROI N1 P2;
  68. D23 = P2 DROI N2 P3;
  69. D34 = P3 DROI N1 P4;
  70. D41 = P4 DROI N2 P1;
  71.  
  72. *
  73. SUR1 = DALL D12 D23 D34 D41 PLAN;
  74. *
  75. * Trace facultatif du maillage
  76. *
  77. SI (NEG GRAPH 'N');
  78. TITR ' FV32 : MAILLAGE';
  79. TRAC 'QUAL' (SUR1 ET P0);
  80. FINSI;
  81. *
  82. *================================================================*
  83. * MODE - materiau - rigidite - masse *
  84. *================================================================*
  85. *
  86. MOD1 = MODE SUR1 MECANIQUE QUA8;
  87.  
  88. MAT1 = MATE MOD1 YOUN 2.E11 NU 0.3 RHO 8.E3;
  89. RIG1 = RIGI MOD1 MAT1;
  90. MAS1 = MASS MOD1 MAT1;
  91. *
  92. *==============================================================*
  93. * conditions aux limites *
  94. *==============================================================*
  95. *
  96. * Pas de conditions autre que la symetrie axiale.
  97. *
  98. *==============================================================*
  99. * calcul des frequences propres *
  100. * et *
  101. * extraction des resultats *
  102. *==============================================================*
  103. *
  104. * Utilisation de l'operateur VIBR. (option PROC)
  105. *
  106. FRE1 = TABLE;
  107. FRE1.1 = 0. ;
  108. FRE1.2 = 243.53;
  109. FRE1.3 = 377.41;
  110. FRE1.4 = 394.11;
  111. FRE1.5 = 397.72;
  112. FRE1.6 = 405.28;
  113.  
  114. RESUL = VIBR PROC (prog 50) (lect 6) RIG1 MAS1 'IMPR';
  115. *
  116. *==============================================================*
  117. * affichache des resultats *
  118. *==============================================================*
  119. *
  120. MESS ' RESULTATS ';
  121. MESS ' --------- ';
  122. *
  123. FRE2 = TABLE; MOD = TABLE; DEF = TABLE;ERG = TABLE;
  124. *
  125. I = 0;
  126. REPETER BLOC1 6;
  127. I = I + 1;
  128. FRE2.I = TIRE RESUL FREQ RANG I;
  129. MESS ' MODE ' (I + 1);
  130. MESS ' ----------';
  131. MESS ' Frequence theorique :' FRE1.I 'Hz';
  132. MESS ' Frequence calculee :' FRE2.I 'Hz';
  133. SI (i > 1) ; ERG.I = 100 * (ABS ((FRE1.I - FRE2.I) / FRE1.I));
  134. MESS ' Soit un ecart de : ' ERG.I '%';
  135. FINSI ;
  136. *
  137. * Extraction et trace des modes propres et calcul des deformees.
  138. * (facultatif)
  139. *
  140. SI (NEG GRAPH 'N');
  141. MOD.I = TIRE RESUL DEPL RANG I;
  142. DEF0 = DEFO SUR1 MOD.I 0.;
  143. DEF.I = DEFO SUR1 MOD.I BLEU;
  144. TRAC (DEF.I ET DEF0);
  145. FINSI;
  146. FIN BLOC1;
  147. *
  148. *==============================================================*
  149. * code fonctionnement *
  150. *==============================================================*
  151. *
  152. ERGMAX = MAXI (PROG ERG.6 ERG.2 ERG.3 ERG.4 ERG.5);
  153.  
  154. SI (ERGMAX <EG 0.5);
  155. ERRE 0;
  156. SINON;
  157. ERRE 5;
  158. FINSI;
  159.  
  160. TEMPS;
  161.  
  162. FIN;
  163.  
  164.  
  165.  
  166.  
  167.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales