Télécharger thgdep1.dgibi

Retour à la liste

Numérotation des lignes :

  1. * fichier : thgdep1.dgibi
  2. IG1 = FAUX ;
  3. *----------------------------------------------------------------------*
  4. * Cas-test de calcul thermomecanique en grands deplacements, avec *
  5. * convergence thermique-mécanique. *
  6. * On teste egalement la reprise en fournissant une liste des temps *
  7. * calcules qui debute au temps suivant. *
  8. *----------------------------------------------------------------------*
  9. 'OPTI' 'DIME' 2 'ELEM' 'QUA4' ;
  10. * *
  11. O1 = 0. 0. ;
  12. X1 = 1. 0. ;
  13. Y1 = 0. 1. ;
  14. * *
  15. L1 = O1 'DROI' 5 X1 ;
  16. S1 = L1 'TRAN' 3 Y1 ;
  17. L2 = S1 'COTE' 2 ;
  18. L3 = S1 'COTE' 3 ;
  19. L4 = S1 'COTE' 4 ;
  20. 'SI' IG1 ;
  21. 'TRAC' 'QUAL' S1 ;
  22. 'FINS' ;
  23. * *
  24. MODT1 = 'MODE' S1 'THERMIQUE' ;
  25. MODM1 = 'MODE' S1 'MECANIQUE' ;
  26. * *
  27. MATT1 = 'MATE' MODT1 'K' 100. 'RHO' 0. 'C' 1. ;
  28. MATM1 = 'MATE' MODM1 'YOUN' 2.E9 'NU' 0.25 'ALPH' 1.E-6 'TALP' 0. 'TREF' 0.;
  29. * *
  30. MOD1 = MODT1 'ET' MODM1 ;
  31. MAT1 = MATT1 'ET' MATM1 ;
  32. * *
  33. CLM1 = ('BLOQ' L1 'UY') 'ET' ('BLOQ' L4 'UX') ;
  34. CLT1 = 'BLOQ' L1 'T' ;
  35. *
  36. F1 = 'PRES' 'MASS' MODM1 L3 (-1.E8) ;
  37. Q1 = 'FLUX' MODT1 L3 300. ;
  38. QREF1 = 'FLUX' MODT1 L3 1. ;
  39. * *
  40. LTPS1 = 'PROG' 0. 1.0 2. ;
  41. LAMP1 = 'PROG' 0. 0.5 1. ;
  42. EV1 = 'EVOL' 'MANU' 'TEMP' LTPS1 'AMPL' LAMP1 ;
  43. * *
  44. CGM1 = 'CHAR' 'MECA' F1 EV1 ;
  45. CGT1 = 'CHAR' 'Q' Q1 EV1 ;
  46. * *
  47. TAB1 = 'TABL' ;
  48. TAB1 . 'MODELE' = MOD1 ;
  49. TAB1 . 'CARACTERISTIQUES' = MAT1 ;
  50. TAB1 . 'BLOCAGES_MECANIQUES' = CLM1 ;
  51. TAB1 . 'BLOCAGES_THERMIQUES' = CLT1 ;
  52. TAB1 . 'CHARGEMENT' = CGM1 'ET' CGT1 ;
  53. TAB1 . 'TEMPS_CALCULES' = 'PROG' 0. 1. ;
  54. TAB1 . 'GRANDS_DEPLACEMENTS' = VRAI ;
  55. TAB1 . 'RELAXATION_THETA' = 1. ;
  56. TAB1 . 'CONVERGENCE_MEC_THE' = VRAI ;
  57. * *
  58. PASAPAS TAB1 ;
  59. * *
  60. CHT1 = TAB1 . 'TEMPERATURES' . 1 ;
  61. DEP1 = TAB1 . 'DEPLACEMENTS' . 1 ;
  62. * *
  63. UXM1 = 'MINI' ('EXCO' DEP1 'UX') ;
  64. UYM1 = 'MAXI' ('EXCO' DEP1 'UY') ;
  65. TM1 = 'MAXI' ('ENLE' CHT1 'LX') ;
  66. FLU1 = ('MAXI' ('TIRE' CGT1 'Q' 1.)) / ('MAXI' QREF1) ;
  67. TREF1 = FLU1 / ('EXTR' MATT1 'K' 1 1 1) * (1. + UYM1) / (1. + UXM1) ;
  68. ERR1 = 'ABS' (TM1 - TREF1) ;
  69. * *
  70. TAB1 . 'TEMPS_CALCULES' = 'PROG' 2. ;
  71. * *
  72. PASAPAS TAB1 ;
  73. * *
  74. IFIN1 = ('DIME' TAB1 . 'TEMPERATURES') - 1 ;
  75. CHT2 = TAB1 . 'TEMPERATURES' . IFIN1 ;
  76. DEP2 = TAB1 . 'DEPLACEMENTS' . IFIN1 ;
  77. * *
  78. UXM2 = 'MINI' ('EXCO' DEP2 'UX') ;
  79. UYM2 = 'MAXI' ('EXCO' DEP2 'UY') ;
  80. TM2 = 'MAXI' ('ENLE' CHT2 'LX') ;
  81. FLU2 = ('MAXI' ('TIRE' CGT1 'Q' 2.)) / ('MAXI' QREF1) ;
  82. TREF2 = FLU2 / ('EXTR' MATT1 'K' 1 1 1) * (1. + UYM2) / (1. + UXM2) ;
  83. ERR2 = 'ABS' (TM2 - TREF2) ;
  84. * *
  85. 'SI' ((ERR1 > 1.E-4) 'OU' (ERR2 > 1.E-4)) ;
  86. 'ERRE' 5 ;
  87. 'SINO' ;
  88. 'OPTI' 'ECHO' 0 ;
  89. 'SAUT' 1 'LIGN' ;
  90. 'MESS' ' ****** Erreur max. = ' ('MAXI' ('PROG' err1 err2)) ;
  91. 'MESS' ' ' ;
  92. 'MESS' ('CHAI' ' -'
  93. '----------------------------- TEST REUSSI ----------------------------'
  94. '-') ;
  95. 'FINS' ;
  96. 'FIN' ;
  97. 'OPTI' 'ECHO' 1 ;
  98.  
  99.  
  100.  
  101.  
  102.  
  103.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales