Télécharger thme3.dgibi

Retour à la liste

Numérotation des lignes :

  1. * fichier : thme3.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4. *----------------------------------------------------------------
  5. *
  6. * Copie du cas-test thme2.dgibi mais appel à la procedure
  7. * NONLINEAIRE au lieu de DUPONT.
  8. *
  9. * Réduction d'un jeu sous l'action d'une sollicitation
  10. * thermique en régime transitoire
  11. *
  12. *----------------------------------------------------------------
  13. *
  14. * Calcul thermo-mécanique ( mécanique et thermique linéaire )
  15. * Utilisation de la procédure PASAPAS
  16. * Utilisation de la procédure utilisateur perso1.
  17. *
  18. *
  19. * | x1 = 0.1 m x2 = 0.1002 m |
  20. * | T1 = 500°C T2 = ? |
  21. * |_______________________________ ____________________________|
  22. * | | | |
  23. * | T_initial = 20°C | | T_initial = 20°C |
  24. * |_______________________________| |____________________________|
  25. * | x0 = 0 m jeu x3 = 0.2002 m |
  26. * | T0 = 20°C T3 = 20°C |
  27. * | Encastrement Encastrement |
  28. *
  29. *
  30. * Le jeu sera considéré comblé quand la distance entre les
  31. * barreaux est inférieure à 0.1mm
  32. *
  33. * on étudie la diffusion thermique dans les barreaux et leurs
  34. * dilatations.
  35. *
  36. * caracteristiques des barreaux :
  37. *
  38. * l = 0.1m
  39. * K = 14.6
  40. * C = 460
  41. * RHO = 7800
  42. * ALPHA = 1E-5
  43. * YOUNG = 2.E11
  44. * NU = 0.00001
  45. *
  46. * Mailles de 0.01 m de cote
  47. *
  48. *----------------------------------------------------------------
  49. *
  50. OPTION ECHO 0;
  51. OPTION DIME 2 ELEM QUA8 MODE PLAN DEFO;
  52. *
  53. *-------------------- Creation du maillage ----------------------
  54. *
  55. DENS 1;
  56. P1 = 0. 0. ;
  57. P2 = 0.1 0. ;
  58. P3 = 0.1 0.01 ;
  59. P4 = 0. 0.01 ;
  60. P5 = 0.1002 0.;
  61. P6 = 0.2002 0.;
  62. P7 = 0.2002 0.01;
  63. P8 = 0.1002 0.01;
  64. P9 = 0.12 0.;
  65. D1 = DROI 10 P1 P2 ;
  66. D2 = DROI 1 P2 P3 ;
  67. D3 = DROI 10 P3 P4 ;
  68. D4 = DROI 1 P4 P1 ;
  69. D5 = DROI 10 P5 P6 ;
  70. D6 = DROI 1 P6 P7 ;
  71. D7 = DROI 10 P7 P8 ;
  72. D8 = DROI 1 P8 P5 ;
  73. L1 = D1 ET D2 ET D3 ET D4;
  74. L2 = D5 ET D6 ET D7 ET D8;
  75. SU1 = SURF L1 PLANE;
  76. SU2 = SURF L2 PLANE;
  77. P9 = SU2 POINT PROCHE P9;
  78. *
  79. *-------------------- Définition du modèle ----------------------
  80. *
  81. MOD1 = MODE (SU1 ET SU2) THERMIQUE ISOTROPE CONS UN;
  82. MOD3 = MODE (SU1 ET SU2) MECANIQUE ELASTIQUE ISOTROPE CONS DEUX ;
  83. MOD = MOD1 et MOD3;
  84. *
  85. *------------------- Définition des matériaux -------------------
  86. *
  87. MAT1 = MATE MOD1 K 14.6 'C' 460. RHO 7800. ;
  88. MAT3 = MATE MOD3 ALPHA 1E-5 YOUN 2E+11 NU 0.00001;
  89. MAT = MAT1 ET MAT3;
  90. *
  91. *------------------- blocages mécaniques ------------------------
  92. *
  93. CL1 = BLOQ UY (SU1 ET SU2);
  94. CL2 = BLOQ UX D4;
  95. CL3 = BLOQ UX D6;
  96. CL_ME = CL1 ET CL2 ET CL3;
  97. *
  98. *------------------- blocages thermiques ------------------------
  99. *
  100. CL4 = BLOQ T D4;
  101. CL5 = BLOQ T D2;
  102. CL6 = BLOQ T D6;
  103. TEM1 = DEPI (CL4 ET CL6) 20.;
  104. TEM2 = DEPI CL5 500.;
  105. CL_TH = CL4 ET CL5 ET CL6;
  106. *
  107. *------------------- températures imposées ----------------------
  108. *
  109. TEM1 = DEPI (CL4 ET CL6) 20.;
  110. TEM2 = DEPI CL5 500.;
  111. TIM = TEM1 ET TEM2;
  112. EV1 = EVOL MANU TEMPS (PROG 0. 200.) y (prog 1. 1.);
  113. CHA = CHAR 'TIMP' TIM EV1;
  114. *
  115. *------------------- température initiale -----------------------
  116. *
  117. TEM0 = MANU CHPO (SU1 ET SU2) 1 T 20.;
  118. *
  119. *--------------- creation de la table pour pasapas ------------
  120. *
  121. ta = table;
  122. ta.modele = mod;
  123. ta.caracteristiques = mat;
  124. ta.blocages_mecaniques = cl_me;
  125. ta.blocages_thermiques = cl_th;
  126. ta.temperatures = table;
  127. ta.temperatures . 0 = tem0;
  128. ta.chargement = cha;
  129. ta.procedure_perso1 = vrai;
  130. ta.ok = faux;
  131. ta.temps_calcules = (prog 0. pas 5. 80.) et (prog 81. pas 1. 99.)
  132. et (prog 100. pas 5. 150.);
  133. *
  134. *------------ procédure utilisateur perso1 --------------------
  135. *
  136. debproc perso1 TTU*TABLE;
  137. dep = ttu.'ESTIMATION'.'DEPLACEMENTS';
  138. WTAB=TTU.'WTABLE';
  139. x = extr dep UX P2;
  140. * list x;
  141. si ((WTAB.'TEMPS0' > 84.5) et ( WTAB.'TEMPS0' < 89.5));
  142. * list ttu.'ESTIMATION'.'TEMPERATURES';
  143. finsi;
  144.  
  145. si (('>' x 0.0001) et (non ttu.ok));
  146. ttu.loup = WTAB.'TEMPS0';
  147. mess ' *************************';
  148. mess ' mise a jour du au contact pour le temps : ' ttu.loup ;
  149. mess ' *************************';
  150. CL7 = bloq T D8;
  151. tim = depi cl7 500.;
  152. WTAB.'BLOCAGES_THERMIQUES' = (WTAB.'BLOCAGES_THERMIQUES' ) et cl7;
  153. EV1 = EVOL MANU TEMPS (PROG 0. 200.) y (prog 1. 1.);
  154. CHA7 = CHAR 'TIMP' TIM EV1;
  155. WTAB.'CHARGEMENT_I' = WTAB.'CHARGEMENT_I' et cha7;
  156. WTAB.'CHARGEMENT' = WTAB.'CHARGEMENT' et cha7;
  157. ttu.ok = vrai;
  158. finsi;
  159. finproc;
  160. *
  161. *------------ Appel à la procédure PASAPAS --------------------
  162. *
  163. *
  164. *----------- Depouillement ------------------------------------
  165. *
  166. a = (14.6 / 7800.)/460.;
  167. tpr1 = prog;
  168. tpr3 = prog;
  169. tep_th = prog;
  170. x = 0.12;
  171. er1 = 0.;
  172. nb = 0;
  173. idim = (dime (ta.temps)) - 1;
  174. *
  175. repeter bou idim;
  176. ite = &bou;
  177. te = ta.temps.ite;
  178. tem = ta.temperatures.ite;
  179. tep1 = extr tem T p9;
  180. tpr1 = tpr1 et (prog tep1);
  181. tpr3 = tpr3 et (prog te);
  182. si ('>' te (ta.loup)) ;
  183. co1 = erf((x - .1002)/(2 * (( a * (te - (ta.loup))**0.5))));
  184. co2 = erf(0.1/(2.*(( a * (te - (ta.loup)))**0.5)));
  185. sol_te = 500. - ((500. - 20.)*co1/co2);
  186. er1 = er1 + (abs ((sol_te - tep1)/sol_te) * 100.);
  187. nb = nb + 1;
  188. sinon;
  189. sol_te = 20.;
  190. finsi;
  191. tep_th = tep_th et (prog sol_te);
  192. fin bou;
  193. *
  194. er1 = er1/nb;
  195. mess 'erreur sur la température :'er1'%';
  196. *
  197. *lvar = TEXT 'EVOLUTION DE LA TEMPERATURE AU POINT 0.12 m';
  198. *titre lvar;
  199. *ev_te = evol manu temps tpr3 temperature tep_th;
  200. *ev_tet = evol manu temps tpr3 temperature tpr1;
  201. *dess (ev_tet et ev_te) ;
  202. *
  203. si ( er1 > 5. ) ;
  204. mess 'Résultat incorrect' ;
  205. erreur 5 ;
  206. finsi ;
  207. *
  208. fin;
  209.  
  210.  
  211.  
  212.  
  213.  
  214.  
  215.  
  216.  
  217.  
  218.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales