Télécharger tran8.dgibi

Retour à la liste

Numérotation des lignes :

  1. * fichier : tran8.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4. * CAS TEST DU 91/06/13 PROVENANCE : TEST
  5.  
  6. *******************************************
  7. * Test tran8.dgibi: jeux de données *
  8. * --------------------------------- *
  9. *******************************************
  10.  
  11. * SI GRAPH = N PAS DE GRAPHIQUE AFFICHE
  12. * SINON SI GRAPH DIFFERENT DE N TOUS
  13. * LES GRAPHIQUES SONT AFFICHES
  14.  
  15. GRAPH = 'N' ;
  16.  
  17. SAUT PAGE;
  18. SI (NEG GRAPH 'N') ;
  19. OPTI ECHO 1 ;
  20. OPTI TRAC PSC ;
  21. SINO ;
  22. OPTI ECHO 0 ;
  23. FINSI ;
  24.  
  25. SAUT PAGE;
  26.  
  27. *******************************************
  28. * TRAN8 *
  29. * *
  30. * THERMIQUE TRANSITOIRE LINEAIRE EN 2D *
  31. * *
  32. * Test NAFEMS numero T3 *
  33. * *
  34. * *
  35. * description *
  36. * ----------- *
  37. * *
  38. * A C B *
  39. * <_0.02_> *
  40. * | | | *
  41. * |=================================| *
  42. * | | *
  43. * <______________0.1 m______________> *
  44. * ---> axe X *
  45. * *
  46. * *
  47. * conditions aux limites *
  48. * ---------------------- *
  49. * *
  50. * - temperature imposee au point A : *
  51. * TA = 0 *
  52. * *
  53. * - temperature imposee au point B : *
  54. * TB = 100 * sin (PI * temps / 40) *
  55. * *
  56. *******************************************
  57. OPTI ELEM QUA4;
  58.  
  59. *---------- geometrie : maillage ---------*
  60.  
  61. PA1 = 0. 0.; PB1 = 0.1 0. ;
  62. PA2 = 0. 0.01; PB2 = 0.1 0.01;
  63.  
  64. N = 10;
  65. D1 = PA1 DROI N PB1;
  66. D2 = PB1 DROI 1 PB2;
  67. D3 = PB2 DROI N PA2;
  68. D4 = PA2 DROI 1 PA1;
  69.  
  70. SUR1 = DALL D1 D2 D3 D4 PLAN;
  71.  
  72. PC = POIN SUR1 PROC (0.08 0.);
  73.  
  74.  
  75. SI (NEG GRAPH 'N');
  76. TITR 'TRAN8 : MAILLAGE';
  77. TRAC 'QUAL' SUR1;
  78. FINSI;
  79.  
  80. *--------- modeles - materiaux -----------*
  81. MODL1 = MODE SUR1 THERMIQUE ISOTROPE QUA4;
  82. MATR1 = MATE MODL1 'RHO' 7200 'K' 35.0 'C' 440.5;
  83.  
  84. * temperatures imposees : fonction du temps
  85. *
  86. * - Cote PA : temperature constante
  87. * de 0 degres celcius
  88. * - Cote PB : temperature variable
  89. * en fonction du temps
  90.  
  91. BLOCD4 = BLOQ D4 'T';
  92. BLOCD2 = BLOQ D2 'T';
  93.  
  94. TEMPD4 = DEPI BLOCD4 1.;
  95. TEMPD2 = DEPI BLOCD2 1.;
  96.  
  97. * Un pas toutes les secondes,
  98. * temps maximum 40. s.
  99. LTEMPS = PROG 0. PAS 1. 40.;
  100.  
  101. LD4 = PROG 41 * 0.;
  102. LD2 = PROG SINU (1. / 80.) AMPL 100 LTEMPS;
  103.  
  104. EVOLD4 = EVOL MANU TEMPS LTEMPS THETA LD4;
  105. EVOLD2 = EVOL MANU TEMPS LTEMPS THETA LD2;
  106.  
  107. CHAD4 = CHAR 'TIMP' TEMPD4 EVOLD4;
  108. CHAD2 = CHAR 'TIMP' TEMPD2 EVOLD2;
  109.  
  110. * Creation d'un flux nul (type chargement)
  111. FLU0 = MANU CHPO (D1 ET D3) 1 Q 0.;
  112.  
  113. EVOL3= EVOL MANU TEMP LTEMPS FLUX (PROG 41 * 1.);
  114. FLU1 = CHAR 'Q' FLU0 EVOL3;
  115.  
  116. *--- objets pour la procedure PASAPAS ----*
  117. BLOCT = (BLOCD2 ET BLOCD4);
  118. CHART = (FLU1 ET CHAD4 ET CHAD2);
  119.  
  120. TAB1 = TABL;
  121. TAB1.'TEMPERATURES' = TABL;
  122. TAB1.'TEMPERATURES' . 0 = MANU CHPO SUR1 1 T 0.;
  123. TAB1.'BLOCAGES_THERMIQUES' = BLOCT;
  124. TAB1.'CHARGEMENT' = CHART;
  125. TAB1.'MODELE' = MODL1;
  126. TAB1.'CARACTERISTIQUES' = MATR1;
  127. TAB1.'TEMPS_SAUVES' = PROG 0. PAS 1. 32.;
  128. TAB1.'TEMPS_CALCULES' = PROG 0. PAS 1. 32.;
  129. TAB1.'PROCEDURE_THERMIQUE' = LINEAIRE;
  130.  
  131. PASAPAS TAB1;
  132.  
  133.  
  134. *------- extraction des resultats --------*
  135. * Temperature du point C a t = 32 s.
  136.  
  137. * Construction de l'evolution de T au cours
  138. * du temps
  139.  
  140. LTEMPE = VIDE 'LISTREEL';
  141. LTEMPS = VIDE 'LISTREEL';
  142. NBPAS = DIME (TAB1. 'TEMPS') ;
  143. REPE SURPAS NBPAS;
  144. INDICE = &SURPAS;
  145. LTEMPS = LTEMPS ET (PROG (TAB1.'TEMPS'. (INDICE - 1)));
  146. LTEMPE = LTEMPE ET (PROG (EXTR TAB1.'TEMPERATURES'. (INDICE - 1) T (SUR1 POIN PROC (0.08 0.))));
  147. FIN SURPAS;
  148.  
  149. EVTEMPE = EVOL BLEU MANU LTEMPS LTEMPE;
  150.  
  151.  
  152. THET1 = EXTR LTEMPE NBPAS;
  153. THET2 = 36.6;
  154.  
  155. ERG =100 * (ABS ((THET2 - THET1) / THET2));
  156.  
  157. * Trace facultatif de la repartition
  158. * de temperature a t = 32 s
  159. SI (NEG GRAPH 'N');
  160. TITR 'TRAN8 : Temperature a t = 32 s';
  161. CHPO3 = PECHE TAB1 'TEMPERATURES' TAB1. 'TEMPS' . (NBPAS - 1);
  162. TRAC SUR1 CHPO3;
  163. TITR 'Evolution de la temperature en fonction du temps : ';
  164. DESS EVTEMPE ;
  165. FINSI;
  166.  
  167. *-------- Test Reactions dans solution -------*
  168. IREAC1 = 'EXIS' TAB1 'REACTIONS_THERMIQUES' ;
  169.  
  170. *-------- affichage des resultats --------*
  171.  
  172. MESS ' RESULTATS ';
  173. MESS ' --------- ';
  174.  
  175. MESS 'Temperature theorique :' THET2' C';
  176. MESS 'Temperature calculee :' THET1' C';
  177. MESS ' Soit un ecart de : ' ERG '%';
  178.  
  179. *------- code fonctionnement -------------*
  180. SI ((ERG &lt;EG 5) 'ET' IREAC1);
  181. ERRE 0;
  182. SINON;
  183. 'SI' ('NON' IREAC1) ;
  184. 'MESS' '***** ERREUR : il manque les reactions thermiques ! ' ;
  185. 'FINS' ;
  186. ERRE 5 ;
  187. FINSI;
  188.  
  189. TEMPS;
  190.  
  191. FIN;
  192.  
  193.  
  194.  
  195.  
  196.  
  197.  
  198.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales