Télécharger vibr14_fourier.dgibi

Retour à la liste

Numérotation des lignes :

  1. *
  2. ************************************************************************
  3. ************************************************************************
  4. *
  5. * VIBR14_FOURIER
  6. *
  7. * Objectif : Calcul des modes propres d'un tube mince orthotrope
  8. * axisymetrique encastre - encastre
  9. * Elements : coque mince DKT
  10. * Creation : BP, 2017-03-01
  11. * Reference : Intercomparaison avec modele 3D CAST3M (vibr14_3d)
  12. *
  13. ************************************************************************
  14. *
  15. * DIMENSION dans le plan (XOY)
  16. *
  17. * solide
  18. * Y
  19. * Y=L | . . . D __ B
  20. * | | |
  21. * | | |
  22. * | | |
  23. * | | |
  24. * | | |
  25. * | | |
  26. * | | |
  27. * | . . . |__| -----> X
  28. * O C A
  29. * R=Ri R=Re
  30. *
  31. * | |
  32. * <-->
  33. * t
  34. *
  35. * la coque mince est definie sur Rmoy=(Re+Ri)/2
  36. *
  37. *
  38. * ORTHOTROPIE dans le plan (Y,Theta)
  39. *
  40. * Y
  41. * |
  42. * V2 beta |
  43. * \ |
  44. * \ |
  45. * \ |
  46. * \ |
  47. * \ |
  48. * \|
  49. * Z-------------+X
  50. *
  51. ************************************************************************
  52.  
  53. GRAPH = FAUX ;
  54. * GRAPH = VRAI ;
  55.  
  56. ************************************************************************
  57. * OPTIONS ET DONNEES
  58. ************************************************************************
  59.  
  60. * options
  61. typEF = mot 'QUA8';
  62. OPTI DIME 2 MODE FOUR NOHA ELEM typEF EPSI LINEAIRE;
  63. OPTI TRAC PSC POTR HELVETICA_16 EPTR 15;
  64.  
  65.  
  66. * geometrie
  67. L = 0.3048;
  68. t = 0.254E-3;
  69. Re = 0.0762;
  70. Ri = Re - t;
  71. Rmoy = 0.5 * (Ri + Re);
  72.  
  73. * nz et nR = nombre d elements selon Z et R
  74. nz = 20; nR = 1;
  75.  
  76. * materiau
  77. Eyl = 206.E9;
  78. nult = 0.3;
  79. rho1 = 7850.;
  80. Eyt = Eyl / 10.;
  81. Glt = Eyt / (2. * (1. + nult));
  82. Gtt = Glt;
  83. nutt = 0.3;
  84. nutl = nult * Eyt / Eyl;
  85. mess Eyl Eyt Glt Gtt nutt;
  86. beta=30.;
  87.  
  88. * nombre de modes calcules
  89. nmod = 2;
  90.  
  91.  
  92. ************************************************************************
  93. * MAILLAGE
  94. ************************************************************************
  95.  
  96. p0 = 0. 0. ;
  97. vaxe = 0. 1. ;
  98. vx = 1. 0. ;
  99.  
  100. * maillage solide
  101. p1i = Ri 0. ;
  102. p1e = Re 0. ;
  103. p2i = Ri L ;
  104. p2e = Re L ;
  105. d1 = p1i droi nR p1e;
  106. d2 = p2i droi nR p2e;
  107.  
  108. mesh8 = REGL d1 nZ d2 ;
  109.  
  110. * maillage coq2
  111. OPTI ELEM SEG2;
  112. p1 = Rmoy 0.;
  113. p2 = Rmoy L;
  114. mesh2 = p1 droi nZ p2;
  115.  
  116.  
  117. ************************************************************************
  118. * MODELEs
  119. ************************************************************************
  120.  
  121. mod2 = MODE mesh2 'MECANIQUE' 'ELASTIQUE' 'ORTHOTROPE' 'COQ2'
  122. 'CONS' 'couche 1';
  123. mod8 = MODE mesh8 'MECANIQUE' 'ELASTIQUE' 'ORTHOTROPE';
  124.  
  125.  
  126. *=======================================================================
  127. *===> BOUCLE SUR LES HARMONIQUES DE FOURIER
  128. *=======================================================================
  129. nHlect = lect 3 4 5 6 7 8 9 10;
  130. nnH = DIME nHlect;
  131.  
  132. w2vibr = prog;
  133. w8vibr = prog;
  134.  
  135. REPE BnH nnH;
  136.  
  137. nH = extr nHlect &BnH;
  138. MESS ' ';
  139. MESS '______________________________________________';
  140. MESS ' ';
  141. MESS '>>>>>>>>>>>>>>>> nH=' nH '<<<<<<<<<<<<<<<<<<<';
  142. MESS '______________________________________________';
  143. MESS ' ';
  144. OPTI MODE FOUR nH;
  145.  
  146. MESS '==================== \b=' beta '====================';
  147. TITRE (chai '\b =' (enti beta)- n_{H}='nH);
  148.  
  149.  
  150.  
  151. ************************************************************************
  152. * MATERIAUx
  153. ************************************************************************
  154.  
  155. mat2 = MATE mod2 'YG1' Eyl 'YG2' Eyt 'NU12' nult 'G12' Glt
  156. 'RHO' rho1 'EPAI' t
  157. 'DIRE' vaxe 'INCL' beta ;
  158.  
  159. mat8 = MATE mod8 'YG1' Eyt 'YG2' Eyl 'YG3' Eyt
  160. 'NU12' nutl 'NU13' nutt 'NU23' nult
  161. 'G12' Glt 'G13' Gtt 'G23' Glt
  162. 'RHO' rho1 'DIRE' vx 'INCL' 0. beta;
  163.  
  164. * verification graphique de l'orientation des fibres
  165. v2 = chan (VLOC mod2 mat2) 'GRAVITE' mod2;
  166. v8 = chan (VLOC mod8 mat8) 'GRAVITE' mod8;
  167.  
  168. SI GRAPH;
  169. xv2 = 0.1 / nZ;
  170. vv2 = vect v2 xv2 mod2 (mots V1R V1Z V2R V2Z V3R V3Z)
  171. (mots 'BLEU' 'BRON' 'ROUG');
  172. TRAC vv2 mesh2 ;
  173. vv8 = vect v8 xv2 mod8 (mots V1R V1Z V2R V2Z V3R V3Z)
  174. (mots 'BLEU' 'BRON' 'ROUG');
  175. TRAC vv8 mesh8 ;
  176. FINSI;
  177.  
  178.  
  179. ************************************************************************
  180. * MATRICES
  181. ************************************************************************
  182.  
  183. * solide :
  184. cl1 = BLOQ 'DEPL' d1;
  185. cl2y = BLOQ 'UZ' d2;
  186. cl2 = BLOQ 'UR' 'UT' d2;
  187. cl_8 = cl1 et cl2 et cl2y;
  188. K8 = RIGI mod8 mat8;
  189. M8 = MASS mod8 mat8;
  190. Ktot8 = K8 et cl_8;
  191.  
  192. * coque :
  193. cl1 = BLOQ 'DEPL' p1;
  194. cl2y = BLOQ 'UZ' p2;
  195. cl2 = BLOQ 'UR' 'UT' p2;
  196. cl_2 = cl1 et cl2 et cl2y;
  197. K2 = RIGI mod2 mat2;
  198. M2 = MASS mod2 mat2;
  199. Ktot2 = K2 et cl_2;
  200.  
  201.  
  202. ************************************************************************
  203. * ANALYSE MODALE
  204. ************************************************************************
  205.  
  206. TMOD_2 = VIBR 'IRAM' 100. 2 Ktot2 M2 ;
  207. TMOD_8 = VIBR 'IRAM' 100. 2 Ktot8 M8 ;
  208.  
  209. * stockage
  210. w2vibr = w2vibr et (TMOD_2 . 'MODES' . 1 . 'FREQUENCE');
  211. w8vibr = w8vibr et (TMOD_8 . 'MODES' . 1 . 'FREQUENCE');
  212.  
  213.  
  214. FIN BnH;
  215. *=======================================================================
  216.  
  217.  
  218.  
  219. ************************************************************************
  220. * TEST DE BON FONCTIONNEMENT
  221. ************************************************************************
  222. * REM : On teste que les harmoniques de Fourier sont 6, 7, 5 et 8.
  223. nHref = lect 6 7 5 8;
  224.  
  225. w_2 nHjj_2 = ORDO w2vibr nHlect;
  226. list nHjj_2;
  227. list w_2;
  228.  
  229. w_8 nHjj_8 = ORDO w8vibr nHlect;
  230. list nHjj_8;
  231. list w_8;
  232.  
  233. * on ne teste que les 4 premiers modes
  234. nHdiff_2 = (extr nHjj_2 (lect 1 2 3 4)) - nHref;
  235. nHdiff_8 = (extr nHjj_8 (lect 1 2 3 4)) - nHref;
  236.  
  237. SI ( ((MAXI nHdiff_2 'ABS') >EG 1)
  238. OU ((MAXI nHdiff_8 'ABS') >EG 1) );
  239. ERRE 5;
  240. SINON;
  241. ERRE 0;
  242. FINSI;
  243.  
  244. FIN ;
  245.  
  246.  
  247.  
  248.  
  249.  
  250.  
  251.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales