Télécharger la plaquette Cast3M


fr en

Télécharger uo2_cas2.dgibi

Retour à la liste

Numérotation des lignes : 

  1. * fichier :  uo2_cas2.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4. *
  5. *     Test uo_cas2.dgibi: Jeux de donnees
  6. *     ------------------------------------
  7. *
  8. * repertoire des fichiers "divers"
  9. DIVERS = VENV 'CASTEM_DIVERS';
  10. *
  11. 'OPTI' 'DIME' 3 'MODE' 'TRID'        ;
  12. 'OPTI' 'ELEM' 'CUB8'                 ;
  13. 'OPTI' 'TRAC' 'PSC'                  ;
  14. 'TEMPS' 'ZERO'                       ;
  15. *
  16. **********************************************************
  17. *                TEST DE VALIDATION                      *
  18. *                ------------------                      *
  19. *                   MODELE UO2                           *
  20. *   (COUPLAGE DES MODELES GATT_MONERIE ET OTTOSEN)       *
  21. *  UO2 STANDARD COMPRESSIBLE AVEC COUPLAGE STATIQUE      *
  22. *                                                        *
  23. *  MAILLAGE:                                             *
  24. *     CUBE                                               *
  25. *                                                        *
  26. *  CHARGEMENT:                                           *
  27. *     DEPLACEMENT VERTICAL IMPOSE EN  TRACTION AVEC      *
  28. *     VITESSE CTE PAR MORCEAU (POSITIVE PUIS NEGATIVE    *
  29. *     PUIS POSITIVE)                                     *
  30. *     TEMPERATURE         LINEAIRE CROISSANTE            *
  31. *     DENSITE DE FISSIONS LINEAIRE CROISSANTE            *
  32. *     OTTOSEN ACTIVE (TRACTION ELASTIQUE - FISSURATION - *
  33. *     OUVERTURE - FERMETURE - COMPRESSION - REOUVERTURE -*
  34. *     POURSUITE DE FISSURATION VERS RUPTURE)             *
  35. *     GONFLEMENT ACTIVE                                  *
  36. *     PAS DE VISCOPLASTICITE (GATT_MONERIE)              *
  37. *     PAS DE DENSIFICATION                               *
  38. **********************************************************
  39. *
  40. DESSI = FAUX ;
  41. *
  42. * -----------------------------*
  43. * MAILLAGE D UN CUBE DE COTE 1 *
  44. * -----------------------------*
  45.    HS2  = 2E-5                                                 ;
  46. *
  47.    OO   = 0.     0.         0.                                 ;
  48.    A1   = HS2    0.         0.                                 ;
  49.    A2   = HS2    0.         HS2                                ;
  50.    A3   = 0.     0.         HS2                                ;
  51. *
  52.    LB   = 'DROIT' 1  OO A1                                     ;
  53.    LD   = 'DROIT' 1  A1 A2                                     ;
  54.    LH   = 'DROIT' 1  A2 A3                                     ;
  55.    LG   = 'DROIT' 1  A3 OO                                     ;
  56. *
  57.    SUA  = 'DALL' LB  LD  LH  LG  'PLAN'                        ;
  58.    SU2  = SUA 'PLUS' (0. HS2 0.)                               ;
  59.    VOL1 = 'VOLU' 1 SUA SU2                                     ;
  60.    'ELIM' (HS2/1000.) VOL1                                     ;
  61. *
  62.    SUB = 'POIN' ('COOR' 3 VOL1) 'INFERIEUR' (HS2/1000.)        ;
  63.    SUH = 'POIN' ('COOR' 3 VOL1) 'SUPERIEUR' (HS2 - (HS2/1000.));
  64.    LG  = 'POIN' ('COOR' 1 VOL1) 'INFERIEUR' (HS2/1000.)        ;
  65. * -----------------------------------------------------*
  66. * Conditions aux limites + deplacement impose sur CLZH *
  67. * -----------------------------------------------------*
  68. CLZB = 'BLOQ' UZ SUB                      ;
  69. CLZH = 'BLOQ' UZ SUH                      ;
  70. CLXG = 'BLOQ' UX LG                       ;
  71. CLYG = 'BLOQ' UY SUA                      ;
  72. CLT  = CLZB 'ET' CLZH 'ET' CLXG 'ET' CLYG ;
  73. * -------*
  74. * Modele *
  75. * -------*
  76. MODL1= MODE VOL1 MECANIQUE ELASTIQUE VISCOPLASTIQUE UO2 ;
  77. *
  78. * Temperature moyenne
  79. * -------------------
  80.   TE1 = 1420. + 273.  ;
  81. *
  82. * Porosite initiale (cte au cours du calcul)
  83. * ------------------------------------------
  84.   PO   = 4.52E-2      ;
  85.  
  86. TA = @GATTPAR ('CHAINE' DIVERS '/fichier_gatt');
  87. *
  88. PP = 'MANU' 'CHML' MODL1 'T' TE1 'PORO' PO RIGIDITE ;
  89. *
  90. *
  91. * --------------------------------------*
  92. * 'YOUN' constant ou fonction de T et f *
  93. * --------------------------------------*
  94.  MATREE = MATE MODL1 'YOUN' (TA.'YOUN')          ;
  95.  EE     = 'VARI' 'NUAG' MODL1 MATREE PP          ;
  96. * EE     = (TA.'YOUN')                            ;
  97.  MATREE = MATE MODL1 'YOUN' EE                   ;
  98. * ------------------------------------*
  99. * 'NU' constant ou fonction de T et f *
  100. * ------------------------------------*
  101.  MATRUU = MATE MODL1 'NU' (TA.'NU')              ;
  102.  UU     = 'VARI' 'NUAG' MODL1 MATRUU PP          ;
  103. * UU     = (TA.'NU')                              ;
  104. * --------------------------------------*
  105. * 'ALPH' constant                       *
  106. * --------------------------------------*
  107.  XALFA  = 1.319E-5 ;
  108. * -----------------------------------------------------------------*
  109. * Temperature de reference et temperature de reference pour 'ALPH' *
  110. * -----------------------------------------------------------------*
  111.  TREF   = 1320. + 273. ;
  112.  TALPHA = 0.  ;
  113. *
  114. * -----------------------------*
  115. * Materiau partie GATT_MONERIE *
  116. * -----------------------------*
  117. * fluage primaire
  118.   TA.'KPUO'   = 0.                ;
  119. * fluage secondaire (2 mecanismes)
  120.   TA.'K1'   = 0.                  ;
  121.   TA.'K2'   = 0.                  ;
  122. * fluage d"irradiation
  123.   TA.'A'    = 0.                  ;
  124. * densification/gonflement
  125.   TA.'BUMI' = 5E3 * (TA.'BUMI')   ;
  126. *
  127. MATR11 = 'MATE' MODL1 'YOUN' EE 'NU' UU 'RHO' (TA.'RHO')  'ALPH' XALFA  'TALP' TALPHA 'TREF' TREF ;
  128. *
  129. MATR12 = 'MATE' MODL1 'R'    (TA.'R')    'DG0' (TA.'DG0') 'DG'  (TA.'DG') 'K1'   (TA.'K1')   'M1'  (TA.'M1')  'Q1'  (TA.'Q1')  'N1'   (TA.'N1') 'K2'   (TA.'K2')   'M2'  (TA.'M2')  'Q2'  (TA.'Q2')  'N2'   (TA.'N2') 'OMEG' (TA.'OMEG') 'H'   (TA.'H')   'Q'   (TA.'Q')   'BETA' (TA.'BETA') 'K'    (TA.'K')    'A'   (TA.'A')   'Q3'  (TA.'Q3')  'N3'   (TA.'N3') 'CR'   (TA.'CR')   'CR1' (TA.'CR1') 'CR2' (TA.'CR2') 'CR3'  (TA.'CR3');
  130. *
  131. MATR13 = 'MATE' MODL1  'KP' (TA.'KPUO')   'AP' (TA.'AP') 'BP' (TA.'BP')     'QP' (TA.'QP') ;
  132. *
  133. MATR14 = 'MATE' MODL1 'ADEN' (TA.'ADEN')   'KGON' (TA.'KGON') 'POR0' (TA.'POR0')   'BUMI' (TA.'BUMI') 'EFIS' (TA.'EFIS')                                ;
  134. *
  135. * TYPE = 0. combustible UO2            sinon combustible AFA3GLAA
  136. * COMP = 0. combustible compressible   sinon incompressible
  137. * DYN  = 0. couplage statique          sinon dynamique
  138. *
  139. * -----------------------------*
  140. * Materiau partie OTTOSEN      *
  141. * -----------------------------*
  142.  MATR16 = 'TAIL' MODL1 ;
  143. *
  144. * Resistance au cisaillement 'GS  ' par defaut: 'YOUN'*1.8E-4
  145. * Ouverture a rupture 'WRUP' = 0 --> 'WRUP' = 2*'GFTR'/'LTR '
  146. * Relation bilineaire 'BILI' = 0 --> 'BILI' = 0 (ouverture)
  147. *
  148.  XGFTR = 1.8   ; XGFTR1=XGFTR ; XGFTR2=XGFTR ; XGFTR3=XGFTR ;
  149.  XLTR  = 150E6 ; XLTR1 =XLTR  ; XLTR2 =XLTR  ; XLTR3 =XLTR  ;
  150.  XBTR  = 0.2   ;
  151. *
  152.  MATR17 = 'MATE' MODL1  'GFTR' XGFTR    'LTR ' XLTR     'BTR ' XBTR 'WRUP' 0.       'BILI' 0. 'GFT1' XGFTR1   'GFT2' XGFTR2   'GFT3' XGFTR3 'GS1 ' 0.       'GS2 ' 0.       'GS3 ' 0. 'LTR1' XLTR1    'LTR2' XLTR2    'LTR3' XLTR3 'WRU1' 0.       'WRU2' 0.       'WRU3' 0. 'BIL1' 0.       'BIL2' 0.       'BIL3' 0.     ;
  153. *
  154. MATR1 = MATR11 'ET' MATR12 'ET' MATR13 'ET' MATR14 'ET' MATR16 'ET' MATR17  ;
  155. *
  156. *
  157. RHO0 = 1. - TA.'POR0'                      ;
  158. TAU0 = TA.'EFIS'*270./238./10950./RHO0     ;
  159. *
  160. *
  161.  'DEBPROC' TRINOME XA*'FLOTTANT' XB*'FLOTTANT' XC*'FLOTTANT' mau*'MOT';
  162.     DISCRI  = ( (XB**2.) - (4.*XA*XC) )**0.5                 ;
  163.     RACINE1 = ( (-1.*XB) + DISCRI ) / (2.*XA)                ;
  164.     RACINE2 = ( (-1.*XB) - DISCRI ) / (2.*XA)                ;
  165.     LRACINE = 'PROG' RACINE1 RACINE2                         ;
  166.     PRACINE = RACINE1 * RACINE2                              ;
  167.     SRACINE = RACINE1 + RACINE2                              ;
  168.     'SI' (PRACINE '<' 0.)                                    ;
  169.         RACINE = 'MAXI' LRACINE                              ;
  170.     'SINON'                                                  ;
  171.         RACINE = 'MINI' LRACINE                              ;
  172.     'FINSI'                                                  ;
  173.  'FINPROC' RACINE                                            ;
  174. *
  175. *
  176. CONVSIG = 1E6                              ;
  177. CONVTO  = 24.*3600E3                       ;
  178. *
  179. TVIT     = 1.0E6                           ;
  180. UZ_TVIT  = HS2/200.                        ;
  181. VUZ1     = UZ_TVIT/TVIT                    ;
  182. VUZ2     = -0.5 * VUZ1                     ;
  183. VUZ3     =  1.7 * VUZ1                     ;
  184. *
  185. TBIF  = 0.6E6                              ;
  186. TFIN  = 1.0E6                              ;
  187. TFIN2 = 1.9E6                              ;
  188. * ---------------------------------*
  189. * Chargement en deplacement impose *
  190. * ---------------------------------*
  191. DEPZ     = 'DEPI' CLZH 1                                   ;
  192. UZ_TBIF  = VUZ1 * TBIF                                     ;
  193. UZ_TFIN  = UZ_TBIF + (VUZ2*(TFIN-TBIF))                    ;
  194. UZ_TFIN2 = UZ_TFIN + (VUZ3*(TFIN2-TFIN))                   ;
  195. 'TITR' 'DEPLACEMENT IMPOSE'                                ;
  196. EVDEP    = 'EVOL' 'MANU' 'Temps (s)' ('PROG' 0. TBIF     TFIN      TFIN2   ) 'Dep (m)'   ('PROG' 0. UZ_TBIF  UZ_TFIN   UZ_TFIN2)    ;
  197. LDEPX = 'EXTR' EVDEP 'ABSC'                                ;
  198. LDEPY = 'EXTR' EVDEP 'ORDO'                                ;
  199. si DESSI ; 'DESS' EVDEP ; 'FINSI'                          ;
  200. CHARMECA = 'CHAR' 'DIMP' DEPZ EVDEP                        ;
  201. * --------------------------*
  202. * Chargement en temperature *
  203. * --------------------------*
  204. TP1      = 1E-4                                                  ;
  205. TE0      = 1320. + 273.                                          ;
  206. TE2      = (TP1*TFIN2) + TE0                                     ;
  207. CHTEMP   = 'MANU' 'CHPO' VOL1 1 'T' 1.                           ;
  208. EVT      = 'EVOL' 'MANU' ('PROG' 0.  TFIN2)  ('PROG' TE0 TE2)    ;
  209. CHARTEMP = 'CHAR' 'T' CHTEMP EVT                                 ;
  210. * ---------------------------------*
  211. * Chargement en densite de fission *
  212. * ---------------------------------*
  213. PHIP1    = 3E14                                                   ;
  214. PHI2     = PHIP1 * TFIN2                                          ;
  215. CHFISS   = 'MANU' 'CHPO' VOL1 1 'DFIS' 1.                         ;
  216. EVF      = 'EVOL' 'MANU' ('PROG' 0.  TFIN2) ('PROG' 0. PHI2)      ;
  217. CHARFISS = 'CHAR' 'DFIS' CHFISS EVF                               ;
  218. *
  219. * ---------------------*
  220. * -------------------- *
  221. * INSTANTS PRIVILEGIES *
  222. * -------------------- *
  223. * ---------------------*
  224. XA     = (TA.'KGON' / 6.) * TAU0 * PHIP1                  ;
  225. *
  226. LZ     = 'MAXI' ('EXCO' MATR16 'LZZ')                     ;
  227. PENTZ  = -1. * ( (XLTR1**2) / (2.*XGFTR1) )               ;
  228. JZ     = 1./(LZ*PENTZ)                                    ;
  229. LZLIM  = ('MAXI' EE) / (('ABS' PENTZ) * (1.+('MAXI' UU))) ;
  230. WRUPT  = (2.*XGFTR1) / XLTR1                              ;
  231. ERUPT  = WRUPT / LZ                                       ;
  232. WFERM  = XBTR * WRUPT                                     ;
  233. EFERM  = WFERM / LZ                                       ;
  234. * ------------*
  235. * Fissuration *
  236. * ------------*
  237. ET1   = VUZ1/HS2                        ;
  238. ET0   = 0.                              ;
  239. B0    = ET1 - (XALFA*TP1)      ; XB = -1. * B0 ;
  240. XC    = (XLTR1/('MAXI' EE)) - ET0       ;
  241. TFISS = TRINOME XA XB XC 'TFISS'        ;
  242. * ----------*
  243. * Fermeture *
  244. * ----------*
  245. * Ouverture residuelle de fermeture
  246. ET1     = VUZ2    / HS2                    ;
  247. ET0     = UZ_TBIF / HS2                    ;
  248. ETH0    = XALFA*TP1*TBIF          ;
  249. GF0     = XA*(TBIF**2)                     ;
  250. FZ0     = ET0-(ETH0+GF0)                   ;
  251. NUM     = FZ0 + (XLTR1*JZ)                 ;
  252. DEN     = (1./('MAXI' EE)) + JZ            ;
  253. SMAX    = NUM/DEN                          ;
  254. EMAX    = JZ*(SMAX-XLTR1)                  ;
  255. WMAX    = EMAX * LZ                        ;
  256. WFERM   = XBTR * WMAX                      ;
  257. EFERM   = WFERM / LZ                       ;
  258. JZ_PRIM = (EMAX - EFERM) / SMAX            ;
  259. *
  260. B0      = ET1 - (XALFA*TP1)       ; XB = -1. * B0 ;
  261. XC      = (EFERM + (ET1*TBIF)) - ET0       ;
  262. TFERM   = TRINOME XA XB XC 'TFERM'         ;
  263. * ------------*
  264. * Reouverture *
  265. * ------------*
  266. ET1     = VUZ3    / HS2                    ;
  267. ET0     = 'IPOL' TFERM LDEPX (LDEPY/HS2)   ;
  268. ETH0    = XALFA*TP1*TFERM         ;
  269. GF0     = XA*(TFERM**2)                    ;
  270. FZ0     = ET0-(ETH0+GF0)                   ;
  271. ET0     = UZ_TFIN / HS2                    ;
  272. *
  273. B0      = ET1 - (XALFA*TP1)       ; XB = -1. * B0 ;
  274. XC      = (FZ0 + (ET1*TFIN)) - ET0         ;
  275. TREOUV   = TRINOME XA XB XC 'TREOUV'       ;
  276. * --------------------------- *
  277. * Poursuite de la fissuration *
  278. * --------------------------- *
  279. ET0     = 'IPOL' TREOUV LDEPX (LDEPY/HS2)  ;
  280. ETH0    = XALFA*TP1*TREOUV        ;
  281. GF0     = XA*(TREOUV**2)                   ;
  282. FZ0     = ET0-(ETH0+GF0)                   ;
  283. ET0     = UZ_TFIN / HS2                    ;
  284. *
  285. B0      = ET1 - (XALFA*TP1)       ; XB = -1. * B0 ;
  286. XC0     = (1./('MAXI' EE)) + JZ_PRIM       ;
  287. XC0     = SMAX * XC0                       ;
  288. XC      = (FZ0 + XC0 + (ET1*TFIN)) - ET0   ;
  289. TBIF2   = TRINOME XA XB XC 'TBIF2'         ;
  290. * -------------------*
  291. * Liste des instants *
  292. * -------------------*
  293. VPAS  = TVIT/40.                                                      ;
  294. LTIME = ('PROG' 0. 'PAS' VPAS TBIF  'PAS' VPAS TFIN  'PAS' VPAS TFIN2) 'ET' ('PROG' TFERM TREOUV TBIF2)                                   ;
  295. LTIME = 'ORDO' LTIME                                                  ;
  296. UN    = 'PROG' ('DIME' LTIME)*1                                       ;
  297. * -------------------*
  298. * Deformation totale *
  299. * -------------------*
  300. EVEPS = EVDEP / HS2                                ;
  301. LEPSX = 'EXTR' EVEPS 'ABSC'                        ;
  302. LEPSY = 'EXTR' EVEPS 'ORDO'                        ;
  303. LEPS  = 'IPOL' LTIME LEPSX LEPSY                   ;
  304. 'TITR' 'DEFORMATION IMPOSEE'                       ;
  305. EVEPS = 'EVOL' 'MANU' 'Temps (s)' LTIME 'Def' LEPS ;
  306. 'SI' DESSI ; 'DESS' EVEPS ; 'FINSI' ;
  307. * -------------------------------------*
  308. * Temperature et deformation thermique *
  309. * -------------------------------------*
  310. LT  = (TP1*LTIME) + ((TE0-273.)*UN)               ;
  311. 'TITR' 'TEMPERATURE'                              ;
  312. EVT = 'EVOL' 'MANU' 'Temps (s)' LTIME 'T (_C)' LT ;
  313. 'SI' DESSI ; 'DESS' EVT ; 'FINSI' ;
  314. *
  315. LTH    = XALFA*TP1*LTIME                      ;
  316. 'TITR' 'DEFORMATION THERMIQUE'                         ;
  317. EVDTH  = 'EVOL' 'MANU' 'Temps (s)' LTIME 'Def Th' LTH  ;
  318. 'SI' DESSI ; 'DESS' EVDTH ; 'FINSI' ;
  319. * -------------------*
  320. * Densite de fission *
  321. * -------------------*
  322. LPHI     = PHIP1*LTIME                                            ;
  323. 'TITR' 'DENSITE DE FISSION'                                       ;
  324. EVF      = 'EVOL' 'MANU' 'Temps (s)' LTIME 'Phi (SI)' LPHI        ;
  325. 'SI' DESSI ; 'DESS' EVF ; 'FINSI' ;
  326. * ------------------------------------------------*
  327. * Taux de combustion et deformation de gonflement *
  328. * ------------------------------------------------*
  329.  LTO     = (TAU0*PHIP1/2.)*(LTIME**2)                                  ;
  330. 'TITR' 'TAUX DE COMBUSTION'                                            ;
  331.  EVTO_SI = 'EVOL' 'MANU' 'Temps (s)' LTIME 'Taux(SI)' LTO              ;
  332. 'SI' DESSI ; 'DESS' EVTO_SI ; 'FINSI' ;
  333.  EVTO    = 'EVOL' 'MANU' 'Temps (s)' LTIME 'Taux(MWj/tU)' (LTO/CONVTO) ;
  334. 'SI' DESSI ; 'DESS' EVTO ; 'FINSI' ;
  335. *
  336.  LGF     = (TA.'KGON' / 3.) * LTO                                      ;
  337. 'TITR' 'DEFORMATION DE GONFLEMENT'                                     ;
  338.  EVGF    = 'EVOL' 'MANU' 'Temps (s)' LTIME 'Def Gonf' LGF              ;
  339. 'SI' DESSI ; 'DESS' EVGF ; 'FINSI' ;
  340.  
  341. * ***************** *
  342. * AVANT FISSURATION *
  343. * ***************** *
  344. LTIME_AV = LTIME 'MASQ' 'EGINFE' TFISS                             ;
  345. LFZ      = LEPS-(LTH+LGF)                                          ;
  346. *
  347. LSIGZ  = ('MAXI' EE) * LFZ                                         ;
  348. SIGF   = 'IPOL' TFISS LTIME (LSIGZ/CONVSIG)                        ;
  349. * ************************************** *
  350. * APRES FISSURATION ET AVANT BIFURCATION *
  351. * ************************************** *
  352. LTIME_AP = LTIME 'MASQ' 'SUPERIEUR' TFISS                          ;
  353. LJZ      = JZ * LTIME_AP                                           ;
  354. NUM      = LFZ + (XLTR1*LJZ)                                       ;
  355. LE1      = (1./('MAXI' EE))*UN                                     ;
  356. DEN      = LE1 + LJZ                                               ;
  357. LSIGZ    = NUM/DEN                                                 ;
  358. *
  359. LXLTR1  = XLTR1*UN                                                 ;
  360. LWZ     = LTIME_AP * ( (LSIGZ-LXLTR1)/PENTZ )                      ;
  361. *
  362. LEPSZF  = LWZ / LZ                                                 ;
  363. *
  364. SIGZB = 'IPOL' TBIF LTIME (LSIGZ/CONVSIG)                          ;
  365. WB    = 'IPOL' TBIF LTIME LWZ                                      ;
  366. * ********************************* *
  367. * APRES BIFURCATION ET EN FERMETURE *
  368. * ********************************* *
  369. LTIME_AV = LTIME 'MASQ' 'EGINFE'    TBIF                 ;
  370. LTIME_AP = LTIME 'MASQ' 'SUPERIEUR' TBIF                 ;
  371. LJZ_PRIM = JZ_PRIM * LTIME_AP                            ;
  372. LEFERM   = EFERM   * LTIME_AP                            ;
  373. NUM      = LFZ - LEFERM                                  ;
  374. DEN      = LE1 + LJZ_PRIM                                ;
  375. LSIGZ    = (LSIGZ  * LTIME_AV) + ((NUM/DEN) * LTIME_AP)  ;
  376. *
  377. LEMAX    = EMAX * LTIME_AP                               ;
  378. LSMAX    = SMAX * LTIME_AP                               ;
  379. LEPSZF   = (LEPSZF * LTIME_AV) + LEMAX + (LJZ_PRIM * (LSIGZ - LSMAX))          ;
  380. *
  381. LWZ      = LZ * LEPSZF                                   ;
  382. *
  383. SIGZC  = 'IPOL' TFERM  LTIME (LSIGZ/CONVSIG)             ;
  384. WFERMC = 'IPOL' TFERM  LTIME LWZ                         ;
  385. * ****************************** *
  386. * APRES FERMETURE EN COMPRESSION *
  387. * ****************************** *
  388. LTIME_AV = LTIME 'MASQ' 'EGINFE'    TFERM              ;
  389. LTIME_AP = LTIME 'MASQ' 'SUPERIEUR' TFERM              ;
  390. *
  391. ET0      = 'IPOL' TFERM LTIME LEPS                     ;
  392. ETH0     = XALFA*TP1*TFERM                    ;
  393. GF0      = XA*(TFERM**2)                               ;
  394. FZ0      = ET0-(ETH0+GF0)                              ;
  395. *
  396. LSIGZ_AP = ('MAXI' EE) * (LFZ - (FZ0 * LTIME_AP))      ;
  397. LSIGZ    = (LSIGZ  * LTIME_AV) + (LSIGZ_AP * LTIME_AP) ;
  398. *
  399. LEPSZF   = (LEPSZF * LTIME_AV) + (EFERM * LTIME_AP)    ;
  400. *
  401. LWZ      = LZ * LEPSZF                                 ;
  402. *
  403. SIGZC    = 'IPOL' TREOUV  LTIME (LSIGZ/CONVSIG)        ;
  404. * ****************************************** *
  405. * REOUVERTURE AVANT POURSUITE DE FISSURATION *
  406. * ****************************************** *
  407. LTIME_AV = LTIME 'MASQ' 'EGINFE'    TREOUV               ;
  408. LTIME_AP = LTIME 'MASQ' 'SUPERIEUR' TREOUV               ;
  409. *
  410. ET0      = 'IPOL' TREOUV LTIME LEPS                      ;
  411. ETH0     = XALFA*TP1*TREOUV                     ;
  412. GF0      = XA*(TREOUV**2)                                ;
  413. FZ0      = ET0-(ETH0+GF0)                                ;
  414. NUM      = LFZ - (FZ0 * LTIME_AP)                        ;
  415. LJZ_PRIM = JZ_PRIM * LTIME_AP                            ;
  416. DEN      = LE1 + LJZ_PRIM                                ;
  417. LSIGZ    = (LSIGZ  * LTIME_AV) + ((NUM/DEN) * LTIME_AP)  ;
  418. *
  419. LEMAX    = EMAX * LTIME_AP                               ;
  420. LSMAX    = SMAX * LTIME_AP                               ;
  421. LEPSZF   = (LEPSZF * LTIME_AV) + LEMAX + (LJZ_PRIM * (LSIGZ - LSMAX))          ;
  422. *
  423. LWZ      = LZ * LEPSZF                                   ;
  424. * ************************ *
  425. * POURSUITE DE FISSURATION *
  426. * ************************ *
  427. LTIME_AV = LTIME 'MASQ' 'EGINFE'    TBIF2               ;
  428. LTIME_AP = LTIME 'MASQ' 'SUPERIEUR' TBIF2               ;
  429. *
  430. LJZ      = JZ * LTIME_AP                                           ;
  431. NUM      = LFZ + (XLTR1*LJZ)                                       ;
  432. DEN      = LE1 + LJZ                                               ;
  433. LSIGZ    = (LSIGZ  * LTIME_AV) + ((NUM/DEN) * LTIME_AP)            ;
  434. *
  435. LWZ      = (LWZ * LTIME_AV) + (LTIME_AP * ( (LSIGZ-LXLTR1)/PENTZ ));
  436. *
  437. LEPSZF  = LWZ / LZ                                                 ;
  438. *
  439. SIGZC  = 'IPOL' TBIF2  LTIME (LSIGZ/CONVSIG)             ;
  440. WC     = 'IPOL' TBIF2  LTIME LWZ                         ;
  441. *
  442. 'TITR' 'CONTRAINTE DANS LA DIRECTION Z'                              ;
  443. EVSIGZ = 'EVOL' 'ROUG' 'MANU' 'Temps (s)' LTIME 'SIGZ(MPa)' (LSIGZ/CONVSIG)             ;
  444. 'SI' DESSI ; 'DESS' EVSIGZ; 'FINSI'                                   ;
  445. 'TITR' 'OUVERTURE DANS LA DIRECTION Z'                                ;
  446. EVWZ   = 'EVOL' 'ROUG' 'MANU' 'Temps (s)' LTIME 'WZ(m)' LWZ           ;
  447. 'SI' DESSI ; 'DESS' EVWZ; 'FINSI'                                     ;
  448. 'TITR' 'DEFORMATION DE FISSURATION DANS LA DIRECTION Z'               ;
  449. EVEPSFZ = 'EVOL' 'ROUG' 'MANU' 'Temps (s)' LTIME 'EPSFZ' LEPSZF       ;
  450. 'SI' DESSI ; 'DESS' EVEPSFZ; 'FINSI'                                  ;
  451. 'TITR' 'RELATION CONTRAINTE/OUVERTURE DANS LA DIRECTION Z'            ;
  452. EV_FISZ = 'EVOL' 'ROUG' 'MANU' 'WZ(m)' LWZ 'SIGZ(MPa)' (LSIGZ/CONVSIG);
  453. 'SI' DESSI ; 'DESS' EV_FISZ; 'FINSI'                                  ;
  454. *-------------------*
  455. * Instants calcules *
  456. *-------------------*
  457. LIST1 = 'PROG' 0.  'PAS' 200.   3000. 'PAS' 1000.  10000. 'PAS' 10000. TFIN2 ;
  458. * ---------------------------------------*
  459. * Variables internes initiales 'PORO'=PO *
  460. * ---------------------------------------*
  461. VAR00 = 'ZERO' MODL1 'VARINTER'                                    ;
  462. VAR01 = 'MANU' 'CHML' MODL1 'PORO' PO 'TYPE' 'VARIABLES INTERNES' 'STRESSES' ;
  463. VAR0 = VAR00 + VAR01                                               ;
  464. *
  465. CHARTOT = CHARMECA 'ET' CHARTEMP 'ET' CHARFISS             ;
  466. *
  467.  TAB1                          = TABLE   ;
  468. * TAB1.'TEMPERATURES'           = TABLE   ;
  469.  TAB1.'VARIABLES_INTERNES'     = TABLE   ;
  470.  TAB1.'BLOCAGES_MECANIQUES'    = CLT     ;
  471.  TAB1.'MODELE'                 = MODL1   ;
  472.  TAB1.'CHARGEMENT'             = CHARTOT ;
  473.  TAB1.'VARIABLES_INTERNES' . 0 = VAR0    ;
  474.  TAB1.'CARACTERISTIQUES'       = MATR1   ;
  475.  TAB1.'TEMPS_CALCULES'         = LIST1   ;
  476.  TAB1.'TEMPS_SAUVES'           = LIST1   ;
  477. *
  478. TMASAU=table;
  479. tab1 . 'MES_SAUVEGARDES'=TMASAU;
  480. TMASAU .'DEFTO'=VRAI;
  481. TMASAU .'DEFIN'=VRAI;
  482.  
  483.  PASAPAS TAB1                            ;
  484. *
  485. *
  486. TT    = TAB1 . 'TEMPS'                      ;
  487. SS    = TAB1 . 'CONTRAINTES'                ;
  488. VV    = TAB1 . 'VARIABLES_INTERNES'         ;
  489. IN    = TAB1 . 'DEFORMATIONS_INELASTIQUES'  ;
  490. NCONT = 'DIME' TAB1 . 'CONTRAINTES'         ;
  491. *
  492. LZEIT  = 'PROG' ;
  493. LSIGZ  = 'PROG' ;
  494. LW1    = 'PROG' ;
  495. LW2    = 'PROG' ;
  496. LW3    = 'PROG' ;
  497. LEPSZF = 'PROG' ;
  498. *
  499. *
  500. 'REPE' BLOC NCONT ;
  501. *
  502.   IND  = &BLOC - 1         ;
  503.   ZEIT = TT.IND            ;
  504. *
  505.   SIG  = SS.IND            ;
  506.   SIGZ = 'EXCO' SIG 'SMZZ' ;
  507.   SIGZ_MAX = 'MAXI' SIGZ   ; SIGZ_MIN = 'MINI' SIGZ   ;
  508. *
  509.   VI    = VV.IND                    ;
  510.   EI    = IN.IND                    ;
  511. *
  512.   W1    = 'MAXI' ('EXCO' VI 'W1')   ;
  513.   W2    = 'MAXI' ('EXCO' VI 'W2')   ;
  514.   W3    = 'MAXI' ('EXCO' VI 'W3')   ;
  515.   EPSZF = 'MAXI' ('EXCO' EI 'EIZZ') ;
  516. *
  517.   LZEIT  = LZEIT  'ET' ('PROG' ZEIT)       ;
  518.   LSIGZ  = LSIGZ  'ET' ('PROG' SIGZ_MAX)   ;
  519.   LW1    = LW1    'ET' ('PROG' W1)         ;
  520.   LW2    = LW2    'ET' ('PROG' W2)         ;
  521.   LW3    = LW3    'ET' ('PROG' W3)         ;
  522.   LEPSZF = LEPSZF 'ET' ('PROG' EPSZF)      ;
  523. *
  524. 'FIN' BLOC ;
  525. *
  526. *
  527. * -----------------------*
  528. * Controle des resultats *
  529. * -----------------------*
  530. LSOUS   = 'PROG' 1E3 'PAS' 2E3 9E3 1E5 8E5 1.5E6 1.6E6 ;
  531.  
  532. UN      = 'PROG' ('DIME' LSOUS)*1                          ;
  533. *
  534. SZ_CAL  = 'IPOL' LSOUS LZEIT LSIGZ                              ;
  535. SZ_ANA  = 'IPOL' LSOUS LTIME (('EXTR' EVSIGZ 'ORDO') * CONVSIG) ;
  536. EFZ_CAL = 'IPOL' LSOUS LZEIT LEPSZF                             ;
  537. EFZ_ANA = 'IPOL' LSOUS LTIME ('EXTR' EVEPSFZ 'ORDO')            ;
  538. WZ_CAL  = 'IPOL' LSOUS LZEIT LW1                                ;
  539. WZ_ANA  = 'IPOL' LSOUS LTIME ('EXTR' EVWZ 'ORDO')               ;
  540. *
  541. PREX = 5E-2                                            ;
  542. T_SZ = (SZ_ANA - SZ_CAL) / (SZ_ANA + UN)               ;
  543. T_SZ = 'MAXI' ('ABS' T_SZ)                             ;
  544. 'SI' ( T_SZ '&lt;EG' PREX )                               ;
  545.    'ERRE' 0                                            ;
  546. 'SINO'                                                 ;
  547.    'MESS' 'ERREUR MAXIMALE CONTRAINTE SELON Z > ' PREX ;
  548.    'ERRE' 5                                            ;
  549. 'FINS'                                                 ;
  550. *
  551. WRUPT   = (2.*XGFTR1) / XLTR1                          ;
  552. ERUPT   = WRUPT / LZ                                   ;
  553. NONZERO = (ERUPT / 1E6) * UN                           ;
  554. T_FZ = (EFZ_ANA - EFZ_CAL) / (EFZ_ANA +  NONZERO)      ;
  555. T_FZ = 'MAXI' ('ABS' T_FZ)                             ;
  556. 'SI' ( T_FZ '&lt;EG' PREX )                               ;
  557.    'ERRE' 0                                            ;
  558. 'SINO'                                                 ;
  559.    'MESS' 'ERREUR MAXIMALE DEFORMATION DE FISSURATION SELON Z > ' PREX                            ;
  560.    'ERRE' 5                                            ;
  561. 'FINS'                                                 ;
  562. *
  563. NONZERO = (WRUPT / 1E6) * UN                           ;
  564. T_WZ = (WZ_ANA - WZ_CAL) / (WZ_ANA +  NONZERO)         ;
  565. T_WZ = 'MAXI' ('ABS' T_WZ)                             ;
  566. 'SI' ( T_WZ '&lt;EG' PREX )                               ;
  567.    'ERRE' 0                                            ;
  568. 'SINO'                                                 ;
  569.    'MESS' 'ERREUR MAXIMALE OUVERTURE SELON Z > ' PREX  ;
  570.    'ERRE' 5                                            ;
  571. 'FINS'                                                 ;
  572. *
  573. *
  574. TAB               = 'TABLE'               ;
  575. TAB . 'TITRE'     = 'TABLE'               ;
  576. TAB . 'TITRE' . 1 = 'Solution Analytique' ;
  577. TAB . 'TITRE' . 2 = 'Solution Calculee'   ;
  578. *
  579. *
  580. EVSIGZ0 = 'EVOL' 'MANU' 'Temps (s)' LZEIT  'SIGZ(MPa)' (LSIGZ/CONVSIG);
  581. 'SI' DESSI                                 ;
  582.    'TITR' 'CONTRAINTE DANS LA DIRECTION Z' ;
  583.    'DESS' (EVSIGZ 'ET' EVSIGZ0) TAB 'LEGE' ;
  584. 'FINSI'                                    ;
  585. *
  586. EVWZ0  = 'EVOL' 'MANU' 'Temps (s)' LZEIT  'WZ(m)' LW1 ;
  587. 'SI' DESSI                                            ;
  588.    'TITR' 'OUVERTURE DANS LA DIRECTION Z'             ;
  589.    'DESS' (EVWZ 'ET' EVWZ0) TAB 'LEGE'                ;
  590. 'FINSI'                                               ;
  591. *
  592. EVEPSFZ0 = 'EVOL' 'MANU' 'Temps (s)' LZEIT  'EPSFZ' LEPSZF ;
  593. 'SI' DESSI                                                 ;
  594.    'TITR' 'DEFORMATION DE FISSURATION DANS LA DIRECTION Z' ;
  595.    'DESS' (EVEPSFZ 'ET' EVEPSFZ0) TAB 'LEGE'               ;
  596. 'FINSI'                                                    ;
  597. *
  598. EVFISZ = 'EVOL' 'MANU' 'WZ(m)' LW1 'SIGZ(MPa)' (LSIGZ/CONVSIG)       ;
  599. 'SI' DESSI                                                           ;
  600.    'TITR' 'RELATION CONTRAINTE/OUVERTURE DANS LA DIRECTION Z'        ;
  601.    'DESS' (EV_FISZ 'ET' EVFISZ) TAB 'LEGE'                           ;
  602. 'FINSI'                                                              ;
  603. *
  604. 'FIN';
  605.  
  606.  
  607.  
  608.  
  609.  
  610.  
  611.  
  612.  
  613.  
  614.  
  615.  
  616.  
  617.  
  618.  
  619.  
  620.  
  621.  
  622.  
  623.  
  624.  
  625.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales