Télécharger traction.dgibi

Retour à la liste

Numérotation des lignes :

  1. * fichier : traction.dgibi
  2. * section : mecanique elastique plastique
  3. *------------------------------------------------------------------------------*
  4. * TRACTION *
  5. *------------------------------------------------------------------------------*
  6. * Objet :
  7. * -------
  8. *
  9. * Exemple de mise en donnees d'un calcul elastoplastique en petits et
  10. * grands deplacements. L'objectif est de retrouver par le calcul la courbe
  11. * d'ecrouissage fournie dans les caracteristiques du modele.
  12. *
  13. * Description :
  14. * -------------
  15. * Essai de traction.
  16. *
  17. * Type de calcul : Mecanique, materiau elastique plastique isotrope
  18. * Mode de calcul : Tridimensionnel,
  19. * - petits deplacements
  20. * - grands deplacements, lagrangien reactualise
  21. * - grands deplacements, lagrangien total
  22. * Type d'element : CUB8
  23. * Chargement : Deplacement impose
  24. * Reference : Comparaison a la courbe de traction fournie en argument
  25. * Objectif : Ecart relatif sur la contrainte < 1 %
  26. *
  27. * Remarque : Les courbes de traction et d'ecrouissage fournies sont :
  28. * ---------- En petites perturbations :
  29. * => courbe d'ecrouissage conventionnelle :
  30. * . eps = dL/L
  31. * . sig = F/So
  32. * En grands deplacements, lagrangien reactualise ou total :
  33. * => courbe d'ecrouissage rationnelle :
  34. * . eps = log (1+dL/L)
  35. * . sig = F/So*(1+dL/L))
  36. *
  37. *------------------------------------------------------------------------------*
  38. graph = faux ;
  39. *---------------------------- PETITES PERTURBATIONS ---------------------------*
  40. opti dime 3 elem cub8 ;
  41. *
  42. * Maillage :
  43. v1 = (0 0 0) droi 1 (1 0 0) tran 1 (0 1 0) volu tran 1 (0 0 1) ;
  44. x1 y1 z1 = v1 coor ;
  45. ptx0 = x1 poin infe 0.01 ;
  46. pty0 = y1 poin infe 0.01 ;
  47. ptz0 = z1 poin infe 0.01 ;
  48. ptz1 = z1 poin supe 0.99 ;
  49. ptx0 = ptx0 coul bleu ;
  50. pty0 = pty0 coul vert ;
  51. ptz0 = ptz0 coul bleu ;
  52. ptz1 = ptz1 coul jaun ;
  53. si graph ;
  54. trac v1 titr 'Traction sur 1 element' ;
  55. elx0 = (enve V1) elem appu stri ptx0 ;
  56. ely0 = (enve V1) elem appu stri pty0 ;
  57. elz0 = (enve V1) elem appu stri ptz0 ;
  58. elz1 = (enve V1) elem appu stri ptz1 ;
  59. elx0 = elx0 coul bleu ;
  60. ely0 = ely0 coul vert ;
  61. elz0 = elz0 coul roug ;
  62. elz1 = elz1 coul jaun ;
  63. el0 = elx0 et ely0 et elz0 ;
  64. mot0 = chai 'Faces bleue : Ux = 0, verte : Uy = 0, rouge : Uz = 0' ;
  65. trac face (el0 et (aret v1)) titr mot0 ;
  66. mot0 = chai format '(F5.2)' 'Face jaune : uz =' epsf1 ;
  67. trac face (elz1 et (aret v1)) titr mot0 ;
  68. fins ;
  69.  
  70. * Modele - Caracteristiques :
  71. *
  72. * Caracteristiques mecaniques :
  73. ym1 = 200.e9 ;
  74. nu1 = 0.3 ;
  75. h1 = 1.e9 ;
  76. sigy1 = 400.e6 ;
  77. *
  78. * Courbes de traction et d'ecrouissage :
  79. epsf1 = 0.5 ;
  80. epsy1 = sigy1 / ym1 ;
  81. leps1 = prog 0. epsy1 pas (0.1 * epsf1) epsf1 ;
  82. leps1p = enle leps1 (lect 1 2) ;
  83. lsig1 = (prog 0. sigy1) et (h1 * (leps1p - epsy1) + sigy1) ;
  84. lepp1 = (enle leps1 1) - epsy1 ;
  85. lsmp1 = h1 * lepp1 + sigy1 ;
  86. trac1 = evol vert manu epeq leps1 smeq lsig1 ;
  87. ecro1 = evol bleu manu epeq lepp1 smeq lsmp1 ;
  88. *
  89. tleg1 = tabl ;
  90. tleg1 . titre = tabl ;
  91. tleg1 . titre . 1 = 'Courbe de traction' ;
  92. tleg1 . titre . 2 = 'Courbe ecrouissage' ;
  93. si graph ;
  94. dess (trac1 et ecro1) titr 'Courbes conventionelles de traction et d ecrouissage' lege tleg1 ;
  95. fins ;
  96.  
  97. opti epsi lineaire ;
  98. mo1 = mode v1 mecanique elastique plastique ;
  99. ma1 = mate mo1 youn ym1 nu nu1 ecro ecro1 ;
  100.  
  101. * C.L. - Chargement :
  102. clx0 = bloq ptx0 ux ;
  103. cly0 = bloq pty0 uy ;
  104. clz0 = bloq ptz0 uz ;
  105. clz1 = bloq ptz1 uz ;
  106. cl0 = clx0 et cly0 et clz0 et clz1 ;
  107.  
  108. dep1 = depi clz1 epsf1 ;
  109. ev1 = evol manu temps (prog 0. 1.) (prog 0. 1.) ;
  110. cg1 = char dimp dep1 ev1 ;
  111.  
  112. * Resolution :
  113. ltcal1 = prog 0. (epsy1/epsf1) 0.1 pas 0.1 1. ;
  114. ta1 = tabl ;
  115. ta1 . modele = mo1 ;
  116. ta1 . caracteristiques = ma1 ;
  117. ta1 . blocages_mecaniques = cl0 ;
  118. ta1 . chargement = cg1 ;
  119. ta1 . temps_calcules = ltcal1 ;
  120.  
  121. pasapas ta1 ;
  122.  
  123. * Comparaison courbes calculee / fournie :
  124. nb1 = dime ta1 . temps_calcules ;
  125. lep1 = prog ;
  126. lsm1 = prog ;
  127. repe b1 nb1 ;
  128. i1 = &b1 - 1 ;
  129. u1 = ta1 . deplacements . i1 ;
  130. eps1 = epsi line mo1 u1 ;
  131. sig1 = ta1 . contraintes . i1 ;
  132. lep1 = lep1 et (prog (maxi abs eps1)) ;
  133. lsm1 = lsm1 et (prog (maxi abs sig1)) ;
  134. fin b1 ;
  135. tranum1 = evol vert manu epeq lep1 smeq lsm1 ;
  136. err1 = maxi abs (lsm1 - (ipol trac1 lep1)) ;
  137. err1 = err1 / (maxi abs lsm1) ;
  138.  
  139. tleg1 = tabl ;
  140. tleg1 . 2 = mot 'MARQ S ROND NOLI' ;
  141. tleg1 . titre = tabl ;
  142. tleg1 . titre . 1 = 'Courbe fournie' ;
  143. tleg1 . titre . 2 = 'Courbe calculee' ;
  144. si graph ;
  145. mot1 = chai format '(F5.2)'
  146. 'Resultat en petits deplacements : ecart contrainte =' (100.*err1) ' %' ;
  147. dess (trac1 et tranum1) titr mot1 lege tleg1 ;
  148. fins ;
  149.  
  150. *---------------- GRANDS DEPLACEMENTS, LAGRANGIEN REACTUALISE -----------------*
  151. *
  152. * Modele - Caracteristiques :
  153. sigy2 = sigy1 * (1. + epsy1) ;
  154. epsy2 = sigy2 / ym1 ;
  155. leps2 = (prog 0. epsy2) et (log (1. + leps1p)) ;
  156. lsig2 = lsig1 * (1. + leps1) ;
  157. lepp2 = (leps2 enle 1) - epsy2 ;
  158. lsmp2 = lsig2 enle 1 ;
  159. trac2 = evol oran manu epeq leps2 smeq lsig2 ;
  160. ecro2 = evol roug manu epeq lepp2 smeq lsmp2 ;
  161. *
  162. tleg1 = tabl ;
  163. tleg1 . titre = tabl ;
  164. tleg1 . titre . 1 = 'Courbe de traction' ;
  165. tleg1 . titre . 2 = 'Courbe ecrouissage' ;
  166. si graph ;
  167. dess (trac2 et ecro2) titr 'Courbes rationnelles de traction et d ecrouissage' lege tleg1 ;
  168. fins ;
  169.  
  170. opti epsi quadratique ;
  171. mo2 = mode v1 mecanique elastique plastique ;
  172. ma2 = mate mo2 youn ym1 nu nu1 ecro ecro2 ;
  173.  
  174. * Resolution en grands deplacements :
  175. ltcal2 = prog 0. (epsy2/epsf1) 0.01 pas 0.01 1. ;
  176. ta2 = tabl ;
  177. ta2 . modele = mo2 ;
  178. ta2 . caracteristiques = ma2 ;
  179. ta2 . blocages_mecaniques = cl0 ;
  180. ta2 . chargement = cg1 ;
  181. ta2 . temps_calcules = ltcal2 ;
  182.  
  183. ta2 . grands_deplacements = vrai ;
  184. ta2 . lagrangien = mot reactualise ;
  185.  
  186. pasapas ta2 ;
  187.  
  188. * Comparaison courbes calculee / fournie :
  189. nb2 = dime ta2 . temps_calcules ;
  190. lep2 = prog ;
  191. lsm2 = prog ;
  192. repe b2 nb2 ;
  193. i2 = &b2 - 1 ;
  194. eps2 = ta2 . deformations . i2 ;
  195. sig2 = ta2 . contraintes . i2 ;
  196. lep2 = lep2 et (prog (maxi abs eps2)) ;
  197. lsm2 = lsm2 et (prog (maxi abs sig2)) ;
  198. fin b2 ;
  199. err2 = maxi abs (lsm2 - (ipol trac2 lep2)) ;
  200. err2 = err2 / (maxi abs lsm2) ;
  201. tranum2 = evol oran manu epeq lep2 smeq lsm2 ;
  202.  
  203. tleg2 = tabl ;
  204. tleg2 . 2 = mot 'MARQ S CARR NOLI' ;
  205. tleg2 . titre = tabl ;
  206. tleg2 . titre . 1 = 'Courbe fournie' ;
  207. tleg2 . titre . 2 = 'Courbe calculee' ;
  208. si graph ;
  209. mot2 = chai format '(F5.2)'
  210. 'Resultat en Lagrangien reactualise : ecart contrainte =' (100.*err2) ' %' ;
  211. dess (trac2 et tranum2) titr mot2 lege tleg2 ;
  212. fins ;
  213.  
  214. *------------------- GRANDS DEPLACEMENTS, LAGRANGIEN TOTAL --------------------*
  215. *
  216. *
  217. * On utilise egalement la courbe de traction rationnelle :
  218. ecro3 = ecro2 coul rose ;
  219. trac3 = trac2 coul rose ;
  220. *
  221. opti epsi quadratique ;
  222. mo3 = mode v1 mecanique elastique plastique ;
  223. ma3 = mate mo3 youn ym1 nu nu1 ecro ecro3 ;
  224.  
  225. * Resolution en grands deplacements :
  226. ltcal3 = ltcal2 ;
  227. ta3 = tabl ;
  228. ta3 . modele = mo3 ;
  229. ta3 . caracteristiques = ma3 ;
  230. ta3 . blocages_mecaniques = cl0 ;
  231. ta3 . chargement = cg1 ;
  232. ta3 . temps_calcules = ltcal3 ;
  233.  
  234. ta3 . grands_deplacements = vrai ;
  235. ta2 . lagrangien = mot total ;
  236.  
  237. pasapas ta3 ;
  238.  
  239. * Comparaison courbes calculee / fournie :
  240. nb3 = dime ta3 . temps_calcules ;
  241. lep3 = prog ;
  242. lsm3 = prog ;
  243. repe b3 nb3 ;
  244. i3 = &b3 - 1 ;
  245. eps3 = ta3 . deformations . i3 ;
  246. sig3 = ta3 . contraintes . i3 ;
  247. lep3 = lep3 et (prog (maxi abs eps3)) ;
  248. lsm3 = lsm3 et (prog (maxi abs sig3)) ;
  249. fin b3 ;
  250. err3 = maxi abs (lsm3 - (ipol trac3 lep3)) ;
  251. err3 = err3 / (maxi abs lsm3) ;
  252. tranum3 = evol rose manu epeq lep3 smeq lsm3 ;
  253.  
  254. tleg3 = tabl ;
  255. tleg3 . 2 = mot 'MARQ S TRIA NOLI' ;
  256. tleg3 . titre = tabl ;
  257. tleg3 . titre . 1 = 'Courbe fournie' ;
  258. tleg3 . titre . 2 = 'Courbe calculee' ;
  259. si graph ;
  260. mot3 = chai format '(F5.2)'
  261. 'Resultat en Lagrangien total : ecart contrainte =' (100.*err3) ' %' ;
  262. dess (trac3 et tranum3) titr mot3 lege tleg3 ;
  263. fins ;
  264.  
  265. *----------------------------------- BILAN ------------------------------------*
  266. *
  267. * Visualisation des differentes courbes :
  268. tleg4 = tabl ;
  269. tleg4 . 4 = mot 'MARQ S ROND NOLI' ;
  270. tleg4 . 5 = mot 'MARQ S CARR NOLI' ;
  271. tleg4 . 6 = mot 'MARQ S TRIA NOLI' ;
  272. tleg4 . titre = tabl ;
  273. tleg4 . titre . 1 = 'Petits deplacements' ;
  274. tleg4 . titre . 2 = 'G. depl. lag. reactualise' ;
  275. tleg4 . titre . 3 = 'G. depl. lag. total' ;
  276. tleg4 . titre . 4 = 'Courbe Calculee' ;
  277. tleg4 . titre . 5 = 'Courbe Calculee' ;
  278. tleg4 . titre . 6 = 'Courbe Calculee' ;
  279. mot4 = 'Courbes de traction calculees suivant differentes hypotheses' ;
  280. si graph ;
  281. dess (trac1 et trac2 et trac3 et tranum1 et tranum2 et tranum3) titr mot4 lege tleg4 ;
  282. fins ;
  283. *
  284. * Test de validation :
  285. err0 = maxi (prog err1 err2 err3) ;
  286.  
  287. si (err0 > 1.e-2) ;
  288. erre 5 ;
  289. fins ;
  290.  
  291. fin ;
  292.  
  293.  
  294.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales