Télécharger thpl3.dgibi

Retour à la liste

Numérotation des lignes :

  1. * fichier : thpl3.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4. * CAS TEST DU 92/03/20 PROVENANCE : TC1
  5. * CAS TEST DU 92/03/19 PROVENANCE : PHIL
  6. opti echo 0;
  7. MESS ' ***************************************************************';
  8. MESS ' * COMMISSION V.P.C.S. : THERMO-PLASTICITE *';
  9. MESS ' * *';
  10. MESS ' * CYLINDRE SOUMIS A UNE REPARTITION LOGARITHMIQUE DE *';
  11. MESS ' * TEMPERATURE, CALCUL EN AXISYMETRIE. *';
  12. MESS ' * *';
  13. MESS ' * FONCTIONS TESTEES : ELASTO-PLASTICITE PARFAITE SOUS *';
  14. MESS ' * CHARGEMENT THERMIQUE. *';
  15. MESS ' * *';
  16. MESS ' ***************************************************************';
  17. MESS ' LES RESULTATS DE REFERENCE SONT LA MOYENNE DES CALCULS';
  18. MESS ' EFFECTUES PAR FRAMASOFT ET LE CETIM';
  19.  
  20. OPTION TRACE BENS;
  21. OPTION DIME 2 ;
  22. OPTION MODE AXIS;
  23. OPTION ELEM QUA8;
  24.  
  25. GRAPH='N';
  26. *
  27. *++++++++++++++++++++++++++++++++*
  28. * GEOMETRIE DU CYLINDRE *
  29. *++++++++++++++++++++++++++++++++*
  30. *
  31. DENS 1. ; RA = 1. ; ZA = 0. ; PA = RA ZA;
  32. DENS 1.2; RB = 2. ; ZB = 0. ; PB = RB ZB;
  33. dens 1.1; pm = 1.497 0;
  34.  
  35.  
  36. DENS 1. ; RC = 1. ; ZC = 0.1 ; PC = RC ZC;
  37. DENS 1.2; RD = 2. ; ZD = 0.1 ; PD = RD ZD;
  38. DENS 1.1; pz = 1.497 0.1;
  39. *
  40. DAm = PA DROIT -7 pm;
  41. DmB = pm droit -3 PB;
  42. DAB = DAm et DmB;
  43.  
  44. DBD = PB DROIT -1 PD;
  45. DDz = PD DROIT -3 Pz;
  46. DCA = PC DROIT -1 PA;
  47. DzC = Pz DROIT -7 PC;
  48. DDC = DDz et DzC;
  49.  
  50. *
  51. SUR1 = DALL DAB DBD DDC DCA PLAN ;
  52.  
  53.  
  54. ELIM SUR1 0.0001;
  55. *
  56. NOSUR1 = NBNO SUR1;
  57. ELSUR1 = NBEL SUR1;
  58. *
  59. SI (NEG GRAPH 'N');
  60. TITR ' SSNA04 : MAILLAGE PAR QUA8 (NOEUDS)';
  61. TRACE NOEUD SUR1;
  62. TITR ' SSNA04 : MAILLAGE PAR QUA8 (ELEMENTS)';
  63. TRACE ELEM SUR1;
  64. FINSI;
  65.  
  66. *+++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++*
  67. * CONDITIONS AUX LIMITES *
  68. *+++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++*
  69. *
  70. CL1 = BLOQUE DAB UZ ;
  71. CL2 = BLOQUE DDC UZ ;
  72. CL = CL1 ET CL2 ;
  73. *
  74. *+++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++*
  75. * MODELES - MATERIAUX - CARACTERISTIQUES
  76. *+++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++*
  77. *
  78. MO = MODE SUR1 'MECANIQUE' 'ELASTIQUE' 'PLASTIQUE' 'PARFAIT' QUA8;
  79.  
  80. MAT = MATE MO YOUN 200000 NU 0.3 ALPHA 12E-6 SIGY 300 'TALP' 0. 'TREF' 0.;
  81. *
  82. *++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++*
  83. * CHAMPS RELATIFS A LA PROCEDURE PASAPAS *
  84. *++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++*
  85. *
  86. *==============================================================*
  87. * CHAMPS DE TEMPERATURE REPARTIE SUR SUR1 *
  88. *==============================================================*
  89. *
  90. * 10 PAS DE CHARGEMENT ENTRE 0C ET 200C
  91. *
  92. T0 = 0.; T1 = 1. ; T2 = 2.; T3 = 3. ;
  93. T4 = 4.; T5 = 5. ; T6 = 6.; T7 = 7. ;
  94. T8 = 8.; T9 = 9. ; T10 = 10.;
  95. *
  96. * CREATION DU CHPOINT DE TEMPERATURE POUR TE = 1C (TEMP. EXTE.)
  97. *
  98. CHPSUR = COOR 1 SUR1;
  99. *
  100. CONST1 = 1. / (LOG 2.);
  101. CHP2 = (LOG CHPSUR) * CONST1;
  102.  
  103. * TRANSFORMATION DU SOUS-TYPE "SCAL" EN SOUS-TYPE "T" POUR CHP2
  104. * UTILISATION DE L'OPERATEUR VARI
  105. *
  106. LIS10 = PROG 0. 200.;
  107. LIS20 = PROG 0. 200.;
  108. EVOL2 = EVOL MANU SCAL LIS10 T LIS20;
  109. *
  110. CHP1 = VARI CHP2 EVOL2 T;
  111.  
  112. *
  113. TEMP = TABLE;TEMPER = TABLE;
  114. TEMP . 0 = T0;TEMP . 1 = T1;
  115. TEMP . 2 = T2;TEMP . 3 = T3;
  116. TEMP . 4 = T4;TEMP . 5 = T5;
  117. TEMP . 6 = T6;TEMP . 7 = T8;
  118. TEMP . 8 = T8;TEMP . 9 = T9;
  119. TEMP . 10 = T10;
  120.  
  121. TEMPER . 0 = MANU CHPO SUR1 1 T 0.;
  122. TEMPER . 1 = (CHP1 * 20.);
  123. TEMPER . 2 = (CHP1 * 40.);
  124. TEMPER . 3 = (CHP1 * 60.);
  125. TEMPER . 4 = (CHP1 * 80.);
  126. TEMPER . 5 = (CHP1 * 100.);
  127. TEMPER . 6 = (CHP1 * 120.);
  128. TEMPER . 7 = (CHP1 * 140.);
  129. TEMPER . 8 = (CHP1 * 160.);
  130. TEMPER . 9 = (CHP1 * 180.);
  131. TEMPER . 10 = (CHP1 * 200.);
  132.  
  133. CHA2 = CHAR 'T' TEMP TEMPER;
  134.  
  135. *
  136. *================================================================
  137. * LISTE DE VALEURS DE TEMPS OU L'ON VEUT DES RESULTATS : LIS1
  138. *================================================================
  139. *
  140. LIS1 = PROG T0 T1 T2 T3 T4 T5 T6 T7 T8 T9 T10;
  141. *
  142. *================================================================
  143. * CREATION D'UN CHAMPS DE FORCE NUL : THERMO-ELASTICITE *
  144. *================================================================
  145. *
  146. LIS2 = PROG T0 T10;
  147. LFORCE = PROG 0. 0. ;
  148. FOR1 = FORCE FZ 1. PA;
  149. CHPO1 = RESU FOR1;
  150. EVOL1 = EVOL MANU TEMPS LIS2 FORCE LFORCE;
  151. CHA1 = CHAR 'MECA' CHPO1 EVOL1;
  152.  
  153. *================================================================
  154. * REMPLISSAGE DE LA TABLE POUR PASAPAS *
  155. *================================================================
  156. *
  157. TAB1 = TABLE;
  158. TAB1.'MODELE' = MO ;
  159. TAB1.'CARACTERISTIQUES' = MAT;
  160. TAB1.'CHARGEMENT' = (CHA1 ET CHA2);
  161. TAB1.'TEMPS_CALCULES' = LIS1;
  162. TAB1.'TEMPS_SAUVES' = LIS1;
  163. TAB1.'BLOCAGES_MECANIQUES' = CL;
  164.  
  165. *
  166. *++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++*
  167. * PROCEDURE PASAPAS *
  168. *++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++*
  169. *
  170. PASAPAS TAB1;
  171. *
  172. *++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++*
  173. * EXTRACTION DES RESULTATS *
  174. *++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++*
  175.  
  176. NN = 10;
  177. CHEL1 = TAB1.CONTRAINTES.NN;
  178.  
  179.  
  180.  
  181. CHPO1 = CHAN CHPO MO CHEL1;
  182.  
  183. CHEL2 = VMIS MO CHEL1;
  184. *
  185. SI (NEG GRAPH 'N');
  186. TITR ' TRACE DES CONTRAINTES DE VON-MISES';
  187. TRAC CHEL2 MO SUR1;
  188. LLIS2 = PROG 0. 290. 295. 300. 305. 310. 600.;
  189. TITR 'LIEU OU IL Y A PLASTIFICATION';
  190. TRAC LLIS2 CHEL2 MO SUR1;
  191. FINSI;
  192. *
  193. SMRRA = EXTR CHPO1 SMRR PA; SMRRA1 = 0.1894;
  194. ERGRRA = ABS (100 * (SMRRA - SMRRA1) / SMRRA1) ;
  195. SMRRB = EXTR CHPO1 SMRR PB; SMRRB1 = 0.152 ;
  196. ERGRRB = ABS (100 * (SMRRB - SMRRB1) / SMRRB1) ;
  197. SMRRM = extr CHPO1 SMRR Pm; SMRRM1 = 47.09;
  198. ERGRRM = ABS (100 * (SMRRM - SMRRM1) / SMRRM1) ;
  199.  
  200.  
  201. SMZZA = EXTR CHPO1 SMZZ PA; SMZZA1 = 114.2 ;
  202. ERGZZA = ABS (100 * (SMZZA - SMZZA1) / SMZZA1) ;
  203. SMZZB = EXTR CHPO1 SMZZ PB; SMZZB1 = -345.9;
  204. ERGZZB = ABS (100 * (SMZZB - SMZZB1) / SMZZB1) ;
  205. SMZZm = EXTR CHPO1 SMZZ Pm; SMZZm1 = -285.1 ;
  206. ERGZZm = ABS (100 * (SMZZm - SMZZm1) / SMZZm1);
  207.  
  208. SMTTA = EXTR CHPO1 SMTT PA; SMTTA1 = 340.8 ;
  209. ERGTTA = ABS (100 * (SMTTA - SMTTA1) / SMTTA1) ;
  210. SMTTB = EXTR CHPO1 SMTT PB; SMTTB1 = -191. ;
  211. ERGTTB = ABS (100 * (SMTTB - SMTTB1) / SMTTB1) ;
  212. SMTTm = EXTR CHPO1 SMTT Pm; SMTTm1 = -51.52;
  213. ERGTTm = ABS (100 * (SMTTm - SMTTm1) / SMTTm1) ;
  214. opti echo 0;
  215.  
  216. MESS ' RESULTATS : TEST SSNA04/90 ';
  217. MESS ' -------------------------- ';
  218. MESS ' rA = 1; rM = 1.497; rB =2;';
  219.  
  220. MESS ' Resultats sur les contraintes interpolees (MPa)';
  221. MESS ' -----------------------------------------------';
  222. *
  223. MESS ' CONT. POINT REFERENCE CALCULEE ECART%';
  224. MESS ' SMRR A ' SMRRA1 SMRRA 'NON SIGNIFICATIF';
  225. MESS ' SMRR B ' SMRRB1 SMRRB 'NON SIGNIFICATIF';
  226. MESS ' SMRR M ' SMRRM1 SMRRM ERGRRM ;
  227.  
  228. MESS ' SMTT A ' SMTTA1 SMTTA ERGTTA ;
  229. MESS ' SMTT B ' SMTTB1 SMTTB ERGTTB ;
  230. MESS ' SMTT M ' SMTTm1 SMTTm ERGTTm ;
  231. *
  232. MESS ' SMZZ A ' SMZZA1 SMZZA ERGZZA ;
  233. MESS ' SMZZ B ' SMZZB1 SMZZB ERGZZB ;
  234. MESS ' SMZZ M ' SMZZm1 SMZZm ERGZZm ;
  235. SAUT 1 LIGN;
  236.  
  237. *
  238. DEP1 = TAB1.DEPLACEMENTS.NN;
  239. *
  240. SI (NEG GRAPH 'N');
  241. TITR ' DEFORMEE : CALCUL AXISYMETRIQUE (SSNA04)';
  242. DEF0 = DEFO SUR1 DEP1 0. ;
  243. DEF1 = DEFO SUR1 DEP1 20. ROUGE ;
  244. TRAC (DEF0 ET DEF1) ;
  245. FINSI;
  246. *
  247. URA = EXTR DEP1 UR PA;
  248. URB = EXTR DEP1 UR PB;
  249. URM = EXTR DEP1 UR Pm;
  250. *
  251. URA1 = 1.808E-03;
  252. URB1 = 3.859E-03;
  253. *
  254. ERGURA = ABS (100 * (URA - URA1) / URA1) ;
  255. ERGURB = ABS (100 * (URB - URB1) / URB1) ;
  256. *
  257. MESS ' Resultats sur les deplacements radiaux ';
  258. MESS ' -------------------------------------- ';
  259. *
  260. MESS ' Deplacement radial theorique pour r = 1 mm :' URA1 'mm';
  261. MESS ' Deplacement radial calcul pour r = 1 mm :' URA 'mm';
  262. MESS ' Soit une erreur relative de :' ERGURA '%';
  263.  
  264. MESS ' Deplacement radial calcul pour r = 1.497 mm : ' URM 'mm';
  265. *
  266. MESS ' Deplacement radial thorique pour r = 2 mm :' URB1 'mm';
  267. MESS ' Deplacement radial calcul pour r = 2 mm :' URB 'mm';
  268. MESS ' Soit une erreur relative de :' ERGURB '%';
  269. *
  270. *
  271. MESS ' Nombre de noeuds : ' NOSUR1;
  272. MESS ' Nombre d elements : ' ELSUR1;
  273. SAUT 1 LIGN ;
  274. *
  275. TEMPS;
  276. *
  277. SAUT 1 LIGN ;
  278. *
  279. *++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++*
  280. * CODE FONCTIONNEMENT *
  281. *++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++*
  282. *
  283. * Maximum des erreurs relatives
  284. *
  285. ERGMAX = MAXI (PROG ERGURA ERGURB ERGTTA ERGTTB ERGZZA ERGZZB
  286. ERGRRM ERGZZM ERGTTM);
  287. * Il y a erreur si un des pourcentage erg*** est superieur a 5%
  288. *
  289. SI (ERGMAX <EG 5.);
  290. ERRE 0 ;
  291. SINON;
  292. ERRE 5 ;
  293. FINSI;
  294. *
  295. FIN;
  296. *
  297.  
  298.  
  299.  
  300.  
  301.  
  302.  
  303.  
  304.  
  305.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales