Télécharger vibr11.dgibi

Retour à la liste

Numérotation des lignes :

  1. *
  2. ************************************************************************
  3. ************************************************************************
  4. *
  5. * VIBR11
  6. *
  7. * Objectif : Calcul des modes propres d'un tube mince isotrope
  8. * axisymetrique encastre - encastre
  9. * Elements : solide-coque SHB8 et coque mince DKT
  10. * Creation : BP, 2017-02-20
  11. * Reference : Cas test SDLA 01/89, Société Française des Mécaniciens,
  12. * Guide de validation des progiciels de calcul des
  13. * structures, AFNOR ed., 1990.
  14. *
  15. ************************************************************************
  16. *
  17. * dimension dans le plan (XOY)
  18. *
  19. * solide-coque
  20. * Y
  21. * Y=L | . . . D __ B
  22. * | | |
  23. * | | |
  24. * | | |
  25. * | | |
  26. * | | |
  27. * | | |
  28. * | | |
  29. * | . . . |__| -----> X
  30. * O C A
  31. * R=Ri R=Re
  32. *
  33. * | |
  34. * <-->
  35. * t
  36. *
  37. * la coque mince est definie sur Rmoy=(Re+Ri)/2
  38. *
  39. ************************************************************************
  40.  
  41. GRAPH = FAUX ;
  42.  
  43. ************************************************************************
  44. * OPTIONS ET DONNEES
  45. ************************************************************************
  46.  
  47. * options
  48. OPTI DIME 3 MODE TRID ELEM CUB8 EPSI LINEAIRE;
  49. OPTI TRAC PSC POTR HELVETICA_16 EPTR 15;
  50.  
  51. * geometrie
  52. L = 0.3048;
  53. t = 0.254E-3;
  54. Re = 0.0762;
  55. Ri = Re - t;
  56. Rmoy = (Ri + Re) / 2.;
  57.  
  58. * nombre d elements selon Z et R
  59. ncirc = 2**8; nz = 20; nR = 1;
  60. * ncirc = 2**8; nz = 40; nR = 1;
  61. * ncirc = 2**9; nz = 80; nR = 1;
  62.  
  63. * materiau
  64. Ey1 = 2.06E11;
  65. nu1 = 0.3;
  66. rho1 = 7850.;
  67.  
  68.  
  69. ************************************************************************
  70. * MAILLAGE
  71. ************************************************************************
  72.  
  73. p0 = 0. 0. 0.;
  74. vaxe = 0. 1. 0.;
  75. vx = 1. 0. 0.;
  76. vz = 0. 0. 1. ;
  77.  
  78. * MAILLAGE COQUE MINCE
  79.  
  80. p1 = Rmoy 0. 0.;
  81. p2 = Rmoy L 0.;
  82. d12 = p1 droi nZ p2;
  83. OPTI ELEM TRI3;
  84. mesh3 = ROTA d12 360. ncirc p0 vaxe;
  85. ELIM mesh3 (1.E-3 * t);
  86. OPTI ELEM CUB8;
  87.  
  88. * recup
  89. y3 = COOR mesh3 2;
  90. py1_3 = POIN y3 EGINFE 1.E-6;
  91. py2_3 = POIN y3 EGSUPE (L - 1.E-6);
  92.  
  93.  
  94. * MAILLAGE SOLIDE-COQUE
  95.  
  96. * !!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
  97. * ATTENTION : avec les SHB8, il faut definir le maillage de telle sorte
  98. * que l'on ait les 4 premiers noeuds du CUB8 = face 1
  99. * et les 4 derniers = face 2 de la coque de maniere a
  100. * respecter l'orientation de l'epaisseur
  101. * ==> seul le maillage "C" est valide
  102. * !!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
  103.  
  104. * kmail = mot 'A';
  105. * kmail = mot 'B';
  106. kmail = mot 'C';
  107.  
  108. *--- facon A de construire le maillage ---*
  109. si (ega kmail 'A');
  110. * maillage massif lineaire 2D
  111. pC = Ri 0. 0.;
  112. pA = Re 0. 0.;
  113. d1 = pC droi nR pA;
  114. d2 = d1 plus (0. L .0);
  115. mesh4 = d1 regl nZ d2;
  116. * maillage 3D
  117. mesh8 = VOLU 'ROTA' mesh4 ncirc 360. p0 vaxe;
  118. ELIM mesh8 (1.E-3*t);
  119. finsi;
  120.  
  121. *--- facon B de construire le maillage ---*
  122. si (ega kmail 'B');
  123. pC = Ri 0. 0.;
  124. pA = Re 0. 0.;
  125. d1 = pC droi nR pA;
  126. mesh4 = rota d1 ncirc 360. p0 vaxe;
  127. ELIM mesh4 (1.E-3*t);
  128. mesh8 = VOLU mesh4 'TRAN' nZ (0. L .0);
  129. finsi;
  130.  
  131. *--- facon C de construire le maillage ---*
  132. si (ega kmail 'C');
  133. pA = Re 0. 0.;
  134. pB = Re L 0.;
  135. pC = Ri 0. 0.;
  136. pD = Ri L 0.;
  137. de = pA droi nz pB;
  138. di = pC droi nz pD;
  139. mesh4e = de ROTA ncirc 360. p0 vaxe;
  140. ELIM mesh4e (1.E-3*t);
  141. mesh4i = di ROTA ncirc 360. p0 vaxe;
  142. ELIM mesh4i (1.E-3*t);
  143. mesh8 = VOLU mesh4i nR mesh4e;
  144. finsi;
  145.  
  146. si GRAPH;
  147. TRAC (0. 10. -30.) mesh8 'CACH';
  148. finsi;
  149.  
  150. * recup
  151. y8 = COOR mesh8 2;
  152. py1 = POIN y8 EGINFE 1.E-6;
  153. py2 = POIN y8 EGSUPE (L - 1.E-6);
  154.  
  155.  
  156. ************************************************************************
  157. * MODELEs ET MATERIAUx
  158. ************************************************************************
  159.  
  160. * coque mince dkt
  161. mod3 = MODE mesh3 'MECANIQUE' 'ELASTIQUE' 'ISOTROPE' 'DKT';
  162. mat3 = MATE mod3 'YOUN' Ey1 'NU' nu1 'RHO' rho1 'EPAI' t;
  163.  
  164. * solide-coque shb8
  165. mod8 = MODE mesh8 'MECANIQUE' 'ELASTIQUE' 'ISOTROPE' 'SHB8';
  166. mat8 = MATE mod8 'YOUN' Ey1 'NU' nu1 'RHO' rho1;
  167.  
  168.  
  169. ************************************************************************
  170. * MATRICES
  171. ************************************************************************
  172.  
  173. * coque mince dkt
  174. cl3 = BLOQ 'DEPL' (py1_3 et py2_3);
  175. K3 = RIGI mod3 mat3;
  176. M3 = MASS mod3 mat3;
  177. Ktot3 = K3 et cl3;
  178.  
  179. * solide-coque shb8
  180. cl8 = BLOQ 'DEPL' (py1 et py2);
  181. K8 = RIGI mod8 mat8;
  182. M8 = MASS mod8 mat8;
  183. K8tot = K8 et cl8;
  184.  
  185. ************************************************************************
  186. * ANALYSE MODALE
  187. ************************************************************************
  188. SI GRAPH;
  189. mopost = mots 'TABL' 'DEFO';
  190. SINO;
  191. mopost = mots 'TABL' ;
  192. FINSI;
  193.  
  194. * coque mince dkt
  195. TMOD_3 = VIBR 'IRAM' 300. 6 Ktot3 M3 ;
  196. POSTVIBR TMOD_3 mopost;
  197.  
  198. * solide-coque shb8
  199. TMOD_8 = VIBR 'IRAM' 300. 6 K8tot M8 ;
  200. POSTVIBR TMOD_8 ;
  201.  
  202.  
  203. ************************************************************************
  204. * TEST DE BON FONCTIONNEMENT
  205. ************************************************************************
  206. * REM : On teste seulement les valeurs propres. On pourrait aussi
  207. * verifier que les harmoniques de Fourier sont 6, 5 et 7.
  208.  
  209. * ref = calcul mené le 20/02/2017 par BP avec maillage tres fin
  210. * et valeurs correlé en 2D Fourier et par la Reference.
  211. w1_ref = ( (prog 534.62 578.44 594.11)
  212. + (prog 533.84 577.41 593.85) ) / 2.;
  213.  
  214. * tolerance = 5% et 1%
  215. wtol_3 = 0.05;
  216. wtol_8 = 0.01;
  217.  
  218. * boucles sur les modes
  219. I= -1 ;
  220. REPE BMOD 3; I = I + 2;
  221. w1_3 = TMOD_3 . 'MODES' . I . 'FREQUENCE';
  222. w1_8 = TMOD_8 . 'MODES' . I . 'FREQUENCE';
  223. w1 = extr w1_ref &BMOD;
  224. err_3 = ABS (w1_3 - w1) / w1;
  225. err_8 = ABS (w1_8 - w1) / w1;
  226. MESS 'MODE ' &BMOD ': DKT ' w1_3 '(' (100.*err_3) '%) '
  227. '- SHB8' w1_8 '(' (100.*err_8) '%) ';
  228. si ((err_3 >eg wtol_3) ou (err_8 >eg wtol_8));
  229. ERRE 5;
  230. finsi;
  231. FIN BMOD ;
  232.  
  233. ERRE 0;
  234.  
  235. fin ;
  236.  
  237.  
  238.  
  239.  
  240.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales