Télécharger thpl2.dgibi

Retour à la liste

Numérotation des lignes :

  1. * fichier : thpl2.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4. * CAS TEST DU 91/06/13 PROVENANCE : TEST
  5.  
  6.  
  7. *******************************************
  8. * Test thpl2.dgibi: jeux de données *
  9. * --------------------------------- *
  10. *******************************************
  11.  
  12. * SI GRAPH = N PAS DE GRAPHIQUE AFFICHE
  13. * SINON SI GRAPH DIFFERENT DE N TOUS
  14. * LES GRAPHIQUES SONT AFFICHES
  15.  
  16. GRAPH = 'N' ;
  17.  
  18. SAUT PAGE;
  19. SI (NEG GRAPH 'N') ;
  20. OPTI ECHO 1 ;
  21. OPTI TRAC PSC ;
  22. SINO ;
  23. OPTI ECHO 0 ;
  24. FINSI ;
  25.  
  26. SAUT PAGE;
  27.  
  28. *******************************************
  29. * THPL2 *
  30. * *
  31. * PLAQUE CARREE ENCASTREE SOUMIS A UN *
  32. * CHAMPS DE TEMPERTURE *
  33. * *
  34. * Test de la commission V.P.C.S. *
  35. * Groupe Thermo-plasticite *
  36. * Statique non lineaire *
  37. * *
  38. * Une plaque carree de 10 cm de cote est*
  39. * encastree et soumise a un champs *
  40. * constant de temperature de 500 degres *
  41. * celsius. *
  42. * *
  43. * On se propose de calculer *
  44. * - contraintes smxx et smyy, *
  45. * - deformations plastiques epxx et epyy*
  46. * *
  47. * Les valeurs trouvees sont ensuites *
  48. * comparees aux valeurs de reference *
  49. * obtenues analytiquement *
  50. *******************************************
  51. OPTION ELEM QUA4;
  52.  
  53. *=========================================*
  54. * geometrie : maillage *
  55. *=========================================*
  56.  
  57. * Dimensions en metres
  58. CO = 0.01;
  59.  
  60. PA = 0. 0.;
  61. PB = CO 0.;
  62. PC = CO CO;
  63. PD = 0. CO;
  64.  
  65. LAB = PA DROIT 8 PB;
  66. LBC = PB DROIT 8 PC;
  67. LCD = PC DROIT 8 PD;
  68. LDA = PD DROIT 8 PA;
  69.  
  70. LIG = LAB ET LBC ET LCD ET LDA;
  71.  
  72. SUR1 = DALL LAB LBC LCD LDA PLAN;
  73.  
  74. SI(NEG GRAPH 'N');
  75. TITR 'THPL2 : MAILLAGE';
  76. TRACE 'QUAL' SUR1;
  77. FINSI;
  78.  
  79. *=========================================*
  80. * conditions aux limites *
  81. *=========================================*
  82. CL = BLOQUE LIG DEPL ROTA;
  83.  
  84. *=========================================*
  85. * MODE - materiau
  86. *=========================================*
  87. MO = MODE SUR1 MECANIQUE ELASTIQUE
  88. PLASTIQUE CINEMATIQUE QUA4;
  89. MAT = MATE MO YOUN 163750.0E6 NU 0.3
  90. ALPHA 13.875E-6 SIGY 100E6
  91. H 2000E6;
  92.  
  93. *=========================================*
  94. * champs relatifs a la procedure PASAPAS *
  95. *=========================================*
  96. * Liste des pseudo-temps ou l'on desire des
  97. * resultats.
  98. T0 = 0. ;
  99. T1 = 1.;
  100. LIS1 = PROG T0 T1;
  101.  
  102. * Champs points de temperature.
  103. TEMP . 0 = T0;
  104. TEMP . 1 = T1;
  105.  
  106. TEMPER = TABL;
  107. TEMPER . 0 = MANU CHPO SUR1 1 T 0. ;
  108. TEMPER . 1 = MANU CHPO SUR1 1 T 500.;
  109. CHA2 = CHAR 'T' TEMP TEMPER;
  110.  
  111. * Chargement mecanique : chargement nul.
  112. LFORCE = PROG 0. 0.;
  113. FOR1 = FORCE FY 1. PA;
  114. CHPO1 = RESU FOR1;
  115. EVOL1 = EVOL MANU TEMPS LIS1 FORCE LFORCE;
  116. CHA1 = CHAR 'MECA' CHPO1 EVOL1;
  117.  
  118. * Parametres pour la procedure PASAPAS
  119. TABDEF = TABL ;
  120. TABDEF .'DEFTO' = VRAI;
  121. TABDEF .'DEFIN' = VRAI;
  122.  
  123. TAB1 = TABL ;
  124. TAB1.'CHARGEMENT' =(CHA1 ET CHA2);
  125. TAB1.'MODELE' = MO ;
  126. TAB1.'CARACTERISTIQUES' = MAT ;
  127. TAB1.'BLOCAGES_MECANIQUES' = CL ;
  128. TAB1.'TEMPS_CALCULES' = LIS1 ;
  129. TAB1.'TEMPS_SAUVES' = LIS1 ;
  130. tab1.'MES_SAUVEGARDES' = TABDEF;
  131.  
  132. * procedure PASAPAS
  133. PASAPAS TAB1;
  134.  
  135. *=========================================*
  136. * Extraction des resultats *
  137. *=========================================*
  138.  
  139. * Contraintes
  140. NN = 1;
  141. CHEL1 = TAB1.CONTRAINTES.NN;
  142.  
  143. * Interpolations aux noeuds :
  144. CHAM2 = CHAN NOEUD MO CHEL1;
  145. CHPO1 = CHAN CHPO MO CHAM2;
  146.  
  147. * Extractionsn des contraintes smxx et smyy
  148. SMXX1 = EXTR CHPO1 SMXX1 PA;
  149. SMYY1 = EXTR CHPO1 SMYY1 PA;
  150. SMXX1 = SMXX1 / 1.E6;
  151. SMYY1 = SMYY1 / 1.E6;
  152.  
  153. SMXX2 = -125.9;
  154. SMYY2 = -125.9;
  155.  
  156. * Calcul de l'erreur commise
  157. ERGSXX = 100.*(ABS((SMXX1-SMXX2)/ SMXX2 ));
  158. ERGSYY = 100.*(ABS((SMYY1-SMYY2)/ SMYY2 ));
  159.  
  160. * Deformations plastiques.
  161. CHEL10 = TAB1.DEFORMATIONS_INELASTIQUES.NN;
  162.  
  163. * Interpolations aux noeuds du maillage
  164. CHAM20 = CHAN NOEUD MO CHEL10;
  165. CHPO10 = CHAN CHPO MO CHAM20;
  166.  
  167. * Extractions des deformations plastiques
  168. EPXX1 = EXTR CHPO10 EIXX PA;
  169. EPYY1 = EXTR CHPO10 EIYY PA;
  170.  
  171. EPXX2 = -0.6399E-2;
  172. EPYY2 = -0.6399E-2;
  173.  
  174. * Calcul de l'erreur commise
  175. ERGEXX = 100.*(ABS((EPXX1-EPXX2)/ EPXX2 ));
  176. ERGEYY = 100.*(ABS((EPYY1-EPYY2)/ EPYY2 ));
  177.  
  178. * Nombre d'elements et noeuds du maillage
  179. NOSUR1 = NBNO SUR1 ;
  180. ELSUR1 = NBEL SUR1 ;
  181.  
  182. *=========================================*
  183. * Affichage des resultats *
  184. *=========================================*
  185. MESS ' RESULTATS ';
  186. MESS ' --------- ';
  187.  
  188. MESS ' Contraintes interpolees (MPa)';
  189. MESS ' -----------------------------';
  190. ' Contrainte theorique smxx :' SMXX2 'MPa';
  191. ' Contrainte calculee smxx :' SMXX1 'MPa';
  192. MESS ' Soit un ecart de :' ERGSXX '%';
  193.  
  194. ' Contrainte theorique smyy :' SMYY2 'MPa';
  195. ' Contrainte calculee smyy :' SMYY1 'MPa';
  196. MESS ' Soit un ecart de :' ERGSYY '%';
  197.  
  198. MESS 'Deformations plastiques interpolees';
  199. MESS '-----------------------------------';
  200.  
  201. ' Deformation plastique theorique epxx :'
  202. EPXX2;
  203. ' Deformation plastique calculee epxx :'
  204. EPXX1;
  205. MESS ' Soit un ecart de :' ERGEXX '%';
  206.  
  207. ' Deformation plastique theorique epyy :'
  208. EPYY2;
  209. ' Deformation plastique calculee epyy :'
  210. EPYY1;
  211. MESS ' Soit un ecart de :' ERGEYY '%';
  212.  
  213. MESS ' Maillage ';
  214. MESS ' -------- ';
  215. MESS ' Nombre de noeuds : ' NOSUR1 ;
  216. MESS ' Nombre d elements : ' ELSUR1 ;
  217.  
  218. SI (NEG GRAPH 'N');
  219. DEP1 = TAB1. 'DEPLACEMENTS' . NN;
  220. DEF0 = DEFO SUR1 DEP1 0.;
  221. DEF1 = DEFO SUR1 DEP1 10. BLEU;
  222. TITR 'THPL2 : DEFORMEE';
  223. TRAC (DEF0 ET DEF1);
  224.  
  225. TITR 'THPL2 : Deformation Plastique';
  226. TRAC CHEL10 MO;
  227. FINSI;
  228.  
  229. *=========================================*
  230. * Code fonctionnement et fin *
  231. *=========================================*
  232. * Maximum des erreurs relatives
  233. ERGMAX = MAXI
  234. (PROG ERGSXX ERGSYY ERGEXX ERGEYY);
  235.  
  236. SI (ERGMAX <EG 5.);
  237. ERRE 0 ;
  238. SINON;
  239. ERRE 5 ;
  240. FINSI;
  241. TEMPS ;
  242.  
  243. FIN;
  244.  
  245.  
  246.  
  247.  
  248.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales