Télécharger thpl1.dgibi

Retour à la liste

Numérotation des lignes :

  1. * fichier : thpl1.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4. * Test Thpl1.dgibi: Jeux de données *
  5. * --------------------------------- *
  6. * *
  7. * CAS TEST DU 92/03/20 PROVENANCE : TC1
  8.  
  9.  
  10. *******************************************
  11. * Test thpl1.dgibi: jeux de données *
  12. * --------------------------------- *
  13. *******************************************
  14.  
  15. * SI GRAPH = N PAS DE GRAPHIQUE AFFICHE
  16. * SINON SI GRAPH DIFFERENT DE N TOUS
  17. * LES GRAPHIQUES SONT AFFICHES
  18.  
  19. GRAPH = 'N' ;
  20.  
  21. SAUT PAGE;
  22. SI (NEG GRAPH 'N') ;
  23. OPTI ECHO 1 ;
  24. OPTI TRAC PSC ;
  25. SINO ;
  26. OPTI ECHO 0 ;
  27. FINSI ;
  28.  
  29. SAUT PAGE;
  30.  
  31. *******************************************
  32. * THPL1 *
  33. * *
  34. * BARREAU CYLINDRIQUE SOUMIS A UN CHAMPS *
  35. * DE TEMPERATURE *
  36. * *
  37. * Test de la Commission V.P.C.S. *
  38. * Groupe Thermo-plasticite Statique *
  39. * non-lineaire *
  40. * Test numero SSNA01/90 *
  41. * *
  42. * Un barreau cylindrique de 100 mm *
  43. * de hauteur et de 20 mm de diametre *
  44. * est bloque axialement a ces deux *
  45. * extremites. Il est soumis a un champ *
  46. * constant de temperature, de 500°C. *
  47. * *
  48. * On traite le probleme en mode *
  49. * axisymetrique avec la procedure *
  50. * PASAPAS car le materiau est plastique*
  51. * *
  52. * On se propose de calculer *
  53. * - la contrainte axiale *
  54. * - la deformation plastique axiale *
  55. *******************************************
  56. OPTION MODE AXIS ELEM QUA4;
  57.  
  58. *=========================================*
  59. * geometrie : maillage *
  60. *=========================================*
  61. * Dimensions en millimetres.
  62. RA = 0.0 ; ZA = 0. ; PA = RA ZA ;
  63. RB = 10. ; ZB = 0. ; PB = RB ZB ;
  64. RC = 10. ; ZC = 100.0 ; PC = RC ZC ;
  65. RD = 0.0 ; ZD = 100.0 ; PD = RD ZD ;
  66.  
  67. DAB = DROI 1 PA PB;
  68. DBC = DROI 10 PB PC;
  69. DCD = DROI 1 PC PD;
  70. DDA = DROI 10 PD PA;
  71.  
  72. SUR = DALL DAB DBC DCD DDA PLAN;
  73.  
  74. ELIM SUR 0.001;
  75.  
  76. SI (NEG GRAPH 'N');
  77. TITR 'THPL1 : MAILLAGE';
  78. TRAC QUAL SUR;
  79. FINSI;
  80.  
  81. ELSUR = NBEL SUR;
  82. NOSUR = NBNO SUR;
  83.  
  84. *=========================================*
  85. * conditions aux limites *
  86. *=========================================*
  87. CL1 = BLOQ UZ DAB ;
  88. CL2 = BLOQ UZ DCD ;
  89. CL = CL1 ET CL2 ;
  90.  
  91. *=========================================*
  92. * MODE - materiau *
  93. *=========================================*
  94. MOD = MODE SUR MECANIQUE ELASTIQUE
  95. PLASTIQUE CINEMATIQUE QUA4;
  96.  
  97. MAT = MATE MOD YOUN 200E3 NU 0.3 SIGY 300
  98. H 2000 ALPH 1.2E-5;
  99.  
  100. *=========================================*
  101. * champs relatifs a la procedure PASAPAS *
  102. *=========================================*
  103. * Liste des pseudo-temps ou l'on desire des
  104. * resultats
  105.  
  106. t0 = 0. ;
  107. t1 = 1. ;
  108. LISTE = PROG T0 T1 ;
  109.  
  110. * Champs-point de temperature aux instants
  111. * t0 et t1.
  112. TEMP . 0 = t0;
  113. TEMP . 1 = t1;
  114.  
  115. TEMPER = TABL;
  116. TEMPER . 0 = MANU CHPO SUR 1 T 0. ;
  117. TEMPER . 1 = MANU CHPO SUR 1 T 500.;
  118. CHA2 = CHAR 'T' TEMP TEMPER;
  119.  
  120. * Chargement mecanique de la structure:
  121. * chargement nul.
  122. LFORCE= PROG 0. 0.;
  123. FOR = FORCE FR 1000. PC;
  124. EVOL1 = EVOL MANU TEMPS LISTE FORCE LFORCE;
  125. CHA1 = CHAR 'MECA' FOR EVOL1;
  126.  
  127. * parametres pour la procedure PASAPAS
  128. TABDEF = TABL ;
  129. TABDEF .'DEFTO' = VRAI;
  130. TABDEF .'DEFIN' = VRAI;
  131.  
  132. TAB1 = TABL ;
  133. TAB1.'CHARGEMENT' =(CHA1 ET CHA2);
  134. TAB1.'MODELE' = MOD ;
  135. TAB1.'CARACTERISTIQUES' = MAT ;
  136. TAB1.'BLOCAGES_MECANIQUES' = CL ;
  137. TAB1.'TEMPS_CALCULES' = LISTE ;
  138. TAB1.'TEMPS_SAUVES' = LISTE ;
  139. tab1.'MES_SAUVEGARDES' = TABDEF;
  140.  
  141. * procedure PASAPAS
  142. PASAPAS TAB1;
  143.  
  144. *=========================================*
  145. * extractions des resultats *
  146. *=========================================*
  147.  
  148. * Contraintes
  149. nn = 1;
  150. CHEL1 = TAB1. 'CONTRAINTES'.nn;
  151.  
  152. CHAM2 = CHAN NOEUD MOD CHEL1;
  153. CHPO1 = CHAN CHPO MOD CHAM2;
  154.  
  155. * Extraction du la contrainte SMZZ
  156. SMZZ1 = EXTR CHPO1 SMZZ PA;
  157. SMZZ2 = -309.0 ;
  158.  
  159. * Deformations plastiques
  160. CHEL10 = TAB1.
  161. 'DEFORMATIONS_INELASTIQUES' .nn;
  162.  
  163. * Interpolations aux noeuds du maillage
  164. * Utilisation des nouveaux chamelems.
  165. CHAM20 = CHAN NOEUD MOD CHEL10;
  166. CHPO10 = CHAN CHPO MOD CHAM20;
  167.  
  168. * Extraction de la deformation plastique
  169. * EPZZ
  170. EPZZ1 = EXTR CHPO10 EIZZ PA;
  171. EPZZ2 = -.4455E-2 ;
  172.  
  173. *=========================================*
  174. * affichage des resultats *
  175. *=========================================*
  176. MESS ' RESULTATS ';
  177. MESS ' --------- ';
  178.  
  179. MESS ' 1) Contraintes ' ;
  180. MESS ' ----------- ' ;
  181.  
  182. MESS ' Contrainte theorique smzz:'
  183. SMZZ2 'Mpa' ;
  184. MESS ' Contrainte calculee smzz :'
  185. SMZZ1 'Mpa' ;
  186. ERG1 = (ABS((SMZZ2-SMZZ1)/SMZZ2)) * 100. ;
  187. MESS ' Soit un ecart de :' ERG1 '%';
  188. MESS ' 2) Deformations plastiques ';
  189. MESS ' ----------------------- ' ;
  190.  
  191. MESS ' Deformation plastique theorique:'
  192. EPZZ2;
  193. MESS ' Deformation plastique calculee :'
  194. EPZZ1;
  195. ERG2 = (ABS((EPZZ2-EPZZ1)/EPZZ2)) * 100. ;
  196. ' Soit un ecart de :' ERG2 '%';
  197.  
  198. MESS ' Maillage ';
  199. MESS ' -------- ';
  200. MESS ' Nombre de noeuds : ' NOSUR;
  201. MESS ' Nombre d elements (qua4): ' ELSUR;
  202.  
  203. SI (NEG GRAPH 'N');
  204. DEP1 = TAB1. 'DEPLACEMENTS' . nn;
  205. DEF0 = DEFO SUR DEP1 0.;
  206. DEF1 = DEFO SUR DEP1 10. BLEU;
  207. TITR 'THPL1 : DEFORMEE';
  208. TRAC (DEF0 ET DEF1);
  209. FINSI;
  210.  
  211. *=========================================*
  212. * code fonctionnement et fin *
  213. *=========================================*
  214.  
  215. * Maximum des erreurs relatives
  216. ERGMAX = MAXI (PROG ERG1 ERG2);
  217.  
  218. * Il y a erreur si un des pourcentage erg*
  219. * est superieur à 5%.
  220.  
  221. SI (ERGMAX <EG 0.03);
  222. ERRE 0 ;
  223. SINON;
  224. ERRE 5 ;
  225. FINSI;
  226.  
  227. TEMPS ;
  228.  
  229. FIN;
  230.  
  231.  
  232.  
  233.  
  234.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales