Télécharger la plaquette Cast3M


fr en

Télécharger uo2_cas3.dgibi

Retour à la liste

Numérotation des lignes : 

  1. * fichier :  uo2_cas3.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4. *
  5. *     Test uo2_cas3.dgibi: Jeux de données            
  6. *     ---------------------------------------         
  7. * 
  8. * repertoire des fichiers "divers"
  9. DIVERS = VENV 'CASTEM_DIVERS';
  10. *
  11. 'OPTI' 'DIME' 2 'MODE' 'PLAN' 'GENE' ;
  12. 'OPTI' 'ELEM' 'QUA8'                 ;
  13. 'OPTI' 'TRAC' 'PSC'                  ;
  14. 'TEMPS' 'ZERO'                       ;
  15. L = 'MOT' LIST ; F = 'MOT' FIN       ;
  16. *                                                                               
  17. ***********************************************************          
  18. *                TEST DE VALIDATION                       *
  19. *                ------------------                       *
  20. *               MODELE GATT_MONERIE                       *
  21. *  AFA3GLAA INCOMPRESSIBLE AVEC COUPLAGE DYNAMIQUE        *
  22. *                                                         *
  23. *  MAILLAGE:                                              *
  24. *     EPROUVETTE CARRE                                    *
  25. *                                                         *
  26. *  CHARGEMENT:                                            *
  27. *     CONTRAINTE DE COMPRESSION IMPOSEE (ESSAI DE FLUAGE) *
  28. *     TEMPERATURE CONSTANTE                               *
  29. *     DENSITE DE FISSIONS CONSTANTE                       *
  30. *     PRIMAIRE - MECANISMES 1 ET 2 - IRRADIATION          *
  31. *     DENSIFICATION - GONFLEMENT                          *
  32. ***********************************************************          
  33. *
  34. GRAPH    = FAUX ;
  35. LISTCOUR = VRAI ;
  36. *
  37. NE   = 1  ;
  38. H    = 1. ;
  39. *
  40. OO   = 0.              0.            ;
  41. A1   = H               0.            ;
  42. A2   = H               H             ;
  43. A3   = 0.              H             ;
  44. *
  45. LB   = 'DROIT' NE  OO A1             ;
  46. LD   = 'DROIT' NE  A1 A2             ;
  47. LH   = 'DROIT' NE  A2 A3             ;
  48. LG   = 'DROIT' NE  A3 OO             ;
  49. *
  50. SU1  = 'DALL' LB  LD  LH  LG  'PLAN' ;
  51. *
  52. * -------*
  53. * Modele *
  54. * -------*
  55. MODL1= MODE SU1 MECANIQUE ELASTIQUE VISCOPLASTIQUE UO2 'DPGE' OO ;
  56. *
  57. * ----------------------*
  58. * Materiau GATT_MONERIE *
  59. * ----------------------*
  60. TE1  = 1300. + 273.  ;
  61. PO   = 4.9E-2        ;
  62. DF1  = 1.E18         ;
  63. *
  64. TA = @GATTPAR ('CHAINE' DIVERS '/fichier_gatt');
  65. *
  66. TA.'BP'   = 0.      ;
  67. TA.'POR0' = PO      ;
  68. TA.'CR'   = 0.16E-2 ;
  69. *
  70. MATREE = MATE MODL1 'YOUN' (TA.'YOUN') ; 
  71. PP = 'MANU' 'CHML' MODL1 'T' TE1 'PORO' PO RIGIDITE ; 
  72. EE = 'VARI' 'NUAG' MODL1 MATREE PP ;
  73. *
  74. MATR11 = 'MATE' MODL1  'YOUN' EE  'NU' 0.  'RHO' 10950.  'ALPH' 0. 'TALP' 0. 'TREF' TE1 ;
  75. *
  76. MATR12 = 'MATE' MODL1 
  77.  'R'    (TA.'R')    'DG0' (TA.'DG0') 'DG'  (TA.'DGCR')
  78.  'K1'   (TA.'K1')   'M1'  (TA.'M1')  'Q1'  (TA.'Q1')  'N1'   (TA.'N1') 
  79.  'K2'   (TA.'K2')   'M2'  (TA.'M2')  'Q2'  (TA.'Q2')  'N2'   (TA.'N2') 
  80.  'OMEG' (TA.'OMEG') 'H'   (TA.'H')   'Q'   (TA.'Q')   'BETA' (TA.'BETA')
  81.  'K'    (TA.'K')    'A'   (TA.'A')   'Q3'  (TA.'Q3')  'N3'   (TA.'N3')
  82.  'CR'   (TA.'CR')   'CR1' (TA.'CR1') 'CR2' (TA.'CR2') 'CR3'  (TA.'CR3');
  83. *
  84. MATR13 = 'MATE' MODL1 
  85.  'KP'   (TA.'KPAF')   'AP' (TA.'AP')  'BP'  (TA.'BP')  'QP'  (TA.'QP') ;
  86. * 
  87. MATR14 = 'MATE' MODL1 
  88.  'ADEN' TA.'ADEN' 'KGON' TA.'KGON'. 
  89.  'POR0' (TA.'POR0') 'BUMI' (TA.'BUMI')  'EFIS' (TA.'EFIS') ;
  90. *
  91. * TYPE = 0. combustible UO2            sinon combustible AFA3GLAA
  92. * COMP = 0. combustible incompressible sinon compressible
  93. * DYN  = 0. couplage dynamique         sinon statique
  94. *
  95. MATR15 = 'MATE' MODL1 'TYPE' 1.   'COMP' 1.   'DYN' 1. ;
  96. *
  97. MATR16 = 'MATE' MODL1
  98.          'DYN1' (TA.'DYN1')   'DYN2' (TA.'DYN2')   'DYN3' (TA.'DYN3') ;
  99. *
  100. * -----------------------------*
  101. * Materiau partie OTTOSEN      *
  102. * -----------------------------*
  103.  MATR17 = 'TAIL' MODL1 ;
  104. *
  105. * Resistance au cisaillement 'GS  ' par defaut: 'YOUN'*1.8E-4
  106. * Ouverture a rupture 'WRUP' = 0 --> 'WRUP' = 2*'GFTR'/'LTR '
  107. * Relation bilineaire 'BILI' ou 'EPSB' = 0 --> 'BILI' = 0 (ouverture)
  108. *
  109.  XGFTR = 1.8  ; XGFTR1=XGFTR ; XGFTR2=XGFTR ;
  110.  XLTR  = 2000E6 ; XLTR1 =XLTR  ; XLTR2 =XLTR  ;
  111. * Deformation a rupture 'EPSR' par defaut: 3*'LTR '/'YOUN'
  112.  XYOUN = 'MAXI' ('VARI' 'NUAG' MODL1 MATREE PP)  ;
  113.  NEPSR = 3. ; XEPSR = NEPSR * (XLTR / XYOUN) ;
  114. *
  115.  MATR18 = 'MATE' MODL1  'GFTR' XGFTR    'LTR ' XLTR     'BTR ' 0.2
  116.                         'WRUP' 0.       'BILI' 0.
  117.                         'GFT1' XGFTR1   'GFT2' XGFTR2
  118.                         'GS1 ' 0.       'GS2 ' 0.
  119.                         'LTR1' XLTR1    'LTR2' XLTR2
  120.                         'WRU1' 0.       'WRU2' 0.
  121.                         'BIL1' 0.       'BIL2' 0.                     ;
  122. *
  123. MATR1 = MATR11 'ET' MATR12 'ET' MATR13 'ET' MATR14 'ET'
  124.         MATR15 'ET' MATR16 'ET' MATR17 'ET' MATR18      ;
  125. *
  126. * -----------------------*
  127. * Conditions aux limites *
  128. * -----------------------*
  129. CLYB = 'BLOQ' 'UY' LB                  ;
  130. CLXG = 'BLOQ' 'UX' LG                  ;
  131. CLT  = CLYB 'ET' CLXG                  ;
  132. *
  133. TMIL = 1.E6 ;
  134. TFIN = 2.E6 ;
  135. *
  136. RHO0 = 1. - TA.'POR0' ;
  137. AKBU = TA.'EFIS'*270./238./10950./RHO0*DF1 ;
  138. * CE QUI SUIT EST VRAI CAR LE FLUX DE FISSIONS EST CONSTANT 
  139. TBU = (TA.'BUMI' / AKBU) - 1. ;
  140. TTBU = ('ENTI' (TBU/10000.)) * 10000. ;
  141. *-------------------*
  142. * Instants calcules *
  143. *-------------------*
  144. 'SI' LISTCOUR ;
  145. *--------------
  146. LIST1 = 'PROG' 0  'PAS' 0.1 1 'PAS' 1 10 'PAS' 10 100 'PAS' 100 1000 
  147.                   'PAS' 500  15000 ;
  148. 'SINON' ;
  149. *--------
  150. LIST1 = 'PROG' 0  'PAS' 0.1 1 'PAS' 1 10 'PAS' 10 100 'PAS' 100 1000 
  151.                   'PAS' 500  30000 ;
  152. 'FINSI' ;
  153. *--------
  154. * ------------------------------*
  155. * Chargement cte en temperature *
  156. * ------------------------------*
  157. CHTEMP   = 'MANU' 'CHPO' SU1 1 'T' 1.           ;
  158. EVT      = 'EVOL' 'MANU' ('PROG' 0.  (2.*TFIN)) 
  159.                          ('PROG' TE1 TE1)       ;
  160. CHARTEMP = 'CHAR' 'T' CHTEMP EVT                ;
  161. * -------------------------------------*
  162. * Chargement cte en densite de fission *
  163. * -------------------------------------*
  164. CHFISS   = 'MANU' 'CHPO' SU1 1 'DFIS' 1.        ;
  165. EVF      = 'EVOL' 'MANU' ('PROG' 0.  (2.*TFIN)) 
  166.                          ('PROG' DF1 DF1)       ;
  167. CHARFISS = 'CHAR' 'DFIS' CHFISS EVF             ;
  168. * -----------------------*
  169. * Chargement en pression *
  170. * -----------------------*
  171. valpres  = 60E6                                    ;
  172. compr    = 'PRES' 'MASS' MODL1 valpres LH          ;
  173. EVP      = 'EVOL' 'MANU' ('PROG' 0.  1. (2.*TFIN)) 
  174.                          ('PROG' 0.  1.        1.) ;
  175. CHARMECA = 'CHAR' 'MECA' compr EVP                 ;
  176. *
  177. CHARTOT  = CHARMECA 'ET' CHARTEMP 'ET' CHARFISS ;
  178. * ---------------------------------------*
  179. * Variables internes initiales 'PORO'=PO *
  180. * ---------------------------------------*
  181. VAR00 = 'ZERO' MODL1 'VARINTER'                                    ;
  182. VAR01 = 'MANU' 'CHML' MODL1 'PORO' PO 
  183.                             'TYPE' 'VARIABLES INTERNES' 'STRESSES' ;
  184. VAR0  = VAR00 + VAR01                                              ;
  185. *
  186. *
  187. TAB1 = TABLE                           ;
  188. TAB1.'TEMPERATURES' = TABLE            ;
  189. TAB1.'VARIABLES_INTERNES'= TABLE       ;
  190. TAB1.'BLOCAGES_MECANIQUES' = CLT       ;
  191. TAB1.'MODELE' = MODL1                  ;
  192. TAB1.'CHARGEMENT' = CHARTOT            ;
  193. TAB1.'TEMPERATURES' . 0 = CHTEMP       ;
  194. TAB1.'VARIABLES_INTERNES' . 0 = VAR0   ; 
  195. TAB1.'CARACTERISTIQUES' = MATR1        ;
  196. TAB1.'TEMPS_CALCULES' = LIST1          ;
  197. TAB1.'TEMPS_SAUVES' = LIST1            ;
  198. *
  199. TMASAU                   = TABLE       ;
  200. tab1 . 'MES_SAUVEGARDES' = TMASAU      ;
  201. TMASAU .'DEFTO' = VRAI                 ;
  202. TMASAU .'DEFIN' = VRAI                 ;
  203. *
  204. PASAPAS TAB1                           ;
  205. *
  206. *
  207. *
  208. *****************************************
  209. *        CONTROLE DES RESULTATS         *
  210. *****************************************
  211. *
  212. *
  213. AP      = TA.'AP'        ;
  214. BP      = TA.'BP'        ;
  215. N1      = TA.'N1'        ;
  216. N2      = TA.'N2'        ;
  217. DG      = TA.'DGCR'      ;
  218. *
  219. * Facteurs multiplicatifs dus au dopage par le Chrome
  220. WC1 = 'TANH' ( (TA.'CR' - TA.'CR2') / TA.'CR3' ) ;
  221. WC1 = 1. + ( 0.5 * TA.'CR1' * (1. + WC1) )       ;
  222. CV  = 180. / PI                                  ;
  223. WC2 = 1. - ( 'COS' (CV * DG / TA.'DG0') )        ;
  224. WC2 = 2. * (TA.'DG0'**TA.'M2') * WC2             ;
  225. *
  226. * Calcul de TO pour la fonction de couplage dynamique
  227. TO = 'TANH' ( (TA.'DYN2' - TE1) / TA.'DYN3' ) ;
  228. TO = TA.'DYN1' * (1. + TO)                    ;
  229. TO = TO + 1.                                  ;
  230. *
  231. BUMI = TA.'BUMI' ;
  232. AKEVD = AKBU*TA.'KGON' ;
  233. ADEN = TA.'ADEN' ; 
  234. KGON = TA.'KGON' ;
  235. * -------------------------------------------------------------------*
  236. * Calcul de la cte AAAA intervenant ds le calcul de la def. de dens. *
  237. * -------------------------------------------------------------------*
  238. BUMAX0=60.D0*BUMI ;
  239. CRIT=1.D-10 ;
  240. 'REPE' BLOC 100 ;         
  241.   BUMAX = BUMI* ('EXP' (1. - (ADEN/(KGON*BUMAX0)))) ;
  242.   BUMAX = (0.2*BUMAX) + (0.8*BUMAX0) ;
  243.   TEST='ABS' ((BUMAX-BUMAX0)/BUMAX0) ;
  244.   'SI' ('<' TEST CRIT) ; 
  245.     'QUIT' BLOC ; 
  246.   'FINS' ;
  247.   BUMAX0=BUMAX ;
  248. 'FIN' BLOC ;
  249. AAAA = (-1.D0*RHO0*(ADEN-(KGON*BUMAX))) /
  250.                 ((1.D0+ADEN)*(LOG(BUMAX/BUMI)))  ;
  251. *
  252. * -----------------------*
  253. * Controle des resultats *
  254. * -----------------------*
  255. SS = TAB1 . 'CONTRAINTES'                   ;
  256. VV = TAB1 . 'VARIABLES_INTERNES'            ;
  257. IN = TAB1 . 'DEFORMATIONS_INELASTIQUES'     ;
  258. NCONT = ('DIME' (TAB1 . 'CONTRAINTES')) - 1 ; 
  259. *
  260. ERMAX1 = 0.        ;
  261. ERMAX2 = 0.        ;
  262. *
  263. Lzeit   = 'PROG' ;
  264. Lteta   = 'PROG' ;
  265. Lteta_c = 'PROG' ;
  266. Lepsv   = 'PROG' ;
  267. Lepsv_c = 'PROG' ;
  268. *
  269. ind0  = 9  ;
  270. zeit0 = 1. ;
  271. *
  272. epsv0 = 'MAXI' ('EXCO' IN.(ind0 + 1) 'EIYY') ; 
  273. *
  274. 'REPE' BLOC (NCONT - ind0) ;
  275. *
  276.   ind = ind0 + &BLOC ;
  277. *
  278. * ----------------------------------------------------
  279. * SMYY = valpres ET LES AUTRES COMPOSANTES SONT NULLES
  280. * ----------------------------------------------------
  281.   SMYY = -1. * valpres ;
  282.   SSM  = SMYY / 3.     ;
  283.   SSEQ = 'ABS' SMYY    ;
  284. * Deviateur des contraintes
  285.   SSPRIM2 = SMYY - SSM ;
  286. * Contrainte YY calculee
  287.   sy_c = 'MAXI' ('EXCO' SS.ind 'SMYY') ;
  288. * --------------------------------------------------------------
  289. * VITESSE DE DEFORMATION VISCO-PLASTIQUE EVP D"ORIGINE THERMIQUE
  290. * --------------------------------------------------------------
  291. *-- fluage primaire
  292. *
  293.   EVP02 = -1.5 * TA.'KPAF' * 
  294.    ('EXP' (-1.*TA.'QP'/(TA.'R'*TE1))) * (SSEQ**AP) ;
  295. *
  296. *-- fluage secondaire (2 mecanismes)
  297. *
  298. * on teste la porosite :
  299.   PP = 'MAXI' ('EXCO' VV . &BLOC 'PORO')   ;
  300.   ECART1 = 'ABS' ((PP - PO) / PO)          ;
  301.   ERMAX1 = 'MAXI' ('PROG' ECART1 ERMAX1)   ;
  302. *
  303.   A1 = (N1* (PP**(-1./N1) - 1.)**(-2.*N1/(N1+1.)))      ;
  304.   B1 = (1. + (2.*PP/3.))/ ((1. - PP) **(2.*N1/(N1+1.))) ;
  305.   B1 = B1 + (A1/4.)                                     ;
  306.   A1 = 0.                                               ;
  307. *
  308.   A2 = (N2* (PP**(-1./N2) - 1.)**(-2.*N2/(N2+1.)))      ;
  309.   B2 = (1. + (2.*PP/3.))/ ((1. - PP) **(2.*N2/(N2+1.))) ;
  310.   B2 = B2 + (A2/4.)                                     ;
  311.   A2 = 0.                                               ;
  312. *
  313.   EVP12 = 0.5 * (TA.'K1' * (DG**TA.'M1') * WC1 *
  314.   ('EXP' (-1.*TA.'Q1'/(TA.'R'*TE1))) * 
  315.   (((A1*((1.5*SSM)**2)) + (B1*(SSEQ ** 2)))**((N1-1.)/2.)) *
  316.   ((A1*1.5*SSM) + (3.*B1*SSPRIM2))) ;
  317. *
  318.   EVP22 = 0.5 * (TA.'K2' * WC2 * ('EXP' (-1.*TA.'Q2'/(TA.'R'*TE1))) * 
  319.   (((A2*((1.5*SSM)**2)) + (B2*(SSEQ ** 2)))**((N2-1.)/2.)) *
  320.   ((A2*1.5*SSM) + (3.*B2*SSPRIM2))) ;
  321. * -----------------------------
  322. * FONCTION DE COUPLAGE STATIQUE
  323. * -----------------------------
  324.   TETA0 = 0.5 * TA.'BETA' *
  325.       (1. + 
  326.       ('TANH' ((TE1 - (TA.'OMEG' * (SSEQ**(-1.*TA.'Q')))) / TA.'H'))) ;
  327. * ------------------------------
  328. * FONCTION DE COUPLAGE DYNAMIQUE
  329. * ------------------------------
  330.   zeit  = TAB1.'TEMPS'.ind        ;
  331.   duree = zeit - zeit0            ; 
  332.   TETA = ( 1. + (zeit/TO) ) ** -1 ;
  333.   TETA = TETA0 * (1. - TETA)      ;
  334. * Fonction de couplage dynamique calculee
  335.   teta_c = 'MAXI' ('EXCO' VV.ind 'TETA') ;
  336. * ----------------------------------
  337. * VITESSE DE DEFORMATION IRRADIATION
  338. * ----------------------------------
  339.   EVIR2 = 1.5 * TA.'A' * DF1 * (SSEQ **(TA.'N3' - 1.)) * 
  340.        ('EXP' (-1.*TA.'Q3'/(TA.'R'*TE1))) * SSPRIM2 ;
  341. * ------------------------------------
  342. * DEFORMATION VISCO-PLASTIQUE SELON YY
  343. * ------------------------------------
  344.  KFI      = 1.+(TA.'K'*DF1)                      ;
  345.  EPSVa    = EVIR2 + ( KFI * (EVP02+EVP12) )      ;
  346.  EPSVb    = KFI * (EVP22 - EVP12)                ;
  347.  INTGTETA = 'LOG' ( 1. + (duree/TO) )            ;
  348.  INTGTETA = TO * INTGTETA                        ;
  349.  INTGTETA = TETA0 * (duree - INTGTETA)           ;
  350.  epsv     = (EPSVa * duree) + (EPSVb * INTGTETA) ;
  351.  epsv     = epsv0 + epsv                         ;
  352. * Deformation viscoplastique calculee
  353.  epsv_c = 'MAXI' ('EXCO' IN.ind 'EIYY') ;
  354. * On teste la deformation viscoplastique :
  355.      ECART2 = 'ABS' ((epsv_c - epsv) / epsv)  ;
  356.      ERMAX2 = 'MAXI' ('PROG' ECART2 ERMAX2)   ;
  357. *
  358.   Lzeit   = Lzeit   'ET' ('PROG' zeit)   ;
  359.   Lteta   = Lteta   'ET' ('PROG' TETA)   ;
  360.   Lteta_c = Lteta_c 'ET' ('PROG' teta_c) ;
  361.   Lepsv   = Lepsv   'ET' ('PROG' epsv)   ;
  362.   Lepsv_c = Lepsv_c 'ET' ('PROG' epsv_c) ;
  363. *
  364. 'FIN' BLOC ;
  365. *
  366.   'SI' (ERMAX1 '&lt;EG' 1E-5)               ;
  367.      'ERRE' 0                            ;
  368.   'SINO'                                 ;
  369.      'MESS' 'POROSITE NON CONSTANTE'     ;
  370.      'MESS' 'ERREUR MAXIMALE POROSITE :' 
  371.              ERMAX1 '> 1E-5 '            ; 
  372.      'ERRE' 5                            ;
  373.   'FINS'                                 ;
  374. *
  375. 'SI' ( ERMAX2 '&lt;EG' 0.05)                                ;
  376.    'ERRE' 0                                              ;
  377. 'SINO'                                                   ;
  378.    'MESS' 'ERREUR MAXIMALE DEFORMATION VISCOPLASTIQUE :' 
  379.            ERMAX2 '> 0.05 '                              ; 
  380.    'ERRE' 5                                              ;
  381. 'FINS'                                                   ;
  382. *
  383. *
  384. 'SI' GRAPH ;
  385.  'TITR' 'Deformations planes general. : Fonction de couplage dynamique';
  386.  EVTETA    = 'EVOL' 'MANU' 'Temps' Lzeit 'TETA' Lteta   ;
  387.  EVTETA_C  = 'EVOL' 'MANU' 'Temps' Lzeit 'TETA' Lteta_c ;
  388.  TAD     = TABLE                                        ;
  389.  TAD . 1 = 'TIRC'                                       ;
  390.  TAD . 2 = 'TIRR'                                       ; 
  391.  TAD . 'TITRE' = TABLE                                  ;
  392.  TAD . 'TITRE' . 1 = 'TETA THEORIQUE'                   ;
  393.  TAD . 'TITRE' . 2 = 'TETA CALCULEE'                    ;
  394.  'DESS' (EVTETA 'ET' EVTETA_C) TAD 'LEGE'               ;
  395. *
  396.   'TITR' 'Deformations planes general. : Deformation viscoplastique' ;
  397.   EVEPSV    = 'EVOL' 'MANU' 'Temps' Lzeit 'EPSV' Lepsv               ;
  398.   EVEPSV_C  = 'EVOL' 'MANU' 'Temps' Lzeit 'EPSV' Lepsv_c             ;
  399.   TAD     = TABLE                                                    ;
  400.   TAD . 1 = 'TIRC'                                                   ;
  401.   TAD . 2 = 'TIRR'                                                   ; 
  402.   TAD . 'TITRE' = TABLE                                              ;
  403.   TAD . 'TITRE' . 1 = 'EPSV THEORIQUE'                               ;
  404.   TAD . 'TITRE' . 2 = 'EPSV CALCULEE'                                ;
  405.   'DESS' (EVEPSV 'ET' EVEPSV_C) TAD 'LEGE'                           ;
  406. 'FINS' ;
  407. *
  408. 'FIN';
  409.  
  410.  
  411.  
  412.  
  413.  
  414.  
  415.  
  416.  
  417.  
  418.  
  419.  
  420.  
  421.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales