Télécharger uo2_cas1.dgibi

Retour à la liste

Numérotation des lignes :

  1. * fichier : uo2_cas1.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4. *
  5. * Test uo2_cas1.dgibi: Jeux de donnees
  6. * ------------------------------------
  7. *
  8. 'OPTI' 'DIME' 3 'MODE' 'TRID' ;
  9. 'OPTI' 'ELEM' 'CUB8' ;
  10. 'OPTI' 'TRAC' 'PSC' ;
  11. 'TEMPS' 'ZERO' ;
  12. L = 'MOT' LIST ; F = 'MOT' FIN ;
  13. *
  14. **********************************************************
  15. * TEST DE VALIDATION *
  16. * ------------------ *
  17. * MODELE UO2 *
  18. * (COUPLAGE DES MODELES GATT_MONERIE ET OTTOSEN) *
  19. * UO2 STANDARD COMPRESSIBLE AVEC COUPLAGE STATIQUE *
  20. * *
  21. * MAILLAGE: *
  22. * CUBE *
  23. * *
  24. * CHARGEMENT: *
  25. * DEPLACEMENTS IMPOSES A VITESSES CTE EN TRACTION *
  26. * SELON LES DIRECTIONS Z ET X : *
  27. * VIT DE DEF EN X = 0.8 * (VIT DE DEF EN Z) *
  28. * TEMPERATURE CTE *
  29. * DENSITE DE FISSIONS CTE *
  30. * OTTOSEN ACTIVE (FISSURATIONS PUIS RUPTURES DS LES *
  31. * DEUX DIRECTIONS (D ABORD Z PUIS X) *
  32. * VISCOPLASTICITE SIMPLIFIEE (VIA CHOIX DES COEFS) *
  33. * ACTIVEE *
  34. * GONFLEMENT ACTIVE *
  35. * PAS DE DENSIFICATION *
  36. **********************************************************
  37. *
  38. DESSI = FAUX ;
  39. *
  40. * -----------------------------*
  41. * MAILLAGE D UN CUBE DE COTE 1 *
  42. * -----------------------------*
  43. HS2 = 2E-5 ;
  44. *
  45. OO = 0. 0. 0. ;
  46. A1 = HS2 0. 0. ;
  47. A2 = HS2 0. HS2 ;
  48. A3 = 0. 0. HS2 ;
  49. *
  50. LB = 'DROIT' 1 OO A1 ;
  51. LD = 'DROIT' 1 A1 A2 ;
  52. LH = 'DROIT' 1 A2 A3 ;
  53. LG = 'DROIT' 1 A3 OO ;
  54. *
  55. SUA = 'DALL' LB LD LH LG 'PLAN' ;
  56. SU2 = SUA 'PLUS' (0. HS2 0.) ;
  57. VOL1 = 'VOLU' 1 SUA SU2 ;
  58. 'ELIM' (HS2/1000.) VOL1 ;
  59. *
  60. SUB = 'POIN' ('COOR' 3 VOL1) 'INFERIEUR' (HS2/1000.) ;
  61. SUH = 'POIN' ('COOR' 3 VOL1) 'SUPERIEUR' (HS2 - (HS2/1000.));
  62. LG = 'POIN' ('COOR' 1 VOL1) 'INFERIEUR' (HS2/1000.) ;
  63. LD = 'POIN' ('COOR' 1 VOL1) 'SUPERIEUR' (HS2 - (HS2/1000.));
  64. *
  65. VOL2 = VOL1 'TOUR' 45. OO (0 HS2 0);
  66. SUB2 = SUB 'TOUR' 45. OO (0 HS2 0); 'ELIM' (HS2/1000.) vol2 SUB2;
  67. SUH2 = SUH 'TOUR' 45. OO (0 HS2 0); 'ELIM' (HS2/1000.) vol2 SUH2;
  68. LG2 = LG 'TOUR' 45. OO (0 HS2 0); 'ELIM' (HS2/1000.) vol2 LG2 ;
  69. LD2 = LD 'TOUR' 45. OO (0 HS2 0); 'ELIM' (HS2/1000.) vol2 LD2 ;
  70. SUA2 = SUA 'TOUR' 45. OO (0 HS2 0); 'ELIM' (HS2/1000.) vol2 SUA2;
  71. VOL1 = VOL2 ;
  72.  
  73. VX2 = (1 0 0) 'TOUR' 45. OO (0 HS2 0);
  74. VZ2 = (0 0 1) 'TOUR' 45. OO (0 HS2 0);
  75. * -----------------------------------------------------*
  76. * Conditions aux limites + deplacement impose sur CLZH *
  77. * -----------------------------------------------------*
  78. CLZB = 'BLOQ' SUB2 'DIRECTION' VZ2 ;
  79. CLZH = 'BLOQ' SUH2 'DIRECTION' VZ2 ;
  80. CLXG = 'BLOQ' LG2 'DIRECTION' VX2 ;
  81. CLXD = 'BLOQ' LD2 'DIRECTION' VX2 ;
  82. CLYG = 'BLOQ' UY SUA2 ;
  83. CLT = CLZB 'ET' CLZH 'ET' CLXG 'ET' CLXD 'ET' CLYG ;
  84. * -------*
  85. * Modele *
  86. * -------*
  87. MODL1= MODE VOL1 MECANIQUE ELASTIQUE VISCOPLASTIQUE UO2 ;
  88. *
  89. TA = @GATTPAR '/u2/castem/divers/fichier_gatt' ;
  90. *
  91. * Temperature moyenne (cte au cours du calcul)
  92. * --------------------------------------------
  93. TE1 = 1420. + 273. ;
  94. *
  95. * Porosite initiale
  96. * -----------------
  97. PO = 4.52E-2 ;
  98. *
  99. * Densite de fission (cte au cours du calcul)
  100. * -------------------------------------------
  101. PHI1 = 3E20 ;
  102. *
  103. RHO0 = 1. - TA.'POR0' ;
  104. TAU0 = TA.'EFIS'*270./238./10950./RHO0 ;
  105. *
  106. PP = 'MANU' 'CHML' MODL1 'T' TE1 'PORO' PO RIGIDITE ;
  107. *
  108. *
  109. * --------------------------------------*
  110. * 'YOUN' constant ou fonction de T et f *
  111. * --------------------------------------*
  112. MATREE = MATE MODL1 'YOUN' (TA.'YOUN') ;
  113. EE = 'VARI' 'NUAG' MODL1 MATREE PP ;
  114. * EE = (TA.'YOUN') ;
  115. MATREE = MATE MODL1 'YOUN' EE ;
  116. * ------------------------------------*
  117. * 'NU' constant ou fonction de T et f *
  118. * ------------------------------------*
  119. MATRUU = MATE MODL1 'NU' (TA.'NU') ;
  120. UU = 'VARI' 'NUAG' MODL1 MATRUU PP ;
  121. * UU = (TA.'NU') ;
  122. * --------------------------------------*
  123. * 'ALPH' constant ou fonction de T et f *
  124. * --------------------------------------*
  125. MATRAA = MATE MODL1 'ALPH' (TA.'ALPH') ;
  126. XALFA = 'VARI' 'NUAG' MODL1 MATRAA PP ;
  127. * XALFA = (TA.'ALPH') ;
  128. MATRAA = MATE MODL1 'ALPH' XALFA ;
  129. * -----------------------------------------------------------------*
  130. * Temperature de reference et temperature de reference pour 'ALPH' *
  131. * -----------------------------------------------------------------*
  132. TREF = TE1 ;
  133. TALPHA = 0. ;
  134. * ----------------------------------------*
  135. * 'ALPH' pour la temperature de reference *
  136. * ----------------------------------------*
  137. PP = 'MANU' 'CHML' MODL1 'T' TREF 'PORO' PO RIGIDITE ;
  138. ALFATREF = 'MAXI' ('VARI' 'NUAG' MODL1 MATRAA PP) ;
  139. *
  140. * -----------------------------*
  141. * Materiau partie GATT_MONERIE *
  142. * -----------------------------*
  143. * fluage primaire (negligeable devant le fluage d'irradiation)
  144. TA.'AP' = 1 ;
  145. TA.'BP' = 0 ;
  146. * fluage secondaire (2 mecanismes)
  147. TA.'N1' = 1. ;
  148. TA.'N2' = 1. ;
  149. * fluage d"irradiation
  150. TA.'N3' = 1. ;
  151. * fonction de couplage
  152. TA.'OMEG' = 0. ;
  153. * densification/gonflement
  154. TA.'BUMI' = 5E3 * (TA.'BUMI') ;
  155. *
  156. MATR11 = 'MATE' MODL1 'YOUN' EE 'NU' UU 'RHO' (TA.'RHO') 'ALPH' XALFA ;
  157. *
  158. MATR12 = 'MATE' MODL1
  159. 'R' (TA.'R') 'DG0' (TA.'DG0') 'DG' (TA.'DG')
  160. 'K1' (TA.'K1') 'M1' (TA.'M1') 'Q1' (TA.'Q1') 'N1' (TA.'N1')
  161. 'K2' (TA.'K2') 'M2' (TA.'M2') 'Q2' (TA.'Q2') 'N2' (TA.'N2')
  162. 'OMEG' (TA.'OMEG') 'H' (TA.'H') 'Q' (TA.'Q') 'BETA' (TA.'BETA')
  163. 'K' (TA.'K') 'A' (TA.'A') 'Q3' (TA.'Q3') 'N3' (TA.'N3')
  164. 'CR' (TA.'CR') 'CR1' (TA.'CR1') 'CR2' (TA.'CR2') 'CR3' (TA.'CR3');
  165. *
  166. MATR13 = 'MATE' MODL1 'KP' (TA.'KPUO') 'AP' (TA.'AP')
  167. 'BP' (TA.'BP') 'QP' (TA.'QP') ;
  168. *
  169. MATR14 = 'MATE' MODL1
  170. 'ADEN' (TA.'ADEN') 'KGON' (TA.'KGON')
  171. 'POR0' (TA.'POR0') 'BUMI' (TA.'BUMI')
  172. 'EFIS' (TA.'EFIS') ;
  173. *
  174. * TYPE = 0. combustible UO2 sinon combustible AFA3GLAA
  175. * COMP = 0. combustible compressible sinon incompressible
  176. * DYN = 0. couplage statique sinon dynamique
  177. *
  178. * -----------------------------*
  179. * Materiau partie OTTOSEN *
  180. * -----------------------------*
  181. MATR16 = 'TAIL' MODL1 ;
  182. *
  183. * Resistance au cisaillement 'GS ' par defaut: 'YOUN'*1.8E-4
  184. * Ouverture a rupture 'WRUP' = 0 --> 'WRUP' = 2*'GFTR'/'LTR '
  185. * Relation bilineaire 'BILI' = 0 --> 'BILI' = 0 (ouverture)
  186. *
  187. XGFTR = 1.8 ; XGFTR1=XGFTR ; XGFTR2=XGFTR ; XGFTR3=XGFTR ;
  188. XLTR = 150E6 ; XLTR1 =XLTR ; XLTR2 =XLTR ; XLTR3 =XLTR ;
  189. XBTR = 0.2 ;
  190. *
  191. MATR17 = 'MATE' MODL1 'GFTR' XGFTR 'LTR ' XLTR 'BTR ' XBTR
  192. 'WRUP' 0. 'BILI' 0.
  193. 'GFT1' XGFTR1 'GFT2' XGFTR2 'GFT3' XGFTR3
  194. 'GS1 ' 0. 'GS2 ' 0. 'GS3 ' 0.
  195. 'LTR1' XLTR1 'LTR2' XLTR2 'LTR3' XLTR3
  196. 'WRU1' 0. 'WRU2' 0. 'WRU3' 0.
  197. 'BIL1' 0. 'BIL2' 0. 'BIL3' 0. ;
  198. *
  199. MATR1 = MATR11 'ET' MATR12 'ET' MATR13 'ET'
  200. MATR14 'ET' MATR16 'ET' MATR17 ;
  201. *
  202. *
  203. ************************************************************************
  204. 'DEBP' XFONC FN*'FLOTTANT' XFN1*'FLOTTANT' DT*'FLOTTANT'
  205. SXN*'FLOTTANT' SZN*'FLOTTANT'
  206. PAX*'FLOTTANT' PAZ*'FLOTTANT'
  207. EX*'FLOTTANT' EZ*'FLOTTANT' NU_SUR_E*'FLOTTANT'
  208. C12*'FLOTTANT' C3*'FLOTTANT' ;
  209.  
  210. UNTIER = 1. / 3. ; DEUXTIER = 2. / 3. ; UNDEMI = 1. / 2. ;
  211.  
  212. det = (EX * EZ) - (NU_SUR_E ** 2) ;
  213. AX = (EZ * PAX) + (NU_SUR_E * PAZ) ;
  214. AZ = (EX * PAZ) + (NU_SUR_E * PAX) ;
  215.  
  216. A = XFN1 / (1. - XFN1) ;
  217. B = (1. + (DEUXTIER * XFN1)) / (1. - XFN1) ;
  218.  
  219. X = UNTIER * C12 * A ;
  220. Y = (DEUXTIER * C12 * B) + (UNDEMI * C3) ;
  221.  
  222. GDT = DT / det ; GDT2 = GDT**2 ;
  223.  
  224. GDET1a = 2. * NU_SUR_E * (Y - X) ;
  225. GDET1b = (EX + EZ) * (X + (2.*Y)) ;
  226. GDET1 = GDT * (GDET1a - GDET1b) ;
  227. GDET2 = 3. * GDT2 * det * Y * (Y + (2.*X)) ;
  228. GDET = (1. - GDET1) + GDET2 ;
  229.  
  230. FONC1a = 3. * Y * GDT * (NU_SUR_E - EX) ;
  231. FONC1a = 1. - FONC1a ;
  232. FONC1b = (GDT * AX) + SXN ;
  233. FONC1c = 3. * Y * GDT * (NU_SUR_E - EZ) ;
  234. FONC1c = 1. - FONC1c ;
  235. FONC1d = (GDT * AZ) + SZN ;
  236. FONC1e = (FONC1b * FONC1a) + (FONC1d * FONC1c) ;
  237. FONC1 = DT * C12 * XFN1 * FONC1e ;
  238. FONC2 = GDET * (XFN1 - FN) ;
  239. VFONC = FONC1 - FONC2 ;
  240. TFONC = ('ABS' VFONC) / FONC1 ;
  241. 'FINP' VFONC TFONC FONC1e GDET ;
  242. ************************************************************************
  243. *
  244. ************************************************************************
  245. 'DEBP' FCTNUL FN*'FLOTTANT' DT*'FLOTTANT'
  246. SXN*'FLOTTANT' SZN*'FLOTTANT'
  247. PAX*'FLOTTANT' PAZ*'FLOTTANT'
  248. EX*'FLOTTANT' EZ*'FLOTTANT' NU_SUR_E*'FLOTTANT'
  249. C12*'FLOTTANT' C3*'FLOTTANT' ;
  250.  
  251. XFN1 = FN ;
  252. V1 TES1 FONCe1 GDET1 = XFONC FN XFN1 DT SXN SZN
  253. PAX PAZ EX EZ NU_SUR_E
  254. C12 C3 ;
  255. XFN2a = GDET1 * FN ;
  256. XFN2b = GDET1 - (DT * C12 * FONCe1) ;
  257. XFN2 = XFN2a / XFN2b ;
  258. *--
  259. 'REPETER' STRU1 ;
  260. *--
  261. V2 TES2 FONCe2 GDET2 = XFONC FN XFN2 DT SXN SZN
  262. PAX PAZ EX EZ NU_SUR_E
  263. C12 C3 ;
  264. PREC = 1E-4 ;
  265. 'SI' ('<EG' TES2 PREC) ;
  266. FN1 = XFN2 ;
  267. GDET1 = GDET2 ;
  268. 'QUIT' STRU1 ;
  269. 'FINSI' ;
  270.  
  271. * 'SI' ('>' &STRU1 100) ;
  272. * 'MESS' 'PAS DE SOLUTION DANS FCTNUL: &STRU1' &STRU1 ;
  273. * 'FINSI' ;
  274.  
  275. * 'SI' ( ('>' (V1 * V2) 0.) 'ET' ('EGA' &STRU1 1) ) ;
  276. * 'MESS' 'MAUVAISE ESTIMATION INITIALE DANS FCTNUL: V1 V2 =' V1 V2 ;
  277. * 'FINSI' ;
  278.  
  279. XX = V1 / (V1 - V2) ;
  280. XXF = ((XFN2 - XFN1) * XX) + XFN1 ;
  281. 'SI' ('<EG' (V1 * V2) 0.) ;
  282. XFN2 = XXF ;
  283. 'SINON' ;
  284. XFN1 = XXF ;
  285. 'FINSI' ;
  286. *--
  287. 'FIN' STRU1 ;
  288. *--
  289. 'FINP' FN1 GDET1 ;
  290. ************************************************************************
  291. *
  292. ************************************************************************
  293. 'DEBP' CONT XFN1*'FLOTTANT' GDET1*'FLOTTANT' DT*'FLOTTANT'
  294. SXN*'FLOTTANT' SZN*'FLOTTANT'
  295. PAX*'FLOTTANT' PAZ*'FLOTTANT'
  296. EX*'FLOTTANT' EZ*'FLOTTANT' NU_SUR_E*'FLOTTANT'
  297. C12*'FLOTTANT' C3*'FLOTTANT' ;
  298.  
  299. UNTIER = 1. / 3. ; DEUXTIER = 2. / 3. ; UNDEMI = 1. / 2. ;
  300.  
  301. det = (EX * EZ) - (NU_SUR_E ** 2) ;
  302. AX = (EZ * PAX) + (NU_SUR_E * PAZ) ;
  303. AZ = (EX * PAZ) + (NU_SUR_E * PAX) ;
  304.  
  305. A = XFN1 / (1. - XFN1) ;
  306. B = (1. + (DEUXTIER * XFN1)) / (1. - XFN1) ;
  307.  
  308. X = UNTIER * C12 * A ;
  309. Y = (DEUXTIER * C12 * B) + (UNDEMI * C3) ;
  310.  
  311. GDT = DT / det ;
  312.  
  313. SZN1a = (GDT * AZ) + SZN ;
  314. SZN1b = NU_SUR_E * (Y - X) ;
  315. SZN1c = EZ * (X + (2. * Y)) ;
  316. SZN1d = 1. - (GDT * (SZN1b - SZN1c)) ;
  317. SZN1e = SZN1a * SZN1d ;
  318. SZN1a = (GDT * AX) + SXN ;
  319. SZN1b = NU_SUR_E * (X + (2. * Y)) ;
  320. SZN1c = EX * (Y - X) ;
  321. SZN1d = GDT * (SZN1c - SZN1b) ;
  322. SZN1 = SZN1e + (SZN1a * SZN1d) ;
  323. SZN1 = SZN1 / GDET1 ;
  324.  
  325. SXN1a = (GDT * AX) + SXN ;
  326. SXN1b = NU_SUR_E * (Y - X) ;
  327. SXN1c = EX * (X + (2. * Y)) ;
  328. SXN1d = 1. - (GDT * (SXN1b - SXN1c)) ;
  329. SXN1e = SXN1a * SXN1d ;
  330. SXN1a = (GDT * AZ) + SZN ;
  331. SXN1b = NU_SUR_E * (X + (2. * Y)) ;
  332. SXN1c = EZ * (Y - X) ;
  333. SXN1d = GDT * (SXN1b - SXN1c) ;
  334. SXN1 = SXN1e - (SXN1a * SXN1d) ;
  335. SXN1 = SXN1 / GDET1 ;
  336.  
  337. 'FINP' SXN1 SZN1 ;
  338. ************************************************************************
  339. *
  340. ************************************************************************
  341. 'DEBP' FISZ XFN1*'FLOTTANT'
  342. SXN1*'FLOTTANT'
  343. PAX*'FLOTTANT' PAZ*'FLOTTANT'
  344. EX*'FLOTTANT' NU_SUR_E*'FLOTTANT'
  345. C12*'FLOTTANT' C3*'FLOTTANT' ;
  346.  
  347. UNTIER = 1. / 3. ; DEUXTIER = 2. / 3. ; UNDEMI = 1. / 2. ;
  348.  
  349. AZ = (EX * PAZ) + (NU_SUR_E * PAX) ;
  350.  
  351. A = XFN1 / (1. - XFN1) ;
  352. B = (1. + (DEUXTIER * XFN1)) / (1. - XFN1) ;
  353.  
  354. X = UNTIER * C12 * A ;
  355. Y = (DEUXTIER * C12 * B) + (UNDEMI * C3) ;
  356.  
  357. VFZ1 = NU_SUR_E * (X + (2. * Y)) ;
  358. VFZ1 = VFZ1 + ((X - Y) * EX) ;
  359. VFZ1 = SXN1 * VFZ1 ;
  360. VEPSFZN1 = (AZ - VFZ1) / EX ;
  361.  
  362. 'FINP' VEPSFZN1 ;
  363. ************************************************************************
  364. *
  365. CONVSIG = 1E6 ;
  366. CONVTO = 24.*3600E3 ;
  367. *
  368. TFIN = 1E5 ;
  369. TMIL = TFIN / 2. ;
  370. *
  371. * ------------------------------*
  372. * Chargement en temperature cte *
  373. * ------------------------------*
  374. TP1 = 1E-4 ;
  375. TE0 = 1320. + 273. ;
  376. TE2 = (TP1*TFIN) + TE0 ;
  377. CHTEMP = 'MANU' 'CHPO' VOL1 1 'T' 1. ;
  378. EVT = 'EVOL' 'MANU' ('PROG' 0. TFIN) ('PROG' TE1 TE1) ;
  379. CHARTEMP = 'CHAR' 'T' CHTEMP EVT ;
  380. * -------------------------------------*
  381. * Chargement en densite de fission cte *
  382. * -------------------------------------*
  383. PHIP1 = 3E14 ;
  384. PHI2 = PHIP1 * TFIN ;
  385. CHFISS = 'MANU' 'CHPO' VOL1 1 'DFIS' 1. ;
  386. EVF = 'EVOL' 'MANU' ('PROG' 0. TFIN) ('PROG' PHI1 PHI1) ;
  387. CHARFISS = 'CHAR' 'DFIS' CHFISS EVF ;
  388. *
  389. *
  390. TE = TE1 ;
  391. PHI = PHI1 ;
  392. UN = 1. ;
  393. *
  394. * --------------------------------------------------------------------
  395. * Coefficients pour la viscoplasticite, l"elasticite et la fissuration
  396. * --------------------------------------------------------------------
  397. *
  398. * Facteurs multiplicatifs dus au dopage par le Chrome
  399. *
  400. WC1 = 'TANH' ( (TA.'CR' - TA.'CR2') / TA.'CR3' ) ;
  401. WC1 = 1. + ( 0.5 * TA.'CR1' * (1. + WC1) ) ;
  402. CV = 180. / PI ;
  403. WC2 = 1. - ( 'COS' (CV * TA.'DG' / TA.'DG0') ) ;
  404. WC2 = 2. * (TA.'DG0'**TA.'M2') * WC2 ;
  405. *
  406. CP = -1. * (TA.'QP') / (TA.'R') / TE ;
  407. CP = TA.'KPUO' * ('EXP' CP) ;
  408. *
  409. C1 = -1. * (TA.'Q1') / (TA.'R') / TE ;
  410. C1 = ( (TA.'DG')**(TA.'M1') ) * ('EXP' C1) ;
  411. C1 = (TA.'K1') / ((TA.'N1') + 1) * C1 ;
  412. C1 = WC1 * C1 ;
  413. *
  414. C2 = -1. * (TA.'Q2') / (TA.'R') / TE ;
  415. C2 = WC2 * ('EXP' C2) ;
  416. C2 = (TA.'K2') / ((TA.'N2') + 1) * C2 ;
  417. *
  418. C3 = -1. * (TA.'Q3') / (TA.'R') / TE ;
  419. C3 = (TA.'A') * PHI * ('EXP' C3) ;
  420. C3 = C3 + (PHI * CP) ;
  421. *
  422. TETA = 'TANH' (TE / (TA.'H')) ;
  423. TETA = 0.5 * (TA.'BETA') * (UN + TETA) ;
  424. *
  425. GROPHI = UN + ((TA.'K') * PHI) ;
  426. *
  427. C12 = ((UN - TETA) * C1) + (TETA * C2) ;
  428. C12 = 1.5 * GROPHI * C12 ;
  429. *
  430. E = 'MAXI' EE ;
  431. NU = 'MAXI' UU ;
  432. NU_SUR_E = NU / E ;
  433. ALFA = 'MAXI' XALFA ;
  434. *
  435. LZ = 'MAXI' ('EXCO' MATR16 'LZZ') ;
  436. PENTZ = -1. * ( (XLTR1**2) / (2.*XGFTR1) ) ;
  437. JZ = 1./(LZ*PENTZ) ;
  438. JX = JZ ;
  439. JX0 = JX ;
  440. *
  441. COEF = 0.8 ;
  442. EPSZ_PT = 3E-7 ; EPSX_PT = COEF * EPSZ_PT ;
  443. EPSTH_PT = 0. ;
  444. EPSG_PT = TA.'KGON' * TAU0 * PHI / 3. ;
  445. PAZ = EPSZ_PT - (EPSTH_PT + EPSG_PT) ;
  446. PAX = EPSX_PT - (EPSTH_PT + EPSG_PT) ;
  447. *
  448. *
  449. PRECIS = 1E-3 ;
  450. SXN = 0. ; SZN = 0. ; FN = PO ; TN = 0. ;
  451. EPSFZN = 0. ; EPSFXN = 0. ;
  452. *
  453. LTIME = 'PROG' TN ;
  454. LSX = 'PROG' SXN ; LSZ = 'PROG' SZN ;
  455. LF = 'PROG' FN ;
  456. LEPSFX = 'PROG' 0. ; LEPSFZ = 'PROG' 0. ;
  457. LEPSVX = 'PROG' 0. ; LEPSVZ = 'PROG' 0. ;
  458. *
  459. * -----------
  460. * t <= TFISS1
  461. * -----------
  462. EX = 1./E ; EZ = 1./E ;
  463. *
  464. DT = 20. ;
  465. *--
  466. 'REPE' BLO1 ;
  467. *--
  468. FN1 GDET1 = FCTNUL FN DT SXN SZN PAX PAZ
  469. EX EZ NU_SUR_E C12 C3 ;
  470.  
  471. SXN1 SZN1 = CONT FN1 GDET1 DT SXN SZN PAX PAZ
  472. EX EZ NU_SUR_E C12 C3 ;
  473.  
  474. LIMZ = (1. + PRECIS) * XLTR1 ;
  475. 'SI' ('>' SZN1 LIMZ) ;
  476. DT = DT * (XLTR1 - SZN) / (SZN1 - SZN) ;
  477. 'ITERER' BLO1 ;
  478. 'FINSI' ;
  479.  
  480. TN1 = TN + DT ;
  481.  
  482. EPSFZN1 = 0. ; EPSFXN1 = 0. ;
  483. *
  484. LTIME = LTIME 'ET' ('PROG' TN1) ;
  485. LF = LF 'ET' ('PROG' FN1) ;
  486. LSX = LSX 'ET' ('PROG' SXN1) ;
  487. LSZ = LSZ 'ET' ('PROG' SZN1) ;
  488. LEPSFX = LEPSFX 'ET' ('PROG' EPSFXN1) ;
  489. LEPSFZ = LEPSFZ 'ET' ('PROG' EPSFZN1) ;
  490. *
  491. TN = TN1 ; SXN = SXN1 ; SZN = SZN1 ; FN = FN1 ;
  492. EPSFZN = EPSFZN1 ; EPSFXN = EPSFXN1 ;
  493. *
  494. TESTZ = 'ABS' ((SZN1 - XLTR1) / XLTR1) ;
  495. 'SI' ('&lt;EG' TESTZ PRECIS) ;
  496. 'QUIT' BLO1 ;
  497. 'FINSI' ;
  498. *--
  499. 'FIN' BLO1 ;
  500. *--
  501. * --------------------
  502. * TFISS1 < t <= TFISS2
  503. * --------------------
  504. EZ = (1./E) + JZ ;
  505. *
  506. DT = 20. ;
  507. *--
  508. 'REPE' BLO2 ;
  509. *--
  510. FN1 GDET1 = FCTNUL FN DT SXN SZN PAX PAZ
  511. EX EZ NU_SUR_E C12 C3 ;
  512.  
  513. SXN1 SZN1 = CONT FN1 GDET1 DT SXN SZN PAX PAZ
  514. EX EZ NU_SUR_E C12 C3 ;
  515.  
  516. LIMZ = -0.5E6 ;
  517. 'SI' ('<' SZN1 LIMZ) ;
  518. DT = DT * (0. - SZN) / (SZN1 - SZN) ;
  519. 'ITERER' BLO2 ;
  520. 'FINSI' ;
  521.  
  522. LIMX = (1. + PRECIS) * XLTR1 ;
  523. 'SI' ('>' SXN1 LIMX) ;
  524. DT = DT * (XLTR1 - SXN) / (SXN1 - SXN) ;
  525. 'ITERER' BLO2 ;
  526. 'FINSI' ;
  527.  
  528. TN1 = TN + DT ;
  529.  
  530. EPSFZN1 = EPSFZN + (JZ * (SZN1 - SZN)) ; EPSFXN1 = 0. ;
  531. *
  532. LTIME = LTIME 'ET' ('PROG' TN1) ;
  533. LF = LF 'ET' ('PROG' FN1) ;
  534. LSX = LSX 'ET' ('PROG' SXN1) ;
  535. LSZ = LSZ 'ET' ('PROG' SZN1) ;
  536. LEPSFX = LEPSFX 'ET' ('PROG' EPSFXN1) ;
  537. LEPSFZ = LEPSFZ 'ET' ('PROG' EPSFZN1) ;
  538. *
  539. TN = TN1 ; SXN = SXN1 ; SZN = SZN1 ; FN = FN1 ;
  540. EPSFZN = EPSFZN1 ; EPSFXN = EPSFXN1 ;
  541. *
  542. TESTZ = 'ABS' SZN1 ;
  543. 'SI' ('&lt;EG' TESTZ ('ABS' LIMZ)) ;
  544. 'QUIT' BLO2 ;
  545. 'FINSI' ;
  546.  
  547. TESTX = 'ABS' ((SXN1 - XLTR1) / XLTR1) ;
  548. 'SI' ('&lt;EG' TESTX PRECIS) ;
  549. 'QUIT' BLO2 ;
  550. 'FINSI' ;
  551. *--
  552. 'FIN' BLO2 ;
  553. *--
  554. * -----------------------------
  555. * TFISS1 < TFISS2 < t <= TRUPT1
  556. * -----------------------------
  557. EX = (1./E) + JX ;
  558. *
  559. DT = 20. ;
  560. *--
  561. 'REPE' BLO3 ;
  562. *--
  563. FN1 GDET1 = FCTNUL FN DT SXN SZN PAX PAZ
  564. EX EZ NU_SUR_E C12 C3 ;
  565.  
  566. SXN1 SZN1 = CONT FN1 GDET1 DT SXN SZN PAX PAZ
  567. EX EZ NU_SUR_E C12 C3 ;
  568.  
  569. LIMZ = -0.5E6 ;
  570. 'SI' ('<' SZN1 LIMZ) ;
  571. DT = DT * (0. - SZN) / (SZN1 - SZN) ;
  572. 'ITERER' BLO3 ;
  573. 'FINSI' ;
  574.  
  575. 'SI' ('>' (SXN1 - SXN) 0.) ;
  576. 'QUIT' BLO3 ;
  577. 'FINSI' ;
  578.  
  579. LIMX = -0.5E6 ;
  580. 'SI' ('<' SXN1 LIMX) ;
  581. DT = DT * (0. - SXN) / (SXN1 - SXN) ;
  582. 'ITERER' BLO3 ;
  583. 'FINSI' ;
  584.  
  585. TN1 = TN + DT ;
  586.  
  587. EPSFXN1 = EPSFXN + (JX * (SXN1 - SXN)) ;
  588. EPSFZN1 = EPSFZN + (JZ * (SZN1 - SZN)) ;
  589. *
  590. LTIME = LTIME 'ET' ('PROG' TN1) ;
  591. LF = LF 'ET' ('PROG' FN1) ;
  592. LSX = LSX 'ET' ('PROG' SXN1) ;
  593. LSZ = LSZ 'ET' ('PROG' SZN1) ;
  594. LEPSFX = LEPSFX 'ET' ('PROG' EPSFXN1) ;
  595. LEPSFZ = LEPSFZ 'ET' ('PROG' EPSFZN1) ;
  596. *
  597. TN = TN1 ; SXN = SXN1 ; SZN = SZN1 ; FN = FN1 ;
  598. EPSFZN = EPSFZN1 ; EPSFXN = EPSFXN1 ;
  599. *
  600. TESTZ = 'ABS' SZN1 ;
  601. 'SI' ('&lt;EG' TESTZ ('ABS' LIMZ)) ;
  602. 'QUIT' BLO3 ;
  603. 'FINSI' ;
  604.  
  605. TESTX = 'ABS' SXN1 ;
  606. 'SI' ('&lt;EG' TESTX ('ABS' LIMX)) ;
  607. 'QUIT' BLO3 ;
  608. 'FINSI' ;
  609. *--
  610. 'FIN' BLO3 ;
  611. * -------------------------------------------------------
  612. * t <= TRUPT1 < TRUPT2 et fermeture de la fissure selon X
  613. * -------------------------------------------------------
  614. SMAX = SXN ;
  615. EMAX = EPSFXN ;
  616. WMAX = EMAX * LZ ;
  617. WFERM = XBTR * WMAX ;
  618. EFERM = XBTR * EMAX ;
  619. JX = (EMAX - EFERM) / SMAX ;
  620. EX = (1./E) + JX ;
  621. *
  622. DT = 20. ;
  623. *--
  624. 'REPE' BLO4 ;
  625. *--
  626. FN1 GDET1 = FCTNUL FN DT SXN SZN PAX PAZ
  627. EX EZ NU_SUR_E C12 C3 ;
  628.  
  629. SXN1 SZN1 = CONT FN1 GDET1 DT SXN SZN PAX PAZ
  630. EX EZ NU_SUR_E C12 C3 ;
  631.  
  632. LIMZ = -0.5E6 ;
  633. 'SI' ('<' SZN1 LIMZ) ;
  634. DT = DT * (0. - SZN) / (SZN1 - SZN) ;
  635. 'ITERER' BLO4 ;
  636. 'FINSI' ;
  637.  
  638. TN1 = TN + DT ;
  639.  
  640. EPSFXN1 = EPSFXN + (JX * (SXN1 - SXN)) ;
  641. EPSFZN1 = EPSFZN + (JZ * (SZN1 - SZN)) ;
  642.  
  643. TESTX = (SXN1 - SXN) * (EPSFXN1 - EPSFXN) ;
  644. 'SI' ('<' TESTX 0.) ;
  645. 'QUIT' BLO4 ;
  646. 'FINSI' ;
  647. *
  648. LTIME = LTIME 'ET' ('PROG' TN1) ;
  649. LF = LF 'ET' ('PROG' FN1) ;
  650. LSX = LSX 'ET' ('PROG' SXN1) ;
  651. LSZ = LSZ 'ET' ('PROG' SZN1) ;
  652. LEPSFX = LEPSFX 'ET' ('PROG' EPSFXN1) ;
  653. LEPSFZ = LEPSFZ 'ET' ('PROG' EPSFZN1) ;
  654. *
  655. TN = TN1 ; SXN = SXN1 ; SZN = SZN1 ; FN = FN1 ;
  656. EPSFZN = EPSFZN1 ; EPSFXN = EPSFXN1 ;
  657. *
  658. TESTZ = 'ABS' SZN1 ;
  659. 'SI' ('&lt;EG' TESTZ ('ABS' LIMZ)) ;
  660. 'QUIT' BLO4 ;
  661. 'FINSI' ;
  662. *--
  663. 'FIN' BLO4 ;
  664. * ------------------------------------------------
  665. * TRUPT1 <= t et reouverture de la fissure selon X
  666. * ------------------------------------------------
  667. SZN1 = 0. ; SZN = SZN1 ;
  668. EZ = E ;
  669. *
  670. DT = 20. ;
  671. *--
  672. 'REPE' BLO5 ;
  673. *--
  674. FN1 GDET1 = FCTNUL FN DT SXN SZN PAX PAZ
  675. EX EZ NU_SUR_E C12 C3 ;
  676.  
  677. SXN1 SZN1 = CONT FN1 GDET1 DT SXN SZN PAX PAZ
  678. EX EZ NU_SUR_E C12 C3 ;
  679.  
  680.  
  681. TN1 = TN + DT ;
  682.  
  683. EPSFXN1 = EPSFXN + (JX * (SXN1 - SXN)) ;
  684. VEPSFZN1 = FISZ FN1 SXN1 PAX PAZ
  685. EX NU_SUR_E C12 C3 ;
  686. EPSFZN1 = EPSFZN + (DT * VEPSFZN1) ;
  687.  
  688. 'SI' ('>' SXN1 SMAX) ;
  689. 'QUIT' BLO5 ;
  690. 'FINSI' ;
  691. *
  692. LTIME = LTIME 'ET' ('PROG' TN1) ;
  693. LF = LF 'ET' ('PROG' FN1) ;
  694. LSX = LSX 'ET' ('PROG' SXN1) ;
  695. LSZ = LSZ 'ET' ('PROG' SZN1) ;
  696. LEPSFX = LEPSFX 'ET' ('PROG' EPSFXN1) ;
  697. LEPSFZ = LEPSFZ 'ET' ('PROG' EPSFZN1) ;
  698. *
  699. TN = TN1 ; SXN = SXN1 ; SZN = SZN1 ; FN = FN1 ;
  700. EPSFZN = EPSFZN1 ; EPSFXN = EPSFXN1 ;
  701. *--
  702. 'FIN' BLO5 ;
  703. * ---------------------------------------------------
  704. * TRUPT1 < t <= TRUPT2
  705. * (reouverture de la fissure selon X jusqu a rupture)
  706. * ---------------------------------------------------
  707. * Le calcul est conduit jusqu a TEND seulement:
  708. TEND = 2E4 ;
  709. *
  710. SXN = SMAX ;
  711. EPSFXN = EMAX ;
  712. *
  713. JX = JX0 ;
  714. EX = (1./E) + JX ;
  715. *
  716. DT = 100. ;
  717. *--
  718. 'REPE' BLO6 ;
  719. *--
  720. FN1 GDET1 = FCTNUL FN DT SXN SZN PAX PAZ
  721. EX EZ NU_SUR_E C12 C3 ;
  722.  
  723. SXN1 SZN1 = CONT FN1 GDET1 DT SXN SZN PAX PAZ
  724. EX EZ NU_SUR_E C12 C3 ;
  725.  
  726.  
  727. TN1 = TN + DT ;
  728.  
  729. 'SI' ('>' TN1 TEND) ;
  730. 'QUIT' BLO6 ;
  731. 'FINSI' ;
  732.  
  733.  
  734. EPSFXN1 = EPSFXN + (JX * (SXN1 - SXN)) ;
  735. VEPSFZN1 = FISZ FN1 SXN1 PAX PAZ
  736. EX NU_SUR_E C12 C3 ;
  737. EPSFZN1 = EPSFZN + (DT * VEPSFZN1) ;
  738.  
  739. LIMX = -0.5E6 ;
  740. 'SI' ('<' SXN1 LIMZ) ;
  741. 'QUIT' BLO6 ;
  742. 'FINSI' ;
  743. *
  744. LTIME = LTIME 'ET' ('PROG' TN1) ;
  745. LF = LF 'ET' ('PROG' FN1) ;
  746. LSX = LSX 'ET' ('PROG' SXN1) ;
  747. LSZ = LSZ 'ET' ('PROG' SZN1) ;
  748. LEPSFX = LEPSFX 'ET' ('PROG' EPSFXN1) ;
  749. LEPSFZ = LEPSFZ 'ET' ('PROG' EPSFZN1) ;
  750. *
  751. TN = TN1 ; SXN = SXN1 ; SZN = SZN1 ; FN = FN1 ;
  752. EPSFZN = EPSFZN1 ; EPSFXN = EPSFXN1 ;
  753. *--
  754. 'FIN' BLO6 ;
  755. *
  756. EV_SX ='EVOL' 'ROUG' 'MANU' 'Temps(s)' LTIME 'SIGX(MPa)'
  757. (LSX/CONVSIG);
  758. EV_SZ ='EVOL' 'ROUG' 'MANU' 'Temps(s)' LTIME 'SIGZ(MPa)'
  759. (LSZ/CONVSIG);
  760. EV_F ='EVOL' 'ROUG' 'MANU' 'Temps(s)' LTIME 'Porosite' LF ;
  761. EV_EPSFX ='EVOL' 'ROUG' 'MANU' 'Temps(s)' LTIME 'Def Fiss X' LEPSFX ;
  762. EV_EPSFZ ='EVOL' 'ROUG' 'MANU' 'Temps(s)' LTIME 'Def Fiss Z' LEPSFZ ;
  763. EV_WX ='EVOL' 'ROUG' 'MANU' 'Temps(s)' LTIME 'WX(m)' (LZ*LEPSFX);
  764. EV_WZ ='EVOL' 'ROUG' 'MANU' 'Temps(s)' LTIME 'WZ(m)' (LZ*LEPSFZ);
  765. EV_FISX ='EVOL' 'ROUG' 'MANU' 'WX(m)' (LZ*LEPSFX)
  766. 'SIGX(MPa)' (LSX/CONVSIG);
  767. EV_FISZ ='EVOL' 'ROUG' 'MANU' 'WZ(m)' (LZ*LEPSFZ)
  768. 'SIGZ(MPa)' (LSZ/CONVSIG);
  769. * ---------------------------------*
  770. * Chargement en deplacement impose *
  771. * ---------------------------------*
  772. EPS_TFIN = EPSZ_PT * TFIN ;
  773. DEPZ = 'DEPI' CLZH 1 ;
  774. DEPX = 'DEPI' CLXD 1 ;
  775. LDEPX = 'PROG' 0 TFIN ;
  776. LDEPY = ('PROG' 0 EPS_TFIN) * HS2 ;
  777. 'TITR' 'DEPLACEMENT IMPOSE' ;
  778. EVDEP = 'EVOL' 'MANU' 'Temps (s)' LDEPX 'Dep (m)' LDEPY ;
  779. 'SI' DESSI ; 'DESS' EVDEP ; 'FINSI' ;
  780. CHARMECZ = 'CHAR' 'DIMP' DEPZ EVDEP ;
  781. CHARMECX = 'CHAR' 'DIMP' DEPX (COEF*EVDEP) ;
  782. CHARMECA = CHARMECZ 'ET' CHARMECX ;
  783. *-------------------*
  784. * Instants calcules *
  785. *-------------------*
  786. LIST1 = 'PROG' 0. 'PAS' 200. TEND ;
  787. *
  788. * ---------------------------------------*
  789. * Variables internes initiales 'PORO'=PO *
  790. * ---------------------------------------*
  791. VAR00 = 'ZERO' MODL1 'VARINTER' ;
  792. VAR01 = 'MANU' 'CHML' MODL1 'PORO' PO
  793. 'TYPE' 'VARIABLES INTERNES' 'STRESSES' ;
  794. VAR0 = VAR00 + VAR01 ;
  795. *
  796. CHARTOT = CHARMECA 'ET' CHARTEMP 'ET' CHARFISS ;
  797. *
  798. TAB1 = TABLE ;
  799. TAB1.'VARIABLES_INTERNES' = TABLE ;
  800. TAB1.'BLOCAGES_MECANIQUES' = CLT ;
  801. TAB1.'MODELE' = MODL1 ;
  802. TAB1.'CHARGEMENT' = CHARTOT ;
  803. TAB1.'VARIABLES_INTERNES' . 0 = VAR0 ;
  804. TAB1.'CARACTERISTIQUES' = MATR1 ;
  805. TAB1.'TEMPS_CALCULES' = LIST1 ;
  806. TAB1.'TEMPS_SAUVES' = LIST1 ;
  807. *
  808. TMASAU=table;
  809. tab1 . 'MES_SAUVEGARDES'=TMASAU;
  810. TMASAU .'DEFTO'=VRAI;
  811. TMASAU .'DEFIN'=VRAI;
  812. PASAPAS TAB1 ;
  813. *
  814. *
  815. * -----------------------*
  816. * Controle des resultats *
  817. * -----------------------*
  818. TT = TAB1 . 'TEMPS' ;
  819. SS = TAB1 . 'CONTRAINTES' ;
  820. VV = TAB1 . 'VARIABLES_INTERNES' ;
  821. IN = TAB1 . 'DEFORMATIONS_INELASTIQUES' ;
  822. NCONT = 'DIME' TAB1 . 'CONTRAINTES' ;
  823. *
  824. LZEIT = 'PROG' ;
  825. LSIGX = 'PROG' ;
  826. LSIGZ = 'PROG' ;
  827. LW1 = 'PROG' ;
  828. LW2 = 'PROG' ;
  829. LW3 = 'PROG' ;
  830. LPORO = 'PROG' ;
  831. LEFX = 'PROG' ;
  832. LEFZ = 'PROG' ;
  833. *
  834. MI = 'MOTS' 'EIXX' 'EIYY' 'EIZZ' 'GIXY' 'GIXZ' 'GIYZ' ;
  835. MV = 'MOTS' 'EVXX' 'EVYY' 'EVZZ' 'GVXY' 'GVXZ' 'GVYZ' ;
  836. ME = 'MOTS' 'EPXX' 'EPYY' 'EPZZ' 'GAXY' 'GAXZ' 'GAYZ' ;
  837. *
  838. *
  839. 'REPE' BLOC NCONT ;
  840. *
  841. IND = &BLOC - 1 ;
  842. ZEIT = TT.IND ;
  843. *
  844. SIG = SS.IND ;
  845. SIG = 'RTENS' SIG MODL1 VX2 (0 1 0) ;
  846. SIGX = 'EXCO' SIG 'SMXX' ;
  847. SIGX_MAX = 'MAXI' SIGX ; SIGX_MIN = 'MINI' SIGX ;
  848. SIGZ = 'EXCO' SIG 'SMZZ' ;
  849. SIGZ_MAX = 'MAXI' SIGZ ; SIGZ_MIN = 'MINI' SIGZ ;
  850. *
  851. VI = VV.IND ;
  852. EI = IN.IND ;
  853. EI = 'CHANG' 'TYPE' ('EXCO' MI EI ME) 'DEFORMATIONS' ;
  854. *
  855. EPS_VP = 'CHANG' 'TYPE' ('EXCO' MV VI ME) 'DEFORMATIONS' ;
  856. DIF = EI - EPS_VP ;
  857. DIF = 'RTENS' DIF MODL1 VX2 (0 1 0) ;
  858. *
  859. PORO = 'MAXI' ('EXCO' VI 'PORO') ;
  860. W1 = 'MAXI' ('EXCO' VI 'W1') ;
  861. W2 = 'MAXI' ('EXCO' VI 'W2') ;
  862. W3 = 'MAXI' ('EXCO' VI 'W3') ;
  863. *
  864. LZEIT = LZEIT 'ET' ('PROG' ZEIT) ;
  865. LSIGX = LSIGX 'ET' ('PROG' SIGX_MAX) ;
  866. LSIGZ = LSIGZ 'ET' ('PROG' SIGZ_MAX) ;
  867. LW1 = LW1 'ET' ('PROG' W1) ;
  868. LW2 = LW2 'ET' ('PROG' W2) ;
  869. LW3 = LW3 'ET' ('PROG' W3) ;
  870. LEFX = LEFX 'ET' ('PROG' ('MAXI' ('EXCO' DIF 'EPXX')));
  871. LEFZ = LEFZ 'ET' ('PROG' ('MAXI' ('EXCO' DIF 'EPZZ')));
  872. LPORO = LPORO 'ET' ('PROG' PORO) ;
  873. *
  874. 'FIN' BLOC ;
  875. *
  876. * ----------------------
  877. * CONTROLE DES RESULTATS
  878. * ----------------------
  879. LSOUS = 'PROG' 1E3 'PAS' 1E3 (TEND - 1E3) ;
  880. UN = 'PROG' ('DIME' LSOUS)*1 ;
  881. *
  882. SX_CAL = 'IPOL' LSOUS LZEIT LSIGX; SX_ANA = 'IPOL' LSOUS LTIME LSX ;
  883. SZ_CAL = 'IPOL' LSOUS LZEIT LSIGZ; SZ_ANA = 'IPOL' LSOUS LTIME LSZ ;
  884. PO_CAL = 'IPOL' LSOUS LZEIT LPORO; PO_ANA = 'IPOL' LSOUS LTIME LF ;
  885. EFX_CAL = 'IPOL' LSOUS LZEIT LEFX ; EFX_ANA = 'IPOL' LSOUS LTIME LEPSFX;
  886. EFZ_CAL = 'IPOL' LSOUS LZEIT LEFZ ; EFZ_ANA = 'IPOL' LSOUS LTIME LEPSFZ;
  887. *
  888. PREX = 5E-3 ;
  889. T_SX = (SX_ANA - SX_CAL) / (SX_ANA + UN) ;
  890. T_SX = 'MAXI' ('ABS' T_SX) ;
  891. 'SI' ( T_SX '&lt;EG' PREX ) ;
  892. 'ERRE' 0 ;
  893. 'SINO' ;
  894. 'MESS' 'ERREUR MAXIMALE CONTRAINTE SELON X = ' T_SX ' > ' PREX ;
  895. 'ERRE' 5 ;
  896. 'FINS' ;
  897. *
  898. T_SZ = (SZ_ANA - SZ_CAL) / (SZ_ANA + UN) ;
  899. T_SZ = 'MAXI' ('ABS' T_SZ) ;
  900. 'SI' ( T_SZ '&lt;EG' PREX ) ;
  901. 'ERRE' 0 ;
  902. 'SINO' ;
  903. 'MESS' 'ERREUR MAXIMALE CONTRAINTE SELON Z = ' T_SZ ' > ' PREX ;
  904. 'ERRE' 5 ;
  905. 'FINS' ;
  906. *
  907. PREX = 1E-4 ;
  908. T_LF = (PO_ANA - PO_CAL) / PO_ANA ;
  909. T_LF = 'MAXI' ('ABS' T_LF) ;
  910. 'SI' ( T_LF '&lt;EG' PREX ) ;
  911. 'ERRE' 0 ;
  912. 'SINO' ;
  913. 'MESS' 'ERREUR MAXIMALE POROSITE = ' T_LF ' > ' PREX ;
  914. 'ERRE' 5 ;
  915. 'FINS' ;
  916. *
  917. WRUPT = (2.*XGFTR1) / XLTR1 ;
  918. ERUPT = WRUPT / LZ ;
  919. NONZERO = (ERUPT / 1E6) * UN ;
  920. PREX = 1E-1 ;
  921. T_FX = (EFX_ANA - EFX_CAL) / (EFX_ANA + NONZERO) ;
  922. T_FX = 'MAXI' ('ABS' T_FX) ;
  923. 'SI' ( T_FX '&lt;EG' PREX ) ;
  924. 'ERRE' 0 ;
  925. 'SINO' ;
  926. 'MESS' 'ERREUR MAXIMALE DEFORMATION DE FISSURATION
  927. SELON X = ' T_FX ' > ' PREX ;
  928. 'ERRE' 5 ;
  929. 'FINS' ;
  930. *
  931. PREX = 1E-2 ;
  932. T_FZ = (EFZ_ANA - EFZ_CAL) / (EFZ_ANA + NONZERO) ;
  933. T_FZ = 'MAXI' ('ABS' T_FZ) ;
  934. 'SI' ( T_FZ '&lt;EG' PREX ) ;
  935. 'ERRE' 0 ;
  936. 'SINO' ;
  937. 'MESS' 'ERREUR MAXIMALE DEFORMATION DE FISSURATION
  938. SELON Z = ' T_FZ ' > ' PREX ;
  939. 'ERRE' 5 ;
  940. 'FINS' ;
  941. *
  942. *
  943. TAB = 'TABLE' ;
  944. TAB . 'TITRE' = 'TABLE' ;
  945. TAB . 'TITRE' . 1 = 'Solution Analytique' ;
  946. TAB . 'TITRE' . 2 = 'Solution Calculee' ;
  947. *
  948. *
  949. EVSIGX = 'EVOL' 'MANU' 'Temps (s)' LZEIT 'SIGX(MPa)' (LSIGX/CONVSIG);
  950. EVSIGZ = 'EVOL' 'MANU' 'Temps (s)' LZEIT 'SIGZ(MPa)' (LSIGZ/CONVSIG);
  951. 'SI' DESSI ;
  952. 'TITR' 'CONTRAINTE DANS LA DEUXIEME DIRECTION DE FISSURATION' ;
  953. 'DESS' (EV_SX 'ET' EVSIGX) TAB 'LEGE' ;
  954. 'TITR' 'CONTRAINTE DANS LA PREMIERE DIRECTION DE FISSURATION' ;
  955. 'DESS' (EV_SZ 'ET' EVSIGZ) TAB 'LEGE' ;
  956. 'FINSI' ;
  957. *
  958. EVPORO = 'EVOL' 'MANU' 'Temps (s)' LZEIT 'Porosite' LPORO ;
  959. 'SI' DESSI ;
  960. 'TITR' 'POROSITE' ;
  961. 'DESS' (EV_F 'ET' EVPORO) TAB 'LEGE' ;
  962. 'FINSI' ;
  963. *
  964. EVWX = 'EVOL' 'MANU' 'Temps (s)' LZEIT 'WX(m)' LW2 ;
  965. EVWZ = 'EVOL' 'MANU' 'Temps (s)' LZEIT 'WZ(m)' LW1 ;
  966. 'SI' DESSI ;
  967. 'TITR' 'OUVERTURE DANS LA DEUXIEME DIRECTION DE FISSURATION' ;
  968. 'DESS' (EV_WX 'ET' EVWX) TAB 'LEGE' ;
  969. 'TITR' 'OUVERTURE DANS LA PREMIERE DIRECTION DE FISSURATION' ;
  970. 'DESS' (EV_WZ 'ET' EVWZ) TAB 'LEGE' ;
  971. 'FINSI' ;
  972. *
  973. EVEPSFX = 'EVOL' 'MANU' 'Temps (s)' LZEIT 'Def Fiss X' LEFX ;
  974. EVEPSFZ = 'EVOL' 'MANU' 'Temps (s)' LZEIT 'Def Fiss Z' LEFZ ;
  975. 'SI' DESSI ;
  976. 'TITR' 'DEFORMATION DE FISS. DANS LA DIRECTION DE FISS. N°2' ;
  977. 'DESS' (EV_EPSFX 'ET' EVEPSFX) TAB 'LEGE' ;
  978. 'TITR' 'DEFORMATION DE FISS. DANS LA DIRECTION DE FISS. N°1' ;
  979. 'DESS' (EV_EPSFZ 'ET' EVEPSFZ) TAB 'LEGE' ;
  980. 'FINSI' ;
  981. *
  982. EVFISX = 'EVOL' 'MANU' 'WX(m)' LW2 'SIGX(MPa)' (LSIGX/CONVSIG) ;
  983. EVFISZ = 'EVOL' 'MANU' 'WZ(m)' LW1 'SIGZ(MPa)' (LSIGZ/CONVSIG) ;
  984. 'SI' DESSI ;
  985. 'TITR' 'RELATION CONTR./OUVERTURE DANS LA DIRECTION DE FISS. N°2' ;
  986. 'DESS' (EV_FISX 'ET' EVFISX) TAB 'LEGE' ;
  987. 'TITR' 'RELATION CONTR./OUVERTURE DANS LA DIRECTION DE FISS. N°1' ;
  988. 'DESS' (EV_FISZ 'ET' EVFISZ) TAB 'LEGE' ;
  989. 'FINSI' ;
  990. *
  991. 'FIN';
  992.  
  993.  
  994.  
  995.  
  996.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales