Télécharger vibr3.dgibi

Retour à la liste

Numérotation des lignes :

  1. * fichier : vibr3.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4. * Test vibr3.dgibi: Jeux de données *
  5. * --------------------------------- *
  6. * *
  7.  
  8. *******************************************************
  9. * Test vibr3.dgibi: jeux de données *
  10. * --------------------------------- *
  11. *******************************************************
  12.  
  13. * SI GRAPH = N PAS DE GRAPHIQUE AFFICHE
  14. * SINON SI GRAPH DIFFERENT DE N TOUS
  15. * LES GRAPHIQUES SONT AFFICHES
  16.  
  17. GRAPH = 'N' ;
  18.  
  19. SAUT PAGE;
  20. SI (NEG GRAPH 'N') ;
  21. OPTI ECHO 1 ;
  22. OPTI TRAC PSC ;
  23. SINO ;
  24. OPTI ECHO 0 ;
  25. FINSI ;
  26.  
  27. SAUT PAGE;
  28. ******************************************************************
  29. * VIBR3
  30. ******************************************************************
  31. * *
  32. * Mots-clés : Vibrations, calcul modal, 2D *
  33. * *
  34. * TEST VIBR3 *
  35. * *
  36. * CAS TEST DU 91/06/13 PROVENANCE : TEST *
  37. * *
  38. * POUTRE DE SECTION VARIABLE : VIBRATION DANS LE PLAN *
  39. * *
  40. * Test NAFEMS numero fv32 *
  41. * *
  42. * La structure est constituee d'une poutre de section *
  43. * variable. Sa longueur est de 10.0 m, sa plus grande largeur *
  44. * est de 5.0 m et sa plus petite largeur est de 1.0 m. *
  45. * *
  46. * On s'interesse aux vibrations dans le plan xOy, c'est-a- *
  47. * dire que le deplacemnt uz de tous les noeuds est nul. On *
  48. * travaille donc en mode plan (dimension 2). *
  49. * *
  50. * La poutre est bloquee le long de l'axe des ordonnees pour *
  51. * les deplacements ux et uy. *
  52. * *
  53. ******************************************************************
  54. OPTI ELEM QUA8;
  55.  
  56. TEMPS;
  57. *
  58. *================================================================*
  59. * geometries et maillages *
  60. *================================================================*
  61. *
  62. * Dimensions en metres
  63. *
  64. * Points
  65. *
  66. P1 = 0. -2.5;
  67. P2 = 0. 2.5;
  68. P3 = 10. 0.5;
  69. P4 = 10. -0.5;
  70. *
  71. * Droites
  72. *
  73. K = 1 ;
  74. N1 = 4 * K; N2 = 8 * K;
  75. *
  76. D12 = P1 DROI N1 P2;
  77. D23 = P2 DROI N2 P3;
  78. D34 = P3 DROI N1 P4;
  79. D41 = P4 DROI N2 P1;
  80. *
  81. SUR1 = DALL D12 D23 D34 D41 PLAN;
  82. *
  83. * Trace facultatif du maillage
  84. *
  85. SI (NEG GRAPH 'N');
  86. TITR ' VIBR3 : MAILLAGE';
  87. TRAC 'QUAL' SUR1;
  88. FINSI;
  89. *
  90. *================================================================*
  91. * modl- materiau - rigidite - masse *
  92. *================================================================*
  93. *
  94. MOD1 = MODE SUR1 MECANIQUE QUA8;
  95. MAT1 = MATE MOD1 YOUN 2.E11 NU 0.3 RHO 8.E3;
  96. RIG1 = RIGI MOD1 MAT1;
  97. MAS1 = MASS MOD1 MAT1;
  98. *
  99. *==============================================================*
  100. * conditions aux limites *
  101. *==============================================================*
  102. *
  103. CLI1 = BLOQ DEPL D12;
  104. RIG1 = RIG1 ET CLI1;
  105. *
  106. *==============================================================*
  107. * calcul des frequences propres *
  108. * et *
  109. * extraction des resultats *
  110. *==============================================================*
  111. *
  112. * Utilisation de l'operateur VIBR.
  113. *
  114. FRE1 = TABLE;
  115. FRE1.1 = 44.623;
  116. FRE1.2 = 130.03;
  117. FRE1.3 = 162.70;
  118. FRE1.4 = 246.05;
  119. FRE1.5 = 379.90;
  120. FRE1.6 = 391.44;
  121. *
  122. RESUL = VIBR INTERVALLE 40 450 BASSE 6 RIG1 MAS1;
  123. *
  124. *==============================================================*
  125. * affichache des resultats *
  126. *==============================================================*
  127. *
  128. MESS ' RESULTATS ';
  129. MESS ' --------- ';
  130. FRE2 = TABLE; MOD = TABLE; DEF = TABLE;ERG = TABLE;
  131. *
  132. I = 0;
  133. REPETER BLOC1 6;
  134. I = I + 1;
  135. FRE2.I = RESUL . MODES . I . FREQUENCE;
  136. ERG.I = 100 * (ABS ((FRE1.I - FRE2.I) / FRE1.I));
  137. MESS ' MODE ' I;
  138. MESS ' ----------';
  139. MESS ' Frequence theorique :' FRE1.I 'Hz';
  140. MESS ' Frequence calculee :' FRE2.I 'Hz';
  141. MESS ' Soit un ecart de :' ERG.I '%';
  142. *
  143. * Extraction et trace des modes propres et calcul des deformees.
  144. * (facultatif)
  145. SI (NEG GRAPH 'N');
  146. MOD.I = RESUL . MODES . I . DEFORMEE_MODALE;
  147. DEF0 = DEFO SUR1 0. MOD.I;
  148. DEF.I = DEFO SUR1 MOD.I BLEU;
  149. TITR 'VIBR3 : MODES PROPRES';
  150. TRAC (DEF0 ET DEF.I);
  151. FINSI;
  152. FIN BLOC1;
  153. *
  154. *==============================================================*
  155. * code fonctionnement *
  156. *==============================================================*
  157. *
  158. ERGMAX = MAXI (PROG ERG.1 ERG.2 ERG.3 ERG.4 ERG.5 ERG.6);
  159.  
  160. SI (ERGMAX <EG 5.5);
  161. ERRE 0;
  162. SINON;
  163. ERRE 5;
  164. FINSI;
  165.  
  166. TEMPS;
  167.  
  168. FIN;
  169.  
  170.  
  171.  
  172.  
  173.  
  174.  
  175.  
  176.  
  177.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales