Télécharger tran12.dgibi

Retour à la liste

Numérotation des lignes :

  1. * fichier : tran10.dgibi
  2. *
  3. * Copie du cas-test "tran10.dgibi" pour tester
  4. * la donnee a PASAPAS d'une :
  5. * - CAPACITE_CONSTANTE
  6. * - CONDUCTIVITE_CONSTRANTE
  7. * et resolution par la procedure NONLINEAIRE
  8.  
  9. * Calcul avec des EF TRI3 (au lieu de QUA4)
  10.  
  11. *******************************************
  12. *******************************************
  13.  
  14. *******************************************
  15. * Test tran10.dgibi: jeux de données *
  16. * --------------------------------- *
  17. *******************************************
  18.  
  19. * SI GRAPH = N PAS DE GRAPHIQUE AFFICHE
  20. * SINON SI GRAPH DIFFERENT DE N TOUS
  21. * LES GRAPHIQUES SONT AFFICHES
  22.  
  23. GRAPH = 'N' ;
  24.  
  25. SAUT PAGE;
  26. SI (NEG GRAPH 'N') ;
  27. OPTI ECHO 1 ;
  28. OPTI TRAC PSC ;
  29. SINO ;
  30. OPTI ECHO 0 ;
  31. FINSI ;
  32.  
  33. SAUT PAGE;
  34.  
  35. *******************************************
  36. * tran10 *
  37. * *
  38. * THERMIQUE TRANSITOIRE LINEAIRE EN 2D *
  39. * *
  40. * Test NAFEMS numero T3 *
  41. * *
  42. * *
  43. * description *
  44. * ----------- *
  45. * *
  46. * A C B *
  47. * <_0.02_> *
  48. * | | | *
  49. * |=================================| *
  50. * | | *
  51. * <______________0.1 m______________> *
  52. * ---> axe X *
  53. * *
  54. * *
  55. * conditions aux limites *
  56. * ---------------------- *
  57. * *
  58. * - temperature imposee au point A : *
  59. * TA = 0 *
  60. * *
  61. * - temperature imposee au point B : *
  62. * TB = 100 * sin (PI * temps / 40) *
  63. * *
  64. *******************************************
  65. OPTI ELEM TRI3;
  66.  
  67. *---------- geometrie : maillage ---------*
  68.  
  69. PA1 = 0. 0.; PB1 = 0.1 0. ;
  70. PA2 = 0. 0.01; PB2 = 0.1 0.01;
  71.  
  72. N = 10;
  73. D1 = PA1 DROI N PB1;
  74. D2 = PB1 DROI 1 PB2;
  75. D3 = PB2 DROI N PA2;
  76. D4 = PA2 DROI 1 PA1;
  77.  
  78. SUR1 = DALL D1 D2 D3 D4 PLAN;
  79.  
  80. PC = POIN SUR1 PROC (0.08 0.);
  81.  
  82.  
  83. SI (NEG GRAPH 'N');
  84. TITR 'TRAN10 : MAILLAGE';
  85. TRAC 'QUAL' SUR1;
  86. FINSI;
  87.  
  88. *--------- modeles - materiaux -----------*
  89. MODL1 = MODE SUR1 THERMIQUE ISOTROPE ;
  90. MATR1 = MATE MODL1 'RHO' 7200 'K' 20.0
  91. 'C' 240.5 ;
  92.  
  93. * test de l'option 'CAPACITE_CONSTANTE'
  94. * de PASAPAS :
  95. MATR2 = MATE MODL1 'RHO' 7200 'K' 15.0
  96. 'C' 200.0 ;
  97. CAP2 = CAPA MODL1 MATR2 ;
  98. CND2 = COND MODL1 MATR2 ;
  99.  
  100. * temperatures imposees : fonction du temps
  101. *
  102. * - Cote PA : temperature constante
  103. * de 0 degres celcius
  104. * - Cote PB : temperature variable
  105. * en fonction du temps
  106.  
  107. BLOCD4 = BLOQ D4 'T';
  108. BLOCD2 = BLOQ D2 'T';
  109.  
  110. TEMPD4 = DEPI BLOCD4 1.;
  111. TEMPD2 = DEPI BLOCD2 1.;
  112.  
  113. * Un pas toutes les secondes,
  114. * temps maximum 40. s.
  115. LTEMPS = PROG 0. PAS 1. 40.;
  116.  
  117. LD4 = PROG 41 * 0.;
  118. LD2 = PROG SINU (1. / 80.) AMPL 100 LTEMPS;
  119.  
  120. EVOLD4 = EVOL MANU TEMPS LTEMPS THETA LD4;
  121. EVOLD2 = EVOL MANU TEMPS LTEMPS THETA LD2;
  122.  
  123. CHAD4 = CHAR 'TIMP' TEMPD4 EVOLD4;
  124. CHAD2 = CHAR 'TIMP' TEMPD2 EVOLD2;
  125.  
  126. * Creation d'un flux nul (type chargement)
  127. FLU0 = MANU CHPO (D1 ET D3) 1 Q 0.;
  128.  
  129. EVOL3= EVOL MANU TEMP LTEMPS FLUX
  130. (PROG 41 * 1.);
  131. FLU1 = CHAR 'Q' FLU0 EVOL3;
  132.  
  133. *--- objets pour la procedure PASAPAS ----*
  134. BLOCT = (BLOCD2 ET BLOCD4);
  135. CHART = (FLU1 ET CHAD4 ET CHAD2);
  136.  
  137. TAB1 = TABL;
  138. TAB1.'TEMPERATURES' = TABL;
  139. TAB1.'TEMPERATURES' . 0 =
  140. MANU CHPO SUR1 1 T 0.;
  141. TAB1.'BLOCAGES_THERMIQUES' = BLOCT;
  142. TAB1.'CHARGEMENT' = CHART;
  143. TAB1.'MODELE' = MODL1;
  144. TAB1.'CARACTERISTIQUES' = MATR1;
  145. TAB1.'TEMPS_SAUVES' =
  146. PROG 0. PAS 1. 32.;
  147. TAB1.'TEMPS_CALCULES' =
  148. PROG 0. PAS 1. 32.;
  149. TAB1.'CAPACITE_CONSTANTE' = CAP2 ;
  150. TAB1.'CONDUCTIVITE_CONSTANTE' = CND2 ;
  151.  
  152. PASAPAS TAB1;
  153.  
  154. *------- extraction des resultats --------*
  155. * Temperature du point C a t = 32 s.
  156.  
  157. * Construction de l'evolution de T au cours
  158. * du temps
  159.  
  160. LTEMPE = VIDE 'LISTREEL';
  161. LTEMPS = VIDE 'LISTREEL';
  162. NBPAS = DIME (TAB1. 'TEMPS') ;
  163. REPE SURPAS NBPAS;
  164. INDICE = &SURPAS;
  165. LTEMPS = LTEMPS ET (PROG
  166. (TAB1.'TEMPS'. (INDICE - 1)));
  167. LTEMPE = LTEMPE ET (PROG
  168. (EXTR TAB1.'TEMPERATURES'. (INDICE - 1) T
  169. (SUR1 POIN PROC (0.08 0.))));
  170. FIN SURPAS;
  171.  
  172. EVTEMPE = EVOL BLEU MANU LTEMPS LTEMPE;
  173.  
  174.  
  175. THET1 = EXTR LTEMPE NBPAS;
  176. THET2 = 36.6;
  177.  
  178. ERG =100 * (ABS ((THET2 - THET1) / THET2));
  179.  
  180. * Trace facultatif de la repartition
  181. * de temperature a t = 32 s
  182. SI (NEG GRAPH 'N');
  183. TITR 'TRAN10 : Temperature a t = 32 s';
  184. CHPO3 = PECHE TAB1 'TEMPERATURES'
  185. TAB1. 'TEMPS' . (NBPAS - 1);
  186. TRAC SUR1 CHPO3;
  187.  
  188. TITR 'Evolution de la temperature en
  189. fonction du temps : ';
  190. DESS EVTEMPE ;
  191. FINSI;
  192.  
  193. *-------- Test Reactions dans solution -------*
  194. IREAC1 = 'EXIS' TAB1 'REACTIONS_THERMIQUES' ;
  195.  
  196. *-------- affichage des resultats --------*
  197.  
  198. MESS ' RESULTATS ';
  199. MESS ' --------- ';
  200.  
  201. MESS 'Temperature theorique :' THET2' C';
  202. MESS 'Temperature calculee :' THET1' C';
  203. MESS ' Soit un ecart de : ' ERG '%';
  204.  
  205. *------- code fonctionnement -------------*
  206. SI ((ERG &lt;EG 5) et IREAC1);
  207. ERRE 0;
  208. SINON;
  209. 'SI' ('NON' IREAC1) ;
  210. 'MESS' '***** ERREUR : il manque les reactions thermiques ! ' ;
  211. 'FINS'
  212. ERRE 5;
  213. FINSI;
  214.  
  215. TEMPS;
  216.  
  217. FIN;
  218.  
  219.  
  220.  
  221.  
  222.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales