Télécharger la plaquette Cast3M


fr en

Télécharger uo2_cas4.dgibi

Retour à la liste

Numérotation des lignes : 

  1. * fichier :  uo2_cas4.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4. *
  5. *     Test uo2_cas4.dgibi: Jeux de données            
  6. *     ---------------------------------------         
  7. * 
  8. * repertoire des fichiers "divers"
  9. DIVERS = VENV 'CASTEM_DIVERS';
  10. *
  11. 'OPTI' 'DIME' 2 'MODE' 'PLAN' 'GENE' ;
  12. 'OPTI' 'ELEM' 'QUA4'                 ;
  13. **'OPTI' 'ECHO' 0 ;
  14. 'TEMPS' 'ZERO'                       ;
  15. L = 'MOT' LIST ; F = 'MOT' FIN       ;
  16. *                                                                               
  17. ***********************************************************          
  18. *                TEST DE VALIDATION                       *
  19. *                ------------------                       *
  20. *               MODELE UO2                                *
  21. *                                                         *
  22. *  MAILLAGE:                                              *
  23. *     EPROUVETTE CARRE                                    *
  24. *                                                         *
  25. *  CHARGEMENT:                                            *
  26. *     DEPLACEMENT IMPOSE                                  *
  27. *     TEMPERATURE                                         *
  28. *     POROSITE CONSTANTE                                  *
  29. *     DENSITE DE FISSIONS CONSTANTE                       *
  30. *     PRIMAIRE - MECANISMES 1 ET 2 - IRRADIATION          *
  31. *     DENSIFICATION - GONFLEMENT                          *
  32. ***********************************************************          
  33. *
  34. H    = 1. ;
  35. *
  36.  
  37. OO   = 0.              0.            ;
  38. A1   = H               0.            ;
  39. A2   = H               H             ;
  40. A3   = 0.              H             ;
  41. *
  42. LB   = 'DROIT'  2 OO A1             ;
  43. LD   = 'DROIT'  5 A1 A2             ;
  44. LH   = 'DROIT' 3  A2 A3             ;
  45. LG   = 'DROIT' 10  A3 OO             ;
  46.  
  47. *
  48. SU1  = surf ( LB et  LD et LH et  LG ) 'PLAN' ;
  49. **trac su1 ;
  50.  
  51. *
  52. * -------*
  53. * Modele *
  54. * -------*
  55. MODL1= MODE SU1 MECANIQUE ELASTIQUE VISCOPLASTIQUE UO2 'DPGE' OO ;
  56. *
  57. * ----------------------*
  58. * Materiau GATT_MONERIE *
  59. * ----------------------*
  60. TE1  = 1300. + 273.  ;
  61. PO   = 4.9E-2        ;
  62. DF1  = 1.E18         ;
  63. *
  64. TA = @GATTPAR ('CHAINE' DIVERS '/fichier_gatt');
  65. *
  66. TA.'POR0' = PO      ;
  67.  
  68. MATR11 = 'MATE' MODL1  'YOUN' TA.YOUN  'NU' (TA.NU)  'RHO' (TA.RHO) 'ALPH' (TA.ALPH) 'TALP' 0. 'TREF' 400.;
  69. *
  70. MATR12 = 'MATE' MODL1 
  71.  'R'    (TA.'R')    'DG0' (TA.'DG0') 'DG'  (TA.'DGCR')
  72.  'K1'   (TA.'K1')   'M1'  (TA.'M1')  'Q1'  (TA.'Q1')  'N1'   (TA.'N1') 
  73.  'K2'   (TA.'K2')   'M2'  (TA.'M2')  'Q2'  (TA.'Q2')  'N2'   (TA.'N2') 
  74.  'OMEG' (TA.'OMEG') 'H'   (TA.'H')   'Q'   (TA.'Q')   'BETA' (TA.'BETA')
  75.  'K'    (TA.'K')    'A'   (TA.'A')   'Q3'  (TA.'Q3')  'N3'   (TA.'N3')
  76.  'CR'   (TA.'CR')   'CR1' (TA.'CR1') 'CR2' (TA.'CR2') 'CR3'  (TA.'CR3');
  77. *
  78. MATR13 = 'MATE' MODL1 
  79.  'KP'   (TA.'KPUO')   'AP' (TA.'AP')  'BP'  (TA.'BP')  'QP'  (TA.'QP') ;
  80. * 
  81. bumi = 1.e10*(TA.'BUMI') ;
  82. MATR14 = 'MATE' MODL1 
  83. 'ADEN' TA.'ADEN' 'KGON' TA.'KGON'. 
  84.  'POR0' (TA.'POR0') 'BUMI' bumi 'EFIS' (TA.'EFIS') ;
  85.  
  86. *
  87. * -----------------------------*
  88. * Materiau partie OTTOSEN      *
  89. * -----------------------------*
  90.  MATR17 = 'TAIL' MODL1 ;
  91. *
  92. * Resistance au cisaillement 'GS  ' par defaut: 'YOUN'*1.8E-4
  93. * Ouverture a rupture 'WRUP' = 0 --> 'WRUP' = 2*'GFTR'/'LTR '
  94. * Relation bilineaire 'BILI' ou 'EPSB' = 0 --> 'BILI' = 0 (ouverture)
  95. *
  96.  XGFTR = 100.8  ; XGFTR1=XGFTR ; XGFTR2=XGFTR ;
  97.  XLTR  = 5.E6 ; XLTR1 =XLTR  ; XLTR2 =XLTR  ;
  98. * Deformation a rupture 'EPSR' par defaut: 3*'LTR '/'YOUN'
  99. * XYOUN = 'MAXI' ('VARI' 'NUAG' MODL1 MATREE PP)  ;
  100. * NEPSR = 3. ; XEPSR = NEPSR * (XLTR / XYOUN) ;
  101. *
  102.  MATR18 = 'MATE' MODL1  'GFTR' XGFTR    'LTR ' XLTR     'BTR ' 0.2
  103.                         'WRUP' 0.       'BILI' 0.
  104.                         'GFT1' XGFTR1   'GFT2' XGFTR2
  105.                         'GS1 ' 0.       'GS2 ' 0.
  106.                         'LTR1' XLTR1    'LTR2' XLTR2
  107.                         'WRU1' 0.       'WRU2' 0.
  108.                         'BIL1' 0.       'BIL2' 0.                     ;
  109. *
  110. MATR1 = MATR11 'ET' MATR12 'ET' MATR13 'ET' MATR14 'ET'
  111.         MATR17 'ET' MATR18      ;
  112. *
  113. * -----------------------*
  114. * Conditions aux limites *
  115. * -----------------------*
  116. CLYB = 'BLOQ' 'UY' LB                  ;
  117. CLXG = 'BLOQ' 'UX' LG                  ;
  118. CLT  = CLYB 'ET' CLXG                  ;
  119. *
  120. TMIL = 1.E6 ;
  121. TFIN = 2.E6 ;
  122. *
  123.  
  124.  
  125. * ------------------------------*
  126. * Chargement en temperature     *
  127. * ------------------------------*
  128. CHTEMP   = 'MANU' 'CHPO' SU1 1 'T' 1.           ;
  129. EVT      = 'EVOL' 'MANU' ('PROG' 0.  (2.*TFIN)) 
  130.                          ('PROG' 400. 500.)       ;
  131. CHARTEMP = 'CHAR' 'T' CHTEMP EVT                ;
  132.  
  133.  
  134. chpor0   = 'MANU' 'CHPO' SU1 1 'PORO' 1.;
  135. EVT      = 'EVOL' 'MANU' ('PROG' 0.  (2.*TFIN)) 
  136.                          ('PROG' 0.049  0.049) ;
  137. CHARPOR = 'CHAR' 'PORO' chpor0 EVT  ;
  138. * -------------------------------------*
  139. * Chargement cte en densite de fission *
  140. * -------------------------------------*
  141. CHFISS   = 'MANU' 'CHPO' SU1 1 'DFIS' 1.        ;
  142. EVF      = 'EVOL' 'MANU' ('PROG' 0.  (2.*TFIN)) 
  143.                          ('PROG' DF1 DF1)       ;
  144. CHARFISS = 'CHAR' 'DFIS' CHFISS EVF             ;
  145. * ---------------------------------*
  146. * Chargement en deplacement impose *
  147. * ---------------------------------*
  148.  
  149. EVP      = 'EVOL' 'MANU' ('PROG' 0.  (2.*TFIN)) 
  150.                          ('PROG' 0.  1.) ;
  151. CL3 = 'BLOQ' LH 'UY' ;
  152. DEP3 = 'DEPI' cl3 100. ;
  153. CHARMECA = 'CHAR' 'DIMP' dep3 evp ;
  154.  
  155. CHARTOT  = CHARMECA 'ET' CHARTEMP 'ET' CHARFISS 'ET' CHARPOR ;
  156. * ---------------------------------------*
  157. * Variables internes initiales 'PORO'=PO *
  158. * ---------------------------------------*
  159. VAR00 = 'ZERO' MODL1 'VARINTER'                                    ;
  160. VAR01 = 'MANU' 'CHML' MODL1 'PORO' PO 
  161.                             'TYPE' 'VARIABLES INTERNES' 'STRESSES' ;
  162. VAR0  = VAR00 + VAR01                                              ;
  163. *
  164. *
  165. TAB1 = TABLE                           ;
  166. TAB1.'TEMPERATURES' = TABLE            ;
  167. TAB1.'VARIABLES_INTERNES'= TABLE       ;
  168. TAB1.'BLOCAGES_MECANIQUES' = CLT   et cl3;
  169. TAB1.'MODELE' = MODL1                  ;
  170. TAB1.'CHARGEMENT' = CHARTOT            ;
  171. TAB1.'TEMPERATURES' . 0 = 'MANU' 'CHPO' SU1 1 'T' 400.  ;
  172. TAB1.'VARIABLES_INTERNES' . 0 = VAR0   ; 
  173. TAB1.'CARACTERISTIQUES' = MATR1        ;
  174. TAB1.'TEMPS_CALCULES' = 'PROG' 0  PAS 0.1 1.2 ;
  175.  
  176. PASAPAS TAB1                           ;
  177.  
  178. **-- Verification de la valeur du taux de combustion (variable interne BU)
  179.  
  180. * Valeur theorique du taux de combustion
  181. *  bu_th = 3.2e-11*0.270*df1*t/(0.238*10950.*(1.-0.049)) 
  182.  
  183. AA = 3.2e-11*0.270*DF1/(0.238*10950.*(1.-0.049)) ;
  184.  
  185. **-- Taux de combustion a l instant 1.1 s (pas de non convergence)
  186.  
  187. BU_CALC1 = 'MINI' ('EXCO' TAB1.'VARIABLES_INTERNES' . 11 'BU') ;
  188. BU_CALC2 = 'MAXI' ('EXCO' TAB1.'VARIABLES_INTERNES' . 11 'BU') ;
  189.  
  190. ECART1 = 'ABS' (BU_CALC1-BU_CALC2) / BU_CALC1 ;
  191.  
  192. BU_TH = AA*1.1 ;
  193. ECART2 = 'ABS' (BU_CALC1-BU_TH) / BU_TH ;
  194.  
  195. **-- Taux de combustion a l instant 1.2 s (apres non convergence)
  196.  
  197. BU_CALC = 'MAXI' ('EXCO' TAB1.'VARIABLES_INTERNES' . 12 'BU') ;
  198. BU_TH = AA*1.2 ;
  199. ECART3 = 'ABS' (BU_CALC-BU_TH) / BU_TH ;
  200.  
  201. 'SI' (ECART1 '<EG' 1.E-8) ;
  202.    'ERRE' 0 ;
  203. 'SINON' ;
  204.    'ERRE' 5 ;
  205. 'FINSI' ;
  206.  
  207. 'SI' (ECART2 '<EG' 1.E-8) ;
  208.    'ERRE' 0 ;
  209. 'SINON' ;
  210.    'ERRE' 5 ;
  211. 'FINSI' ;
  212.  
  213. 'SI' (ECART3 '<EG' 1.E-8) ;
  214.    'ERRE' 0 ;
  215. 'SINON' ;
  216.    'ERRE' 5 ;
  217. 'FINSI' ;
  218. 'FIN' ;
  219.  
  220.  
  221.  
  222.  
  223.  
  224.  
  225.  
  226.  
  227.  
  228.  
  229.  
  230.  
  231.  
  232.  
  233.  
  234.  
  235.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales