Télécharger tran10.dgibi

Retour à la liste

Numérotation des lignes :

  1. * fichier : tran10.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4. *
  5. * Copie du cas-test "tran8.dgibi" mais appel
  6. * a la procedure de resolution NONLINEAIRE
  7. * (meme si pb. lineaire).
  8.  
  9. *******************************************
  10. * Test tran10.dgibi: jeux de données *
  11. * --------------------------------- *
  12. *******************************************
  13.  
  14. * SI GRAPH = N PAS DE GRAPHIQUE AFFICHE
  15. * SINON SI GRAPH DIFFERENT DE N TOUS
  16. * LES GRAPHIQUES SONT AFFICHES
  17.  
  18. GRAPH = 'N' ;
  19.  
  20. SAUT PAGE;
  21. SI (NEG GRAPH 'N') ;
  22. OPTI ECHO 1 ;
  23. OPTI TRAC PSC ;
  24. SINO ;
  25. OPTI ECHO 0 ;
  26. FINSI ;
  27.  
  28. SAUT PAGE;
  29.  
  30. *******************************************
  31. * tran10 *
  32. * *
  33. * THERMIQUE TRANSITOIRE LINEAIRE EN 2D *
  34. * *
  35. * Test NAFEMS numero T3 *
  36. * *
  37. * *
  38. * description *
  39. * ----------- *
  40. * *
  41. * A C B *
  42. * <_0.02_> *
  43. * | | | *
  44. * |=================================| *
  45. * | | *
  46. * <______________0.1 m______________> *
  47. * ---> axe X *
  48. * *
  49. * *
  50. * conditions aux limites *
  51. * ---------------------- *
  52. * *
  53. * - temperature imposee au point A : *
  54. * TA = 0 *
  55. * *
  56. * - temperature imposee au point B : *
  57. * TB = 100 * sin (PI * temps / 40) *
  58. * *
  59. *******************************************
  60. OPTI ELEM QUA4;
  61.  
  62. *---------- geometrie : maillage ---------*
  63.  
  64. PA1 = 0. 0.; PB1 = 0.1 0. ;
  65. PA2 = 0. 0.01; PB2 = 0.1 0.01;
  66.  
  67. N = 10;
  68. D1 = PA1 DROI N PB1;
  69. D2 = PB1 DROI 1 PB2;
  70. D3 = PB2 DROI N PA2;
  71. D4 = PA2 DROI 1 PA1;
  72.  
  73. SUR1 = DALL D1 D2 D3 D4 PLAN;
  74.  
  75. PC = POIN SUR1 PROC (0.08 0.);
  76.  
  77.  
  78. SI (NEG GRAPH 'N');
  79. TITR 'TRAN10 : MAILLAGE';
  80. TRAC 'QUAL' SUR1;
  81. FINSI;
  82.  
  83. *--------- modeles - materiaux -----------*
  84. MODL1 = MODE SUR1 THERMIQUE ISOTROPE QUA4;
  85. MATR1 = MATE MODL1 'RHO' 7200 'K' 35.0 'C' 440.5;
  86.  
  87. * temperatures imposees : fonction du temps
  88. *
  89. * - Cote PA : temperature constante
  90. * de 0 degres celcius
  91. * - Cote PB : temperature variable
  92. * en fonction du temps
  93.  
  94. BLOCD4 = BLOQ D4 'T';
  95. BLOCD2 = BLOQ D2 'T';
  96.  
  97. TEMPD4 = DEPI BLOCD4 1.;
  98. TEMPD2 = DEPI BLOCD2 1.;
  99.  
  100. * Un pas toutes les secondes,
  101. * temps maximum 40. s.
  102. LTEMPS = PROG 0. PAS 1. 40.;
  103.  
  104. LD4 = PROG 41 * 0.;
  105. LD2 = PROG SINU (1. / 80.) AMPL 100 LTEMPS;
  106.  
  107. EVOLD4 = EVOL MANU TEMPS LTEMPS THETA LD4;
  108. EVOLD2 = EVOL MANU TEMPS LTEMPS THETA LD2;
  109.  
  110. CHAD4 = CHAR 'TIMP' TEMPD4 EVOLD4;
  111. CHAD2 = CHAR 'TIMP' TEMPD2 EVOLD2;
  112.  
  113. * Creation d'un flux nul (type chargement)
  114. FLU0 = MANU CHPO (D1 ET D3) 1 Q 0.;
  115.  
  116. EVOL3= EVOL MANU TEMP LTEMPS FLUX (PROG 41 * 1.);
  117. FLU1 = CHAR 'Q' FLU0 EVOL3;
  118.  
  119. *--- objets pour la procedure PASAPAS ----*
  120. BLOCT = (BLOCD2 ET BLOCD4);
  121. CHART = (FLU1 ET CHAD4 ET CHAD2);
  122.  
  123. TAB1 = TABL;
  124. TAB1.'TEMPERATURES' = TABL;
  125. TAB1.'TEMPERATURES' . 0 = MANU CHPO SUR1 1 T 0.;
  126. TAB1.'BLOCAGES_THERMIQUES' = BLOCT;
  127. TAB1.'CHARGEMENT' = CHART;
  128. TAB1.'MODELE' = MODL1;
  129. TAB1.'CARACTERISTIQUES' = MATR1;
  130. TAB1.'TEMPS_SAUVES' = PROG 0. PAS 1. 32.;
  131. TAB1.'TEMPS_CALCULES' = PROG 0. PAS 1. 32.;
  132.  
  133. PASAPAS TAB1;
  134.  
  135.  
  136. *------- extraction des resultats --------*
  137. * Temperature du point C a t = 32 s.
  138.  
  139. * Construction de l'evolution de T au cours
  140. * du temps
  141.  
  142. LTEMPE = VIDE 'LISTREEL';
  143. LTEMPS = VIDE 'LISTREEL';
  144. NBPAS = DIME (TAB1. 'TEMPS') ;
  145. REPE SURPAS NBPAS;
  146. INDICE = &SURPAS;
  147. LTEMPS = LTEMPS ET (PROG (TAB1.'TEMPS'. (INDICE - 1)));
  148. LTEMPE = LTEMPE ET (PROG (EXTR TAB1.'TEMPERATURES'. (INDICE - 1) T (SUR1 POIN PROC (0.08 0.))));
  149. FIN SURPAS;
  150.  
  151. EVTEMPE = EVOL BLEU MANU LTEMPS LTEMPE;
  152.  
  153.  
  154. THET1 = EXTR LTEMPE NBPAS;
  155. THET2 = 36.6;
  156.  
  157. ERG =100 * (ABS ((THET2 - THET1) / THET2));
  158.  
  159. * Trace facultatif de la repartition
  160. * de temperature a t = 32 s
  161. SI (NEG GRAPH 'N');
  162. TITR 'TRAN10 : Temperature a t = 32 s';
  163. CHPO3 = PECHE TAB1 'TEMPERATURES' TAB1. 'TEMPS' . (NBPAS - 1);
  164. TRAC SUR1 CHPO3;
  165. TITR 'Evolution de la temperature en fonction du temps : ';
  166. DESS EVTEMPE ;
  167. FINSI;
  168.  
  169. *-------- Test Reactions dans solution -------*
  170. IREAC1 = 'EXIS' TAB1 'REACTIONS_THERMIQUES' ;
  171.  
  172. *-------- affichage des resultats --------*
  173.  
  174. MESS ' RESULTATS ';
  175. MESS ' --------- ';
  176.  
  177. MESS 'Temperature theorique :' THET2' C';
  178. MESS 'Temperature calculee :' THET1' C';
  179. MESS ' Soit un ecart de : ' ERG '%';
  180.  
  181. *------- code fonctionnement -------------*
  182. SI ((ERG &lt;EG 5) et IREAC1);
  183. ERRE 0;
  184. SINON;
  185. 'SI' ('NON' IREAC1) ;
  186. 'MESS' '***** ERREUR : il manque les reactions thermiques ! ' ;
  187. 'FINS' ERRE 5;
  188. FINSI;
  189.  
  190. TEMPS;
  191.  
  192. FIN;
  193.  
  194.  
  195.  
  196.  
  197.  
  198.  
  199.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales