Télécharger vibr4.dgibi

Retour à la liste

Numérotation des lignes :

  1. * fichier : vibr4.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4.  
  5. *******************************************************
  6. * Test vibr4.dgibi: jeux de données *
  7. * --------------------------------- *
  8. *******************************************************
  9.  
  10. * SI GRAPH = N PAS DE GRAPHIQUE AFFICHE
  11. * SINON SI GRAPH DIFFERENT DE N TOUS
  12. * LES GRAPHIQUES SONT AFFICHES
  13.  
  14. GRAPH = 'N' ;
  15.  
  16. SAUT PAGE;
  17. SI (NEG GRAPH 'N') ;
  18. OPTI TRAC PSC ;
  19. FINSI ;
  20.  
  21. SAUT PAGE;
  22. ****************************************************************
  23. * VIBR4
  24. ****************************************************************
  25. * *
  26. * Mots-clés : Vibrations, calcul modal, 3D *
  27. * *
  28. * TEST VIBR4 *
  29. * *
  30. * CAS TEST DU 91/06/13 PROVENANCE : TEST *
  31. * *
  32. * PLAQUE EPAISSE EN FORME DE LOSANGE *
  33. * *
  34. * Test NAFEMS numero fv22 *
  35. * *
  36. * On cherche les frequences et modes propres d'une plaque *
  37. * en forme de losange d'un metre d'epaisseur. *
  38. * *
  39. * Les conditions aux limites imposees (voir dessin)sont *
  40. * les suivantes : *
  41. * - ux = uy = rz = 0 pour tout les noeuds, *
  42. * - uz' = rx' = ry = 0 pour les 4 cotes. *
  43. * *
  44. * dessin *
  45. * ------ *
  46. * *
  47. * axe y' *
  48. * | *
  49. * | *
  50. * | axe x' *
  51. * P4 -----> *
  52. * ----------------- P3 *
  53. * axe y / / *
  54. * | / / *
  55. * | / / *
  56. * | / / *
  57. * | / / *
  58. * | / / *
  59. * ----------------- ---> axe x *
  60. * P1 P2 *
  61. * *
  62. * |_____10.m______| *
  63. * *
  64. * *
  65. * *
  66. ****************************************************************
  67. OPTI ELEM QUA8;
  68. OPTI EPSI LINEAIRE;
  69. *
  70. *--------------------------------------------------------------*
  71. * geometrie - maillage *
  72. *--------------------------------------------------------------*
  73. *
  74. ALPHA = 45.; COS = COS ALPHA; SIN = SIN ALPHA;
  75. *
  76. P1 = 0. 0. 0.;
  77. P2 = 10. 0. 0.;
  78. P3 = (10. * (1 + COS)) (10. * SIN) 0.;
  79. P4 = (10. * COS) (10. * SIN) 0.;
  80. *
  81. OEIL = 7. -100. 70.;
  82. *
  83. D12 = P1 DROI 6 P2;
  84. D23 = P2 DROI 6 P3;
  85. D34 = P3 DROI 6 P4;
  86. D41 = P4 DROI 6 P1;
  87. *
  88. SUR1 = DALL D12 D23 D34 D41 PLAN;
  89. *
  90. SI (NEG GRAPH 'N');
  91. TRAC OEIL 'QUAL' SUR1;
  92. FINSI;
  93. *
  94. *--------------------------------------------------------------*
  95. * MODE - materiau - caracteristique *
  96. * rigidite - masse *
  97. *--------------------------------------------------------------*
  98. *
  99. MOD1 = MODE SUR1 MECANIQUE COQ8;
  100. MAT1 = MATE MOD1 YOUN 2.E11 NU 0.3 RHO 8.E3;
  101. CAR1 = CARA MOD1 EPAI 1.;
  102. MAT1 = MAT1 ET CAR1;
  103. RIG1 = RIGI MOD1 MAT1 ;
  104. MAS1 = MASS MOD1 MAT1;
  105. *
  106. *--------------------------------------------------------------*
  107. * conditions aux limites *
  108. *--------------------------------------------------------------*
  109. * - ux = uy = rz = 0 pour tout les noeuds,
  110. * - uz' = rx' = ry' = 0 pour les 4 cotes.
  111.  
  112. si (faux);
  113.  
  114. CL1 = BLOQ UX SUR1;
  115. CL2 = BLOQ UY SUR1;
  116. CL3 = BLOQ RZ SUR1;
  117.  
  118. CL4 = BLOQ UZ (D12 ET D34);
  119. CL5 = BLOQ RX (D12 ET D34);
  120. CL6 = BLOQ RY (D12 ET D34);
  121.  
  122. DIR1 = COS SIN 0.; DIR2 = (-1 * SIN) COS 0.;
  123. CL7 = BLOQ UZ (D23 ET D41);
  124. CL8 = BLOQ ROTA DIRECTION DIR1 (D23 ET D41);
  125. CL9 = BLOQ ROTA DIRECTION DIR2 (D23 ET D41);
  126.  
  127. RIG1 = RIG1 ET CL1 ET CL2 ET CL3 ET CL4 ET CL5
  128. ET CL6 ET CL7 ET CL8 ET CL9;
  129.  
  130. sinon;
  131. * CL1 = BLOQ 'UX' 'UY' 'RZ' SUR1;
  132. CL1 = BLOQ 'UX' 'UY' SUR1;
  133. CL2 = BLOQ 'UZ' 'RX' 'RY' (D12 ET D23 ET D34 ET D41);
  134.  
  135. RIG1 = RIG1 ET CL1 ET CL2 ;
  136.  
  137. finsi;
  138. *
  139. *--------------------------------------------------------------*
  140. * calcul des frequences propres *
  141. *--------------------------------------------------------------*
  142. *
  143. * table des frequence propres theoriques
  144. FRE1 = TABLE;
  145. FRE1.1 = 133.95;
  146. FRE1.2 = 201.41;
  147. FRE1.3 = 265.81;
  148. FRE1.4 = 282.74;
  149. FRE1.5 = 334.45;
  150. FRE1.6 = 386.62;
  151.  
  152. * Utilisation de l'operateur VIBR avec l'option PROCH
  153. * + listreel de 6 valeurs :
  154. * 6 repetitions de la methode de la puissance inverse avec 6 decalage
  155. * spectral
  156. LIST1 = PROG FRE1.1 FRE1.2 FRE1.3 FRE1.4 FRE1.5 FRE1.6;
  157. RESUL2 = VIBR PROC LIST1 RIG1 MAS1;
  158. * RESUL2 = VIBR PROC (prog 100.) (lect 6) RIG1 MAS1;
  159.  
  160. * Utilisation de l'operateur VIBR avec l'option IRAM :
  161. * opti impi 5;
  162. RESUL3 = VIBR IRAM 100. 6 RIG1 MAS1;
  163. * opti impi 0;
  164.  
  165. *
  166. *--------------------------------------------------------------*
  167. * extraction des resultats ... *
  168. *--------------------------------------------------------------*
  169. *
  170. *... via la procedure explorer :
  171. *
  172. * il faut une table BASE_MODALE en entree d'EXPLORER
  173. * (obtenue directement avec: TVIBR3 = VIBR IRAM 100. 6 RIG1 MAS1 'TBAS';
  174. * ou en effectuant la petite transformation ci-dessous:)
  175. TRES3 = TRADUIRE RESUL3;
  176. TVIBR3 = TABL 'BASE_MODALE';
  177. TVIBR3 . 'MODES' = TRES3;
  178. toto = TABL;
  179. toto . 'MAILLAGE' = SUR1;
  180. * * +en interactif
  181. * OPTI TRAC X ;
  182. * EXPLORER TVIBR3 (mots 'TABL' 'DEF0' 'DEFO') toto;
  183. * +en ps
  184. OPTI TRAC PSC ;
  185. EXPLORER TVIBR3 (mots 'TABL' 'DEF0' 'DEFO') toto;
  186. *
  187. *... a la main :
  188. *
  189. FRE3 = TABLE; ERG3 = TABLE;
  190. FRE2 = TABLE; ERG2 = TABLE;
  191. DEP = TABLE; DEF = TABLE;
  192.  
  193. OPTI ECHO 0;
  194. MESS ' RESULTATS ';
  195. MESS ' ----------------------------------------------------------';
  196. MESS ' | Frequence propre en Hz (erreur relative en %) ';
  197. MESS ' Mode | Theorie | VIBR PROCH | VIBR IRAM ';
  198. MESS ' ----------------------------------------------------------';
  199. I = 0;
  200. REPETER BLOC1 6;
  201. I = I + 1;
  202. FRE2.I = TIRE RESUL2 FREQ RANG I;
  203. ERG2.I = 100 * (ABS ((FRE2.I - FRE1.I) / FRE1.I));
  204. FRE3.I = TIRE RESUL3 FREQ RANG I;
  205. ERG3.I = 100 * (ABS ((FRE3.I - FRE1.I) / FRE1.I));
  206. chacha = chai I *5 ' |' FORMAT '(F9.3)' FRE1.I
  207. ' |' FORMAT '(F9.3)' FRE2.I ' (' FORMAT '(F5.3)' ERG2.I '%)'
  208. ' |' FORMAT '(F9.3)' FRE3.I ' (' FORMAT '(F5.3)' ERG3.I '%)';
  209. MESS chacha;
  210. SI (NEG GRAPH 'N');
  211. DEP.I = TIRE RESUL2 DEPL RANG I;
  212. DEPZ = EXCO DEP.I 'UZ';
  213. DEF0 = DEFO SUR1 DEP.I 0. 'NOIR';
  214. DEF.I = DEFO SUR1 DEP.I 1. 'BLEU';
  215. TRAC OEIL (DEF0 ET DEF.I);
  216. TRAC OEIL DEPZ SUR1 (DEFO SUR1 DEP.I 0.5 NOIR);
  217. FINSI;
  218. FIN BLOC1;
  219. MESS ' ----------------------------------------------------------';
  220. OPTI ECHO 1;
  221. *
  222. *
  223. *--------------------------------------------------------------*
  224. * code fonctionnement *
  225. *--------------------------------------------------------------*
  226. *
  227. ERG2MAX = MAXI (PROG ERG2.1 ERG2.2 ERG2.3 ERG2.4 ERG2.5 ERG2.6);
  228. ERG3MAX = MAXI (PROG ERG3.1 ERG3.2 ERG3.3 ERG3.4 ERG3.5 ERG3.6);
  229.  
  230. SI (ERG2MAX > 4.5);
  231. MESS 'ERREUR VIBR OPTION PROCHE';
  232. ERRE 5;
  233. FINSI;
  234. SI (ERG3MAX > 4.5);
  235. MESS 'ERREUR VIBR OPTION IRAM';
  236. ERRE 5;
  237. FINSI;
  238. ERRE 0;
  239.  
  240.  
  241. FIN;
  242.  
  243.  
  244.  
  245.  
  246.  
  247.  
  248.  
  249.  
  250.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales