Exemples de jeux de données Cast3M

* fichier : traction316L.dgibi
* section : Mecanique, Plastique
*----------------------------------------------------------------------*
* Essai de traction cyclique sur de l'acier 316L a 20 degC.            *
*                                                                      *
* Validation des donnees materiaux integrees dans la procedure BIBLIO. *
* Reproduction de la courbe de traction presentee dans la reference,   *
* Fig. 2. (a).                                                         *
*                                                                      *
* Description :                                                        *
* -------------                                                        *
*                                                                      *
* Type de calcul : mecanique, plastique                                *
* Mode de calcul : 3D                                                  *
* Type d'element : CUB8                                                *
* Chargement     : Deplacement impose                                  *
* Reference      :                                                     *
* ----------------                                                     *
* O. Muransky, C.J. Hamelin, M.C. Smith, P.J. Bendeich, L. Edwards,
* "The effect of plasticity theory on predicted residual stress fields
*  in numerical weld analyses",
* Computational Materials Science 54 (2012) 125–134.
*                                                                      *
*----------------------------------------------------------------------*
*
opti dime 3 elem cub8 ;
 
* Pour affichages, mettre IG1 a VRAI :
ig1      = faux ;
 
* Pour calcul complet, mettre icomplet a vrai :
icomplet = faux ;
 
*opti trac psc eptr 5 ;
 
ig1      = ig1 ou (ega (vale trac) 'PSC') ;
 
*------------------------------ Modele EF -----------------------------*
 
* Temperature essai :
T0      = 20. ;
 
* Maillage cube unite :
L1      = (0 0 0) droi 1 (1 0 0) ;
S1      = L1 tran 1 (0 1 0) ;
V1      = S1 volu tran 1 (0 0 1) ;
 
si ig1 ;
  trac V1 titr 'Traction sur un cube unite' ;
fins ;
 
* Donnees 316L :
t316L   = biblio '316L' refe 4 ;
 
* Modele et Caracteristiques :
mod1    = mode V1 mecanique elastique plastique chaboche2 ;
mat1    = mate mod1 'YOUN' t316L.'YOUN' 'NU' t316L.'NU' 'ALPH' t316L.'ALPH'
                    'R0'   t316L.'R0'   'RM' t316L.'RM' 'B' t316L.'B'
                    'A1'   t316L.'A1'   'C1' t316L.'C1' 'A2' t316L.'A2' 'C2' t316L.'C2' 
                    'PSI'  1. 'OMEG' 0. 'TREF' T0 'TALP' T0 ;
 
* CL (blocages) :
Sx0     = (V1 coor 1) poin infe 1.e-3 ;
Sy0     = (V1 coor 2) poin infe 1.e-3 ;
S2      = V1 face 2 ;
CLUS1   = bloq S1 uz ;
CLUX0   = bloq Sx0 ux ;
CLUY0   = bloq Sy0 uy ;
CLUS2   = bloq S2 uz ;
cl0     = CLUS1 et CLUX0 et CLUY0 et CLUS2 ;
 
* Deplacement impose :
DCLS2   = depi CLUS2 1. ;
 
* Evolution temporelle :
epoint1 = 1.e-3 ;
emax1   = 0.015 ;
temax1  = emax1 / epoint1 ;
lamp1   = prog 0.  1.  -1.  1.  -1.  1.  -1.  1.  -1.  0. ;
ltps1   = prog 0.  1.   3.  5.   7.  9.  11. 13.  15. 16. ;
lamp1   = emax1 * lamp1 ;
ltps1   = temax1 * ltps1 ;
ev1     = evol manu temp ltps1 lamp1 ;
 
* Chargement mecanique :
cg1     = char dimp DCLS2 ev1 ;
 
* Chargement thermique :
cht1    = manu chpo V1 1 'T' T0 ;
cgt1    = char t cht1 ;
 
si ig1 ;
  dess ev1 titr 'Evolution temporelle du deplacement impose.' ;;
fins ;
 
*------------------------- Resolution PASAPAS -------------------------*
 
tpas1    = table ;
tpas1.modele = mod1 ;
tpas1.caracteristiques = mat1 ;
tpas1.chargement = cg1 et cgt1 ;
tpas1.blocages_mecaniques = cl0 ;
si icomplet ;
  tpas1.temps_calcules = ltps1 raff (0.05*temax1) ;
sino ;
  tpas1.temps_calcules = (ltps1 raff (0.05*temax1)) extr (lect 1 pas 1 10) ;
fins ;
 
list tpas1.temps_calcules ;
 
pasapas tpas1 ;
 
*----------------------- Visualisation resultat -----------------------*
 
* Courbe de traction a la temperature courante :
pz1      = S2 poin proc (0 0 1) ;
lu1      = prog 0. ;
lf1      = prog 0. ;
nb1      = (dime tpas1.temps) - 1 ;
repe b1 nb1 ;
  i1       = &b1 ;
  ui1      = (tpas1.deplacements.i1) extr 'UZ' pz1 ;
  fi1      = ((tpas1.reactions.i1) redu s2) resu ;
  fi1      = extr fi1 'FZ' ((extr fi1 mail) poin 1) ;
  lu1      = lu1 et ui1 ;
  lf1      = lf1 et fi1 ;
fin B1 ;
evfu1    = evol vert manu 'dL/L (%)' (100.*lu1) 'F/So (MPa)' (1.e-6*lf1) ;
 
si ig1 ;
  dess evfu1 gril point titr 'Courbe de traction cyclique 316L a 20. degC.' logo posy exce ;
fins ;
 
fin ;