Télécharger thm1.dgibi

Retour à la liste

Numérotation des lignes :

  1. * fichier : thm1.dgibi
  2. *---------------------------------------------------------------------*
  3. * *
  4. * Cas-test du modele THERMOHYDRIQUE SCHREFLER *
  5. * *
  6. * Description : Simulation d'une structure composite constituee d'un *
  7. * ------------- modele THM et d'un modele THERMIQUE classique en 2D *
  8. * Deformation Plane. De plus, CL de CONVECTION appli- *
  9. * -quee a une extremite du milieu THM. *
  10. * *
  11. * Par defaut, comportement mecanique endommageable pour *
  12. * verifier possibilite couplage avec endommagement. *
  13. * *
  14. * Test de non-regression sur resultats du 7/10/2008. *
  15. * *
  16. * *
  17. *---------------------------------------------------------------------*
  18. *
  19. * *
  20. 'OPTI' 'DIME' 2 'ELEM' 'QUA8' 'MODE' 'PLAN' 'DEFO' ;
  21. * *
  22. * Calcul sur tous les pas de temps : ICOMPLET = VRAI ;
  23. ICOMPLET = FAUX ;
  24. * *
  25. * Simulation avec un modele d'endommagement : IMAZARS = VRAI ;
  26. IMAZARS = VRAI ;
  27. * *
  28. * Traces : ITRAC1 = VRAI ;
  29. ITRAC1 = FAUX ;
  30. * *
  31. 'OPTI' 'ECHO' 0 ;
  32. * *
  33. *---------------------------------------------------------------------*
  34. * *
  35. * I. Geometrie et Donnees Initiales *
  36. * *
  37. *---------------------------------------------------------------------*
  38. * *
  39. *--------------------------- I.1. Geometrie --------------------------*
  40. * *
  41. PA1 = 0. 0. ;
  42. PB1 = 0. 0.01 ;
  43. PC1 = 0.3 0.01 ;
  44. PD1 = 0.3 0. ;
  45. * *
  46. * Nombre d'elements suivant Ox et Oy : *
  47. NBEX1 = 60 ;
  48. NBEY1 = 1 ;
  49. * Droites contour de la geometrie : *
  50. DAB1 = PA1 'DROI' NBEY1 PB1 ;
  51. DCD1 = PC1 'DROI' NBEY1 PD1 ;
  52. DBC1 = PB1 'DROI' NBEX1 PC1 ;
  53. DDA1 = PD1 'DROI' NBEX1 PA1 ;
  54. DFE1 = DCD1 'PLUS' (0.01 0.) ;
  55. * *
  56. SURF1 = 'DALL' DAB1 DBC1 DCD1 DDA1 ;
  57. SURF2 = DCD1 'REGL' 1 DFE1 ;
  58. * *
  59. *-------------------- I.2. Discretisation en Temps -------------------*
  60. * *
  61. 'SI' ICOMPLET ;
  62. LTPSCAL1 = PROG 0. PAS 100. 36000. ;
  63. 'SINO' ;
  64. LTPSCAL1 = PROG 0. PAS 100. 300. ;
  65. 'FINS' ;
  66. * *
  67. *--------------------- I.3. Conditions Initiales ---------------------*
  68. * *
  69. * Temperature (TK0), Pression de Gaz (PG0), Humidite Relative (HR0) *
  70. * et Pression Capillaire (PC0) Initiales : *
  71. TK0 = 298.15 ;
  72. PG0 = 101325. ;
  73. HR0 = 0.60895 ;
  74. PC0 = 68.3596E6 ;
  75. * *
  76. *---------------------------------------------------------------------*
  77. * *
  78. * II. Modelisation *
  79. * *
  80. *---------------------------------------------------------------------*
  81. * *
  82. *---------------- II.1. Modeles et Caracteristiques ------------------*
  83. * *
  84. MODTH1 = 'MODE' SURF1 'THERMOHYDRIQUE' ;
  85. MODTH2 = 'MODE' SURF2 'THERMIQUE' ;
  86. MODCO1 = 'MODE' DAB1 'THERMIQUE' 'CONVECTION' ;
  87. 'SI' IMAZARS ;
  88. MODM1 = 'MODE' SURF1 'MECANIQUE' 'ELASTIQUE' 'ISOTROPE'
  89. 'ENDOMMAGEMENT' 'MAZARS' ;
  90. 'SINO' ;
  91. MODM1 = 'MODE' SURF1 'MECANIQUE' 'ELASTIQUE' 'ISOTROPE' ;
  92. 'FINS' ;
  93. MODM2 = 'MODE' SURF2 'MECANIQUE' 'ELASTIQUE' 'ISOTROPE' ;
  94. MOD0 = MODTH1 'ET' MODM1 'ET' MODTH2 'ET' MODM2 ;
  95. MOD0 = MODTH1 'ET' MODM1 'ET' MODTH2 'ET' MODM2 'ET' MODCO1 ;
  96. * *
  97. * Module d'Young (MY1), Coefficient de Poisson (NU1) et Dilatation *
  98. * Thermique (ALPH1) : *
  99. MY1 = 'EVOL' 'MANU'
  100. 'T ' ('PROG' 20. 60. 110. 250.)
  101. 'YOUN' ('PROG' 38.5E9 33.E9 29.8E9 20.4E9) ;
  102. NU1 = 0.25 ;
  103. ALPH1 = 11.E-6 ;
  104. * *
  105. * Parametres pour modele MAZARS : *
  106. EPSD1 = 2.E-04 ;
  107. AT1 = 1. ;
  108. BT1 = 1.E4 ;
  109. AC1 = 1.2 ;
  110. BC1 = 1.5E3 ;
  111. BETA1 = 1.06 ;
  112. * *
  113. CH0 = 'MANU' 'CHPO' SURF1 3 'PG' PG0 'PC' PC0 'T' TK0 ;
  114. MATTH1 F0 = @MATETHM MODTH1 CH0 ;
  115. MATTH2 = 'MATE' MODTH2 'RHO' 1. 'C' 0. 'K' 1.E-6 ;
  116. MATCO1 = 'MATE' MODCO1 'H' 1.E6 ;
  117. 'SI' IMAZARS ;
  118. MATM1 = 'MATE' MODM1 'YOUN' MY1 'NU' NU1 'ALPH' ALPH1 'RHO' 2.E3
  119. 'KTR0' EPSD1 'ATRA' AT1 'BTRA' BT1 'ACOM' AC1 'BCOM' BC1 'BETA' BETA1 ;
  120. 'SINO' ;
  121. MATM1 = 'MATE' MODM1 'YOUN' MY1 'NU' NU1 'ALPH' ALPH1 ;
  122. 'FINS' ;
  123. MATM2 = 'MATE' MODM2 'YOUN' 1.E9 'NU' 0.3 'ALPH' 1.E-6 ;
  124. MAT0 = MATTH1 'ET' MATM1 'ET' MATTH2 'ET' MATM2 ;
  125. MAT0 = MATTH1 'ET' MATM1 'ET' MATTH2 'ET' MATM2 'ET' MATCO1 ;
  126. * *
  127. *--------------------- II.2. C.L. et Chargements ---------------------*
  128. * *
  129. * II.2.1. ThermoHydriques : *
  130. CLPG1 = 'BLOQ' 'PG' DAB1 ;
  131. CLPC1 = 'BLOQ' 'PC' DAB1 ;
  132. CLTH0 = CLPG1 'ET' CLPC1 ;
  133. * *
  134. CHPG1 = 'DEPI' CLPG1 1. ;
  135. CHPC1 = 'DEPI' CLPC1 1. ;
  136. CHTK1 = 'MANU' 'CHPO' DAB1 1 'T ' 1. ;
  137. EVPG1 = 'EVOL' 'MANU' 'TEMPS' ('PROG' 0. 300. 36000.)
  138. ('PROG' 101325. 431325. 758925.) ;
  139. EVPC1 = 'EVOL' 'MANU' 'TEMPS' ('PROG' 0. 300. 36000.)
  140. ('PROG' 6.8362E7 4.39004E7 4.08575E7) ;
  141. EVTK1 = 'EVOL' 'MANU' 'TEMPS' ('PROG' 0. 300. 36000.)
  142. ('PROG' 298.15 418. 440.) ;
  143. CGPG1 = 'CHAR' 'TIMP' CHPG1 EVPG1 ;
  144. CGPC1 = 'CHAR' 'TIMP' CHPC1 EVPC1 ;
  145. CGTK1 = 'CHAR' 'TECO' CHTK1 EVTK1 ;
  146. CG0 = CGPG1 'ET' CGPC1 'ET' CGTK1 ;
  147. * *
  148. * Mecaniques : *
  149. CLME1 = 'BLOQ' 'UX' DAB1 ;
  150. CLME2 = 'BLOQ' 'UY' DBC1 ;
  151. CLME3 = 'BLOQ' 'UY' DDA1 ;
  152. CLME0 = CLME1 'ET' CLME2 'ET' CLME3 ;
  153. * *
  154. *---------------------------------------------------------------------*
  155. * *
  156. * III. Resolution PASAPAS *
  157. * *
  158. *---------------------------------------------------------------------*
  159. * *
  160. *---------------------- III.1. Table de Donnees ----------------------*
  161. * *
  162. TPAS1 = 'TABL' ;
  163. TPAS1 . 'MODELE' = MOD0 ;
  164. TPAS1 . 'CARACTERISTIQUES' = MAT0 ;
  165. TPAS1 . 'BLOCAGES_THERMIQUES' = CLTH0 ;
  166. TPAS1 . 'BLOCAGES_MECANIQUES' = CLME0 ;
  167. TPAS1 . 'CHARGEMENT' = CG0 ;
  168. TPAS1 . 'TEMPS_CALCULES' = LTPSCAL1 ;
  169. TPAS1 . 'PROCEDURE_THERMIQUE' = 'NONLINEAIRE' ;
  170. TPAS1 . 'RELAXATION_THETA' = 1.0 ;
  171. TPAS1 . 'MOVA' = 'D' ;
  172. * *
  173. TPAS1 . 'TEMPERATURES' = 'TABL' ;
  174. TPAS1 . 'TEMPERATURES' . 0 = CH0 ;
  175. * *
  176.  
  177. *------------------------- III.2. Resolution -------------------------*
  178. * *
  179. PASAPAS TPAS1 ;
  180. * *
  181. *---------------------------------------------------------------------*
  182. * *
  183. * IV. Post-traitement *
  184. * *
  185. *---------------------------------------------------------------------*
  186. * *
  187. *------------------- IV.1. Solution de comparaison -------------------*
  188. * *
  189. EVPGR1 = 'EVOL' 'TURQ' 'MANU'
  190. 'X ' ('PROG' 0.00000E+00 5.00000E-02 1.00000E-01)
  191. 'PG' ('PROG' 1.01325E+05 1.01325E+05 1.01325E+05) ;
  192. EVPCR1 = 'EVOL' 'TURQ' 'MANU'
  193. 'X ' ('PROG' 0.00000E+00 5.00000E-02 1.00000E-01)
  194. 'PC' ('PROG' 6.83596E+07 6.83596E+07 6.83596E+07) ;
  195. EVTKR1 = 'EVOL' 'TURQ' 'MANU'
  196. 'X ' ('PROG' 0.00000E+00 5.00000E-02 1.00000E-01)
  197. 'T ' ('PROG' 2.98150E+02 2.98150E+02 2.98150E+02) ;
  198. EVPGR2 = 'EVOL' 'VERT' 'MANU'
  199. 'X ' ('PROG' 0.00000E+00 5.00000E-02 1.00000E-01)
  200. 'PG' ('PROG' 4.31325E+05 1.03086E+05 1.01345E+05) ;
  201. EVPCR2 = 'EVOL' 'VERT' 'MANU'
  202. 'X ' ('PROG' 0.00000E+00 5.00000E-02 1.00000E-01)
  203. 'PC' ('PROG' 4.39004E+07 6.75367E+07 6.83477E+07) ;
  204. EVTKR2 = 'EVOL' 'VERT' 'MANU'
  205. 'X ' ('PROG' 0.00000E+00 5.00000E-02 1.00000E-01)
  206. 'T ' ('PROG' 4.17982E+02 3.01067E+02 2.98192E+02) ;
  207. 'SI' ICOMPLET ;
  208. EVPGR3 = 'EVOL' 'JAUN' 'MANU'
  209. 'X ' ('PROG' 0.00000E+00 5.00000E-02 1.00000E-01)
  210. 'PG' ('PROG' 5.11160E+05 2.70857E+05 1.21151E+05) ;
  211. EVPCR3 = 'EVOL' 'JAUN' 'MANU'
  212. 'X ' ('PROG' 0.00000E+00 5.00000E-02 1.00000E-01)
  213. 'PC' ('PROG' 4.31589E+07 4.31737E+07 5.23776E+07) ;
  214. EVTKR3 = 'EVOL' 'JAUN' 'MANU'
  215. 'X ' ('PROG' 0.00000E+00 5.00000E-02 1.00000E-01)
  216. 'T ' ('PROG' 4.23359E+02 3.83641E+02 3.52063E+02) ;
  217. EVPGR4 = 'EVOL' 'ORAN' 'MANU'
  218. 'X ' ('PROG' 0.00000E+00 5.00000E-02 1.00000E-01)
  219. 'PG' ('PROG' 6.76337E+05 5.09370E+05 3.86782E+05) ;
  220. EVPCR4 = 'EVOL' 'ORAN' 'MANU'
  221. 'X ' ('PROG' 0.00000E+00 5.00000E-02 1.00000E-01)
  222. 'PC' ('PROG' 4.16246E+07 3.94484E+07 4.15511E+07) ;
  223. EVTKR4 = 'EVOL' 'ORAN' 'MANU'
  224. 'X ' ('PROG' 0.00000E+00 5.00000E-02 1.00000E-01)
  225. 'T ' ('PROG' 4.34453E+02 4.08195E+02 3.86481E+02) ;
  226. EVPGR5 = 'EVOL' 'ROUG' 'MANU'
  227. 'X ' ('PROG' 0.00000E+00 5.00000E-02 1.00000E-01)
  228. 'PG' ('PROG' 7.58925E+05 6.08924E+05 5.02148E+05) ;
  229. EVPCR5 = 'EVOL' 'ROUG' 'MANU'
  230. 'X ' ('PROG' 0.00000E+00 5.00000E-02 1.00000E-01)
  231. 'PC' ('PROG' 4.08575E+07 3.79207E+07 3.89898E+07) ;
  232. EVTKR5 = 'EVOL' 'ROUG' 'MANU'
  233. 'X ' ('PROG' 0.00000E+00 5.00000E-02 1.00000E-01)
  234. 'T ' ('PROG' 4.39999E+02 4.16870E+02 3.97931E+02) ;
  235. EVPGR0 = EVPGR1 'ET' EVPGR2 'ET' EVPGR3 'ET' EVPGR4 'ET' EVPGR5 ;
  236. EVPCR0 = EVPCR1 'ET' EVPCR2 'ET' EVPCR3 'ET' EVPCR4 'ET' EVPCR5 ;
  237. EVTKR0 = EVTKR1 'ET' EVTKR2 'ET' EVTKR3 'ET' EVTKR4 'ET' EVTKR5 ;
  238. 'SINO' ;
  239. EVPGR0 = EVPGR1 'ET' EVPGR2 ;
  240. EVPCR0 = EVPCR1 'ET' EVPCR2 ;
  241. EVTKR0 = EVTKR1 'ET' EVTKR2 ;
  242. 'FINS' ;
  243. * *
  244. *------------ IV.2. Depouillement de la solution calculee ------------*
  245. * *
  246. TTEMPS1 = TPAS1 . 'TEMPS' ;
  247. IDIM1 = 'DIME' TTEMPS1 ;
  248. TINDEX1 = 'TABL' ;
  249. 'REPE' BOU1 IDIM1 ;
  250. IM1 = &BOU1 - 1 ;
  251. TPSI1 = TTEMPS1 . IM1 ;
  252. TINDEX1 . TPSI1 = IM1 ;
  253. 'FIN' BOU1 ;
  254. * *
  255. TSOL1 = TPAS1 . 'TEMPERATURES' ;
  256. * *
  257. PX1 = DBC1 'POIN' 'PROC' (0.05 0.) ;
  258. PX2 = DBC1 'POIN' 'PROC' (0.10 0.) ;
  259. DX1 = (PB1 'DROI' 1 PX1) 'ET' (PX1 'DROI' PX2) ;
  260. * *
  261. SOLPG1 = 'EVOL' 'TURQ' 'CHPO' (TSOL1 . (TINDEX1 . 0.)) 'PG' DX1 ;
  262. SOLPC1 = 'EVOL' 'TURQ' 'CHPO' (TSOL1 . (TINDEX1 . 0.)) 'PC' DX1 ;
  263. SOLTK1 = 'EVOL' 'TURQ' 'CHPO' (TSOL1 . (TINDEX1 . 0.)) 'T ' DX1 ;
  264. SOLPG2 = 'EVOL' 'VERT' 'CHPO' (TSOL1 . (TINDEX1 . 300.)) 'PG' DX1 ;
  265. SOLPC2 = 'EVOL' 'VERT' 'CHPO' (TSOL1 . (TINDEX1 . 300.)) 'PC' DX1 ;
  266. SOLTK2 = 'EVOL' 'VERT' 'CHPO' (TSOL1 . (TINDEX1 . 300.)) 'T ' DX1 ;
  267. 'SI' ICOMPLET ;
  268. SOLPG3 = 'EVOL' 'JAUN' 'CHPO' (TSOL1 . (TINDEX1 . 9.E3)) 'PG' DX1 ;
  269. SOLPC3 = 'EVOL' 'JAUN' 'CHPO' (TSOL1 . (TINDEX1 . 9.E3)) 'PC' DX1 ;
  270. SOLTK3 = 'EVOL' 'JAUN' 'CHPO' (TSOL1 . (TINDEX1 . 9.E3)) 'T ' DX1 ;
  271. SOLPG4 = 'EVOL' 'ORAN' 'CHPO' (TSOL1 . (TINDEX1 . 27.E3)) 'PG' DX1 ;
  272. SOLPC4 = 'EVOL' 'ORAN' 'CHPO' (TSOL1 . (TINDEX1 . 27.E3)) 'PC' DX1 ;
  273. SOLTK4 = 'EVOL' 'ORAN' 'CHPO' (TSOL1 . (TINDEX1 . 27.E3)) 'T ' DX1 ;
  274. SOLPG5 = 'EVOL' 'ROUG' 'CHPO' (TSOL1 . (TINDEX1 . 36.E3)) 'PG' DX1 ;
  275. SOLPC5 = 'EVOL' 'ROUG' 'CHPO' (TSOL1 . (TINDEX1 . 36.E3)) 'PC' DX1 ;
  276. SOLTK5 = 'EVOL' 'ROUG' 'CHPO' (TSOL1 . (TINDEX1 . 36.E3)) 'T ' DX1 ;
  277. 'FINS' ;
  278. * *
  279. 'SI' ICOMPLET ;
  280. EVPGTOT1 = SOLPG1 'ET' SOLPG2 'ET' SOLPG3 'ET' SOLPG4 'ET' SOLPG5 ;
  281. EVPCTOT1 = SOLPC1 'ET' SOLPC2 'ET' SOLPC3 'ET' SOLPC4 'ET' SOLPC5 ;
  282. EVTPTOT1 = SOLTK1 'ET' SOLTK2 'ET' SOLTK3 'ET' SOLTK4 'ET' SOLTK5 ;
  283. 'SINO' ;
  284. EVPGTOT1 = SOLPG1 'ET' SOLPG2 ;
  285. EVPCTOT1 = SOLPC1 'ET' SOLPC2 ;
  286. EVTPTOT1 = SOLTK1 'ET' SOLTK2 ;
  287. 'FINS' ;
  288. * *
  289. *--------------------------- IV.3. Traces ----------------------------*
  290. * *
  291. 'SI' ITRAC1 ;
  292. TDESS1 = 'TABL' ;
  293. TDESS1 . 1 = 'MOT' 'MARQ SS CROI NOLI' ;
  294. TDESS1 . 2 = 'MOT' 'MARQ SS CROI NOLI' ;
  295. TDESS1 . 'TITRE' = 'TABL' ;
  296. TDESS1 . 'TITRE' . 1 = 'MOT' 'PAS DE LEGENDE' ;
  297. TDESS1 . 'TITRE' . 2 = 'MOT' 'PAS DE LEGENDE' ;
  298. TDESS1 . 'TITRE' . 6 = 'MOT' 'Initial' ;
  299. TDESS1 . 'TITRE' . 7 = 'MOT' 't = 5 mn' ;
  300. 'SI' ICOMPLET ;
  301. TDESS1 . 3 = 'MOT' 'MARQ SS CROI NOLI' ;
  302. TDESS1 . 4 = 'MOT' 'MARQ SS CROI NOLI' ;
  303. TDESS1 . 5 = 'MOT' 'MARQ SS CROI NOLI' ;
  304. TDESS1 . 'TITRE' . 3 = 'MOT' 'PAS DE LEGENDE' ;
  305. TDESS1 . 'TITRE' . 4 = 'MOT' 'PAS DE LEGENDE' ;
  306. TDESS1 . 'TITRE' . 5 = 'MOT' 'PAS DE LEGENDE' ;
  307. TDESS1 . 'TITRE' . 8 = 'MOT' 't = 2 h 30' ;
  308. TDESS1 . 'TITRE' . 9 = 'MOT' 't = 7 h 30 mn' ;
  309. TDESS1 . 'TITRE' . 10 = 'MOT' 't = 10 h' ;
  310. 'FINS' ;
  311. * *
  312. TIT1 = 'MOT'
  313. 'Simulation (lignes) Vs. Solution de Refence (points).' ;
  314. 'DESS' TDESS1 (EVPGR0 'ET' EVPGTOT1) 'TITR' TIT1 ;
  315. 'DESS' TDESS1 (EVPCR0 'ET' EVPCTOT1) 'TITR' TIT1 ;
  316. 'DESS' TDESS1 (EVTKR0 'ET' EVTPTOT1) 'TITR' TIT1 ;
  317. 'FINS' ;
  318. * *
  319. *------------------------ IV.4. Calcul erreur ------------------------*
  320. * *
  321. ERRPG1 = ('MAXI' 'ABS' ('EXTR' (EVPGR1 - SOLPG1) 'ORDO'))
  322. / ('MAXI' ('EXTR' EVPGR1 'ORDO')) ;
  323. ERRPC1 = ('MAXI' 'ABS' ('EXTR' (EVPCR1 - SOLPC1) 'ORDO'))
  324. / ('MAXI' ('EXTR' EVPCR1 'ORDO')) ;
  325. ERRTK1 = ('MAXI' 'ABS' ('EXTR' (EVTKR1 - SOLTK1) 'ORDO'))
  326. / ('MAXI' ('EXTR' EVTKR1 'ORDO')) ;
  327. ERRPG2 = ('MAXI' 'ABS' ('EXTR' (EVPGR2 - SOLPG2) 'ORDO'))
  328. / ('MAXI' ('EXTR' EVPGR2 'ORDO')) ;
  329. ERRPC2 = ('MAXI' 'ABS' ('EXTR' (EVPCR2 - SOLPC2) 'ORDO'))
  330. / ('MAXI' ('EXTR' EVPCR2 'ORDO')) ;
  331. ERRTK2 = ('MAXI' 'ABS' ('EXTR' (EVTKR2 - SOLTK2) 'ORDO'))
  332. / ('MAXI' ('EXTR' EVTKR2 'ORDO')) ;
  333. 'SI' ICOMPLET ;
  334. ERRPG3 = ('MAXI' 'ABS' ('EXTR' (EVPGR3 - SOLPG3) 'ORDO'))
  335. / ('MAXI' ('EXTR' EVPGR3 'ORDO')) ;
  336. ERRPC3 = ('MAXI' 'ABS' ('EXTR' (EVPCR3 - SOLPC3) 'ORDO'))
  337. / ('MAXI' ('EXTR' EVPCR3 'ORDO')) ;
  338. ERRTK3 = ('MAXI' 'ABS' ('EXTR' (EVTKR3 - SOLTK3) 'ORDO'))
  339. / ('MAXI' ('EXTR' EVTKR3 'ORDO')) ;
  340. ERRPG4 = ('MAXI' 'ABS' ('EXTR' (EVPGR4 - SOLPG4) 'ORDO'))
  341. / ('MAXI' ('EXTR' EVPGR4 'ORDO')) ;
  342. ERRPC4 = ('MAXI' 'ABS' ('EXTR' (EVPCR4 - SOLPC4) 'ORDO'))
  343. / ('MAXI' ('EXTR' EVPCR4 'ORDO')) ;
  344. ERRTK4 = ('MAXI' 'ABS' ('EXTR' (EVTKR4 - SOLTK4) 'ORDO'))
  345. / ('MAXI' ('EXTR' EVTKR4 'ORDO')) ;
  346. ERRPG5 = ('MAXI' 'ABS' ('EXTR' (EVPGR5 - SOLPG5) 'ORDO'))
  347. / ('MAXI' ('EXTR' EVPGR5 'ORDO')) ;
  348. ERRPC5 = ('MAXI' 'ABS' ('EXTR' (EVPCR5 - SOLPC5) 'ORDO'))
  349. / ('MAXI' ('EXTR' EVPCR5 'ORDO')) ;
  350. ERRTK5 = ('MAXI' 'ABS' ('EXTR' (EVTKR5 - SOLTK5) 'ORDO'))
  351. / ('MAXI' ('EXTR' EVTKR5 'ORDO')) ;
  352. 'FINS' ;
  353. * *
  354. 'SI' ICOMPLET ;
  355. ERRPG0 = 'MAXI' ('PROG' ERRPG1 ERRPG2 ERRPG3 ERRPG4 ERRPG5) ;
  356. ERRPC0 = 'MAXI' ('PROG' ERRPC1 ERRPC2 ERRPC3 ERRPC4 ERRPC5) ;
  357. ERRTK0 = 'MAXI' ('PROG' ERRTK1 ERRTK2 ERRTK3 ERRTK4 ERRTK5) ;
  358. 'SINO' ;
  359. ERRPG0 = 'MAXI' ('PROG' ERRPG1 ERRPG2) ;
  360. ERRPC0 = 'MAXI' ('PROG' ERRPC1 ERRPC2) ;
  361. ERRTK0 = 'MAXI' ('PROG' ERRTK1 ERRTK2) ;
  362. 'FINS' ;
  363. ERR0 = 'MAXI' ('PROG' ERRPG0 ERRPC0 ERRTK0) ;
  364. * *
  365. 'SI' (ERR0 '>' 1.E-3) ;
  366. 'ERRE' 5 ;
  367. 'FIN' ;
  368. 'SINO' ;
  369. 'MESS' ' ****** Ecart relatif max. solution de reference =' ERR0 ;
  370. 'SAUT' 1 'LIGN' ;
  371. 'MESS'
  372. '----------------------- CAS-TEST THM1 REUSSI ! -----------------------'
  373. ;
  374. 'SAUT' 1 'LIGN' ;
  375. 'FINS' ;
  376. * *
  377. 'FIN' ;
  378.  
  379.  
  380.  
  381.  
  382.  
  383.  
  384.  
  385.  
  386.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales