Télécharger tran2.dgibi

Retour à la liste

Numérotation des lignes :

  1. * fichier : tran2.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4. * CAS TEST DU 91/06/24 PROVENANCE : DELA
  5.  
  6. *******************************************
  7. * Test tran2.dgibi: jeux de données *
  8. * --------------------------------- *
  9. *******************************************
  10.  
  11. * SI GRAPH = N PAS DE GRAPHIQUE AFFICHE
  12. * SINON SI GRAPH DIFFERENT DE N TOUS
  13. * LES GRAPHIQUES SONT AFFICHES
  14.  
  15. GRAPH = 'N' ;
  16.  
  17. SAUT PAGE;
  18. SI (NEG GRAPH 'N') ;
  19. OPTI ECHO 1 ;
  20. OPTI TRAC X ;
  21. SINO ;
  22. OPTI ECHO 1 ;
  23. FINSI ;
  24.  
  25. SAUT PAGE;
  26.  
  27. *-----------------------------------------*
  28. * *
  29. * TEST TRAN2 *
  30. * *
  31. *--- Problème : *
  32. * *
  33. * Problème de Valentin : *
  34. * thermique transitoire linéaire *
  35. * *
  36. * *
  37. *--- Description de la géométrie : *
  38. * *
  39. * A ----- B *
  40. * | | *
  41. * | | AB = 1. *
  42. * | | BC = 10. *
  43. * | | EC = 4. *
  44. * | | *
  45. * | | *
  46. * F |-----| E *
  47. * | | *
  48. * D | | C *
  49. * X------ -----> R *
  50. * R=0. *
  51. * *
  52. * Conductivité isotrope : K = 1.*
  53. * Capacité du matériau : C = 1.*
  54. * RHO= 1.*
  55. * Sur AB , température imposée: T = 1.*
  56. * Sur BC , convection forcée : TE= 1.*
  57. * H= 10.*
  58. * Dans CDFE , source volumique: Q = 1.*
  59. * Ailleurs, flux imposé : F = 0.*
  60. * *
  61. *--- Calcul : *
  62. * Calcul axisymétrique *
  63. * Recherche de la température maximale*
  64. * dans le cylindre épais par une *
  65. * méthode pas à pas. L'évolution de la*
  66. * température est comparée avec la *
  67. * solution analytique *
  68. * *
  69. *--- Résultats : *
  70. * *
  71. * Comparer avec le cas-test THERMX *
  72. * 'PLI45' *
  73. * La température maximale doit tendre *
  74. * vers 1.3 *
  75. * *
  76. *-----------------------------------------*
  77.  
  78. TITR 'PROBLEME DE VALENTIN - THERMIQUE TRANSITOIRE LINEAIRE' ;
  79. OPTI DIME 2 ELEM TRI6 MODE AXIS ;
  80. TEMPS ;
  81.  
  82. *------- Création de la géométrie --------*
  83. PD = 0. 0. ;
  84. PC = 1. 0. ;
  85. PB = 1. 10. ;
  86. PA = 0. 10. ;
  87. PE = 1. 4. ;
  88. PF = 0. 4. ;
  89. D1 = DROITE 4 PD PC ;
  90. D2 = DROITE 5 PC PE ;
  91. D3 = DROITE 4 PE PF ;
  92. D4 = DROITE 5 PF PD ;
  93. LIG1 = D1 ET D2 ET D3 ET D4 ;
  94. D5 = DROITE 8 PF PA ;
  95. D6 = DROITE 4 PA PB ;
  96. D7 = DROITE 8 PB PE ;
  97. LIG2 = D3 ET D5 ET D6 ET D7 ;
  98. SURF1 = SURF LIG1 PLANE ;
  99. SURF2 = SURF LIG2 PLANE ;
  100. SURF3 = SURF1 ET SURF2 ;
  101.  
  102. SI(NEG GRAPH 'N');
  103. TRAC 'QUAL' SURF3 ;
  104. FINSI;
  105.  
  106. *--- DONNEES DU PROBLEME DE THERMIQUE ----*
  107.  
  108. *------ 1 - Modélisation du maillage SURF3:
  109. * formulation + matériau
  110. MOD1 = MODE SURF3 THERMIQUE ISOTROPE ;
  111.  
  112. *------ 2 - Création d'un CHAMELEM de
  113. * sous-type CARACTERISTIQUES
  114. MAT1 = MATE MOD1 K 1. 'C' 1. RHO 1. ;
  115.  
  116. *------ 3 - Condition de source volumique :
  117. * calcul du CHPOINT des flux
  118. * nodaux équivalents
  119. S1 = SOURCE MOD1 1. SURF1 ;
  120.  
  121. *------ 4 - Modèle pour la formulation
  122. * convection et type d'élément
  123. MOD2 = MODE (D2 ET D7) THERMIQUE CONVECTION;
  124. MOD4 = MOD1 ET MOD2;
  125.  
  126. *------ 5 - Création de CHAMELEM de
  127. * caractéristiques pour la
  128. * convection
  129. MAT2 = MATE MOD2 H 10. ;
  130. MAT4 = MAT1 ET MAT2 ;
  131.  
  132. *------ 6 - Blocage des températures
  133. B1 = BLOQ T D6 ;
  134.  
  135. *------ 7 - Valeur de T imposée
  136. E1 = DEPI B1 1. ;
  137.  
  138. *------ 8 - Condition de flux nul : calcul
  139. * du CHPOINT de flux équivalent
  140. FF1 = FLUX MOD1 0. D1 ;
  141.  
  142. *------ 9 - Assemblage des CHPOINTs de flux
  143. * équivalents
  144. QQQ1 = S1 ET FF1 ;
  145.  
  146. *------ 10 - chargement
  147. D69 = D7 'ET' D2;
  148. CH_TE = 'MANU' 'CHPO' 1 D69 'T' 1.;
  149.  
  150. PP1 = PROG 0. PAS 0.05 NPAS 50 ;
  151. PP2 = PROG 51. * 1. ;
  152. MEVOL1 = EVOL MANU 'TEMPS' PP1 'COEFF' PP2;
  153. MEVOL2 = EVOL MANU 'TEMPS' (PROG 0. 2.) 'T' (PROG 1. 1.);
  154. CHA1 = CHAR 'Q ' QQQ1 MEVOL1 ;
  155. CHA2 = CHAR 'TIMP' E1 MEVOL2;
  156. CHA3 = CHAR 'TECO' CH_TE MEVOL2;
  157. CHA4 = CHA1 ET CHA2 ET CHA3;
  158.  
  159. * ----- 11 - remplissage pour PASAPAS
  160. CHTER0 = MANU CHPO SURF3 1 T 1. ;
  161.  
  162. ETAB = TABL ;
  163. ETAB.'TEMPERATURES' = TABL ;
  164. ETAB.'TEMPERATURES' . 0 = CHTER0 ;
  165. ETAB.'MODELE' = MOD4 ;
  166. ETAB.'CARACTERISTIQUES' = MAT4 ;
  167. ETAB.'BLOCAGES_THERMIQUES' = B1 ;
  168. ETAB.'CHARGEMENT' = CHA4 ;
  169. ETAB.'PROCEDURE_THERMIQUE' = LINEAIRE ;
  170. ETAB.'TEMPS_CALCULES' = PROG 0.1 0.2 0.3 0.4 0.5 0.6 0.7 0.8 0.9 1. 1.1 1.2 1.3;
  171.  
  172.  
  173. PASAPAS ETAB ;
  174.  
  175. LISTT = PROG ;
  176. TEMP1 = PROG ;
  177. REPETER BOUCSOR (DIME ETAB.'TEMPERATURES');
  178. ITERA = &BOUCSOR;
  179. LISTT = INSE LISTT ITERA (ETAB.'TEMPS'. (ITERA-1)) ;
  180. TEMP1 = INSE TEMP1 ITERA ( MAXI ( ETAB.'TEMPERATURES'. (ITERA-1) ));
  181. FIN BOUCSOR ;
  182.  
  183. *----- 12 - SORTIE DES RESULTATS
  184. EV1 = EVOL BLEU MANU 'TEMPS' LISTT 'TEMPERATURE' TEMP1 ;
  185. TIME = PROG 0.1 0.200 0.300 0.400 0.500 0.600 0.700 0.800 0.900 1.000 1.100 1.200 1.300 ;
  186. LTEM = PROG 1.076 1.135 1.179 1.212 1.236 1.253 1.266 1.276 1.282 1.287 1.290 1.293 1.295 ;
  187. EV2 = EVOL ROUGE MANU TIME LTEM ;
  188.  
  189. SI(NEG GRAPH 'N');
  190. TITR 'EVOLUTION DE LA TEMPERATURE MAXIMALE';
  191. DESS (EV1 ET EV2) ;
  192. FINSI;
  193.  
  194. TEMPS ;
  195.  
  196. * CODE DE FONCTIONNEMENT BASé SUR UN ECART
  197. * MILIEU DE COURBE
  198. * TEST RUDIMENTAIRE POUVANT ETRE OPTIMISé
  199. TREF = 1.253;
  200. ITER1A= 6;
  201. TMAX = MAXI (ETAB.'TEMPERATURES'.ITER1A);
  202. RESI = 100. * (ABS((TMAX-TREF)/TREF));
  203. SI(RESI <EG 5.);
  204. ERRE 0;
  205. SINO;
  206. ERRE 5;
  207. FINSI;
  208.  
  209.  
  210. FIN;
  211.  
  212.  
  213.  
  214.  
  215.  
  216.  
  217.  
  218.  
  219.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales