Télécharger transport4.dgibi

Retour à la liste

Numérotation des lignes :

  1. * fichier : transport4.dgibi
  2. ******************** CAS TEST : transport4.dgibi ************************
  3. *
  4. GRAPH = faux ;
  5. CRIT1 = 1.D-3 ;
  6. 'SAUTER' 'PAGE';
  7.  
  8. ************************************************************************
  9. *
  10. * Petit programme testant le transport en milieu poreux avec
  11. * - limite de solubilité diminuant linéairement vers l'aval.
  12. * l'équilibre chimique soluté/précipité à cinétique linéaire
  13. * (théta-méthode)
  14. * - coefficient de retard constant
  15. * (équilibre soluté/adsorbat instantané linéaire)
  16. *
  17. * pour un cas test 2D simple :
  18. * Une petite source baignant dans un champ de vitesse uniforme.
  19. *
  20. * P4 *---------------* P3
  21. * | |
  22. * | |
  23. * | |
  24. * P5 |---------------| P2
  25. * | |
  26. * | |
  27. * | |
  28. * | |
  29. * P6 *----* P9 - - - * P11
  30. * | | |
  31. * P7 *----* P8 - - - * P10
  32. * | |
  33. * | |
  34. * P0 *---------------* P1
  35. *
  36. ************************************************************************
  37. 'OPTION' 'ECHO' 0 ;
  38. 'SAUTER' 'PAGE';
  39. 'TITRE' 'Validation du transport';
  40. * ==============
  41. * | PARAMETRES |
  42. * ==============
  43. *
  44. * Paramètres internes :
  45. * =====================
  46. 'OPTION' 'ECHO' 0 'DIME' 2 'ELEM' 'QUA4' ;
  47. 'OPTION' 'ISOV' 'SURFACE' ;
  48. 'OPTION' 'TRAC' 'PSC' ;
  49.  
  50. * Paramètres de convivialité :
  51. * ============================
  52. * Trace les limites de solubilité ?
  53. TrLimSol= vrai ;
  54. * Trace le coefficient de dissolution ?
  55. TrCoDis = Vrai ;
  56. * Trace le coefficient de retard ?
  57. TrRet = vrai ;
  58. * Trace les profils de concentration suivant certaines lignes ?
  59. TrLEvol = Vrai ;
  60. * Trace les évolutions de concentration en certaines points ?
  61. TrPEvol = Vrai ;
  62. * Trace les champs de concentration en soluté, précipité ?
  63. TrConc = vrai ;
  64. TrPrec = vrai ;
  65. * Trace la quantité de précipité dissout ?
  66. TrLib = Vrai ;
  67. * Trace le flux à travers une ligne ?
  68. TrFlux = Vrai ;
  69.  
  70. SI ('EGA' GRAPH 'N');
  71. TrLEvol = faux ;
  72. TrPEvol = faux ;
  73. TrConc = faux ;
  74. TrPrec = faux ;
  75. TrLib = faux ;
  76. TrFlux = faux ;
  77. TrLimSol= faux ;
  78. TrCoDis = faux ;
  79. TrRet = faux ;
  80. FINSI;
  81.  
  82. * Grandeurs physiques :
  83. * =====================
  84. * VITESSE DE DARCY
  85. UXImp = 0.;
  86. UYImp = 1.;
  87.  
  88. * POROSITE
  89. ValPor = 1.;
  90.  
  91. *-- Facteur de forme :
  92. FacForme = 1.;
  93.  
  94. * RETARD
  95. *-- Coefficient de retard et matrice de retard
  96. * (éventuellement scalaire) :
  97. CofRetar = 10. ;
  98. * LIMITE DE SOLUBILITE
  99. *-- Limite de solubilité en mol/l (global et fond):
  100. * Cette valeur ne sert que si la dissolution est instantanée ou
  101. * d'ordre 1.
  102. CSat1 = 1. ;
  103. CSat2 = 0.1 ;
  104.  
  105. * DIFFUSIVITE
  106. *-- Diffusivité moléculaire du traceur en m²/s
  107. DifMolec = 2.d0;
  108.  
  109. * NATURE DISSOLUTION
  110. *-- Nature de la dissolution (si existe) et logiques associés :
  111. *NaturDis = 'Pas de dissolution';
  112. *NaturDis = 'Imposée';
  113. NaturDis = 'Ordre 1';
  114. *NaturDis = 'Instant_Pénal';
  115. *NaturDis = 'Instant_PFDis';
  116.  
  117. Solub = 'NEG' NaturDis 'Pas de dissolution';
  118. SoluA = 'EGA' NaturDis 'Imposée';
  119. SoluP = 'EGA' NaturDis 'Ordre 1';
  120. SoluI = ('EGA' NaturDis 'Instant_PFDis')
  121. OU ('EGA' NaturDis 'Instant_Pénal');
  122. SoluL = SoluP OU SoluI;
  123.  
  124. * PARAM. NUM. DISSOLUTION
  125. *-- Grandeur(s) associée(s) à la dissolution :
  126. si SoluP;
  127. * Coefficient de dissolution
  128. ValCoDis = LOG 2.;
  129. finsi;
  130.  
  131. * QUANTITES INITIALES
  132. *-- Concentration en marqueur dans la source à t=0 (mol/l d'eau):
  133. CActif0 = CSat1;
  134.  
  135. *-- Précipité de marqueur dans la source à t=0 (mol/dm² de milieu):
  136. SI Solub;
  137. PActif0 = 10. * CSat1 * CofRetar;
  138. FINSI;
  139.  
  140. * TEMPS DE CALCUL
  141. * initial, final, et pas de temps :
  142. TIni = 0.;
  143. TFin = 100.;
  144. DelTaT = 10. ;
  145.  
  146. * METHODES NUMERIQUES
  147. *-- Coef. d'implicitation (1 = implicite, 0 = explicite)
  148. * Diffusion :
  149. TetaDif = 1. ;
  150. * Convection :
  151. TetaCnv = 1. ;
  152. * Dissolution progressive
  153. TetaDis = 1. ;
  154.  
  155. *-- Coefficient d'élimination :
  156. EpsElim = .1 ;
  157.  
  158. *-- Précision de la machine :
  159. EpsPrec = 1.D-14;
  160.  
  161. * ============
  162. * | MAILLAGE |
  163. * ============
  164. * Dimensions (m) :
  165. * ----------------
  166. LX1 = 1.;
  167. LXM = 5.;
  168. LY1 = 4.;
  169. LY2 = 5.;
  170. LY3 = 8.;
  171. LYM = 12.;
  172.  
  173. * Découpages :
  174. * ------------
  175. N = 1;
  176. NX = 'ENTIER' (N * LXM);
  177. NY = 'ENTIER' (N * LYM + 1);
  178. NX1 = 'MAXIMUM' ('LECT' ('ENTIER' (NX * LX1 / LXM)) 1);
  179. NX2 = NX - NX1;
  180. NY1 = 'MAXIMUM' ('LECT' ('ENTIER' (NY * LY1 / LYM)) 1);
  181. NY2 = 'MAXIMUM' ('LECT' ('ENTIER' (NY * (LY2 - LY1) / LYM)) 1);
  182. NY3 = 'MAXIMUM' ('LECT' ('ENTIER' (NY * (LY3 - LY2) / LYM)) 1);
  183. NY4 = 'MAXIMUM' ('LECT' ('ENTIER' (NY * (LYM - LY3) / LYM)) 1);
  184. NY = NY1 + NY2 + NY3 + NY4;
  185.  
  186. * Points :
  187. * --------
  188. p0 = 0. 0.;
  189. p1 = LXM 0.;
  190. p2 = LXM LY3;
  191. p3 = LXM LYM;
  192. p4 = 0. LYM;
  193. p5 = 0. LY3;
  194. p6 = 0. LY2;
  195. p7 = 0. LY1;
  196. p8 = LX1 LY1;
  197. p9 = LX1 LY2;
  198. p10 = LXM LY1;
  199. p11 = LXM LY2;
  200.  
  201. * Droites :
  202. * ---------
  203. 'OPTION' 'COULEUR' 'BLAN';
  204. D4D5 = 'DROITE' P4 NY4 P5;
  205. D5D6 = 'DROITE' P5 NY3 P6;
  206. D6D7 = 'DROITE' P6 NY2 P7;
  207. D7D0 = 'DROITE' P7 NY1 P0;
  208. D2D5 = 'DROITE' P2 NX P5;
  209. 'OPTION' 'COULEUR' 'TURQ';
  210. D0D1 = 'DROITE' P0 NX P1;
  211. D1D10 = 'DROITE' P1 NY1 P10;
  212. D10D11= 'DROITE' P10 NY2 P11;
  213. D11D2 = 'DROITE' P11 NY3 P2;
  214. D2D3 = 'DROITE' P2 NY4 P3;
  215. D3D4 = 'DROITE' P3 NX P4;
  216. D7D8 = 'DROITE' P7 NX1 P8;
  217. D8D9 = 'DROITE' P8 NY2 P9;
  218. D9D6 = 'DROITE' P9 NX1 P6;
  219. D10D8 = 'DROITE' P10 NX2 P8;
  220. D11D9 = 'DROITE' P11 NX2 P9;
  221. D2D5 = 'DROITE' P2 NX P5;
  222. D8D7 = 'INVERSE' D7D8;
  223. D8D10 = 'INVERSE' D10D8;
  224. D9D8 = 'INVERSE' D8D9;
  225. D6D9 = 'INVERSE' D9D6;
  226. D9D11 = 'INVERSE' D11D9;
  227. D5D2 = 'INVERSE' D2D5;
  228. D4D3 = 'INVERSE' D3D4;
  229.  
  230. *-- Pour les conditions aux limites :
  231. LInf = D0D1;
  232. Lsup = D3D4;
  233. LDroit = D1D10 ET D10D11 ET D11D2 ET D2D3;
  234. LGau = 'INVERSE' (D4D5 ET D5D6 ET D6D7 ET D7D0);
  235.  
  236. *-- Pour faire la somme des flux :
  237. * pour le tranfert d'activité (loin des conditions aux limites) :
  238. LFlux = D5D2;
  239.  
  240. * Surfaces maillées :
  241. * -------------------
  242. SActif = 'ORIENTER' ('COULEUR' ('DALLER' D7D8 D8D9 D9D6 D6D7) 'ROUG') ;
  243. SFond = 'ORIENTER' ('COULEUR' ('DALLER' D2D3 D3D4 D4D5 D5D2) 'VERT') ;
  244. SCoeur = 'ORIENTER' ('COULEUR' (
  245. ('DALLER' D0D1 D1D10 (D10D8 ET D8D7) D7D0)
  246. ET ('DALLER' D8D10 D10D11 D11D9 D9D8)
  247. ET ('DALLER' (D6D9 ET D9D11) D11D2 D2D5 D5D6)
  248. ) 'TURQ' ) ;
  249. SGran = 'COULEUR' (SCoeur et SFond) 'TURQ' ;
  250. Mtot = SActif ET SGran;
  251.  
  252. LTrame = 'COULEUR' ((CONT SActif) ET (CONT SGran)) 'BLAN';
  253. *
  254. * Elements contenant tous les points de calcul
  255.  
  256. QMtot = 'CHAN' Mtot 'QUAF' ;
  257. QFond = 'CHAN' SFond 'QUAF' ;
  258. QActif = 'CHAN' SActif 'QUAF' ;
  259. QGran = 'CHAN' SGran 'QUAF' ;
  260. QInf = 'CHAN' LInf 'QUAF' ;
  261. QDro = 'CHAN' LDroit 'QUAF' ;
  262. QSup = 'CHAN' Lsup 'QUAF' ;
  263. QGau = 'CHAN' LGau 'QUAF' ;
  264. QLFlux = 'CHAN' LFlux 'QUAF' ;
  265. ELIM 0.001 ( QMtot ET QActif ET QFond ET QGran ET QLFlux ET
  266. QGau ET QInf ET QDro ET QSup) ;
  267.  
  268. * Domaines :
  269. * ----------
  270. * Modèle (Mo) :
  271. MoHydro = 'MODELE' QMtot DARCY ISOTROPE ;
  272. MoFond = 'MODELE' QFond DARCY ISOTROPE ;
  273. MoActif = 'MODELE' QActif DARCY ISOTROPE ;
  274. MoGran = 'MODELE' QGran DARCY ISOTROPE ;
  275. MoInf = 'MODELE' QInf DARCY ISOTROPE ;
  276. MoDro = 'MODELE' QDro DARCY ISOTROPE ;
  277. MoSup = 'MODELE' QSup DARCY ISOTROPE ;
  278. MoGau = 'MODELE' QGau DARCY ISOTROPE ;
  279. MoFlux = 'MODELE' QLFlux DARCY ISOTROPE ;
  280.  
  281. * Longueurs, Normales et Orientations des arêtes du domaine ;
  282. Chyb1 = 'DOMA' MoHydro 'SURFACE';
  283. Chyb2 = 'DOMA' MoHydro 'NORMALE';
  284. VolChPro = 'DOMA' MoHydro 'VOLUME';
  285. CeHydro = 'DOMA' MoHydro 'CENTRE';
  286. CeFlux = 'DOMA' MoFlux 'CENTRE';
  287.  
  288. * Création des normales à la ligne sur laquelle on mesure les flux :
  289. NleFlux = 'MANU' 'CHPO' CeFlux 2 'UX' 0. 'UY' +1. NATURE DIFFUS;
  290. DFluxTIT = 'CHAINE' 'la ligne y=' 'FORMAT' '(F5.0)'
  291. ('COOR' 2 P2) 'm';
  292.  
  293. * Points où l'on suivra la concentration :
  294. * ----------------------------------------
  295. PEvol = 'TABLE';
  296. * Centre du combustible :
  297. PEvol.1 = 'TABLE';
  298. PEvol.1 .'T' = 'CHAINE' 'dans la source' ;
  299. PEvol.1 .'P' = 'CENTRE';
  300. PEvol.1 .'M' = ( (.5 * LX1) ((LY2 + LY1) / 2.) );
  301. PEvol.1 .'M' = CeHydro 'POINT' 'PROC' (PEvol.1 .'M');
  302. * Juste après la transition aval :
  303. PEvol.2 = 'TABLE';
  304. PEvol.2 .'T' = 'CHAINE' 'post-transition aval' ;
  305. PEvol.2 .'P' = 'CENTRE';
  306. PEvol.2 .'M' = CeHydro 'POINT'
  307. 'PROC' (P5 'PLUS' (0.05 0.05));
  308.  
  309. * Lignes où capturer les évolutions des concentrations :
  310. * ------------------------------------------------------
  311. LEvol = 'TABLE';
  312.  
  313. 'REPETER' Bcl8 ('NBEL' LGau);
  314. pt = CeHydro 'POINT' 'PROC'
  315. ((LGau 'POINT' &Bcl8) 'PLUS' (0 0.01));
  316. SI (&Bcl8 > 2);
  317. LGauC = LGauC ET ('MANU' 'SEG2' pt0 pt);
  318. FINSI;
  319. SI (&Bcl8 'EGA' 2);
  320. LGauC = ('MANU' 'SEG2' pt0 pt);
  321. FINSI;
  322. pt0 = pt;
  323. 'FIN' Bcl8;
  324. 'OUBLIER' pt0;
  325. 'OUBLIER' pt;
  326.  
  327. LEvol.1 = 'TABLE';
  328. LEvol.1 .M = 'COULEUR' LGauC 'BLAN';
  329. LEvol.1 .P = 'CENTRE';
  330. LEvol.1 .L = 'Y (m)';
  331. LEvol.1 .T = 'CHAINE' 'longitudinale' ;
  332.  
  333. * ===============
  334. * | HYDRAULIQUE |
  335. * ===============
  336. * La donnée est U. Pour obtenir VDarcy et QF, on simule une résolution
  337. * de Darcy. On prend pour cela K = 1 et grad h = U :
  338.  
  339. * Matériau associé (Ma) :
  340. MaHydro = 'MATERIAU' MoHydro 'K' 1.;
  341.  
  342. * Matrice hybride élémentaire :
  343. MeHydro = 'MHYB' MoHydro MaHydro;
  344.  
  345. * Trace de Concentration :
  346. FAHydro= 'DOMA' MoHydro 'FACE' ;
  347. XX YY = 'COOR' FAHydro ;
  348. Un = 'MANU' 'CHPO' FAHydro 1 'SCAL' 1.;
  349. THHydro = (-1.) * (UXImp * XX) - (UYImp * YY) + Un;
  350. THHydro = 'NOMC' THHydro 'TH';
  351.  
  352. * Concentration :
  353. XX YY = 'COOR' CeHydro ;
  354. Un = 'MANU' 'CHPO' CeHydro 1 'SCAL' 1.;
  355. HHydro = (-1.) * (UXImp * XX) - (UYImp * YY) + Un;
  356. HHydro = 'NOMC' HHydro 'H';
  357.  
  358. * Flux et vitesses :
  359. QFHydro = 'HDEB' MoHydro MeHydro HHydro THHydro ;
  360. VCDarcy = 'HVIT' MoHydro QFHydro ;
  361.  
  362. * =============
  363. * | TRANSPORT |
  364. * =============
  365. * Modèle propre au transport :
  366. * ----------------------------
  367. MoTransp = 'MODELE' QMtot DARCY ISOTROPE ;
  368.  
  369. * Matrice Porosité cinématique (Type ChamElem) :
  370. * ----------------------------------------------
  371. CeTransp= 'DOMA' MoTransp 'CENTRE' ;
  372. MaPor1 = 'MANU' 'CHPO' CeTransp 1 'CK' ValPor NATURE DIFFUS;
  373. MaPor = 'KCHA' MoTransp MaPor1 'CHAM';
  374. MaPorVol= VolChPro * ('EXCO' 'CK' MaPor1 'SCAL');
  375.  
  376. * Matrice coef. de retard (Type Scalaire car constant) :
  377. * ----------------------------------------------
  378. MaRet1 = CofRetar;
  379.  
  380. * Porosité * retard * volume de maille (x Ccentre = soluté + adsorbat par maille)
  381. * ------------------------------------
  382. PorVoRet = MaPorVol * MaRet1;
  383.  
  384. * Temps :
  385. * -------
  386. * Temps à calculer
  387. LiTCalc = 'PROG' TIni 'PAS' DeltaT Tfin;
  388. NTCalc = 'DIME' LiTCalc;
  389. 'REMPLACER' LiTCalc NTCalc Tfin;
  390.  
  391. * Ecriture de ces temps sous forme de table ;
  392. TabTCalc = 'TABLE';
  393. 'REPETER' Bcl26 NTCalc;
  394. Id = &Bcl26 - 1;
  395. Tps = 'EXTR' LiTCalc &Bcl26;
  396. TabTCalc.Id = Tps;
  397. 'FIN' Bcl26;
  398.  
  399. * Temps sauvegardés
  400. LiTSauv = LiTCalc ;
  401. NTSauv = NTCalc ;
  402.  
  403. * Temps de tracage des champs
  404. LiIndGph = 'LECT' 0 5 10 ;
  405. NTGrph = 'DIME' LiIndGph;
  406.  
  407. * Temps de tracage des évolutions
  408. LiTEvol = litsauv ;
  409. liindEvl = 'LECT' 0 pas 1 (ntsauv - 1) ;
  410. NTEvol = 'DIME' litevol;
  411.  
  412. * Temps servant à la création des chargements
  413. TSup = 1.2 * TFin;
  414. DelTDef = 0.001 * TSup;
  415.  
  416. * ====================================
  417. * | CONSTRUCTION DES DONNEES DE BASE |
  418. * ====================================
  419. * Dissolution / Libération ;
  420. * --------------------------
  421. *-- Matrice Limite de solubilité ;
  422. * Variation linéaire décroissance de l'amont vers l'aval :
  423. XX YY = 'COOR' CeHydro;
  424. MaSol4 = 'MANU' 'CHPO' CeHydro 1 'H' (CSat2 - CSat1)
  425. NATURE DIFFUS;
  426. MaSol1 = (YY * MaSol4 / LYM) + CSat1;
  427.  
  428. * Matrice Coefficient de dissolution :
  429. * ------------------------------------
  430. SI SoluP;
  431. MaCoDis1 = 'MANU' 'CHPO' CeHydro 1 'SCAL' ValCoDis;
  432. FINSI;
  433.  
  434. * Matériau associé au transport :
  435. * -------------------------------
  436. * Terme diffusif pur (diffusivité effective) = Porosité * Diffusivité :
  437. DifEff = DifMolec * FacForme * MaPor;
  438. MaTransp = 'MATERIAU' MoTransp 'K' DifEff ;
  439.  
  440. * Matrice hybride élémentaire :
  441. * -----------------------------
  442. MeTransp = 'MHYB' MoTransp MaTransp;
  443.  
  444. * Conditions Initiales :
  445. * ----------------------
  446. *-- Traces de concentration (quelconque car le transport est implicité).
  447. TC0 = 'MANU' 'CHPO' FaHydro 1 'TH' 0. 'NATURE' 'DISCRET';
  448.  
  449. *-- Concentration aux centres des éléments (sert à définir la quantité
  450. * initiale d'élément) :
  451. Conc01 = 'MANU' 'CHPO' CeHydro 1 'H' 0. 'NATURE' 'DISCRET';
  452. Conc02 = 'MANU' 'CHPO' ('DOMA' MoActif 'CENTRE') 1 'H' CActif0
  453. 'NATURE' 'DISCRET';
  454. Conc0 = Conc01 ET Conc02;
  455. Conc0 = 'NOMC'
  456. ('KCHT' MoHydro 'SCAL' 'CENTRE' ('NOMC' Conc0 'SCAL')) 'H';
  457.  
  458. *-- Flux diffusif initial (aux centres des faces) - décoratif puisque la
  459. * diffusion est implicite :
  460. QFDif0 = 'MANU' 'CHPO' FaHydro 1 'FLUX' 0. 'NATURE' 'DISCRET';
  461.  
  462. *-- Précipité :
  463. SI Solub;
  464. Prec01 = 'MANU' 'CHPO' ( 'DOMA' MoActif 'CENTRE') 1 'H'
  465. PActif0 'NATURE' 'DISCRET';
  466. Prec02 = 'MANU' 'CHPO' CeHydro 1 'H' 0. 'NATURE' 'DISCRET';
  467. Prec0 = Prec01 ET Prec02;
  468. Prec0 = 'NOMC'
  469. ('KCHT' MoHydro 'SCAL' 'CENTRE' ('NOMC' Prec0 'SCAL')) 'H';
  470. FINSI;
  471.  
  472. *-- Libération de soluté à partir du précipité (décoratif aussi):
  473. SI Solub;
  474. Libe0 = 'MANU' 'CHPO' CeHydro 1 'H' 0. 'NATURE' 'DISCRET';
  475. FINSI;
  476.  
  477. * Conditions aux limites (type CHARGEMENT) :
  478. * ------------------------------------------
  479. * Concentration imposée en amont et en aval, flux nul ailleurs.
  480. Ceinf= DOMA MoInf 'CENTRE' ;
  481. CeSup= DOMA MoSup 'CENTRE' ;
  482. CCL = 'MANU' 'CHPO' (Ceinf et CeSup) 1 'TH' 0.
  483. 'NATURE' 'DISCRET';
  484. RigCL = 'BLOQUE' (CeInf et CeSup) 'TH';
  485. CharCL = 'DEPIMPOSE' RigCL CCL ;
  486. ChgCL = 'CHARG' CharCL
  487. ('EVOL' 'MANU' ('PROG' 0. TSup) ('PROG' 1. 1.));
  488.  
  489. * ===============================
  490. * | Vérification des paramètres |
  491. * | de CONVERGENCE |
  492. * ===============================
  493. MESS 'Vérification des paramètres de CONVERGENCE :';
  494. MESS '--------------------------------------------';
  495.  
  496. * Cohérence dissolution progressive :
  497. * -----------------------------------
  498. * Pour éviter que la dissolution progressive ne soit si rapide que
  499. * l'on dépasse régulièrement la limite de solubilité, au risque
  500. * d'osciller, voire de diverger, vérifier que Codis * DeltaT < 1 :
  501. SI SoluP;
  502. Stietel = (1. - TetaDis) * MaCoDis1 * DeltaT;
  503. SI ('NEG' (TYPE Stietel) 'CHPOINT ');
  504. StietelM = Stietel;
  505. SINON;
  506. StietelM = 'MAXIMUM' Stietel;
  507. FINSI;
  508. MESS 'Le nombre de Stietel (dissolution progressive) atteint '
  509. StietelM ;
  510. SI (StietelM > 1.);
  511. MESS 'Attention, il est supérieur à 1';
  512. SI ('NEG' (TYPE MaCoDis1) 'CHPOINT ');
  513. MinCoDis = MaCoDis1;
  514. SINON;
  515. MinCoDis = 'MINIMUM' MaCoDis1;
  516. FINSI;
  517. MESS 'Il faut prendre un pas de temps d au plus'
  518. (1. / MinCoDis) 'ans. ';
  519. SINON;
  520. MESS 'Il est bien inférieur à 1';
  521. FINSI;
  522. MESS ' ';
  523. FINSI;
  524. * ==============
  525. * | Résolution |
  526. * ==============
  527. *-- Table de transport :
  528. Transp = 'TABLE';
  529. Transp.'TEMPS' = 'TABLE';
  530. Transp.'TRACE_CONC' = 'TABLE';
  531. Transp.'CONCENTRATION' = 'TABLE';
  532. Transp.'FLUX' = 'TABLE';
  533. SI Solub;
  534. Transp.'PRECIPITE' = 'TABLE';
  535. Transp.'DISSOLUTION' = 'TABLE';
  536. FINSI;
  537.  
  538. Transp.'SOUSTYPE' = 'DARCY_TRANSITOIRE';
  539. Transp.'MODELE' = MoTransp;
  540. Transp.'CARACTERISTIQUES' = MaTransp;
  541. Transp.'POROSITE' = MaPor;
  542. Transp.'CONVECTION' = QFHydro;
  543. Transp.'COEF_RETARD' = MaRet1;
  544. SI SoluL;
  545. Transp.'LIMITE_SOLUBILITE' = MaSol1;
  546. FINSI;
  547. SI SoluP;
  548. Transp.'COEF_DISSOLUTION' = MaCoDis1;
  549. FINSI;
  550.  
  551. * Conditions initiales :
  552. Transp.'TEMPS'. 0 = TIni;
  553. Transp.'TRACE_CONC'. 0 = TC0;
  554. Transp.'CONCENTRATION'. 0 = Conc0;
  555. Transp.'FLUX'. 0 = QFDif0;
  556. SI Solub;
  557. Transp.'PRECIPITE'. 0 = Prec0;
  558. Transp.'DISSOLUTION'. 0 = Libe0;
  559. FINSI;
  560.  
  561. * Conditions aux limites :
  562. Transp.'BLOCAGE' = RigCL;
  563. Transp.'TRACE_IMPOSE' = ChgCL;
  564.  
  565. * Paramètres numériques :
  566. Transp.'THETA_DIFF' = TetaDif;
  567. Transp.'THETA_CONVECTION' = TetaCnv;
  568. SI SoluP;
  569. Transp.'THETA_DISS' = TetaDis;
  570. FINSI;
  571. Transp.'TEMPS_CALCULES' = LiTCalc;
  572. Transp.'TEMPS_SAUVES' = LiTSauv;
  573.  
  574. * ==========
  575. * | CALCUL |
  576. * ==========
  577.  
  578. DARCYTRA Transp;
  579.  
  580. * ===================
  581. * | POST-TRAITEMENT |
  582. * ===================
  583.  
  584. MESS ' ';
  585. MESS 'Post-Traitement :';
  586. MESS '-----------------';
  587. MESS ' ';
  588.  
  589. IndTSauv = 'INDEX' (Transp.temps);
  590.  
  591. * Préparation tracé :
  592. * -------------------
  593. * Calcul du flux à travers une certaine ligne :
  594. * ---------------------------------------------
  595. * Les propriétés de la ligne sont stockées dans DFlux et NleFlux.
  596. * Le nom de la ligne doit etre mis dans DFluxTIT .
  597. NORHydro = 'DOMA' MoTransp 'NORMALE' ;
  598. Ori2 = 'PSCAL' ('REDU' NORHydro CeFlux ) NleFlux
  599. ('MOTS' 'UX' 'UY') ('MOTS' 'UX' 'UY');
  600. FlInt = 0.;
  601. liabs2 = 'ENLEVER' litcalc 1;
  602. 'REPETER' Bcl21 (NTSauv - 1);
  603. i = &Bcl21 + 1;
  604. Id = IndTSauv.i;
  605. Tps = Transp.Temps.Id;
  606. Id1 = IndTSauv.(i - 1);
  607. Tp1 = Transp.Temps.(id - 1);
  608. dt = Tps - Tp1;
  609.  
  610. *-- Flux diffusif et convectif à l'instant d'indice Id
  611. * (diffusion implicite TetaDif et convection implicite TetaCnv) :
  612. * méthode par produit scalaire flux * normale sur 1 ligne
  613.  
  614. * Débit diffusif sortant :
  615. DebD1 = ((1. - TetaDif) * Transp.Flux.Id1)
  616. + (TetaDif * Transp.Flux.Id);
  617. DebD2 = 'REDU' DebD1 CeFlux ;
  618. DebD3 = 'RESULT' (DebD2 * Ori2);
  619. FlD = ('MAXIMUM' DebD3);
  620. Fl = FlD;
  621.  
  622. * Débit convectif sortant :
  623. THCnv = ((1. - TetaCnv) * Transp.Trace_Conc.Id1)
  624. + (TetaCnv * Transp.Trace_Conc.Id);
  625. DebC1 = ('EXCO' 'TH' THCnv 'SCAL') * Transp.Convection;
  626. DebC2 = 'REDU' DebC1 CeFlux ;
  627. DebC3 = 'RESULT' (DebC2 * Ori2);
  628. FlC = ('MAXIMUM' DebC3);
  629. Fl = FlC + FlD;
  630.  
  631. FlInt = FlInt + (Fl * dt);
  632.  
  633. SI (i 'EGA' 2);
  634. LiFlC = 'PROG' FlC;
  635. LiFlD = 'PROG' FlD;
  636. LiFl = 'PROG' Fl;
  637. LiFlI = 'PROG' FlInt;
  638. SINON;
  639. LiFlC = 'INSERER' LiFlC (i - 1) FlC;
  640. LiFlD = 'INSERER' LiFlD (i - 1) FlD;
  641. LiFl = 'INSERER' LiFl (i - 1) Fl;
  642. LiFlI = 'INSERER' LiFlI (i - 1) FlInt;
  643. FINSI;
  644. 'FIN' Bcl21;
  645.  
  646. EvFlC = 'EVOL' 'JAUN' 'MANU' 't (ans)' LiAbs2 'Debit_Conv' LiFlC;
  647. EvFlD = 'EVOL' 'BLEU' 'MANU' 't (ans)' LiAbs2 'Debit_Diff' LiFlD;
  648. EvFl = 'EVOL' 'VERT' 'MANU' 't (ans)' LiAbs2 'Debit' LiFl;
  649. EvFlI = 'EVOL' 'VERT' 'MANU' 't (ans)' LiAbs2 'Debit_int.' LiFlI;
  650.  
  651. * Tracé :
  652. * ------
  653. * Décalage des champs les uns par rapport aux autres :
  654. Decal1 = (1.2 * LXM) 0.;
  655. Decal2 = (2.4 * LXM) 0.;
  656.  
  657. * Tracé du champ de limite de solubilité :
  658. * ----------------------------------------
  659. SI (TrLimSol ET SoluL);
  660. 'TITRE' 'Limite de solubilite';
  661. MaSol2 = 'KCHA' MoTransp MaSol1 'CHAM';
  662. 'TRAC' MoTransp MaSol2 LTrame;
  663. FINSI;
  664.  
  665. * Tracé du champ de coefficient de dissolution :
  666. * ----------------------------------------------
  667. SI (TrCoDis ET SoluP);
  668. 'TITRE' 'Coefficient de dissolution (1/an)';
  669. MaCoDis2 = 'KCHA' MoTransp MaCoDis1 'CHAM';
  670. 'TRAC' MoTransp MaCoDis2 LTrame;
  671. FINSI;
  672.  
  673. * Tracé du champ de coefficient de retard :
  674. * -----------------------------------------
  675. SI (TrRet ET ('EXISTE' Transp COEF_RETARD));
  676. 'TITRE' 'Coefficient de Retard';
  677. MaRet0 = Transp.COEF_RETARD;
  678. SI ('EGA' (TYPE MaRet0) 'FLOTTANT');
  679. MaRet1 = MANU 'CHPO' CeTransp 1 'SCAL' MaRet0;
  680. SINON;
  681. MaRet1 = MaRet0;
  682. FINSI;
  683. MaRet2 = 'KCHA' MoTransp MaRet1 'CHAM';
  684. MaRet3 = 'KCHT' MoTransp 'SCAL' 'CENTRE' ('NOMC' MaRet1 'SCAL');
  685. MaRet4 = 'ELNO' MoTransp MaRet3;
  686.  
  687. Rmin = 'MINIMUM' MaRet1;
  688. Rmax = 'MAXIMUM' MaRet1;
  689. SI (('MINIMUM' MaRet1) < (('MAXIMUM' MaRet1) - EpsPrec));
  690. Ech = 'PROG' Rmin 'PAS' ((Rmax - Rmin) / 4.) Rmax;
  691. 'TRAC' MoTransp MaRet2 LTrame Ech;
  692. SINON;
  693. Ech = 'PROG' 0. ('MAXIMUM' MaRet1);
  694. 'TRAC' MoTransp MaRet2 LTrame Ech;
  695. FINSI;
  696. FINSI;
  697.  
  698. * Tracé des profils de conc, prec, diss le long des lignes choisies :
  699. * -------------------------------------------------------------------
  700. SI TrLEvol;
  701.  
  702. IndLEvol = 'INDEX' LEvol;
  703. TabEvlC = table;
  704. SI Solub;
  705. TabEvlP = table;
  706. TabEvlL = table;
  707. Finsi;
  708.  
  709. 'REPETER' Bcl ('DIME' LEvol);
  710. * pour chaque ligne i où suivre les valeurs :
  711. i = IndLEvol.&Bcl;
  712.  
  713. * détermination du nom de la composante à suivre et évolution de
  714. * la limite de solubilité :
  715. si ('EGA' (LEvol.i.'P') 'CENTRE');
  716. mot1 = 'H';
  717. finsi;
  718. si ('EGA' (LEvol.i.'P') 'FACE');
  719. mot1 = 'TH';
  720. finsi;
  721. si ('EGA' (LEvol.i.'P') 'SOMMET');
  722. mot1 = 'SCAL';
  723. finsi;
  724.  
  725. * Evolution des concentrations :
  726. TitDesC = 'CHAINE' 'Concentration ' (LEvol.i.'T') ;
  727. TabEvlC.i = TRACHIS Transp 'CONCENTRATION' (LEvol.i.'M') LiIndevl
  728. ('MOTS' mot1) ('MOTS' ' ') 'PREF' ' ' ;
  729.  
  730. si (SoluL et ('NEG' (LEvol.i.'P') 'FACE'));
  731. * Adjonction de la limite de solubilité :
  732. si ('EGA' (LEvol.i.'P') 'CENTRE');
  733. EvSatL = 'EVOL' 'BLAN' 'CHPO' MaSol1 'H' (LEvol.I.'M');
  734. finsi;
  735. si ('EGA' (LEvol.i.'P') 'SOMMET');
  736. EvSatL = 'EVOL' 'BLAN' 'CHPO' MaSolS 'SCAL' (LEvol.I.'M');
  737. finsi;
  738. EvSatL = 'EXTR' EvSatL 'COUR' 1;
  739. nn = 'DIME' TabEvlC.i ;
  740. 'REPETER' bcl2 nn ;
  741. j = nn - &bcl2 + 1;
  742. TabEvlC.i.(j + 1) = TabEvlC.i.j;
  743. 'FIN' bcl2;
  744. TabEvlC.i.1 = table;
  745. TabEvlC.i.1 .'VALEUR' = EvSatL ;
  746. TabEvlC.i.1 .'LEGEND1' = 'Csat' ;
  747. TabEvlC.i.1 .'LEGEND2' = ' ';
  748. finsi;
  749.  
  750. DESTRA (TabEvlC.i) 'MIMA' 'AXES'
  751. 'TITR' TitDesC 'TITX' (LEvol.i.'L') 'TITY' 'C (mol/l)'
  752. 'YBOR' 0. CSat1 ;
  753.  
  754. SI (Solub et ('NEG' (LEvol.i.'P') 'FACE'));;
  755. * Evolution des précipités :
  756. TitDesP = 'CHAINE' 'Precipite ' (LEvol.i.'T') ;
  757. TabEvlP.i = TRACHIS Transp 'PRECIPITE' (LEvol.i.'M') LiIndevl
  758. ('MOTS' mot1) ('MOTS' ' ') 'PREF' ' ' ;
  759. DESTRA (TabEvlP.i) 'MIMA' 'AXES' 'TITR' TitDesP
  760. 'TITX' (LEvol.i.'L') 'TITY' 'P (mol/dm3)' ;
  761. * Evolution des dissolutions :
  762. TitDesL = 'CHAINE' 'Dissolution ' (LEvol.i.'T') ;
  763. TabEvlL.i = TRACHIS Transp 'DISSOLUTION' (LEvol.i.'M') LiIndevl
  764. ('MOTS' mot1) ('MOTS' ' ') 'PREF' ' ' ;
  765. DESTRA (TabEvlL.i) 'MIMA' 'AXES' 'TITR' TitDesL
  766. 'TITX' (LEvol.i.'L') 'TITY' 'L (mol/dm3/an)' ;
  767. Finsi;
  768.  
  769. 'FIN' bcl;
  770.  
  771. FINSI;
  772.  
  773. * Tracé des évolutions de conc, prec, diss aux points choisis :
  774. * -------------------------------------------------------------
  775. * (L'indice 0 est réservé à un point de la source)
  776. SI (TrPEvol ET (('DIME' ('INDEX' PEVol)) > 0));
  777.  
  778. IndPEvol = 'INDEX' PEvol;
  779. TabEvpC = table;
  780. SI Solub;
  781. TabEvpP = table;
  782. TabEvpL = table;
  783. Finsi;
  784.  
  785. 'REPETER' Bcl ('DIME' PEvol);
  786. * pour chaque point i où suivre les valeurs :
  787. i = IndPEvol.&Bcl;
  788.  
  789. * détermination du nom de la composante à suivre et évolution de
  790. * la limite de solubilité :
  791. si ('EGA' (PEvol.i.'P') 'CENTRE');
  792. mot1 = 'H';
  793. finsi;
  794. si ('EGA' (PEvol.i.'P') 'FACE');
  795. mot1 = 'TH';
  796. finsi;
  797. si ('EGA' (PEvol.i.'P') 'SOMMET');
  798. mot1 = 'SCAL';
  799. finsi;
  800.  
  801. * Evolution des concentrations :
  802. TitDesC = 'CHAINE' 'Concentration ' (PEvol.i.'T') ;
  803. TabEvpC.i = TRACHIT Transp 'CONCENTRATION'
  804. ('MANU' 'POI1' (PEvol.i.'M')) LiIndEvl
  805. ('MOTS' mot1) 'PREF' ' ' ;
  806.  
  807. si (SoluL et ('NEG' (PEvol.i.'P') 'FACE'));
  808. * Adjonction de la limite de solubilité :
  809. si ('EGA' (PEvol.i.'P') 'CENTRE');
  810. ValCSat = MaSol1 'EXTR' 'H' (PEvol.i.'M');
  811. finsi;
  812. si ('EGA' (PEvol.i.'P') 'SOMMET');
  813. ValCSat = MaSolS 'EXTR' 'SCAL' (PEvol.i.'M');
  814. finsi;
  815. EvSatP = 'EVOL' 'MANU' ('PROG' 0. TFin) ('PROG' 2*ValCSat);
  816. nn = 'DIME' TabEvpC.i ;
  817. 'REPETER' bcl2 nn ;
  818. j = nn - &bcl2 + 1;
  819. TabEvpC.i.(j + 1) = TabEvpC.i.j;
  820. 'FIN' bcl2;
  821. TabEvpC.i.1 = table;
  822. TabEvpC.i.1 .'VALEUR' = EvSatP ;
  823. TabEvpC.i.1 .'LEGEND1' = 'Csat' ;
  824. TabEvpC.i.1 .'LEGEND2' = ' ';
  825. FINSI;
  826.  
  827. DESTRA (TabEvpC.i) 'MIMA' 'AXES'
  828. 'TITR' TitDesC 'TITX' 't (an)' 'TITY' 'C (mol/l)'
  829. 'YBOR' 0. CSat1 'XBOR' Tini TFin ;
  830.  
  831. SI (Solub et ('NEG' (PEvol.i.'P') 'FACE'));;
  832. * Evolution des précipités :
  833. TitDesP = 'CHAINE' 'Precipite ' (PEvol.i.'T') ;
  834. TabEvpP.i = TRACHIT Transp 'PRECIPITE'
  835. ('MANU' 'POI1' (PEvol.i.'M')) LiIndevl
  836. ('MOTS' mot1) 'PREF' ' ' ;
  837. DESTRA (TabEvpP.i) 'MIMA' 'AXES' 'TITR' TitDesP
  838. 'TITX' 't (an)' 'TITY' 'P (mol/dm3)'
  839. 'XBOR' Tini TFin ;
  840. * Evolution des dissolutions :
  841. TitDesL = 'CHAINE' 'Dissolution ' (PEvol.i.'T') ;
  842. TabEvpL.i = TRACHIT Transp 'DISSOLUTION'
  843. ('MANU' 'POI1' (PEvol.i.'M')) LiIndevl
  844. ('MOTS' mot1) 'PREF' ' ' ;
  845. DESTRA (TabEvpL.i) 'MIMA' 'AXES' 'TITR' TitDesL
  846. 'TITX' 't (an)' 'TITY' 'L (mol/dm3/an)'
  847. 'XBOR' Tini TFin ;
  848. Finsi;
  849.  
  850. 'FIN' bcl;
  851.  
  852. FINSI; COMM 'SI TrPEvol';
  853.  
  854. * Tracé des champs de conc, prec, aux différents instants :
  855. * ---------------------------------------------------------
  856. * On déplace les supports des chpos pour tracer les fractions de
  857. * précipité à côté des concentrations :
  858. TrPrec = TrPrec ET Solub;
  859.  
  860. *-- On trace pour chaque temps choisi :
  861. SI (TrConc OU TrPrec);
  862.  
  863. *-- Echelles :
  864. SI TrConc;
  865. SI SoluL;
  866. CMinD = 'MINIMUM' MaSol1;
  867. CMaxD = 'MAXIMUM' MaSol1;
  868. SINON;
  869. CMinD = 0.;
  870. CMaxD = 0.;
  871. FINSI;
  872. FINSI;
  873.  
  874. 'REPETER' Bcl17 NTSauv;
  875. i = &Bcl17;
  876. Id = IndTSauv.i;
  877. SI TrConc;
  878. CMinD = 'MINIMUM'
  879. ('PROG' CMinD ('MINIMUM' Transp.Concentration.Id));
  880. CMaxD = 'MAXIMUM'
  881. ('PROG' CMaxD ('MAXIMUM' Transp.Concentration.Id));
  882. FINSI;
  883. 'FIN' Bcl17;
  884.  
  885. SI TrConc;
  886. CMinD = 'MINIMUM' ('PROG' CMinD (CMaxD * 1.e-2));
  887. CMinD = 'MAXIMUM' ('PROG' CMinD 0.);
  888. EchC0 = 'PROG' 0. 'PAS' (CMaxD / 13.) CMaxD;
  889. FINSI;
  890.  
  891. 'REPETER' Bcl3 NTGrph;
  892. Id = 'EXTR' LiIndgph &Bcl3;
  893. Tps = Transp.Temps.Id;
  894. TitGraph = ' ' ;
  895. SI TrConc;
  896. TitGraph = 'CHAINE' TitGraph 'Solute ';
  897. FINSI;
  898. SI (TrConc ET TrPrec);
  899. TitGraph = 'CHAINE' TitGraph 'et ';
  900. FINSI;
  901. SI TrPrec;
  902. TitGraph = 'CHAINE' TitGraph 'Precipite ';
  903. FINSI;
  904. TitGraph = 'CHAINE' TitGraph 'a t=' Tps ' ans ';
  905. 'TITRE' TitGraph;
  906.  
  907. SI TrConc;
  908. Conc2 = 'KCHA' MoTransp Transp.Concentration.Id 'CHAM';
  909. MoTot = MoTransp;
  910. Tot2 = Conc2;
  911. FINSI;
  912. SI TrPrec;
  913. Prec1 = 'KCHA' MoTransp Transp.Precipite.Id 'CHAM';
  914. MoTra2 Prec2 = MoTransp Prec1 'PLUS' Decal1;
  915. LTra2 = LTrame 'PLUS' Decal1;
  916. 'ELIMINATION' (ltra2 'ET' ('EXTR' Prec2 'MAIL')) epselim;
  917. SI (NON TrConc);
  918. Tot2 = Prec2;
  919. MoTot = MoTra2;
  920. SINON;
  921. Tot2 = Tot2 ET Prec2;
  922. MoTot = MoTot ET MoTra2;
  923. FINSI;
  924. FINSI;
  925.  
  926. SI (('MINIMUM' Tot2) < (('MAXIMUM' Tot2) - EpsPrec));
  927. SI (TrConc ET (NON TrPrec));
  928. SI (('MINIMUM' Conc2) < (('MAXIMUM' Conc2) - EpsPrec));
  929. 'TRACER' Motot conc2 echc0 LTrame;
  930. FINSI;
  931. SINON;
  932. SI TrConc;
  933. 'TRACER' MoTot Tot2 echc0 ;
  934. SINON;
  935. 'TRACER' MoTot Tot2 echc0 ltra2 ;
  936. FINSI;
  937. FINSI;
  938. FINSI;
  939. 'FIN' Bcl3;
  940. FINSI;
  941.  
  942. * Tracé des champs de dissolution :
  943. * ---------------------------------
  944. TrLib = TrLib ET Solub;
  945. SI TrLib;
  946. 'REPETER' Bcl22 (NTgrph - 1);
  947. Id = ('EXTR' LiIndgph (&Bcl22 + 1)) - 1 ;
  948. Tps = Transp.Temps.Id;
  949. Id2 = Id + 1;
  950. Tp2 = Transp.Temps.Id2;
  951. dt = Tp2 - Tps;
  952. TitGraph = 'CHAINE' 'Quantite dissoute entre '
  953. Tps ' et ' Tp2 ' annees (mol/m3/an)';
  954. 'TITRE' TitGraph;
  955. Libe2 = Transp.Dissolution.Id2;
  956. Libe3 = 'KCHA' MoTransp Libe2 'CHAM';;
  957. SI ((('MAXIMUM' Libe3) - ('MINIMUM' Libe3)) > EpsPrec);
  958. 'TRAC' MoTransp Libe3 Ltrame ;
  959. FINSI;
  960. 'FIN' Bcl22;
  961. FINSI;
  962.  
  963. * Tracé du flux traversant la ligne choisie (en mol/l/an) :
  964. * ---------------------------------------------------------
  965. SI TrFlux ;
  966.  
  967. TitDess = 'CHAINE' 'Flux traversant ' DFluxTIT ;
  968. TabDess = 'TABLE';
  969. TabDess.1 = 'MARQ CARR' ;
  970. TabDess.2 = 'MARQ TRIA' ;
  971. TabDess.3 = 'MARQ PLUS' ;
  972. TabDess.'TITRE' = 'TABLE';
  973. TabDess.'TITRE' . 1 = 'Debit_Convectif';
  974. TabDess.'TITRE' . 2 = 'Debit_Diffusif';
  975. TabDess.'TITRE' . 3 = 'Debit_Total';
  976. EvTot = EvFlC ET EvFlD ET EvFl;
  977. 'DESSIN' EvTot 'MIMA' TabDess 'TITR' TitDess 'TITX' 't (an)' 'TITY'
  978. 'mol/l/an' 'LEGE' 'AXES' 'XBOR' TIni TFin;
  979. FINSI;
  980.  
  981. * ===========================
  982. * | TEST DE BON DEROULEMENT |
  983. * ===========================
  984. * Le test se fait en comparant le flux total traversant la ligne avec
  985. * une liste obtenue par un calcul préalable.
  986. liflsav = 'PROG' .30290 .58543 .78354 .92082 1.0185 1.0894 1.0285
  987. .86475 .69182 .54609 ;
  988.  
  989. *'LISTE' lifl ;
  990.  
  991. err1 = 'MAXIMUM' ('ABS' (lifl - liflsav)) / ('MAXIMUM' liflsav);
  992. mess 'Erreur = ' err1 ;
  993.  
  994. si (err1 > CRIT1);
  995. 'ERREUR' 5;
  996. sinon;
  997. 'ERREUR' 0;
  998. finsi;
  999.  
  1000. Fin;
  1001.  
  1002.  
  1003.  
  1004.  
  1005.  
  1006.  
  1007.  
  1008.  
  1009.  
  1010.  
  1011.  
  1012.  
  1013.  
  1014.  
  1015.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales