Télécharger uo2s_cas2.dgibi

Retour à la liste

Numérotation des lignes :

  1. * fichier : uo2s_cas2.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4. *
  5. * Test uo2s_cas2.dgibi: Jeux de donnees
  6. * -------------------------------------
  7. *
  8. 'OPTI' 'DIME' 3 'MODE' 'TRID' ;
  9. * ajout de option epsilon lineaire pour la precision des test!
  10. OPTION epsilon lineaire;
  11. 'OPTI' 'ELEM' 'CUB8' ;
  12. 'OPTI' 'TRAC' 'PSC' ;
  13. 'TEMPS' 'ZERO' ;
  14. *
  15. **********************************************************
  16. * TEST DE VALIDATION *
  17. * ------------------ *
  18. * MODELE UO2 *
  19. * (COUPLAGE DES MODELES GATT_MONERIE ET OTTOSEN) *
  20. * UO2 STANDARD COMPRESSIBLE AVEC COUPLAGE STATIQUE *
  21. * RESOLUTION SIMPLIFIEE *
  22. * *
  23. * MAILLAGE: *
  24. * CUBE *
  25. * *
  26. * CHARGEMENT: *
  27. * DEPLACEMENT VERTICAL IMPOSE EN TRACTION AVEC *
  28. * VITESSE POSITIVE CTE PAR MORCEAU (3 MORCEAUX) *
  29. * TEMPERATURE LINEAIRE CROISSANTE *
  30. * DENSITE DE FISSIONS LINEAIRE CROISSANTE *
  31. * OTTOSEN ACTIVE (TRACTION ELASTIQUE - *
  32. * FISSURATION = FRACTURATION - OUVERTURE *
  33. * FERMETURE - COMPRESSION - REOUVERTURE *
  34. * GONFLEMENT ACTIVE *
  35. * PAS DE VISCOPLASTICITE (GATT_MONERIE) *
  36. * PAS DE DENSIFICATION *
  37. **********************************************************
  38. *
  39. DESSI = FAUX ;
  40. *
  41. * -----------------------------*
  42. * MAILLAGE D UN CUBE DE COTE 1 *
  43. * -----------------------------*
  44. HS2 = 2E-5 ;
  45. *
  46. OO = 0. 0. 0. ;
  47. A1 = HS2 0. 0. ;
  48. A2 = HS2 0. HS2 ;
  49. A3 = 0. 0. HS2 ;
  50. *
  51. LB = 'DROIT' 1 OO A1 ;
  52. LD = 'DROIT' 1 A1 A2 ;
  53. LH = 'DROIT' 1 A2 A3 ;
  54. LG = 'DROIT' 1 A3 OO ;
  55. *
  56. SUA = 'DALL' LB LD LH LG 'PLAN' ;
  57. SU2 = SUA 'PLUS' (0. HS2 0.) ;
  58. VOL1 = 'VOLU' 1 SUA SU2 ;
  59. 'ELIM' (HS2/1000.) VOL1 ;
  60. *
  61. SUB = 'POIN' ('COOR' 3 VOL1) 'INFERIEUR' (HS2/1000.) ;
  62. SUH = 'POIN' ('COOR' 3 VOL1) 'SUPERIEUR' (HS2 - (HS2/1000.));
  63. LG = 'POIN' ('COOR' 1 VOL1) 'INFERIEUR' (HS2/1000.) ;
  64. * -----------------------------------------------------*
  65. * Conditions aux limites + deplacement impose sur CLZH *
  66. * -----------------------------------------------------*
  67. CLZB = 'BLOQ' UZ SUB ;
  68. CLZH = 'BLOQ' UZ SUH ;
  69. CLXG = 'BLOQ' UX LG ;
  70. CLYG = 'BLOQ' UY SUA ;
  71. CLT = CLZB 'ET' CLZH 'ET' CLXG 'ET' CLYG ;
  72. * -------*
  73. * Modele *
  74. * -------*
  75. MODL1= MODE VOL1 MECANIQUE ELASTIQUE VISCOPLASTIQUE UO2 ;
  76. *
  77. * Temperature moyenne
  78. * -------------------
  79. TE1 = 1420. + 273. ;
  80. *
  81. * Porosite initiale (cte au cours du calcul)
  82. * ------------------------------------------
  83. PO = 4.52E-2 ;
  84.  
  85. TA = @GATTPAR '/u2/castem/divers/fichier_gatt' ;
  86. *
  87. PP = 'MANU' 'CHML' MODL1 'T' TE1 'PORO' PO RIGIDITE ;
  88. *
  89. *
  90. * --------------------------------------*
  91. * 'YOUN' constant ou fonction de T et f *
  92. * --------------------------------------*
  93. MATREE = MATE MODL1 'YOUN' (TA.'YOUN') ;
  94. EE = 'VARI' 'NUAG' MODL1 MATREE PP ;
  95. * EE = (TA.'YOUN') ;
  96. MATREE = MATE MODL1 'YOUN' EE ;
  97. * ------------------------------------*
  98. * 'NU' constant ou fonction de T et f *
  99. * ------------------------------------*
  100. MATRUU = MATE MODL1 'NU' (TA.'NU') ;
  101. UU = 'VARI' 'NUAG' MODL1 MATRUU PP ;
  102. * UU = (TA.'NU') ;
  103. * --------------------------------------*
  104. * 'ALPH' constant *
  105. * --------------------------------------*
  106. ALFA = 1.319E-5 ;
  107. * -----------------------------------------------------------------*
  108. * Temperature de reference et temperature de reference pour 'ALPH' *
  109. * -----------------------------------------------------------------*
  110. TREF = TE1 ;
  111. TALPHA = 0. ;
  112. *TALPHA = TE1 ;
  113. *
  114. * -----------------------------*
  115. * Materiau partie GATT_MONERIE *
  116. * -----------------------------*
  117. * fluage primaire
  118. TA.'KPUO' = 0. ;
  119. * fluage secondaire (2 mecanismes)
  120. TA.'K1' = 0. ;
  121. TA.'K2' = 0. ;
  122. * fluage d"irradiation
  123. TA.'A' = 0. ;
  124. * densification/gonflement
  125. TA.'BUMI' = 1E4 * (TA.'BUMI') ;
  126. *
  127. MATR11 = 'MATE' MODL1 'YOUN' EE 'NU' UU 'RHO' (TA.'RHO') 'ALPH' ALFA ;
  128. *
  129. MATR12 = 'MATE' MODL1 'R' (TA.'R') 'DG0' (TA.'DG0') 'DG' (TA.'DG') 'K1' (TA.'K1') 'M1' (TA.'M1') 'Q1' (TA.'Q1') 'N1' (TA.'N1') 'K2' (TA.'K2') 'M2' (TA.'M2') 'Q2' (TA.'Q2') 'N2' (TA.'N2') 'OMEG' (TA.'OMEG') 'H' (TA.'H') 'Q' (TA.'Q') 'BETA' (TA.'BETA') 'K' (TA.'K') 'A' (TA.'A') 'Q3' (TA.'Q3') 'N3' (TA.'N3') 'CR' (TA.'CR') 'CR1' (TA.'CR1') 'CR2' (TA.'CR2') 'CR3' (TA.'CR3');
  130. *
  131. MATR13 = 'MATE' MODL1 'KP' (TA.'KPUO') 'AP' (TA.'AP') 'BP' (TA.'BP') 'QP' (TA.'QP') ;
  132. *
  133. MATR14 = 'MATE' MODL1 'ADEN' (TA.'ADEN') 'KGON' (TA.'KGON') 'POR0' (TA.'POR0') 'BUMI' (TA.'BUMI') 'EFIS' (TA.'EFIS') ;
  134. *
  135. * TYPE = 0. combustible UO2 sinon combustible AFA3GLAA
  136. * COMP = 0. combustible compressible sinon incompressible
  137. * DYN = 0. couplage statique sinon dynamique
  138. *
  139. * -----------------------------*
  140. * Materiau partie OTTOSEN *
  141. * -----------------------------*
  142. MATR16 = 'TAIL' MODL1 ;
  143. *
  144. * Resistance au cisaillement 'GS ' par defaut: 'YOUN'*1.8E-4
  145. * Ouverture a rupture 'WRUP' = 0 --> 'WRUP' = 2*'GFTR'/'LTR '
  146. * Relation bilineaire 'BILI' = 0 --> 'BILI' = 0 (ouverture)
  147. *
  148. XGFTR = 3.0 ; XGFTR1=XGFTR ; XGFTR2=XGFTR ; XGFTR3=XGFTR ;
  149. XLTR = 136E6 ; XLTR1 =XLTR ; XLTR2 =XLTR ; XLTR3 =XLTR ;
  150. XBTR = 0. ;
  151. *
  152. MATR17 = 'MATE' MODL1 'GFTR' XGFTR 'LTR ' XLTR 'BTR ' XBTR 'WRUP' 0. 'BILI' 0. 'GFT1' XGFTR1 'GFT2' XGFTR2 'GFT3' XGFTR3 'GS1 ' 0. 'GS2 ' 0. 'GS3 ' 0. 'LTR1' XLTR1 'LTR2' XLTR2 'LTR3' XLTR3 'WRU1' 0. 'WRU2' 0. 'WRU3' 0. 'BIL1' 0. 'BIL2' 0. 'BIL3' 0. 'SIMP' 1. ;
  153. *
  154. MATR1 = MATR11 'ET' MATR12 'ET' MATR13 'ET' MATR14 'ET' MATR16 'ET' MATR17 ;
  155. *
  156. *
  157. *-------------------------------------------------------
  158. * module d'young
  159. *-------------------------------------------------------
  160. E = 'MAXI' EE ;
  161. *-------------------------------------------------------
  162. *
  163. *
  164. *----------------------------------------------------------------------
  165. 'DEBPROC' TRINOME XA*'FLOTTANT' XB*'FLOTTANT' XC*'FLOTTANT' ;
  166. DISCRI = ( (XB**2.) - (4.*XA*XC) )**0.5 ;
  167. RACINE1 = ( (-1.*XB) + DISCRI ) / (2.*XA) ;
  168. RACINE2 = ( (-1.*XB) - DISCRI ) / (2.*XA) ;
  169. LRACINE = 'PROG' RACINE1 RACINE2 ;
  170. PRACINE = RACINE1 * RACINE2 ;
  171. SRACINE = RACINE1 + RACINE2 ;
  172. 'SI' (PRACINE '<' 0.) ;
  173. RACINE = 'MAXI' LRACINE ;
  174. 'SINON' ;
  175. RACINE = 'MINI' LRACINE ;
  176. 'FINSI' ;
  177. 'FINPROC' RACINE ;
  178. *----------------------------------------------------------------------
  179. *
  180. *-------------------------------------------
  181. * facteurs de conversion
  182. *-------------------------------------------
  183. CONVSIG = 1E6 ;
  184. CONVTO = 24.*3600E3 ;
  185. *-------------------------------------------
  186. *
  187. *-------------------------------
  188. * fin d"ouverture apres fracture
  189. *-------------------------------
  190. t1 = 1.5E6 ;
  191. mess 't1 = ' t1 ' secondes' ;
  192. *--------------------------------------------------
  193. * fin de diminution de la contrainte de compression
  194. *--------------------------------------------------
  195. t2 = 3.8E6 ;
  196. mess 't2 = ' t2 ' secondes' ;
  197. *------------
  198. * temps final
  199. *------------
  200. t3 = 5.5E6 ;
  201. mess 't3 = ' t3 ' secondes' ;
  202. *
  203. * -------------------------*
  204. * vitesses de deformation *
  205. * -------------------------*
  206. * pour 0 < t < t1
  207. *----------------
  208. EPS1 = 7E-9 ;
  209.  
  210. * pour t1 < t < t2
  211. *-----------------
  212. EPS2 = 5E-9 ;
  213.  
  214. * pour t2 < t
  215. *------------
  216. EPS3 = 16E-9 ;
  217.  
  218. * -------------*
  219. * deformation *
  220. * -------------*
  221. eps_t1 = EPS1 * t1 ;
  222. eps_t2 = ( EPS2 * (t2 - t1) ) + eps_t1 ;
  223. eps_t3 = ( EPS3 * (t3 - t2) ) + eps_t2 ;
  224. *
  225. progt = 'PROG' 0 t1 t2 t3 ;
  226. progeps = 'PROG' 0 eps_t1 eps_t2 eps_t3 ;
  227. eveps = 'EVOL' 'MANU' 't(s)' progt 'eps' progeps ;
  228. * --------------------*
  229. * deplacement impose *
  230. * --------------------*
  231. progdep = HS2 * progeps ;
  232. 'TITR' 'DEPLACEMENT IMPOSE SELON DIRECTION Z' ;
  233. evdep = 'EVOL' 'MANU' 't(s)' progt 'dep(m)' progdep ;
  234. si DESSI ; 'DESS' evdep ; 'FINSI' ;
  235. DEPZ = 'DEPI' CLZH 1 ;
  236. CHARMECA = 'CHAR' 'DIMP' DEPZ evdep ;
  237. * --------------------------------------*
  238. * Vitesse d"evolution de la temperature *
  239. * --------------------------------------*
  240. TP1 = 1E-4 ;
  241. *
  242. * ------------------------------*
  243. * Vitesse de densite de fission *
  244. * ------------------------------*
  245. PHIP1 = 3E14 ;
  246. *
  247. *-------------------------------
  248. * premier coefficient du trinome
  249. *-------------------------------
  250. RHO0 = 1. - TA.'POR0' ;
  251. TAU0 = TA.'EFIS'*270./238./10950./RHO0 ;
  252. XA = (TA.'KGON' / 6.) * TAU0 * PHIP1 ;
  253. *
  254. *--------------------------------
  255. * caracteristiques de fissuration
  256. *--------------------------------
  257. LZ = 'MAXI' ('EXCO' MATR16 'LZZ') ;
  258. PENTZ = -1. * ( (XLTR1**2) / (2.*XGFTR1) ) ;
  259. JZ = 1./(LZ*PENTZ) ;
  260. WRUPT = (2.*XGFTR1) / XLTR1 ;
  261. ERUPT = WRUPT / LZ ;
  262. *
  263. * -------------------------------------------------------------- *
  264. * INSTANTS PRIVILEGIES - CONTRAINTE - DEFORMATION DE FISSURATION *
  265. * -------------------------------------------------------------- *
  266. *
  267. npas = 20 ;
  268. *
  269. * ---------------------
  270. * fissuration = rupture
  271. * ---------------------
  272. XB = (ALFA * TP1) - EPS1 ;
  273. XC = XLTR1 / E ;
  274. TFISS = TRINOME XA XB XC ;
  275. mess 'TFISS = ' TFISS ' secondes' ;
  276. tpas = TFISS / npas ;
  277. prt_th = 'PROG' 0 'PAS' tpas TFISS ;
  278. prt_th2 = prt_th ** 2 ;
  279. prs_th = (-1. * XB * prt_th) - (XA * prt_th2) ;
  280. prs_th = E * prs_th ;
  281. prf_th = 'PROG' ('DIME' prt_th)*0. ;
  282. * ---------
  283. * ouverture
  284. * ---------
  285. tpas = (t1 - TFISS) / npas ;
  286. prt = 'PROG' (TFISS + 1) (TFISS + tpas) 'PAS' tpas t1 ;
  287. prt2 = prt ** 2 ;
  288. prs = 'PROG' ('DIME' prt)*0. ;
  289. b = -1. * XC ;
  290. prb = 'PROG' ('DIME' prt) * b ;
  291. prf = (-1. * XB * prt) - (XA * prt2) ;
  292. prf = prf + prb ;
  293. prt_th = prt_th 'ET' prt ;
  294. prs_th = prs_th 'ET' prs ;
  295. prf_th = prf_th 'ET' prf ;
  296. *----------
  297. * fermeture
  298. *----------
  299. XB = (ALFA * TP1) - EPS2 ;
  300. XC = t1 * (EPS2 - EPS1) - b ;
  301. TFERM = TRINOME XA XB XC ;
  302. mess 'TFERM = ' TFERM ' secondes' ;
  303. tpas = (TFERM - t1) / npas ;
  304. prt = 'PROG' (t1 + tpas) 'PAS' tpas TFERM ;
  305. prt2 = prt ** 2 ;
  306. prs = 'PROG' ('DIME' prt)*0. ;
  307. cte = t1 * (EPS1 - EPS2) + b ;
  308. prcte = 'PROG' ('DIME' prt) * cte ;
  309. prf = ((-1. * XB * prt) - (XA * prt2)) + prcte ;
  310. prt_th = prt_th 'ET' prt ;
  311. prs_th = prs_th 'ET' prs ;
  312. prf_th = prf_th 'ET' prf ;
  313. *---------------------------------------
  314. * compression et contrainte decroissante
  315. *---------------------------------------
  316. tpas = (t2 - TFERM) / npas ;
  317. prt = 'PROG' (TFERM + tpas) 'PAS' tpas t2 ;
  318. prt2 = prt ** 2 ;
  319. prcte = 'PROG' ('DIME' prt) * cte ;
  320. prs = ((-1. * XB * prt) - (XA * prt2)) + prcte ;
  321. prs = E * prs ;
  322. prf = 'PROG' ('DIME' prt)*0. ;
  323. prt_th = prt_th 'ET' prt ;
  324. prs_th = prs_th 'ET' prs ;
  325. prf_th = prf_th 'ET' prf ;
  326. *-------------------------------------
  327. * compression et contrainte croissante
  328. *-------------------------------------
  329. XB = (ALFA * TP1) - EPS3 ;
  330. XC = (t1 * (EPS2 - EPS1)) + (t2 * (EPS3 - EPS2)) - b ;
  331. TREOUV = TRINOME XA XB XC ;
  332. mess 'TREOUV = ' TREOUV ' secondes' ;
  333. tpas = (TREOUV - t2) / npas ;
  334. prt = 'PROG' (t2 + tpas) 'PAS' tpas TREOUV ;
  335. prt2 = prt ** 2 ;
  336. cte = cte + (t2 * (EPS2 - EPS3)) ;
  337. prcte = 'PROG' ('DIME' prt) * cte ;
  338. prs = ((-1. * XB * prt) - (XA * prt2)) + prcte ;
  339. prs = E * prs ;
  340. prf = 'PROG' ('DIME' prt)*0. ;
  341. prt_th = prt_th 'ET' prt ;
  342. prs_th = prs_th 'ET' prs ;
  343. prf_th = prf_th 'ET' prf ;
  344. *------------
  345. * reouverture
  346. *------------
  347. tpas = (t3 - TREOUV) / npas ;
  348. prt = 'PROG' (TREOUV + tpas) 'PAS' tpas t3 ;
  349. prt2 = prt ** 2 ;
  350. prs = 'PROG' ('DIME' prt)*0. ;
  351. prcte = 'PROG' ('DIME' prt) * cte ;
  352. prf = ((-1. * XB * prt) - (XA * prt2)) + prcte ;
  353. prt_th = prt_th 'ET' prt ;
  354. prs_th = prs_th 'ET' prs ;
  355. prf_th = prf_th 'ET' prf ;
  356. *
  357. prs_th = prs_th / CONVSIG ;
  358. prw_th = LZ * prf_th ;
  359. *
  360. 'TITR' 'CONTRAINTE DANS LA DIRECTION Z' ;
  361. evs = 'EVOL' 'ROUG' 'MANU' 'Temps (s)' prt_th 'SIGZ(MPa)' prs_th ;
  362. 'TITR' 'DEFORMATION DE FISSURATION DANS LA DIRECTION Z' ;
  363. evf = 'EVOL' 'ROUG' 'MANU' 'Temps (s)' prt_th 'EPSFZ' prf_th ;
  364. 'TITR' 'OUVERTURE DANS LA DIRECTION Z' ;
  365. evw = 'EVOL' 'ROUG' 'MANU' 'Temps (s)' prt_th 'WZ(m)' prw_th ;
  366. 'TITR' 'RELATION CONTRAINTE/OUVERTURE DANS LA DIRECTION Z' ;
  367. evsw = 'EVOL' 'ROUG' 'MANU' 'WZ(m)' prw_th 'SIGZ(MPa)' prs_th ;
  368. *
  369. * --------------------------*
  370. * chargement en temperature *
  371. * --------------------------*
  372. TE0 = 1320. + 273. ;
  373. progun = 'PROG' ('DIME' progt)*1 ;
  374. progtemp = (TP1*progt) + (TE0*progun) ;
  375. 'TITR' 'TEMPERATURE IMPOSEE' ;
  376. EVT = 'EVOL' 'MANU' 't(s)' progt 'T(K)' progtemp ;
  377. si DESSI ; 'DESS' EVT ; 'FINSI' ;
  378. CHTEMP = 'MANU' 'CHPO' VOL1 1 'T' 1. ;
  379. CHARTEMP = 'CHAR' 'T' CHTEMP EVT ;
  380. * ---------------------------------*
  381. * Chargement en densite de fission *
  382. * ---------------------------------*
  383. progfiss = PHIP1 * progt ;
  384. 'TITR' 'DENSITE DE FISSION' ;
  385. EVFIS = 'EVOL' 'MANU' 't(s)' progt 'fission/m3/s' progfiss ;
  386. si DESSI ; 'DESS' EVFIS ; 'FINSI' ;
  387. CHFISS = 'MANU' 'CHPO' VOL1 1 'DFIS' 1. ;
  388. CHARFISS = 'CHAR' 'DFIS' CHFISS EVFIS ;
  389. *
  390. *
  391. *-------------------*
  392. * Instants calcules *
  393. *-------------------*
  394. LIST1 = 'PROG' 1E4 'PAS' 1E4 2.0E5 'PAS' 1E5 2.0E6 'PAS' 1E5 t3 ;
  395. * ---------------------------------------*
  396. * Variables internes initiales 'PORO'=PO *
  397. * ---------------------------------------*
  398. VAR00 = 'ZERO' MODL1 'VARINTER' ;
  399. VAR01 = 'MANU' 'CHML' MODL1 'PORO' PO 'TYPE' 'VARIABLES INTERNES' 'STRESSES' ;
  400. VAR0 = VAR00 + VAR01 ;
  401. *
  402. CHARTOT = CHARMECA 'ET' CHARTEMP 'ET' CHARFISS ;
  403. *
  404. TAB1 = TABLE ;
  405. * TAB1.'TEMPERATURES' = TABLE ;
  406. TAB1.'VARIABLES_INTERNES' = TABLE ;
  407. TAB1.'BLOCAGES_MECANIQUES' = CLT ;
  408. TAB1.'MODELE' = MODL1 ;
  409. TAB1.'CHARGEMENT' = CHARTOT ;
  410. TAB1.'VARIABLES_INTERNES' . 0 = VAR0 ;
  411. TAB1.'CARACTERISTIQUES' = MATR1 ;
  412. TAB1.'TEMPS_CALCULES' = LIST1 ;
  413. TAB1.'TEMPS_SAUVES' = LIST1 ;
  414. *TAB1.'TALPHA_REFERENCE' = TALPHA ;
  415. *
  416. TMASAU=table;
  417. tab1 . 'MES_SAUVEGARDES'=TMASAU;
  418. TMASAU .'DEFTO'=VRAI;
  419. TMASAU .'DEFIN'=VRAI;
  420. PASAPAS TAB1 ;
  421. 'TEMPS' ;
  422. *
  423. *
  424. TT = TAB1 . 'TEMPS' ;
  425. SS = TAB1 . 'CONTRAINTES' ;
  426. VV = TAB1 . 'VARIABLES_INTERNES' ;
  427. IN = TAB1 . 'DEFORMATIONS_INELASTIQUES' ;
  428. NCONT = 'DIME' TAB1 . 'CONTRAINTES' ;
  429. *
  430. LZEIT = 'PROG' ;
  431. LSIGZ = 'PROG' ;
  432. LW1 = 'PROG' ;
  433. LW2 = 'PROG' ;
  434. LW3 = 'PROG' ;
  435. LEPSZF = 'PROG' ;
  436. *
  437. *
  438. 'REPE' BLOC NCONT ;
  439. *
  440. IND = &BLOC - 1 ;
  441. ZEIT = TT.IND ;
  442. *
  443. SIG = SS.IND ;
  444. SIGZ = 'EXCO' SIG 'SMZZ' ;
  445. SIGZ_MAX = 'MAXI' SIGZ ;
  446. *
  447. VI = VV.IND ;
  448. EI = IN.IND ;
  449. *
  450. W1 = 'MAXI' ('EXCO' VI 'W1') ;
  451. W2 = 'MAXI' ('EXCO' VI 'W2') ;
  452. W3 = 'MAXI' ('EXCO' VI 'W3') ;
  453. EPSZF = 'MAXI' ('EXCO' EI 'EIZZ') ;
  454. *
  455. LZEIT = LZEIT 'ET' ('PROG' ZEIT) ;
  456. LSIGZ = LSIGZ 'ET' ('PROG' SIGZ_MAX) ;
  457. LW1 = LW1 'ET' ('PROG' W1) ;
  458. LW2 = LW2 'ET' ('PROG' W2) ;
  459. LW3 = LW3 'ET' ('PROG' W3) ;
  460. LEPSZF = LEPSZF 'ET' ('PROG' EPSZF) ;
  461. *
  462. 'FIN' BLOC ;
  463. *
  464. *
  465. LSIGZ = LSIGZ/CONVSIG ;
  466. 'TITR' 'CONTRAINTE DANS LA DIRECTION Z' ;
  467. EVSIGZ = 'EVOL' 'BLEU' 'MANU' 'Temps (s)' LZEIT 'SIGZ(MPa)' LSIGZ; ;
  468. *
  469. 'TITR' 'OUVERTURE DANS LA DIRECTION Z' ;
  470. EVWZ = 'EVOL' 'BLEU' 'MANU' 'Temps (s)' LZEIT 'WZ(m)' LW1 ;
  471. *
  472. 'TITR' 'DEFORMATION DE FISSURATION DANS LA DIRECTION Z' ;
  473. EVEPSFZ = 'EVOL' 'BLEU' 'MANU' 'Temps (s)' LZEIT 'EPSFZ' LEPSZF ;
  474. *
  475. 'TITR' 'RELATION CONTRAINTE/OUVERTURE DANS LA DIRECTION Z' ;
  476. EVSIGWZ = 'EVOL' 'BLEU' 'MANU' 'WZ(m)' LW1 'SIGZ(MPa)' LSIGZ ;
  477. *
  478. *
  479. * -----------------------*
  480. * Controle des resultats *
  481. * -----------------------*
  482. *
  483. TAB = 'TABLE' ;
  484. TAB . 'TITRE' = 'TABLE' ;
  485. TAB . 'TITRE' . 1 = 'Resultat analytique' ;
  486. TAB . 'TITRE' . 2 = 'Resolution simplifiee' ;
  487. *
  488. *
  489. 'SI' DESSI ;
  490. 'TITR' 'CONTRAINTE DANS LA DIRECTION Z' ;
  491. 'DESS' (evs 'ET' EVSIGZ) TAB 'LEGE' ;
  492. 'FINSI' ;
  493. *
  494. 'SI' DESSI ;
  495. 'TITR' 'OUVERTURE DANS LA DIRECTION Z' ;
  496. 'DESS' (evw 'ET' EVWZ) TAB 'LEGE' ;
  497. 'FINSI' ;
  498. *
  499. 'SI' DESSI ;
  500. 'TITR' 'DEFORMATION DE FISSURATION DANS LA DIRECTION Z' ;
  501. 'DESS' (evf 'ET' EVEPSFZ) TAB 'LEGE' ;
  502. 'FINSI' ;
  503. *
  504. 'SI' DESSI ;
  505. 'TITR' 'RELATION CONTRAINTE/OUVERTURE DANS LA DIRECTION Z' ;
  506. 'DESS' (evsw 'ET' EVSIGWZ) TAB 'LEGE' ;
  507. 'FINSI' ;
  508. *
  509. *
  510. PREX = 5E-2 ;
  511. LSOUS = 'PROG' (0.99*TFISS) (1.06*TFISS) t1 (0.99*TFERM) t2 (1.05*TREOUV) t3 ;
  512. UN = 'PROG' ('DIME' LSOUS)*1 ;
  513. SZ_CAL = 'IPOL' LSOUS LZEIT LSIGZ ;
  514. SZ_ANA = 'IPOL' LSOUS prt_th prs_th ;
  515. T_SZ = (SZ_ANA - SZ_CAL) / (SZ_ANA + UN) ;
  516. T_SZ = 'MAXI' ('ABS' T_SZ) ;
  517. 'SI' ( T_SZ '&lt;EG' PREX ) ;
  518. 'ERRE' 0 ;
  519. 'SINO' ;
  520. 'MESS' 'ERREUR MAXIMALE CONTRAINTE SELON Z > ' PREX ;
  521. 'ERRE' 5 ;
  522. 'FINS' ;
  523. *
  524. PREX = 17E-2 ;
  525. LSOUS = 'PROG' (0.99*TFISS) (1.06*TFISS) t1 t2 t3 ;
  526. UN = 'PROG' ('DIME' LSOUS)*1 ;
  527. WRUPT = (2.*XGFTR1) / XLTR1 ;
  528. ERUPT = WRUPT / LZ ;
  529. NONZERO = (ERUPT / 1E6) * UN ;
  530. EFZ_CAL = 'IPOL' LSOUS LZEIT LEPSZF ;
  531. EFZ_ANA = 'IPOL' LSOUS prt_th prf_th ;
  532. T_FZ = (EFZ_ANA - EFZ_CAL) / (EFZ_ANA + NONZERO) ;
  533. T_FZ = 'MAXI' ('ABS' T_FZ) ;
  534. 'SI' ( T_FZ '&lt;EG' PREX ) ;
  535. 'ERRE' 0 ;
  536. 'SINO' ;
  537. 'MESS' 'ERREUR MAXIMALE DEFORMATION DE FISSURATION SELON Z > ' PREX ;
  538. 'ERRE' 5 ;
  539. 'FINS' ;
  540. *
  541. WZ_CAL = 'IPOL' LSOUS LZEIT LW1 ;
  542. WZ_ANA = 'IPOL' LSOUS prt_th prw_th ;
  543. NONZERO = (WRUPT / 1E6) * UN ;
  544. T_WZ = (WZ_ANA - WZ_CAL) / (WZ_ANA + NONZERO) ;
  545. T_WZ = 'MAXI' ('ABS' T_WZ) ;
  546. 'SI' ( T_WZ '&lt;EG' PREX ) ;
  547. 'ERRE' 0 ;
  548. 'SINO' ;
  549. 'MESS' 'ERREUR MAXIMALE OUVERTURE SELON Z > ' PREX ;
  550. 'ERRE' 5 ;
  551. 'FINS' ;
  552. *
  553. 'FIN';
  554.  
  555.  
  556.  
  557.  
  558.  
  559.  
  560.  
  561.  
  562.  
  563.  
  564.  
  565.  
  566.  
  567.  
  568.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales